{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPDBATCH867)}}
====== IPDBATCH867 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:APROPNAME|APROPNAME]], [[george:macro:CLOSE|CLOSE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2OPT|HUNT2OPT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:UP|UP]]
22FL ... SEG IPDBATCH,1, KEVIN WORVILL,,G269,G170
22^= ...#OPT G170 = 0
23DW ...# FOR UGUG EDIT M269 (REMOTE *LP LISTFILE DEBATCHERS)
23YG ...#SKI G170&1
24D6 ...# WITH UGUG EDIT M170 (VARIABLE REMOTE *LP WIDTHS)
24XQ ... SEGENTRY K1IPDBATCH,STARTLF
25CB ... SEGENTRY K2IPDBATCH,NDLF
25X2 ...UEAZ 4HZZZZ
26BL ...UEA1 #01010101
26W= ...UEA40 #40404040
27*W ...XUEA2 12H
27TG ...NEWLINES #76207632
28*6 ...[
28SQ ...[************************************************************
29#B ...[
29S2 ...STARTLF
2=?L ...[
2=R= ...[************************************************************
2?=W ...[
2?QG ...[ SET UP AND OUTPUT DEBATCHER LINES FOR LP DOCS.
2#=6 ...[
2#PQ ... STOZ AWORK4(2) [ FLAG START LF
2*9B ...# GET PROPERTY NAME
2*P2 ... OPENSYS ,PROPERTY,READ
2B8L ... MHUNTW 3,GOUT,GPROPNOS
2BN= ... APROPNAME GPROPNUM(3),0,XUEA4
2C7W ... CLOSE
2CMG ... BRN XUEA5
2D76 ...XUEA4 CLOSE
2DLQ ... BRN XPROP
2F6B ...[
2FL2 ...[************************************************************
2G5L ...[
2GK= ...NDLF
2H4W ...[
2HJG ...[************************************************************
2J46 ...[
2JHQ ... LDCT 0 #400
2K3B ... STO 0 AWORK4(2) [ FLAG END LF
2KH2 ... MHUNTW 3,AMXOR,ADCB
2L2L ... LDX 0 IMDNPU(3)
2LG= ... ANDN 0 #7777
2L^W ... SLL 0 2
2MFG ... STO 0 AWORK3(2) [ NPU SIZE CHARS
2M^6 ...# AWORK3 ALREADY SET UP AT LF START
2NDQ ...XPROP LDN 3 XUEA2(1)
2NYB ... LDN 4 ACOMMUNE1(2)
2PD2 ... MOVE 3 3 [ NO PROP
2PXL ...XUEA5
2QC= ...# GET IUSER/BATCHC FOR DEBATCHER
2QWW ... MHUNTW 3,AMXOR,ADCB
2RBG ... LDX 4 IDENTNO(3)
2RW6 ... LDX 3 IADIN(3) [POINTER TO AMOP/IPBIN
2S*Q ... HUNT2OPT 3,IUSER,BATCHC
2STB ... LDX 7 ALOGLEN(3)
2T*2 ... SBN 7 2 [ GETS LAST ID FIRST
2TSL ...NRJE SMO 7
2W#= ... TXU 4 A1(3) [CHECK ID OF PRINTER
2WRW ... BCC YGOT
2X?G ... SBN 7 2 [ 2 WORD ENTRIES ID/DEBATCHER
2XR6 ... BPZ 7 NRJE [ NEXT ONE DOWN
2Y=Q ...XRJE GEOERR 1,UEARJELF [ RIGHT ENTRY NOT FOUND
2YQB ...YGOT ADX 3 7
2^=2 ... ADN 3 1 [ X3 POINTS TO DEBATCHER WORD
2^PL ... LDX 7 A1(3) [ CURRENT DEBATCHER WORD
329= ... LDX 4 AWORK4(2) [ 0=START, B0=END OF LF
32NW ... BNZ 4 NDBCH [ DONT UPDATE AT END
338G ... TXU 7 UEAZ(1) [ Z YET ?
33N6 ... BCS XZ [ NO
347Q ... LDX 7 UEA40(1)
34MB ...XZ ADX 7 UEA1(1)
3572 ... STO 7 A1(3) [ UPDATE DEBATCH WORD
35LL ...NDBCH STO 7 AWORK4(2) [ SAVE DEBATCH WORD
366= ... CALL 7 SETU [ GET FIRST BLOCK
36KW ... LDX 2 FX2
375G ... LDN 0 4 [ LINES OF DEBATCHERS
37K6 ...NDBL STO 0 AWORK2(2) [ SAVE LINE COUNT
384Q ...#SKI G170&1$1
38JB ... LDN 7 128 [ ENOUGH CHARS FOR 1 LINE
3942 ...#SKI G170&1
39HL ...(
3=3= ... LDN 7 8
3=GW ... ADX 7 IWIDTH(2)
3?2G ...)
3?G6 ... CALL 6 YETFL [ NEW BLOCK IF FULL/NO ROOM
3?^Q ... LDX 2 FX2
3#FB ... LDN 4 ACES
3#^2 ... MVCH 4 3 [ SPACE FILL REMAINDER LAST WORD
3*DL ... ANDX 5 BITS22LS [ #17777777
3*Y= ... LDN 4 NEWLINES(1)
3BCW ... MOVE 4 1
3BXG ... ADN 5 1 [ INSERT NEW LINE,UPDATE POINTER
3CC6 ... LDN 4 ACOMMUNE1(2)
3CWQ ... MOVE 4 3 [ MOVE IN PROPERTY NAME
3DBB ... ADN 5 3 [ UPDATE COUNT
3DW2 ... LDN 4 AWORK4(2) [ DEBATCHER
3F*L ... MOVE 4 1
3FT= ...#SKI G170&1$1
3G#W ... LDN 3 26
3GSG ...#SKI G170&1
3H#6 ...(
3HRQ ... LDX 3 IWIDTH(2)
3J?B ... SRL 3 2
3JR2 ... SBN 3 4
3K=L ...)
3KQ= ... LDX 4 5
3L9W ... ADN 5 1
3LPG ... MOVE 4 0(3) [ FILL LINE
3M96 ... ADX 5 3 [ UPDATE COUNT
3MNQ ... LDX 0 AWORK2(2) [ DEBATCHER LINE COUNT
3N8B ... BCT 0 NDBL [ NEXT LINE
3NN2 ... LDN 4 NEWLINES(1)
3P7L ... MOVE 4 1
3PM= ... ADN 5 1
3Q6W ...# NOW TIDY UP FOR IPBOUT
3QLG ... MHUNTW 2,AMXOR,IOUT
3R66 ... SBN 5 IDATA(2)
3RKQ ... SLC 5 2
3S5B ... DSA 5 IPBIDE+1(2) [ OUTPUT CHAR COUNT
3SK2 ... ADN 5 IDATA-A1*4+3
3T4L ... SRL 5 2
3TJ= ... ALTLEN 2,5 [ SHORTEN AMXOR-IOUT FOR IPBOUT
3W3W ... LDX 7 AWORK1(2)
3WHG ... STO 7 ACOMMUNE1(2) [ SAVE BLOCK COUNT
3X36 ... UP
3XGQ ...[ FOLLOWING CODE AS IN IPBLISTA
3Y2B ...[************************************************************
3YG2 ...[
3Y^L ...SETU
3^F= ...[
3^YW ...[************************************************************
42DG ...[
42Y6 ...#
43CQ ...# GET AMXOR/IOUT BLOCK FOR OUTPUT ; ON ENTRY MESSAGE CHAR CT. IN X4
43XB ...#
44C2 ... SMO FX2
44WL ... LDX 4 AWORK3 [NPU SIZE IN CHARS
45B= ...[
45TW ...[************************************************************
46*G ...[
46T6 ...PCOR
47#Q ...[
47SB ...[************************************************************
48#2 ...[
48RL ... SBX 7 FX1
49?= ... LDX 5 4
49QW ... ADN 5 IDATA-A1*4+3 [ROUND UP
4==G ... SRL 5 2 [NO. OF WORDS IN OUTPUT
4=Q6 ... SETUPCORE 5,2,AMXOR,IOUT,1
4?9Q ... STOZ IMOPTY(2) [DON'T WAKE UNLESS LAST BLOCK
4?PB ... LDN 0 1
4#92 ... SMO FX2
4#NL ... ADS 0 AWORK1 [COUNT OF BLOCKS FOR OUTPUT
4*8= ... MHUNTW 1,AMXOR,ADCB
4*MW ... LDX 5 IDENTNO(1)
4B7G ... STO 5 IPBIDE(2) [IDENTIFIER NUMBER
4BM6 ... LDX 1 FX1
4C6Q ... ORX 4 GSIGN
4CLB ... STO 4 IPBIDE+1(2) [OUTPUT CHARACTER COUNT
4D62 ... LDN 5 IDATA(2) [START ADDRESS OF OUTPUT
4DKL ... ADX 7 FX1
4F5= ... STOZ IBSW(2) [BLOCK STATUS WORD
4FJW ... EXIT 7 0
4G4G ...[
4GJ6 ...[************************************************************
4H3Q ...[
4HHB ...YETFL
4J32 ...[
4JGL ...[************************************************************
4K2= ...[
4KFW ...#
4K^G ...# GET NEW AMXOR/IOUT BLOCK IF NOT ENOUGH ROOM FOR NEXT MOVE OR MVCH
4LF6 ...#
4LYQ ... MHUNTW 2,AMXOR,IOUT
4MDB ... ADX 2 ALOGLEN(2)
4MY2 ... ADN 2 A1 [POINT TO WORD AFTER BLOCK
4NCL ... SBX 2 5 [DCH POINTER IN X5
4NX= ... SLC 2 2 [GET AMOUNT OF ROOM LEFT
4PBW ... TXL 7 2 [X7 CONTAINS COUNT OF CHARS TO INSERT
4PWG ... BCS (6) [ENOUGH ROOM : EXIT
4QB6 ...[
4QTQ ...[************************************************************
4R*B ...[
4RT2 ...UZNEWIO
4S#L ...[
4SS= ...[************************************************************
4T?W ...[
4TRG ... SBX 6 FX1
4W?6 ... MHUNTW 2,AMXOR,IOUT
4WQQ ... SBN 5 IDATA(2)
4X=B ... SLC 5 2
4XQ2 ... DSA 5 IPBIDE+1(2) [OUTPUT CHAR COUNT
4Y9L ... ADN 5 IDATA-A1*4+3
4YP= ... SRL 5 2
4^8W ... ALTLEN 2,5 [SHORTEN AMXOR/IOUT FOR IPBOUT
4^NG ... CALL 7 SETU [GET NEW AMXOR/IOUT
5286 ... ADX 6 FX1
52MQ ... LDX 3 2 [AMXOR/IOUT ADDRESS FOR MAIN PATH
537B ... EXIT 6 0
53M2 ...[
546L ...[
54L= ...#END
####
##RY ...
^^^^ ...771370340012