{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPCONG8)}}
====== IPCONG8 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:DCA|DCA]], [[george:macro:DESUSPEND|DESUSPEND]], [[george:macro:DSCA|DSCA]], [[george:macro:GPERIIPC|GPERIIPC]], [[george:macro:HUNT2|HUNT2]], [[george:macro:JDISENG|JDISENG]], [[george:macro:LOCK|LOCK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SIPCM|SIPCM]], [[george:macro:TIPCREP|TIPCREP]], [[george:macro:UNLOCK|UNLOCK]]
22FL SEG IPCONG,,JOHN BAILEY
22^= #
23DW SEGENTRY K1IPCONG,X1IPCONG
23YG SEGENTRY K2IPCONG,X2IPCONG
24D6 #
24XQ # STORED WORDS
25CB RESBITS #777700
25X2 TMESSCODES #04000040
26BL #04000041
26W= #04000042
27*W #04000043
27TG #04000046
28*6 #03000047
28SQ #07000060
29#B #07000061
29S2 #04000066
2=?L #03000067
2=R= #02000070
2?=W #02000071
2?QG #03000077
2#=6 TBIT1 #20000000
2#PQ TBIT2 #10000000
2*9B TBIT3 #4000000
2*P2 TBIT4 #2000000
2B8L TBIT5 #1000000
2BN= TBIT11 #10000
2C7W TTLIM +7 [MAX TASK NO + 1
2CMG TIPBACT +IPCA+IPCBX [TYPE OF IPB ACTIVITY
2D76 ROK #0
2DLQ RTO #22000000
2F6B RNI #02000000
2FL2 RNINE #02400000
2G5L OBJW #40000*IPCG4+#11
2GK= OBJR #40000*IPCG4+#12
2H4W # SUBROUTINE USED TO SET OBJECT PROGRAM REPLIES
2HJG #
2J46 SREL
2JHQ LDX 3 IPCPTR(2) [FIND IPC ACTIVITY
2K3B HUNT2 3,IPCD,IPSTACK [FIND STACK BLOCK
2KH2 LDX 1 ARINGNO(3)
2L2L ANDN 1 #7777
2LG= BZE 1 SFR1 [STACK EMPTY
2L^W ADN 3 A1
2MFG SFR3 LDX 0 ALINUM(3)
2M^6 BXE 0 ACOMMUNE1(2),SFR2
2NDQ ADN 3 ARECLEN
2NYB BCT 1 SFR3
2PD2 SFR1 NGN 3 #7777
2PXL SFR2 LDX 1 FX1
2QC= EXIT 7 0
2QWW # S/R TO LOCATE ACTIVITY OWNING A GEORGE LINK
2RBG SLACT LDX 2 FPTR(3) [CONTROL BLOCK
2RW6 SBN 2 A1
2S*Q SLACT1
2STB LDX 2 BPTR(2)
2T*2 LDX 0 ATYPE(2)
2TSL BXL 0 CACT,SLACT1
2W#= EXIT 7 0
2WRW # S/R TO SET REPLY ETC ON GEORGE LINK
2X?G SGCLR LDX 4 7
2XR6 CALL 7 SREL
2Y=Q LDX 2 FPTR(3)
2YQB STO 6 IPCGREP-A1(2) [STORE REPLY
2^=2 LDX 0 GSIGN
2^PL ORN 0 1
329= ERS 0 ASTATUS1(3) [UNSET T.I.P.
32NW STOZ ATIMCT(3)
338G STOZ ASTR(3)
33N6 STOZ ALENTR(3)
347Q STOZ ASTMEL(3)
34MB NGN 0 2
3572 ANDS 0 ASTATUS2(3)
35LL CALL 7 SLACT
366= DESUSPEND [DESUSPEND ACTIVITY
36KW MFREE IPCD,ATASK [FREE TASK BLOCK
375G EXIT 4 0
37K6 # ENTRY POINT FOR TRANSFER TASKS
384Q # FOR GEORGE LINKS
38JB #
3942 X1IPCONG
39HL TFRG MHUNT 3,IPCD,ATASK
3=3= LDX 0 A1(3)
3=GW STO 0 ACOMMUNE1(2) [LINK IDENTIFIER
3?2G CALL 7 SREL [LOCATE RING ELEMENT
3?G6 LDX 0 ASTATUS1(3)
3?^Q ANDN 0 1
3#FB BZE 0 P2
3#^2 LDX 0 GSIGN
3*DL ORS 0 ASTATUS1(3) [MARK TR IN PROGRESS
3*Y= # SET UP TRANSFER REQUEST MESSAGE
3BCW SMO ALTPROG(3)
3BXG LDX 0 TMESSCODES(1) [HEADER
3CC6 STO 0 IPWRB(2)
3CWQ LDX 0 ALINUM(3)
3DBB STO 0 IPWRB+1(2) [LINK IDENTIFIER
3DW2 LDX 0 ALENTR(3)
3F*L STO 0 IPWRB+2(2) [LENGTH OF TRANSFER
3FT= LDN 7 IPWRB(2)
3G#W SUM 6 3
3GSG NGS 6 IPWRB+3(2) [CHECKSUM
3H#6 # SET UP CONTROL AREA AND SEND MESSAGE
3HRQ #
3J?B # 1-WRITE PART
3JR2 LDN 0 #31
3K=L DCA ,DLA,0,MODE
3KQ= LDN 0 4
3L9W DCA ,DLA,0,COUNT
3LPG LDN 0 IPWRB(2)
3M96 DCA ,STO,0,CTSA
3MNQ # 2-READ PART
3N8B LDN 0 #32
3NN2 DSCA ,DLA,0,MODE
3P7L LDN 4 11
3PM= DSCA ,DLA,4,COUNT
3Q6W LDN 0 IPREB(2)
3QLG DSCA ,STO,0,CTSA
3R66 # 3-ISSUE PERI
3RKQ GPERIIPC ,2
3S5B ... TIPCREP ,TF1,TF2,TF3,TF4,TF6,TF2,TF5
3SK2 # VALDATE REPLY MESSAGE
3T4L LDX 0 CPRW2(2) [REPLY TO READ PART
3TJ= ANDN 0 #7777
3W3W SBX 4 0 [AMOUNT TRANSFERRED
3WHG LDCH 0 IPREB(2)
3X36 BXU 0 4,TF6 [COUNT WRONG
3XGQ LDN 7 IPREB(2)
3Y2B SMO 4
3YG2 SUM 6 0 [CALCULATE CHECKSUM
3Y^L BNZ 6 TF6 [J IF WRONG
3^F= LDX 0 IPREB+1(2)
3^YW SRC 0 12
42DG ERX 0 IPWRB+1(2)
42Y6 ANDN 0 #7777
43CQ BNZ 0 TF6 [WRONG LINK
43XB # SWITCH ON TYPE OF REPLY
44C2 CALL 7 SREL
44WL LDX 0 IPREB(2)
45B= ANDN 0 #77
45TW SBN 0 #47
46*G BZE 0 TFC [NO TRANSFER
46T6 SBN 0 #20
47#Q BZE 0 TFD [NO LINK
47SB ADN 0 #21
48#2 BNZ 0 TF6
48RL # DO ACTUAL TRANSFER
49?= #
49QW # 1-SWITCH ON TYPE OF ACCESS
4==G LDX 0 ASTMEL(3)
4=Q6 SMO 0
4?9Q BRN £
4?PB BRN TFABS
4#92 BRN TFBLK
4#NL BRN TFBFR
4*8= BRN TFACT
4*MW # 2-PREPARE FOR TRANSFER : ABS CASE
4B7G TFABS LDX 0 ASTR(3)
4BM6 BRN TFB
4C6Q # 3-PREPARE FOR TRANSFER : BLK CASE
4CLB TFBLK CALL 7 SLACT
4D62 LDX 6 ASTR(3)
4DKL ANDX 6 HALFTOP [TYPE OF BLOCK SPECIFIED
4F5= TFBK1 LDX 2 FPTR(2) [LOCATE SPECIFIED BLOCK ...
4FJW LDX 0 ATYPE(2)
4G4G ANDX 0 HALFTOP
4GJ6 BXU 0 6,TFBK1 [IF NOT FOUND,TRY NEXT
4H3Q LDX 6 2 [REMEMBER ADDRESS
4HHB LOCK 2
4J32 LDX 0 ASTR(3)
4JGL ANDN 0 #7777
4K2= ADX 0 6 [CALCULATE ABSOLUTE ADDRESS
4KFW BRN TFB
4K^G # 4-PREPARE FOR TRANSFER : BFR CASE
4LF6 TFBFR LDX 6 ASTR(3)
4LYQ ANDN 6 #7777
4MDB SETNCORE 6,1,IPCD,ATASK [SET UP BUFFER BLOCK
4MY2 CALL 7 SREL
4NCL LDX 0 ASTR(3)
4NX= ANDX 0 HALFTOP
4PBW STO 0 ATYPE(2) [RENAME
4PWG CALL 7 SLACT
4QB6 LDX 6 2
4QTQ CHAIN 1,2 [CHAIN BUFFER BLOCK
4R*B SMO 6
4RT2 LDX 2 FPTR
4S#L LOCK 2
4SS= SMO 6
4T?W LDX 0 FPTR
4TRG ADN 0 A1
4W?6 BRN TFB
4WQQ # 5-PREPARE FOR TRANSFER : ACT CASE
4X=B TFACT CALL 7 SLACT
4XQ2 LDX 6 2
4Y9L LOCK 2
4YP= LDX 0 ASTR(3)
4^8W ADX 0 6
4^NG # 6-SET UP CONTROL AREA
5286 TFB LDX 6 ALTPROG(3)
52MQ BZE 6 TFR [J IF READ
537B # WRITE PERI
53M2 DCA ,STO,0,CTSA
546L LDN 0 #11
54L= DCA ,DLA,0,MODE [MODE
555W LDX 6 IPREB+2(2) [DIFFERENCE IN COUNTS
55KG BPZ 6 TFW1 [ENOUGH
5656 NGS 6 AWORK4(2) [STORE REMAINDER
56JQ LDCT 0 #100
574B ORS 0 AWORK4(2) [AND LONG BLOCK BIT
57J2 ADX 6 IPWRB+2(2) [COUNT TO BE TRANSFERRED
583L BRN TFW2
58H= TFW1 STOZ AWORK4(2) [NO REMAINDER
592W LDX 6 IPWRB+2(2) [COUNT
59GG TFW2 DCA ,DLA,6,COUNT [STORE COUNT
5=26 # 6-DO TRANSFER
5=FQ GPERIIPC ,2,CT
5=^B ... TIPCREP CT,TF1,TF2,TF7,TF1
5?5? ... LDX 0 CPRW1(2) [REPLY WORD
5?98 ... ANDN 0 #7777 [LOOK FOR REMAINDER COUNT
5?*5 ... BNZ 0 TF6 [MAJOR ERROR IF SO
5?F2 BRN TFB1
5?YL TFR DSCA ,STO,0,CTSA [START ADDRESS
5#D= LDN 0 #12
5#XW DSCA ,DLA,0,MODE [MODE
5*CG LDX 6 IPREB+2(2) [DIFFERENCE
5*X6 BPZ 6 TFR1 [SUFFICIENT
5BBQ LDCT 0 #100
5BWB STO 0 AWORK4(2) [LONG BLOCK
5CB2 LDX 6 IPWRB+2(2) [COUNT
5CTL BRN TFR2
5D*= TFR1 STO 6 AWORK4(2) [RENAINDER
5DSW LDX 6 IPWRB+2(2)
5F#G SBX 6 IPREB+2(2) [COUNT
5FS6 TFR2
5G?Q DSCA ,DLA,6,COUNT [STORE COUNT
5GRB GPERIIPC ,2,SP
5H?2 ... TIPCREP SP,TF1,TF2,TF7,,TF1
5HQL # SET REPLY AND CLEAR UP
5J== TFB1 CALL 7 SREL [LOCATE ENTRY
5JPW SMO ASTMEL(3)
5K9G BRN £ [SWITCH
5KP6 BRN TFB2 [ ABS
5L8Q BRN TFB3 [ BLK
5LNB BRN TFB3 [ BFR
5M82 BRN TFB4 [ ACT
5MML # BLK & BFR CASES
5N7= TFB3 CALL 7 SLACT [FIND ACTIVITY BLOCK
5NLW LDX 6 ASTR(3)
5P6G ANDX 6 HALFTOP [TYPE
5PL6 TFB3A LDX 2 FPTR(2)
5Q5Q LDX 0 ATYPE(2)
5QKB ANDX 0 HALFTOP
5R52 BXU 0 6,TFB3A [NEXT
5RJL TFB3B UNLOCK 2
5S4= BRN TFB2
5SHW # ALT CASE
5T3G TFB4 CALL 7 SLACT [LOCATE ACT
5TH6 BRN TFB3B
5W2Q # SET REPLY
5WGB TFB2 LDN 6 0
5X22 JDISENG ,TFD1
5XFL LDCT 6 #10 [OPERABLE BIT
5X^= TFD1 ORX 6 AWORK4(2)
5YDW CALL 7 SGCLR
5YYG BRN NEXTASK
5^D6 TFC LDX 0 GSIGN
5^XQ ERS 0 ASTATUS1(3)
62CB MFREE IPCD,ATASK
62X2 BRN NEXTASK
63BL # NO LINK CASE
63W= TFD LDCT 0 #240
64*W ORS 0 ASTATUS2(3) [MARK DISEST REP
64FR ... LDN 0 #7777
64KN ... ANDS 0 ACOMMUNE1(2)
64PK ... ANDS 0 ALINUM(3)
64TG LDCT 0 #24
65*6 STO 0 AWORK4(2) [SET UP REPLY
65SQ BRN TFB2 [INSERT REPLY
66#B # ERROR CASES
66S2 TF1 LDX 6 TFREP(1) [TIME-OUT
67?L CALL 7 SGCLR
67R= BRN TIME
68=W TF2 LDX 6 TFREP(1) [RESET
68QG ORN 6 1
69=6 CALL 7 SGCLR
69PQ BRN RESETA
6=9B TF3 SIPCM SI [INOP(A)
6=P2 TF5 LDX 6 TIREP(1) [INOP(B)
6?8L TF5A CALL 7 SGCLR
6?N= BRN NOP
6#7W TF4 CALL 7 SREL
6#MG LDX 0 GSIGN
6*76 ERS 0 ASTATUS1(3)
6*LQ BRN NPUT
6B6B TF6 LDX 6 TFREP(1)
6BL2 ORN 6 2
6C5L CALL 7 SGCLR
6CK= BRN WHOOPS
6D4W TF7 LDX 6 TFREP(1) [INOP(C)
6DJG ORN 6 3
6F46 SIPCM SI
6FHQ BRN TF5A
6G3B TFREP #3200000
6GH2 TIREP #2000000
6H2L NPUT ACROSS IPCONA,2
6HG= NOPS SIPCM SI
6H^W NOP ACROSS IPCONE,2 [DEAL WITH INOPERABLE IPB
6JFG WHOOPS
6J^6 ACROSS IPCONE,1 [DEAL WITH ERROR
6KDQ RESETA
6KYB ACROSS IPCONE,3 [DEAL WITH ERROR DETECTED
6LD2 TIME
6LXL ACROSS IPCONE,5
6MC= P2 MFREE IPCD,ATASK
6MWW NEXTASK
6NBG ACROSS IPCON,1
6NW6 # S/R TO SET REPLY TO GEORGE TRANSFER
6P*Q SGSR
6PTB CALL 7 SREL
6Q*2 ...SGSR2 LDX 2 FPTR(3)
6QSL STO 6 IPCGREP-IPCRNG(2) [STORE REPLY
6R#= ... NGNC 0 2
6RRW ... ANDS 0 ASTATUS1(3)
6SR6 STOZ ATIMCT(3)
6T=Q STOZ ASTR(3)
6TQB STOZ ALENTR(3)
6W=2 NGN 0 2
6WPL ANDS 0 ASTATUS2(3)
6X9= STOZ ASTMEL(3)
6XNW CALL 7 SLACT [LOCATE ACTIVITY
6Y8G DESUSPEND [KICK IT
6YN6 EXIT 4 0
6^7Q # TRANSFERS FOR GEORGE IPC LINKS
6^MB #
7272 X2IPCONG
72LL TGL
736= # SEND O.K. MESSAGE
73B4 ... CALL 7 SREL
73KW LDX 0 TMESSCODES+4(1)
745G STO 0 IPWRB(2)
74K6 LDX 0 ACOMMUNE1(2)
754Q STO 0 IPWRB+1(2) [LINK IDENTIFIER
75JB ... LDX 0 ALTPROG(3)
7642 BNZ 0 TGL1 [THIS END WRITING
76HL LDX 0 ALENTR(3)
773= SBX 0 IPREB+2(2)
77GW BRN TGL2
782G TGL1 LDX 0 IPREB+2(2)
78G6 SBX 0 ALENTR(3)
78^Q TGL2 STO 0 IPWRB+2(2)
79FB LDN 7 IPWRB(2)
79^2 SUM 6 3
7=DL NGS 6 IPWRB+3(2) [CHECKSUM
7=Y= # SET UP CONTROL AREA AND SEND REPLY
7?CW LDN 0 #11
7?XG DCA ,DLA,0,MODE
7#C6 LDN 0 4
7#WQ DCA ,DLA,0,COUNT
7*BB LDN 0 IPWRB(2)
7*W2 DCA ,STO,0,CTSA
7B*L GPERIIPC ,2,CT
7BT= TIPCREP CT,TIME,RESETA,NOPS,WHOOPS
7C#W # PREPARE FOR TRANSFER
7CSG #
7D#6 # 1 - SWITCH ON TYPE OF ACCESS
7DRQ CALL 7 SREL [LOCATE RING ELEMENT
7F?B LDX 0 ASTMEL(3)
7FR2 SMO 0
7G=L BRN £
7GQ= BRN TGABS
7H9W BRN TGBLK
7HPG BRN TGBFR
7J96 BRN TGACT
7JNQ # 2 - ABS CASE
7K8B TGABS LDX 0 ASTR(3)
7KN2 BRN TGB [STARTOFTRANSFER
7L7L # 3 - BLK CASE
7LM= TGBLK CALL 7 SLACT
7M6W LDX 6 ASTR(3)
7MLG ANDX 6 HALFTOP
7N66 TGBLK1
7NKQ LDX 2 FPTR(2)
7P5B LDX 0 ATYPE(2)
7PK2 ANDX 0 HALFTOP
7Q4L BXU 0 6,TGBLK1
7QJ= LDX 6 2 [REMEMBER ADDRESS
7R3W LOCK 2 [LOCK BLOCK
7RHG LDX 0 ASTR(3)
7S36 ANDN 0 #7777
7SGQ ADX 0 6 [CALCULATE ABS ADDRESS
7T2B BRN TGB
7TG2 # 4 - BFR CASE
7T^L TGBFR LDX 6 ASTR(3)
7WF= ANDN 6 #7777
7WYW SETNCORE 6,1,IPCD,ATASK [BUFFER BLOCK
7XDG CALL 7 SREL
7XY6 LDX 0 ASTR(3)
7YCQ ANDX 0 HALFTOP
7YXB STO 0 ATYPE(1) [RENAME
7^C2 CALL 7 SLACT [LOCATE ACTIVITY
7^WL LDX 6 2 [ADDRESS
82B= CHAIN 1,2 [RECHAIN BLOCK
82TW SMO 6
83*G LDX 2 FPTR [RELOCATE BLOCK
83T6 LOCK 2 [LOCK IT
84#Q SMO 6
84SB LDX 0 FPTR [RELOCATE IT
85#2 ADN 0 A1
85RL BRN TGB
86?= # 5 - ACT CASE
86QW TGACT LDX 2 FPTR(3)
87=G SBN 2 A1
87Q6 CALL 7 SLACT [LOCATE ACTIVITY BLOCK
889Q LDX 6 2
88PB LOCK 2 [LOCK IT
8992 LDX 0 ASTR(3)
89NL ADX 0 6
8=8= # DO TRANSFER
8=MW #
8?7G # 1 - SET UP CONTROL AREA
8?M6 TGB LDX 6 ALTPROG(3)
8#6Q BZE 6 TGR [J IF READ
8#LB # WRITE PERI
8*62 DCA ,STO,0,CTSA [START ADDRESS
8*KL LDN 0 #11
8B5= DCA ,DLA,0,MODE [MODE
8BJW LDX 6 IPWRB+2(2) [DIFFERENCE IN COUNTS
8C4G BPZ 6 TGW1 [SUFFICIENT
8CJ6 NGS 6 AWORK4(2) [NOTE DIFFERENCE
8D3Q LDCT 0 #100
8DHB ORS 0 AWORK4(2) [LONG BLOCK BIT
8F32 ... LDX 6 IPREB+2(2) [COUNT TO BE TRANSFERRED
8FGL BRN TGW2
8G2= TGW1 STOZ AWORK4(2) [NO REMAINDER
8GFW ... LDX 6 ALENTR(3) [COUNT
8G^G TGW2 DCA ,DLA,6,COUNT [STORE COUNT
8HF6 # 2A - DO TRANSFER
8HYQ GPERIIPC ,2,CT
8JDB ... TIPCREP CT,TG1,TG2,TG3,TG1
8JJ? ... LDX 0 CPRW1(2) [REPLY WORD
8JN8 ... ANDN 0 #7777 [LOOK FOR REMAINDER CT
8JS5 ... BNZ 0 TG4 [MAJOR ERROR IF SO
8JY2 BRN TGB1
8KCL # READ PERI
8KX= TGR DSCA ,STO,0,CTSA [START ADDRESS
8LBW LDN 0 #12
8LWG DSCA ,DLA,0,MODE [MODE
8MB6 LDX 6 IPWRB+2(2) [DIFFERENCE
8MTQ BPZ 6 TGR1 [SUFFICIENT
8N*B LDCT 0 #100
8NT2 STO 0 AWORK4(2) [LONG BLOCK
8P#L LDX 6 IPREB+2(2) [COUNT
8PS= BRN TGR2
8Q?W TGR1 STO 6 AWORK4(2)
8QRG LDX 6 IPREB+2(2)
8R?6 ADX 6 IPWRB+2(2) [COUNT
8RQQ TGR2 DSCA ,DLA,6,COUNT [STORE COUNT
8S=B # 2B - DO READ TRANSFER
8SQ2 GPERIIPC ,2,SP
8T9L ... TIPCREP SP,TG1,TG2,TG3,,TG1
8TP= # 3 - SET REPLY AND CLEAR UP
8W8W TGB1 CALL 7 SREL [LOCATE ENTRY
8WNG SMO ASTMEL(3)
8X86 BRN £ [SWITCH
8XMQ BRN TGB2 [ABS
8Y7B BRN TGB3 [BLK
8YM2 BRN TGB3 [BFR
8^6L BRN TGB4 [ACT
8^L= # BLK AND BFR CASES
925W TGB3 CALL 7 SLACT [FIND ACTIVITY BLOCK
92KG LDX 6 ASTR(3)
9356 ANDX 6 HALFTOP [TYPE
93JQ TGB3A LDX 2 FPTR(2)
944B LDX 0 ATYPE(2)
94J2 ANDX 0 HALFTOP
953L BXU 0 6,TGB3A [NEXT
95H= TGB3B UNLOCK 2
962W BRN TGB2
96GG # ACT CASE
9726 TGB4 CALL 7 SLACT [LOCATE ACTIVITY
97FQ BRN TGB3B
97^B # CLEAR DETAILS
9=X6 # SET REPLY
9?BQ ...TGB2 LDN 6 0
9?WB JDISENG ,TGD1
9#B2 LDCT 6 #10
9#TL TGD1 ORX 6 AWORK4(2)
9**= ... CALL 4 SGSR2
9C?Q BRN NEXTASK
9CRB # ERROR CASES
9D?2 TG1 LDX 6 TFREP(1) [TIME-OUT
9DQL CALL 4 SGSR
9F== BRN TIME
9FPW TG2 LDX 6 TFREP(1) [RESET
9G9G CALL 4 SGSR
9GP6 BRN RESETA
9H8Q TG3 SIPCM SI [INOP
9HNB LDX 6 TIREP(1)
9J82 ... CALL 4 SGSR [SET REPLY
9JML BRN NOP
9JRH ...TG4 LDX 6 TFREP(1) [REMAINDER SEEN ON WRITE
9JXD ... CALL 4 SGSR
9K3* ... BRN WHOOPS
9K7= MENDAREA 1023-0?,K9IPCONG
9KLW #END
^^^^ ...52356416001000000000