{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPLPM84)}}
====== IPLPM84 ======
(George Source)

**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:SEG|SEG]], [[george:macro:WRONG|WRONG]]

<code - IPLPM84.txt>22FL ...      SEG IPLPM,84,.    LEONARD COHEN - DSO.,IPL
24D6    #   
24XQ    #     PLEASE RETURN EDIT LISTINGS TO MARY WILSON.   
25CB    #   
25X2    #     THIS SEGMENT RESETS 1900-7600 COUPLERS. IT HAS NULL EFFECT ON 
26BL    #     CONFIGURATIONS WITHOUT A 7600.
26W=    #   
27*W    #     IF, AT ERROR TIME, PERIS WERE IN PROGRESS THEY MUST BE TERMINATED,
27TG    #     OTHERWISE THEY WOULD CONTINUE, POSSIBLY AFTER GEORGE HAD BEEN RE- 
28*6    #     LOADED, WITH DISASTEROUS RESULTS. 
28SQ    #   
29#B    #     THE RESET MODE PERIS RAISE THE G LINE ON THE INTERFACE - FOR  
29S2    #     COUPLER OUTWARDS (TYPE 46) G RESET TERMINATES THE CURRENT TRANSFER
2=?L    #     FOR COUPLER INWARDS (TYPE 47) G RESET CAUSES THE COUPLER TO   
2=R=    #     DISCARD THE REST OF THE CURRENT TRANSFER. ANY PERIS THAT WERE IN  
2?=W    #     PROGRESS ARE TERMINATED WITH THE REPLY 'TERMINATED: RESET'.   
2?QG    #   
2#=6    #     THE RESET PERIS ARE, IN EFFECT, INSTANTANEOUS EXECUTIVE MODE SUB- 
2#PQ    #     ROUTINES. THERE ARE NO REPLIES, RESPONSES OR END OF TRANSFER  
2*9B    #     EVENTS, EXECPT FOR THE EFFECT ON OUTSTANDING PERIS.   
2*P2    #   
2B8L    #     FOR MORE DETAILED DESCRIPTIONS SEE THE EXECUTIVE  
2BN=    #     AND HARDWARE SPECIFICATIONS.  
2C7W    #   
2CMG    K1IPLPM                            [ENTERED FROM PMDR   
2D76    #   
2DLQ          BVCR  £                      [CLEAR OVERFLOW  
2F6B          LDN   3  JPTI+46-1           [SET ADDRESS OF FIRST DEVICE TYPE - 1
2FL2          LDN   7  10                  [SET FIRST RESET MODE PLUS 2 
2G5L    NEXTYPE 
2GK=          ADN   3  1                   [ADDRESS OF BDT  
2H4W          SBN   7  1                   [9 FOR 46, 8 FOR 47  
2HJG          LDX   2  0(3)                [BDT ADDRESS 
2J46    NEXTDEVICE  
2JHQ          BXE   2  1(3),MORE           [J IF NO MORE OF THIS TYPE   
2K3B          LDX   1  0(2)                [ADDRESS OF DEVICE TABLE 
2KH2          LDXC  0  K52+1(1) 
2L2L          BCS      WRONG               [J IF WRONGED
2LG=          LDX   6  K50(1)              [KEEP CURRENT PERI MODE IF ANY   
2L^W          STO   7  K50(1)              [SET APPROPRIATE RESET MODE  
2MFG ...      PERI  0  1                   [ISSUE REST TO DEVICE
2M^6          STO   6  K50(1)              [RESTORE PREVIOUS MODE   
2NDQ    WRONG   
2NYB          ADN   2  1
2PD2          BRN   NEXTDEVICE             [GO FOR NEXT DEVICE  
2PXL    MORE
2QC=          BVCI  NEXTYPE                [J FOR TYPR 47   
2QWW          BRN   (JPMSEG)               [J TO NEXT PM OVERLAY
2RBG          FIXTRA   K2IPLPM  
2RW6    #GAP  20
2S*Q    #END
^^^^ ...01236634000200000000
</code>