{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPCOPENA83)}}
====== IPCOPENA83 ======
(George Source)
**Macros used:** [[george:macro:BBS|BBS]], [[george:macro:BBUS|BBUS]], [[george:macro:CAPCA|CAPCA]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CHECKEXT|CHECKEXT]], [[george:macro:CHEKPRIV|CHEKPRIV]], [[george:macro:FCJOB|FCJOB]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:GETACT|GETACT]], [[george:macro:GETNO|GETNO]], [[george:macro:GETWORD|GETWORD]], [[george:macro:HUNT2|HUNT2]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:INFIPCA|INFIPCA]], [[george:macro:LINK|LINK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCK|LOCK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:PUTPERENT|PUTPERENT]], [[george:macro:ROLPA|ROLPA]], [[george:macro:RTTEST|RTTEST]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TRACE|TRACE]], [[george:macro:TRUSTED|TRUSTED]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:WORDFIN|WORDFIN]]
22FL SEG IPCOPENA,,JOHN BAILEY.
22^= #
23DW #
23YG SEGENTRY K1IPCOPENA,X1IPCOPENA
24D6 #
24XQ #
25CB
25X2 SP #20
26BL REJR #42000000
26W= RESA #40000000
27*W OA #41
27TG OZ #73
28*6 XCA +5
28SQ XTA +CHREAD
29#B +CHREAD+CHWRITE
29S2 OPL LINK IPCPERI,1
2=?L XENL LINK IPCEN,1
2=R= PRHL LINK IPCPASS,1
2?=W #
2?QG #
2?S4 ...#UNS IPCPRIVSK
2?TL ...(
2?X8 ...# PRIV NAME TO BE FILLED IN BY IPCPRIV
2?YQ ... FIXTRA AIPCOPENA [++++++ IPCPRIV
2#2# ... 8H
2#3W ...NOPRIV
2#5D ... UNPLUG
2#72 ... ILLEGAL ILLNOPRIV [++++++ IPCPRIV
2#8J ...)
2#=6 X1IPCOPENA
2#?T ...#UNS IPCPRIVSK
2#*J ...(
2#C? ... FIXTRA BIPCOPENA [++++++ IPCPRIV
2#HJ ... NULL [SET TO BRN CIPCOPENA BY IPCREOFF
2#MW ...)
2#PQ # CHECK THAT PROGRAM REALTIME
2*9B RTTEST PST,,PCA,,
2*P2 UNPLUG
2B8L ILLEGAL NOTREAL
2BDD ...PST
2BN= # VALIDATE CONTROL AREA
2BQ8 ...#UNS IPCPRIVSK
2BS6 ...(
2BW4 ... FIXTRA CIPCOPENA
2BY2 ... BRN MAC [SET TO NULL BY IPCPRIV
2B^Y ... CHEKPRIV ,AIPCOPENA,NOPRIV
2C3W ...MAC
2C5S ...)
2CBM ... LDN 4 5
2CMG CHECKEXT EVENT2(2),4,PL1,2,W,P1,HLOCK1
2D76 # CHECK MODE
2DLQ P1 LDX 7 EVENT4(2)
2F6B TRACE 7,OPENPERI
2FL2 LDN 5 0
2G5L DLA 7 5
2GK= ERN 5 #400
2H4W BZE 5 P2
2HJG DLA 7 5
2J46 ERN 5 #200
2JHQ BZE 5 P2
2K3B DLA 7 5
2KH2 ERN 5 #1700 [TEST FOR ENQUIRY OPEN
2L2L BNZ 5 PL2 [IF NOT BRANCH TO ILLEGAL
2LG= #
2L^W # CODE FOR OPEN PERIS REQUESTING ENQUIRY FILES
2MFG LDX 6 EVENT3(2)
2M^6 STO 2 7
2NDQ LDX 4 EVENT2(2)
2NYB ADN 4 1
2PD2 UNPLUG
2PXL CAPCA
2QC= STO 4 AWORK4(2)
2QWW GETACT AOLPT,IPC,1
2RBG LDX 3 BPTR(2)
2RW6 LDX 0 JOBNO(2)
2S*Q STO 0 JOBNO(3)
2STB LDX 0 GSIGN
2T*2 STO 0 FRECHADD(3)
2TSL STO 0 GIVE(3)
2W#= LDN 4 ATMLI
2WRW STO 4 ATMARK(3)
2X?G STOZ ALINAME(3)
2XR6 STOZ ALINAME+1(3)
2Y=Q STOZ ALINAME+2(3)
2YQB LDN 4 #1700
2^=2 STO 4 ALINDIR(3)
2^PL LINKSET 3,XENL(1) [SET LINK TO IPCENQUIRY,1
329= ANDN 6 #77 [SET UP ENTRY FOR PRB
32NW STO 6 AUNNO(3)
338G LDCT 4 28
33N6 ADX 4 6
347Q LDX 5 GSIGN
34MB PUTPERENT 4,5
3572 ROLPA
35LL TRUSTED 7,PR1,Q
366= LDX 0 GSIGN [SET Q-TRUSTED MARKER
36KW STO 0 ALINAME(3)
375G PR1 LDX 5 AWORK4(2)
37K6 LDX 4 RESA(1)
384Q GETWORD 5,1,WRITE
38JB TESTREP OK,PR2
3942 WORDFIN
3=3= BRN OUTFN
3=GW PR2 STO 4 0(1)
3?2G WORDFIN
3?G6 FCJOB 3,FX2,,CPA,
3?^Q LDN 0 1 [REALTIME PERIPHERALS
3#9J ... FIXTRA FIPCOPENA [++++++ IPCREOFF
3#FB ADS 0 AEXCO(3)
3#^2 RUNPROG
3*DL #
3*Y= # CODE FOR OPEN PERIS REQUESTING NORMAL LINKS
3BCW P2 LDN 4 AWORK1(2)
3BXG LDX 3 EVENT2(2)
3CC6 ADN 3 2
3CWQ LDN 6 3
3DBB FOUTMOVE 2,3,4,6,HLOCK1,2
3DW2 LDN 3 AWORK1(2)
3F*L LDCH 5 0(3)
3FT= TXL 5 OA(1) [CHECK FILENAME VALID
3G#W BCS OUTFN
3GSG TXL 5 OZ(1)
3H#6 BCC OUTFN
3HRQ LDN 6 11
3J?B BCHX 3 £
3JR2 P3 LDCH 5 0(3)
3K=L TXL 5 OZ(1)
3KQ= BCC OUTFN
3L9W BCHX 3 £
3LPG BCT 6 P3
3M96 LDX 6 EVENT3(2) [READ IN PROPERTIES REQUESTED
3MNQ P4 LDX 2 FX2 [PROPERTIES REQUESTED AVAILABLE?
3N8B LDX 0 EVENT4(2)
3ND8 ... LDN 7 9 [HLOCKDOWN LENGTH
3NN2 BPZ 0 XM
3P7L LDX 1 EVENT3(2)
3PM= SRL 1 6
3Q6W BZE 1 XM
3QLG BBUS 15,1,X1
3R66 ERN 1 #740
3RKQ BZE 1 XM
3S5B ...X1 BBS 16,1,XM1 [J IF WMC REQUESTED
3SK2 HUNT2 1,IPCA,INTERN,2
3T4L LDX 0 APROPRES(1)
3TJ= BNZ 0 XM
3W3W LDX 1 FX1
3WHG LDX 5 EVENT2(2)
3X36 ADN 5 1
3XGQ BRN OUT1
3XJF ...# WMC REQUESTED
3XL8 ...XM1
3XMX ... LDX 1 EVENT4(2)
3XPL ... ANDN 1 #7777
3XR* ... SBN 1 #400
3XT4 ... BNZ 1 XM [J IF NOT WRITE
3XWR ...# WMC WRITE SPECIFIED
3XYG ... LDN 7 13 [HLOCKDOWN LENGTH
3Y2B XM LDX 1 FX1
3YG2 TRACE 2,TESTPROP
3Y^L BRN PL
3^F= OUT1 LDX 6 REJR(1)
3^YW LDX 5 EVENT2(2)
42DG ADN 5 1
42Y6 UNPLUG
43CQ CAPCA
43XB STO 5 AWORK4(2)
44C2 BRN OUT2
44WL PL GETNO 4
45B= LDX 5 EVENT2(2)
45TW ADN 5 1
46*G BNZ 4 PLA
46T6 BRN OUT1
47#Q # SET UP ENTRY FOR PRB
47SB ...PLA
48#2 ... LDX 3 EVENT4(2)
48RL UNPLUG
49?= CAPCA
49C7 ... STO 5 AWORK4(2)
49H4 ... LDX 5 6
49L^ ... ANDN 6 #77
4=6K ... LDCT 0 #34
4=L9 ... ORX 6 0
4?5T ... PUTPERENT 6,GSIGN
4#NL STO 6 ACOMMUNE1(2)
4#YD ... STO 3 ACOMMUNE2(2)
4*8= TRACE 6,PRBENT
4*MW # SET UP AOLPT BLOCK AND STORE DETAILS OF LINK
4*R2 ... LDX 6 7
4*W6 ...#SKI G4
4*^= ...(
4B4B ... TRACE 6,IPCLOCK [X6 = 9 OR 13
4B7G ... SETUPCORE 6,2,ADATA,HLOCKDOWN
4B=L ... SRL 6 2 [9 TO 2,13 TO 3
4B*Q ... STO 6 HLOCKBN(2) [SET ENTRY COUNT
4BDW ... STOZ HLOCKB1(2)
4BJ2 ... STOZ HLOCKB2(2)
4BM6 ... SBN 6 2
4BQ= ... BZE 6 OPA2 [J ONLY 2 ENTRIED
4BTB ... STOZ HLOCKB3(2)
4BYG ...OPA2
4C3L ...)
4C6Q GETACT AOLPT,IPC,1
4CLB ... LDX 6 5
4D62 LDX 3 BPTR(2)
4DKL TRACE 3,PTROLPA
4F5= STO 4 BLINO(3) [LINK NO
4FJW LDN 4 #777
4G4G SLL 4 6
4GJ6 ANDX 4 6
4H3Q BBUS 9,4,PR
4HHB SRL 4 6
4J32 ERN 4 #740
4JGL SLL 4 6
4K2= PR STO 4 AREQPR(3) [PROPERTIES REQUESTED
4KFW ANDN 6 #77
4K^G STO 6 AUNNO(3) [UNIT NO
4LF6 LDN 0 ATOVAL
4LYQ STO 0 ATOTIM(3) [TIMEOUT COUNT
4MDB LDX 0 GSIGN
4MY2 STO 0 FRECHADD(3)
4NCL LDN 4 AWORK1(2)
4NX= LDN 5 ALINAME(3) [LINK NAME
4PBW MOVE 4 3
4PWG LDX 0 JOBNO(2)
4QB6 STO 0 JOBNO(3) [JOB NO
4QTQ LDN 4 ATMLI
4R*B STO 4 ATMARK(3)
4RT2 STOZ ARINGEL+1(3)
4S#L LINKSET 3,OPL(1) [SET LINK TO IPCPERI,1
4SJD ... LDX 7 ACOMMUNE2(2)
4SS= ANDN 7 #777
4T?W STO 7 ALINDIR(3) [LINK DIRECTION
4TRG SRL 7 7
4W?6 SMO 7
4WQQ LDX 0 XTA-1(1)
4X=B STO 0 ATYPA(3)
4XQ2 LDX 0 GSIGN
4Y9L STO 0 GIVE(3)
4YP= LOCK 3
4^8W LDX 6 ACOMMUNE1(2)
4^NG LDX 7 BLINO(3)
5286 #SKI G4
52MQ MHUNTW 3,ADATA,HLOCKDOWN
537B ROLPA
53M2 #SKIP G4
546L (
54L= CHAIN 3,6
555W LDX 3 6
55KG )
5656 GETACT IPCA,HANGER
56JQ LDX 2 BPTR(2)
574B STO 7 HLINKIPC(2)
57J2 LINKSET 2,PRHL(1) [SET LINK TO IPCPASS,1
583L LDX 2 FX2
58H= # PUT LINK RECORD IN STACK AND WAKE UP IPC ACTIVITY
592W INFIPCA 3
59GG FCJOB 3,FX2,,CPA,
5=26 LDN 0 1
5=9Y ... FIXTRA EIPCOPENA [++++++ IPCREOFF
5=FQ ADS 0 AEXCO(3)
5=^B LDX 6 RESA(1)
5?F2 OUT2 LDX 7 AWORK4(2)
5?YL GETWORD 7,3,WRITE
5#D= TESTREP OK,PR3
5#XW WORDFIN
5*X6 BRN OUTFN
5BBQ PR3 STO 6 0(3)
5BWB WORDFIN
5CB2 RUNPROG
5CTL PL1 UNPLUG
5D*= ILLEGAL NOCA,
5DSW PL2 UNPLUG
5F#G ILLEGAL MODE,
5FS6 ...OUTFN
5G3Y ... UNPLUG
5G?Q ILLEGAL ILLINS
5GRB #
5H?2 #
5HQL MENDAREA 100,K2IPCOPENA
5J== #
5JPW #
5K9G #END
^^^^ ...34250153001600000000