{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPCPERI83)}}
====== IPCPERI83 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CANTR|CANTR]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CHECKB|CHECKB]], [[george:macro:CHECKEXT|CHECKEXT]], [[george:macro:CLEAR|CLEAR]], [[george:macro:CLEARALL|CLEARALL]], [[george:macro:CLINK|CLINK]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR3|COOR3]], [[george:macro:COOR4|COOR4]], [[george:macro:FCJOB|FCJOB]], [[george:macro:FINDACTFB|FINDACTFB]], [[george:macro:FINMOVE|FINMOVE]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:GDISREP|GDISREP]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT|HUNT]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:INFIPCA|INFIPCA]], [[george:macro:LINK|LINK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCK|LOCK]], [[george:macro:LOCKCA|LOCKCA]], [[george:macro:MASK|MASK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OLPFIN|OLPFIN]], [[george:macro:RELOFP|RELOFP]], [[george:macro:SCBB|SCBB]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TELEST|TELEST]], [[george:macro:TOPCA|TOPCA]], [[george:macro:TRACE|TRACE]], [[george:macro:TRAST|TRAST]], [[george:macro:TREQST|TREQST]], [[george:macro:TRIPB|TRIPB]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:UP|UP]]
22FL ... SEG IPCPERI,,KEITH MARTIN
22^= #
23DW #
23YG SEGENTRY K1IPCPERI,X1IPCPERI
24D6 SEGENTRY K3IPCPERI,X3IPCPERI
24XQ SEGENTRY K4IPCPERI,X4IPCPERI
25CB SEGENTRY K5IPCPERI,X5IPCPERI
25X2 #
26BL #
26FQ ...MINLENGTH +1
26JW ...MAXLENGTH +512
26N2 ...WMCREADMAX +601
26R6 ...MODE21 #21
26W= MASK #77777
27*W TOR #22400000
27TG RESPA #40000000
28*6 RESPR #42000000
28SQ XDIS #2400000
29#B ...YAM #27377777
29S2 XCA +4
2=?L PR1 LINK IPCPERI,4
2=R= PR2 LINK IPCPASS,1
2=YD ...P1IPCPERI
2?5L ... CLEAR APETADDR(2),0
2?=W X1IPCPERI
2?QG FINDACTFB 3,FX2,APET,,,BPTR
2#=6 TRACE 3,IPCPERI
2#PQ # VALIDATE CONTROL AREA
2*9B LOCKCA 3,EVENT2(2),,2 [CA IN HLOCK1 OF OLPA
2*P2 X5IPCPERI
2B8L S1 LDX 7 EVENT4(2)
2BN= TRACE 7,MOVEMODE
2C7W ANDX 7 MASK(1)
2CMG LDN 4 #5776
2D76 ANDX 4 7
2DLQ BZE 4 TRANS [J IF MODES 0,1,#2000 OR #2001
2DN7 ... LDX 4 MASK(1)
2DPJ ... ANDX 4 7 [GET MODE
2DQ^ ... ORN 4 #2000
2DSB ... ERN 4 #2000 [LOSE CONDITIONAL - IF ANY
2DTR ... BXU 4 MODE21(1),PE1 [J IF NOT MODE *21
2DX8 ... LDN 4 6
2DYK ... TRACE 4,IPCEXTCH
2F22 ... CHECKEXT EVENT2(2),4,NISA,3,W,TRANS,HLOCK1
2F3C ... BRN TRANS [J FOR MODE *21
2F4S ...PE1
2F6B LDN 4 #1000
2FL2 TXU 7 4
2G5L BCC XCANC
2GK= LDN 4 4
2H4W TXU 7 4
2HJG BCC XCANC
2J46 XNIS LDN 6 2
2JHQ BRN NIS
2K3B # EXTRACT C.A. DETAILS FROM OBJ PROG - I.E. SET :
2KH2 # X4=LENGTH,X5=BUFFER ADDRESS
2KQS ...# X6=LENGTH,X7=BUFFER ADDR FOR MODE *21 ZERO OTHERWISE
2L2L TRANS LDX 0 ALINDIR(2)
2LG= SRL 0 8
2LM^ ... LDN 6 1
2LTN ... ANDX 6 7 [X6= 0 READ , 1 WRITE
2M3C ... BXU 6 0,XNIS [J IF TRANS WRONG DIRN - ERROR
2M96 ... LDX 5 7
2MBT ... ANDN 5 #77
2MJJ ... BXU 5 MODE21(1),TR1 [J IF NOT MODE *21
2MQ? ... LDX 6 AREQPR(2)
2MY2 ... SRL 6 11
2N5P ... ANDN 6 3
2N?D ... BNZ 6 XNIS [J IF MODE *21 & NOT WMC REQUESTED
2NF7 ...TR1
2NLW ... STOZ ACOMMUNE3(2) [LENGTH-2 =0 IN CASE NOT M
2NSK ... STOZ ACOMMUNE4(2) [ALSO START ADDR 2
2P2# ... LDEX 5 7 [9 BITS OF MODE
2P83 ... LDN 7 2 [SET NOT MODE *21 INITIALLY
2P*Q ... BXU 5 MODE21(1),TR1A [J IF NOT MODE *21
2PHF ... LDN 7 4 [SET TO MOVE 4 WDS
2PP8 ...TR1A
2PWX ... LDX 4 EVENT2(2) [PTR TO CA
2Q4L ... ADN 4 2
2Q=* ... LDN 5 ACOMMUNE1(2) [READ IN TO ACOMMUNE1 ON
2QD4 ... FOUTMOVE 3,4,5,7,HLOCK1,2,1
2QKR ... LDX 4 ACOMMUNE1(2)
2QRG ... LDX 5 ACOMMUNE2(2)
2Q^9 ... LDX 6 ACOMMUNE3(2)
2R6Y ... LDX 7 ACOMMUNE4(2)
2R#M ...#
2RGB ...# NOW VALIDATE LENGTH OF TRANSFERS
2RN5 ... BXGE 4 MINLENGTH(1),SXA
2RTS ...S7
2S3H ... LDN 6 4
2S9= ... BRN NIS
2SB^ ...SXA
2SJN ... BZE 7 SXD [J IF NOT MODE 21
2SQC ... BXL 6 MINLENGTH(1),S7
2SY6 ...SXD
2T5T ...#
2T?J ... LDX 0 AREQPR(2)
2TF? ... BZE 0 SX1 [J IF NO REQUESTS
2TM2 ... SRL 0 11
2TSP ... ANDN 0 3
2W2D ... BZE 0 SX2 [J IF WMC REQUESTED
2W87 ...# NOT WMC REQUESTED
2W*W ...SX1
2WDP ... BNZ 7 XNIS [ILLEGAL MODE IF MODE *21 & NOT WMC O
2WHK ... BXL 4 MAXLENGTH(1),SX5
2WP# ... BRN S7 [ERROR
2WX3 ...# WMC REQUESTED
2X4Q ...SX2
2X=F ... LDX 0 ALINDIR(2)
2XD8 ... SBN 0 #200
2XKX ... BNZ 0 SX3 [J IF WRITE
2XRL ...# WMC READ
2X^* ... BXL 4 WMCREADMAX(1),SX5
2Y74 ... BRN S7 [ERROR
2Y#R ...# WMC WRITE
2YGG ...SX3
2YN9 ... LDEX 0 EVENT4(2)
2YTY ... BXE 0 MODE21(1),SX4 [J IF MODE *21
2^3M ...# WMC WRITE MODE 1
2^9B ... BXL 4 MAXLENGTH(1),SX5
2^C5 ... BRN S7 [ERROR
2^JS ...# WMC WRITE MODE *21
2^QH ...SX4
2^Y= ... LDX 0 4
325^ ... ADX 0 6
32?N ... BXGE 0 WMCREADMAX(1),S7
32FC ...SX5
32NW # VALIDATE DATA AREA
32YC ... CHECKB 5,4,NISB,3,ATYPA(2),S2A,,,P1IPCPERI
337Y ...S2A
33CF ... LDEX 0 EVENT4(2)
33M2 ... BXU 0 MODE21(1),S2Q [J IF NOT MODE *21
33WH ...# DONT OVERWRITE HLOCK3(OR TRY TO) IF TRANSFER STORED
3464 ... TRAST 0
34*K ... BNZ 0 R1 [J IF STORED TRANSFER
34K6 ...#
34SM ...#SKI G4
3548 ...(
35?P ... MHUNTW 2,ADATA,HLOCKDOWN
35H= ... SMO FX2
35QR ... STO 2 AWORK3
362# ... LOCK 2
369T ...)
36FB ... CHECKB 7,6,NISB,3,ATYPA(2),S2,HLOCKB3,AWORK3(2),P1IPCPERI
36NX ...S2
36YD ...#SKI G4
377^ ...(
37CG ... LDX 2 AWORK3(2)
37M3 ... UNLOCK 2
37WJ ...)
3865 ...S2Q
38*L ... LDX 2 FX2
38K7 ... STO 7 ACOMMUNE3(2) [START 2
38SN ... STO 6 ACOMMUNE4(2) [LENGTH 2
3949 ... LDX 7 EVENT4(2) [WD 0 OF CA
39?Q ... ANDX 7 MASK(1) [MODE
39*# ...# TEST FOR STORED TRANSFER
39BW ...# THIS HAS ALLREADY BEEN DONE FOR MODE *21
39DD ... TRAST 6
39G2 ... BNZ 6 RR [J IF STOTED TRANSFER
39GS ...XSB
39HL TELEST 6
3=3= BPZ 6 S3 [J IF ESTABLISHED OR UNESTABLISHED
3=GW ADN 6 1
3?2G BPZ 6 S4 [J IF JUST DISESTABLISHED
3?G6 LDX 1 ARINGEL(2)
3?^Q LDX 0 ASTATUS2(1)
3#FB SLL 0 5
3#^2 BPZ 0 S2AZ
3*DL SMO FX1
3*Y= LDX 0 YAM
3BCW ANDS 0 ASTATUS2(1)
3BXG LDCT 0 1
3CC6 ORS 0 ASTATUS2(1)
3CWQ LDX 1 FX1
3DBB BRN S2B
3DJL ...S2AZ
3DQW ... LDCT 6 #010
3D^6 ... ORS 6 ASTATUS2(1) [ MARK LINK OPEN IN PROGRESS
3F7B ... LDX 6 BLINO(2)
3F*L GETACT IPCA,HANGER
3FT= LDX 2 BPTR(2)
3G#W STOZ JSOURCE1(2)
3GSG STOZ JSOURCE2(2)
3H#6 STOZ JSOURCE3(2)
3HRQ STOZ HBRIN(2)
3J?B STO 6 HLINKIPC(2)
3JR2 LINKSET 2,PR2(1) [SET LINK TO IPCPASS,1
3KQ= HUNT 1,APERI,APROPNOS
3L9W BNG 1 NFGI
3LPG LDX 6 ALOGLEN(1)
3M96 SETUPCORE 6,3,APERI,APROPNOS
3MNQ CHAIN 3,BPTR(2)
3N8B MHUNT 2,APERI,APROPNOS
3NN2 LDN 2 A1(2)
3P7L LDN 3 A1(3)
3PM= SMO 6
3Q6W MOVE 2 0
3QLG NFGI LDX 2 FX2
3R66 INFIPCA 2
3RKQ FINDACTFB 3,FX2,APET,,,BPTR
3S5B S2B LDN 0 #2000
3SK2 ANDX 0 7
3T4L BZE 0 XGO
3TJ= LDN 5 TOR(1)
3W3W BRN RESPN
3WHG S4 GDISREP 2 [SET 'DISEST. REPLY GIVEN' MARKER
3X36 LDN 5 XDIS(1)
3XGQ BRN RESPN
3Y2B S3 LDN 6 #2000
3YG2 ANDX 6 7
3Y^L BZE 6 XGO [J IF NOT CONDITIONAL
3^F= TREQST 6
3^YW BZE 6 NOREQ [REJECT IF NO REQUEST STORED
42DG SMO AWORK1(2)
42Y6 LDX 1 ARINGEL(2)
43CQ LDN 6 4
43XB ORS 6 ASTATUS1(1) [MARK IF CONDITIONAL TRANSFER
44C2 LDX 1 FX1
44WL XGO LDN 6 RESPA(1)
453S ... STO 5 ACOMMUNE1(2) [START 1
4592 ... STO 4 ACOMMUNE2(2) [LENGTH 1
45B= LDX 7 EVENT2(2)
45TW ADN 7 1
46*G LDN 1 1
46T6 FINMOVE 3,7,6,1,HLOCK1,2,1
47#Q TRACE 6,IPFMOVE
47SB SCBB 2
48#2 ... TRIPB
48RL OLPFIN 3
49?= BRN K1IPCPERI
49QW NOREQ TELEST 6 [LINK ESTABLISHED?
4==G BNZ 6 RR
4=?H ... LDX 6 AREQPR(2)
4=#J ... BZE 6 XSA [J IF NO REQUESTS
4=*K ... SRL 6 11
4=BL ... ANDN 6 3
4=CM ... BNZ 6 XSA [J IF NOT WMC REQUESTED
4=DN ... SMO AWORK1(2)
4=FP ... LDX 6 ARINGEL(2) [PTR TO IPSTACK ENTRY
4=GQ ... LDCT 0 #010
4=HR ... SMO 6
4=JS ... ANDX 0 ASTATUS2
4=KT ... BZE 0 XSA [J IF NOT OPEN IN PROGRESS
4=LW ... COOR4 ATIMWT
4=MX ... BRN XSB
4=NY ...XSA
4=Q6 LDN 5 TOR(1)
4?9Q BRN RESPN
4?PB XCANC LDN 0 #1700
4#92 TXU 0 ALINDIR(2)
4#NL BCC XCANM
4*8= LDX 2 FX2
4*MW LDN 0 0
4B7G CANTR 0
4BM6 TRACE 6,IPCANC
4C6Q BNG 6 RR
4CLB XCANM LDN 5 RESPA(1) [SET ACCEPTED RESPONSE
4CYR ...RESPN
4D?8 ... LDX 6 EVENT2(2)
4DKL ADN 6 1
4F5= LDN 4 1
4FJW FINMOVE 3,6,5,4,HLOCK1,2,1
4G4G S6 SBN 7 #1000
4GJ6 BZE 7 XCLO
4GKN ...#SKI G4
4GM= ...(
4GNS ... LDX 2 ALINDIR(2)
4GQB ... SBX 2 #400
4GRY ... BNZ 2 S6XY [J IF READING
4GTG ... MHUNTW 2,ADATA,HLOCKDOWN
4GX4 ... CLEARALL 3,0,2
4GYL ...S6XY
4H28 ...)
4H3Q OLPFIN 3
4HHB BRN K1IPCPERI
4J32 XCLO LDCT 6 28
4JGL LDX 0 GSIGN
4K2= ORS 0 BLINO(2)
4KFW LDX 5 AUNNO(2)
4K^G ADX 5 6
4LF6 TRACE 5,IPRELOF
4LYQ RELOFP 5
4M2^ ...# TEST LEGALITY OF LENGTH+ADDR WHEN STORED
4M58 ...# TRANSFER - SAVES HLOCKB3
4M7C ...R1
4M9L ... CLEAR 3,0,HLOCK2,1 [CLEAR BEFORE USING
4M?T ... CHECKB 7,6,NISB,3,ATYPA(2),R2,HLOCK2,,P1IPCPERI
4MB4 ...R2
4MDB #
4MY2 # LOAD REJECTED RESPONSE
4NCL RR LDN 5 RESPR(1)
4NX= BRN RESPN
4PBW # REPORT ILLEGAL OBJ PROG EVENT
4PWG NISA LDN 6 1
4QB6 BRN NIS
4QTQ NISB LDN 6 3
4R*B NIS STO 3 7
4RT2 TOPCA PR1(1)
4S#L COOR1
4SS= BRN K1IPCPERI
4T?W X3IPCPERI
4TRG # ENTERED FROM RELPERENT.
4W?6 TRACE 3,ENFRELIP
4WQQ LDX 7 BLINO(3)
4X=B BNG 7 NA
4XQ2 LDX 4 ALINDIR(3)
4Y9L LDN 5 #1700
4YP= TXU 4 5
4^8W BCC NC
4^NG NBA CANTR 3
5286 BPZ 6 NC
52MQ COOR3 #41
537B BRN NBA
53M2 NB FINDACTFB 3,,AOLPT,,,FPTR
546L LDX 0 BLINO(3)
54L= TXU 0 7
555W BCS NB
55KG NA LDX 0 GSIGN
5656 ERS 0 BLINO(3)
56JQ NC CLINK 3
574B FCJOB 3,FX2,,CPA,
57J2 LDN 0 1
57RS ... FIXTRA AIPCPERI [++++++ IPCREOFF
583L SBS 0 AEXCO(3)
58H= UP
592W X4IPCPERI
59GG TRACE 0,IPERPERI
5=26 UNPLUG
5=FQ SMO 6
5=^B X BRN X
5?F2 BRN NOC
5?YL BRN NMO
5#D= BRN NOB
5#XW BRN NCT
5*CG GEOERR 1,IPCP
5*X6 NOC ILLEGAL NOCA,
5BBQ ...NMO ILLEGAL MODE,
5BWB NOB ILLEGAL NOBUF,
5CB2 NCT ILLEGAL COUNT
5CTL #
5D*= #
5DSW MENDAREA 100,K2IPCPERI
5F#G #
5FS6 #
5G?Q #END
^^^^ ...51577573003500000000