{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: JOBLIST867)}}
====== JOBLIST867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLENG|ALTLENG]], [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DELETE|DELETE]], [[george:macro:DOWN|DOWN]], [[george:macro:FILEMOVE|FILEMOVE]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FOX|FOX]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INSERT|INSERT]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JLADJUST|JLADJUST]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:JOBSOURCE|JOBSOURCE]], [[george:macro:JWWFUPDATE|JWWFUPDATE]], [[george:macro:MBS|MBS]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:NEWJBNUM|NEWJBNUM]], [[george:macro:ON|ON]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:POP|POP]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SKIP|SKIP]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:STEPREWRITE|STEPREWRITE]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VOP|VOP]], [[george:macro:WRITEJL|WRITEJL]]
22FL #LIS K0JOBLIST>K0HLS>K0GREATGEO>K0ALLGEO
22MW ... SEG JOBLIST,867,SECTION CENT
22W6 ...[
234B ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23=L ...[
23DW #OPT WELLTEST=0
24D6 [
24XQ [ ENTRY POINTS
25CB [
25X2 SEGENTRY K1JOBLIST,XK1 [APPEND RECORD
26BL SEGENTRY K2JOBLIST,XK2 [DELETE RECORD
26W= SEGENTRY K3JOBLIST,XK3 [DELETE RECORD X6 = JOBNO
27*W SEGENTRY K4JOBLIST,XK4 [ DELETE A RECORD...
27TG [
28*6 [ USED IN ABANDON BEFORE USER CONTEXT IS GAINED
28SQ [ EG BREAKIN DURING WAIT ON LOGIN
29#B [
29S2 SEGENTRY K5JOBLIST,XK5 [ DELETE USER ENTRY ONLY
2=?L [
2=R= [ USING A JWELL,COPYSYS BLOCK
2?=W [
2?*F ...[
2?D4 ...[ THIS ENTRY POINT IS USED BY THE ABANDON(TEMP) COMMAND
2?GM ...[
2?K= ... SEGENTRY K6JOBLIST,XK6
2?LH ... SEGENTRY K7JOBLIST,XK7
2?MC ... SEGENTRY K8JOBLIST,XK8
2?MM ... SEGENTRY K9JOBLIST,XK9
2?MQ ... SEGENTRY K10JOBLIST,XK10 [USED BY JLASLOST MACRO
2?MT ...[
2?QG SEGENTRY K99JOBLIST
2#=6 [
2#PQ [
2#^J ... BITDEFS AWORK4,0,TEMP,POPPED,MONEY
2*6Q ... BITDEFS AWORK4,3,XFROZEN,XJLCH
2*9B [
2*P2 #DEF SZAJDF=JDFLANG-JOBCURDIR+3
2B8L #DEF RRH=A1+FRH
2BN= XTAB +IVTP
2C7W +IVLP
2CMG +IVCP
2D76 MASQ #20000000
2DLQ PCON #700000
2F6B N512 +512
2FL2 MSECS 1000
2G5L [
2GK= [
2H4W #DEF SIZELIST=10
2HJG XJOBLIST +SIZELIST
2J46 12H
2JHQ 12HJOBLIST
2K3B 1
2KH2 1
2L2L 4H****
2LG= TLANG 4HB5B1
2LQ3 ...STYLE #31
2LSL ... #32
2L^W [
2MFG [
2M^6 [
2NDQ [
2NYB [
2TSL [
2W#= [ THIS SEGMENT SETS UP THE ENTRY FOR JOBDATA IN THE SYSTEM/JOBLIST
2WRW [ FILE.
2X?G [ THIS SEGMENT IS MAINLY USED FOR CREATING THE SYSTEM
2XR6 [ AND USER JOBLIST ENTRIES. THE USER JOBLIST ENTRY IS WRITTEN
2Y=Q [ WITH THE ASSUMPTION THAT THE FILE IS OPEN AND POSITIONED
2YQB [ CORRECTLY FROM A PREVIOUS GETJOB.... THE SYSTEM JOBLIST
2^=2 [ ENTRY IS LEFT IN CORE AS A FILE/FRB BLOCK
2^PL [
329= [
32NW [
338G XK1
33D? ... LDX 0 ACOMMUNE2(2)
33GW ... DEX 0 AWORK1(2) [SAVE JD PARAM NO., BUT KEEP B0 !!
33N6 MHUNTW 3,JWELL,COPYSYS
347Q ADN 3 RRH
34MB NEWJBNUM 5
3572 STO 5 JLJOBNO(3)
35LL TRACE 5,JOBLIST
366= [
36KW [
375G LDX 4 CLEANCT [ ARRIVAL TIME
37K6 LDN 5 0
384Q LDN 6 K9
38JB MPY 4 6
3942 DVR 4 MSECS(1)
39HL STO 5 JLARRIVET(3) [ IN JOB BLOCK
3=3= [
3=GW LDX 5 EDATE [ ARRIVAL
3?2G STO 5 JLARRIVED(3) [ DATE
3?G6 [
3?^Q LDN 4 CPREFIX(2) [ NO-USER CONTEXT USERNAME
3#FB LDX 0 CONTEXT(2)
3#^2 ANDN 0 1
3*DL BZE 0 XM
3*FX ...#UNS G400
3*H8 ...(
3*JF ... LDX 4 2
3*KQ ... HUNTW 2,IUSER,G400USER
3*M3 ... BNG 2 X1HOOK
3*N# ... LDN 4 A1(2)
3*PK ... LDX 2 FX2
3*QW ... BRN XM
3*S7 ...X1HOOK
3*TD ... LDX 2 4
3*WP ...)
3*Y= FJOCA 2
3BCW LDN 4 JUSER(2) [ USER CONTEXT USERNAME
3BXG LDX 2 FX2
3CC6 XM LDN 5 JLUSER(3)
3CWQ MOVE 4 3
3DBB [
3DW2 LDX 0 JSOURCE3(2) [ CONSOLE PROPERTY NUMBER
3F*L STO 0 JLPROPNO(3)
3FT= [
3G#W JOBSOURCE
3GSG MHUNTW 3,JWELL,COPYSYS
3H4? ... LDN 5 0
3H6W ...SETASSOCS
3H#6 JLADJUST 3
3HRQ HUNT 2,APERI,ASSOCS
3J?B BNG 2 NASS [ J IF NO ASSOCIATIONS
3JR2 LDN 1 JLASSOCS(3) [ ADDRESS FOR ASSOCIATIONS
3K=L LDX 4 A1(2) [ NO OF ASSOCS
3KQ= BZE 4 NASS1
3L9W XASN LDN 2 A1+1(2)
3LPG XASNX LDX 3 FX1
3M96 LDN 7 2
3MNQ [
3N8B [ LOOK FOR PERIPHERAL TYPE OF ASSOCIATION
3NN2 [
3P7L XAS
3PM= SMO 7
3Q6W LDX 0 XTAB(3)
3QLG ANDX 0 0(2)
3R66 BZE 0 XNOAE
3RKQ [
3S5B [ TYPE FOUND SO ENTER IN JOBLIST RECORD
3SK2 [
3T4L SMO 7
3TJ= LDX 0 0(1)
3W3W [
3WHG [ ONLY ACCPET THEFIRST ASSOCIATION FOR A PROPERTY
3X36 [
3XGQ BNZ 0 XNOAE
3Y2B LDX 0 1(2)
3YG2 [ PROPERTY
3Y^L SMO 7
3^F= STO 0 0(1)
3^YW XNOAE SBN 7 1
42DG [
42Y6 [ CHECK OTHER PERI TYPES
43CQ [
43XB BPZ 7 XAS
44C2 [
44WL [ FOLLOWED BY OTHER PROPERTIES
45B= [
45TW ADN 2 ASSOCSLEN
46*G BCT 4 XASNX
46T6 [
47#Q [ LEAVE BLOCK AS AT START
47SB [
48#2 MHUNT 3,JWELL,COPYSYS
48RL JLADJUST 3
49?= NASS1 LDX 1 FX1
49QW NASS LDX 2 FX2
4=CN ... BNZ 5 (5)
4=Q6 [
4?9Q LDX 0 JSOURCE3(2)
4?PB BZE 0 NOTR
4#92 BS 3,JLBCLUS [ REMOTE BIT
4#NL [
4*8= NOTR LDX 4 AWORK2(2)
4*MW BPZ 4 NOTM [ J IF NOT MOP
4B7G BS 3,JLBMOP [ SET MOP BIT
4BM6 ADN 4 1
4C6Q BZE 4 SLN
4CLB BS 3,JLBDC [ MUST BE DC
4D62 BRN SALL
4DKL SLN BS 3,JLBLN [ SET LOGIN BIT
4F5= BRN SALL
4FJW NOTM BZE 4 SJB
4G4G BS 3,JLBRJ [ RJ
4GJ6 BRN SALL
4H3Q SJB BS 3,JLBJB [ JB
4HHB SALL LDXC 0 CONTEXT(2)
4J32 BCC SOUTB [ J IF NOT SYSTEM ISSUED
4JGL BS 3,JLBSYSIS
4K2= ...SOUTB LDX 0 CLONG1(2) [ DEAL WITH B/S PRIVS
4KFW ANDX 0 MASQ(1)
4K^G BZE 0 SOUT
4LF6 BS 3,JLBSPRIV
4LYQ SOUT
4QTQ [
4R*B [
4RT2 [ CREATE JWELL/ACLB FROM CURRENT CLB
4S#L [
4SS= MHUNT 3,CLB
4T?W LDX 7 ANUMCHA(3) [ COMMAND CHAR LENGTH
4TRG ADN 7 11
4W?6 SRL 7 2 [ ROUND UP ONE WORD PLUS RED TAPE
4WQQ SETUPCORE 7,3,JWELL,ACLB
4X=B STO 7 RRH(3) [ RECORD LENGTH
4XQ2 LDX 0 GSIGN [ FOR INDEXING RECOGNITION
4Y9L STO 0 A1+1(3)
4YP= LDX 0 ACES
4^8W SMO 7
4^NG STO 0 RRH-1(3) [ SPACE-FILL LAST WORD
5286 HUNT 2,CLB
52MQ LDN 4 CLBFIR(2)
537B LDN 5 RRH+2(3)
53M2 LDX 7 ANUMCHA(2) [ CHARS TO MOVE
546L XL TXL 7 N512(1)
54L= BCC X512 [ J IF > 512 CHARS STILL
555W SMO 7 [ < 512
55KG X512 MVCH 4 0
5656 SBN 7 512
56JQ BZE 7 OUT
574B BPZ 7 XL [ LOOP IF MORE TO DO
57J2 OUT
583L HUNT 2,ADATA,CSTORE
58H= BNG 2 WRTIT [ J IF NO RESIDUAL PARAMS
592W MHUNTW 3,JWELL,COPYSYS
59GG LDX 4 ALOGLEN(3)
5=26 ADX 4 ALOGLEN(2)
5=9Y ... SBN 4 1
5=FQ BRN STR
5=^B [
5?F2 RHUNT MHUNTW 2,JWELL,COPYSYS [ ROUTINE FOR ALTLEN
5?YL EXIT 1 0
5#D= [
5#XW STR ALTLENG 3,4,RHUNT
5*CG MHUNTW 2,JWELL,COPYSYS
5*X6 JLADJUST 2
5BBQ MHUNTW 3,ADATA,CSTORE
5BWB LDN 5 JLRESTF+1(2)
5CB2 LDN 4 A1+2(3)
5CTL LDX 6 A1(3)
5D*= ... SBN 6 1
5DSW [
5F#G [ SIZE OF REMAINDER FIELD
5FS6 [
5G?Q STO 6 JLRESTF(2)
5GRB SMO 6
5H?2 ... MOVE 4 511
5HQL LDN 0 JLRESTF
5J52 ... ADX 0 JOBDATASIZE
5J== STO 0 JLRESTPTR(2)
5JPW SBX 2 JOBDATASIZE
5K9G ADS 6 0(2)
5KF# ... FREECORE 3
5KP6 [
5L8Q WRTIT
5L?M ... MHUNTW 2,JWELL,COPYSYS
5L#L ... ADN 2 A1
5L*K ... LDX 0 JOBTIME
5LBJ ... STO 0 JLJT(2)
5LCH ... LDX 0 COREDEFAULT
5LDG ... SEGENTRY K50JOBLIST [FOR NEWNEEDS MACRO
5LFF ... STO 0 JLMAXSIZE(2)
5LGD ... HUNT 3,CPB,CMULTI
5LHC ... BNG 3 NOJOBD [NO CMULTI => NO JOBDATA PARAM
5LJB ... DOWN JOBDATA,3 [INCORPORATE JD IN COPYSYS BLOCK
5LK* ... BRN XJDERROR [J IF ERROR
5LL# ...NOJOBD
5LM* ...[
5LNB WRITEJL JWELL,COPYSYS
5M82 HUNT 3,JWELL,JPARAMS
5MML BPZ 3 WRTP
5N7= CALL 7 SETJW
5NLW NAME 3,JWELL,JPARAMS
5P6G WRTP WRITEJL JWELL,JPARAMS
5PL6 HUNT 3,JWELL,AJDF
5Q5Q BPZ 3 WJA
5QKB [
5R52 MHUNT 3,JWELL,COPYSYS
5RJL JLADJUST 3
5S4= JBC WMK,3,JLBJB [ J IF NOT JOB
5SHW SETNCORE SZAJDF,3,JWELL,AJDF
5T3G LDN 5 JDFNAME(3) [ NAME OF JDF
5TH6 MHUNT 2,JWELL,COPYSYS
5W2Q LDN 4 A1+FRH+JLJOBNAME(2)
5WGB MOVE 4 3
5X22 LDX 2 FX2
5XFL LDN 0 1
5X^= STO 0 JDFGEN(3) [ GEN NO OF JDF FILE
5YDW LDX 0 TLANG(1)
5YYG STO 0 JDFLANG(3) [ JDF LANG CODE
5^D6 LDN 4 CPREFIX(2) [ AS JOB THIS IS USERNAME
5^XQ LDN 5 JDFDIR(3)
62CB MOVE 4 3
62X2 WJA
63BL LDN 4 CPREFIX(2)
63D* ...#UNS G400
63G4 ...(
63HR ... HUNTW 2,IUSER,G400USER
63KG ... BNG 2 X2HOOK
63M9 ... LDN 4 A1(2)
63NY ...X2HOOK
63QM ... LDX 2 FX2
63SB ...)
63W= LDN 5 JOBCURDIR(3)
64*W MOVE 4 3
64TG ... STOZ JDFWFNAME(3)
65SQ LDN 0 SZAJDF
66#B STO 0 A1(3) [ RECORD SIZE
66S2 LDX 0 GSIGN
67?L STO 0 A1+1(3) [ MAINTAIN INDEXING
67R= BRN WJW
6834 ...[
68=W WMK SETNCORE SZAJDF,3,JWELL,AJDF
68B2 ... STOZ A1(3)
68F6 ... LDN 4 A1(3)
68J= ... LDN 5 A1+1(3)
68MB ... MOVE 4 SZAJDF-1
68QG BRN WJA
692# ...[
69=6 WJW WRITEJL JWELL,AJDF
69PQ WRITEJL JWELL,ACLB
6=9B CLOSETOP
6=F8 ... UPPLUS 1
6?N= [
6?R7 ...[
6?W4 ...XJDERROR
6?X3 ... CLOSETOP [CLOSE USR JOBLIST
6?YF ... LDEX 0 AWORK1(2) [B0 OF AWORK1 MEANS 'NOWELL' GIVEN !!
6?^Y ... STO 0 ACOMMUNE2(2) [RESTORE JD PARAM NO.
6#3W ... UP
6#7W [
6#MG SETJW
6*76 SBX 7 FX1
6*LQ SETNCORE 2,3,JWELL,JPARAMS
6B6B LDN 0 2
6BL2 STO 0 A1(3)
6C5L LDX 0 GSIGN
6CK= STO 0 A1+1(3)
6D4W ADX 7 FX1
6DJG EXIT 7 0
6F46 [
6FHQ [
6G3B [
6GH2 SCRUBJOB
6GTC ... HUNT 3,JWELL,COPYSYS
6H7S ... BNG 3 SCRUBNO
6HG= LDX 6 A1+FRH+JLJOBNO(3) [ JOB NUMBER
6H^W [
6JFG SCRUBNO [ JOB NUMBER SUPPLIED
6J^6 SBX 7 FX1
6KDQ GETJOB 6,SYSTEM [ OBTAIN ENTRY
6KYB TESTREP2 OK,S4
6LD2 GEOERR 1,NO JOB
6LKQ ...S4 HUNT 3,JWELL,COPYSYS [ CREATE JWELL BLOCK IF NOT ONE ABOUT
6LRG ... BPZ 3 S41
6L^= ... READAGAIN
6M72 ... MHUNT 3,FILE,FRB
6M#Q ... NAME 3,JWELL,COPYSYS
6MC3 ...S41 JLADJUST 3
6MC* ... LDN 1 0
6MCM ... JBC S4B,2,TEMP [J IF NOT TEMP AB
6MC^ ... LDN 1 1
6MD? ...S4B HLSINFORM SBIN,LOGOUT,6,1,,JLSTAT(3)
6MDK ...SBIN MHUNTW 3,JWELL,COPYSYS
6MDX ... JLADJUST 3
6MF# ... JBC S41A,3,JLBMOP
6MHK ... BC 2,TEMP
6MKX ...S41A
6ML8 ... JBC S41B,3,JLBRUNNING
6ML? ... JBS S41B,3,JLBSYSIS
6MLB ... LDX 0 CONTEXT(2)
6MLF ... ANDN 0 #4000
6MLJ ... BZE 0 S41B [ONLY INTERESTED IN F/S JOBS
6MLL ... ERS 0 CONTEXT(2)
6MLM ... LDN 0 2
6MLN ... ANDX 0 CONTEXT(2)
6MLP ... BNZ 0 S41AA [J IF NOUSER CONTEXT
6MLQ ... FJOCA 1,2
6MLR ... LDX 0 GSIGN
6MLS ... ERS 0 JURGE(1)
6MLT ...S41AA
6MLW ... LDN 1 4
6MLX ... ANDX 1 CONTEXT(2)
6MLY ... SRL 1 2
6MMD ... LDX 0 HLSCOUNT(1)
6MMF ... SBN 0 1
6MMG ... BPZ 0 S41C
6MMH ... GEOERR 0,HLSCOUNT
6MMJ ...S41C STO 0 HLSCOUNT(1)
6MMK ... FSHCODE AORB
6MML ...SMACHB1
6MMM ... BZE 1 S41D [J IF MOP
6MMN ... JBS S41B,,HLSBFS [J IF HLS IN CONTROL
6MMP ... BRN S41E
6MMQ ...S41D JBS S41B,,HLSMFS
6MMR ...S41E SMO FX1
6MMW ... LDX 0 STYLE(1)
6MM^ ... FOX 0
6MN4 ...S41B
6PL3 ... DELETE [ DELETE RECORD
6PMG ... ADX 7 FX1
6PTB ... LDX 2 FX2
6Q*2 EXIT 7 0
6QSL [
6R#= SCRUBUSER
6RRW SBX 7 FX1 [ DELETE USER JOBLIST ENTRY
6RX2 ... JMBS S1A,2,MONEY,XFROZEN
6S?G SETNCORE SIZELIST,3,FILE,FABSNB
6SR6 LDN 5 A1(3)
6T=Q LDN 4 XJOBLIST(1)
6TQB MOVE 4 SIZELIST [ INITIALISE
6W=2 ADN 5 1
6WPL MHUNTW 2,JWELL,COPYSYS
6X9= LDN 4 A1+FRH+JLUSER(2) [ USERNAME
6XNW MOVE 4 3
6Y8G #SKI WELLTEST
6YN6 RGTRACE 8,XGEO
6^7Q SMO FX2
6^MB STOZ AWORK2
6^QG ...[
6^TL ... USEROPEN XGEO,GENERAL,NOERREP,UNTRAP,REPLY,FROZEN
72LL TESTREP2 OK,S0,CANT,XESS
736= ROR GEOERR 1,JOBLIST
73KW XESS LDX 0 AWORK1(2) [ ERROR IF CANT AND JOBLIST NOT OPEN
745G ... BZE 0 XAGAIN
74K6 STO 0 AWORK2(2) [ REMEMBER TO REOPEN
754Q CLOSETOP [ CLOSE :SYSTEM.JOBLIST
75#J ...XAGAIN
75JB USEROPEN XGEO,GENERAL,NOERREP,UNTRAP
7642 S0 MFREE FILE,FABSNB
7698 ... BRN S1
76BB ...S1A FILEMOVE 1,0
76HL S1 MHUNTW 3,JWELL,COPYSYS
773= LDN 4 A1+FRH+JLJOBNAME(3)
77GW GETJOB 4,USER [ USER JOBLIST ENTRY
782G TESTREP2 OK,S2
78G6 GEOERR 1,NOJOB
78HT ...[
78KK ...S2 JMBAC S22,2,TEMP,XJLCH
78P4 ... STEPAGAIN
78SH ... ADX 3 JOBDATASIZE
78WT ... JBS SJL,2,XJLCH
78Y2 ... BC 3,JLBRUNNING
78Y^ ... BS 3,JLBNOTCAND
78^Y ... JBS S45,2,MONEY
7926 ... JBC NFZ2,2,XFROZEN
7928 ... BS 3,JLBFROZENNC
792= ... BRN S46
792? ...[
792# ...SJL MHUNTW 1,JWELL,COPYSYS
792B ... JLADJUST 1
792D ... LDX 0 JLSTAT(1)
792G ... STO 0 JLSTAT(3) [CHANGE USER JL ENTRY
792J ... LDX 0 JLBUDGETS(1)
792L ... STO 0 JLBUDGETS(3)
792N ... BRN S46
792P ...[
792Q ...NFZ2
792X ... BS 3,JLBABAND
7938 ... MHUNTW 2,JWELL,COPYSYS
793? ... JLADJUST 2
793B ... JBC S46,2,JLBRUNNING
793F ... BS 3,JLBABANDON
793W ... BRN S46
794* ...[
794T ...S45 BS 3,JLBHARDUP
795S ...S46
796B ... SBX 3 JOBDATASIZE
796Y ... STEPREWRITE
797G ... JBS S32,2,XJLCH [J IF JUST CHANGING JL
797R ... READAGAIN
798L ... MHUNTW 3,FILE,FRB
799F ... NAME 3,FILE,FWB
799J ... LDN 4 2
799M ...STEP STEP
799Q ... BCT 4 STEP
799R ...[
799T ... JWWFUPDATE 3
799Y ... STEPREWRITE
79=3 ... LDN 4 2
79=6 ...SBACK BACKSPACE
79=9 ... BCT 4 SBACK
79=C ... BRN S31
79#6 ...[
79*W ...S22 SKIP ,3
79FB LDN 4 4
79^2 S3 DELETE [ AND DELETE IT
7=DL BCT 4 S3
7=H6 ...S31 JMBAC S32,2,MONEY,XFROZEN
7=T6 ... FILEMOVE 0,1
7?3B ... BRN S6
7?9L ...S32 CLOSETOP [ CLOSE USER JOBLIST
7?CW LDX 0 AWORK2(2)
7?XG BZE 0 S6
7#C6 [
7#WQ [ REOPEN SYSTEM JOBLIST
7*BB [
7*W2 OPENSYS ,JOBLIST,GENERAL
7*^X ...S6 HUNTW 3,FILE,FWB
7B5S ... BNG 3 S6A
7B9P ... LDX 4 A1+JLJOBNO(3)
7B*L ... GETJOB 4,SYSTEM
7BFH ... INSERT
7BKD ... MFREEW FILE,FWB
7BP* ...S6A ADX 7 FX1
7BT= EXIT 7 0
7C#W XGEO GEOERR 1,USER BRK
7CSG [
7D#6 [
7DRQ TRAP SBX 4 FX1
7F?B STO 4 AWORK1(2)
7FH8 ... JBS ON,2,POPPED
7FR2 ...
7G2S ...POPC POP POPC,,JWACCESS
7G=L ON OPENSYS ,JOBLIST,GENERAL
7GQ= TESTREP2 OK,OUTR
7H9W GEOERR 1,JOBLIST?
7HPG OUTR ADX 4 FX1
7J96 EXIT 4 0
7JNQ [
7K8B [
7KN2 [ DELETE RECORDS REFERRING TO THE CURRENT JOB
7L7L [
7L#S ...XK2 STOZ AWORK4(2) [ MARKER FOR TEMP AB
7LG2 ... JBC XK22,2,EXABTEMP
7LM8 ... BS 2,TEMP
7LSB ...XK22
7M6W LDX 6 JOBNO(2)
7SGQ [
7T2B XK3 LDN 5 0 [ AS XK2 BUT SET ELSEWHERE
7TG2 LDXC 0 CONTEXT(2)
7T^L BCC XT
7WF= NGN 5 1 [ SYSTEM ISSUED
7WYW [
7XDG XT
7XY6 SYST CALL 4 TRAP [ POP AND OPEN JOBLIST
86?= [
86QW THEND CALL 7 SCRUBNO [ DELETE :SYSTEM.JOBLIST ENTRY
87=G [
87G# ...[
87Q6 ...SEND CALL 7 SCRUBUSER [ DELETE USER JOBLIST ENTRY
87^Y ...[
889Q ... MHUNT 3,JWELL,COPYSYS [ FOR JWUPDATE TO BE DONE
88FJ ... JLADJUST 3
88PB ... JBS SYSEND,3,JLBSYSIS [ J IF SYSTEM ISSUED
88^8 ... LDN 4 1
8992 ... JBS STEMP,2,TEMP [ J IF TEMP AB
89DS ... JBC NOTDG,3,JLBNOTCAND [ J IF JOB NOT DG
89NL ... STO 4 ACOMMUNE3(2) [ DG UPDATE COUNT
89YD ... STOZ ACOMMUNE2(2)
8=8= ... DOWN JWUPDATE,1
8=D4 ... BRN SYSEND
8=MW ...[
8=XN ...NOTDG JBS SLIVE,3,JLBRUNNING [ J IF JOB STARTED
8?7G ... LDN 4 JWELLONE
8?C# ...SLIVE STO 4 ACOMMUNE2(2) [ WELL/LIVE UPDATE
8?M6 ... STOZ ACOMMUNE3(2) [ NO DG UPDATE THIS TIME
8?WY ... ACROSS JWUPDATE,2 [ CLOSE AND VOP BY JWUPDATE
8#6Q ...[
8#BJ ...STEMP
8#LB ...[
8#W8 ... JBS SYSEND,3,JLBNOTCAND [ NO UPDATE IF ALREADY NOT CAND
8*62 ... STO 4 ACOMMUNE3(2)
8**S ... JBS RUNG,3,JLBRUNNING [ J IF WAS RUNNING
8*KL ... LDN 4 JWELLONE
8*TD ...RUNG STO 4 ACOMMUNE2(2)
8B5= ... DOWN JWUPDATE,2
8B6N ...[
8B87 ... MHUNTW 3,JWELL,COPYSYS
8B96 ... LDX 7 JLJOBNO+A1(3)
8B=5 ... JLADJUST 3
8B?4 ... HLSINFORM SYSEND,NONCAND,7,,,JLSTAT(3)
8B*4 ...SYSEND
8BBL ... JMBS UP,2,MONEY,XFROZEN
8BHH ...RETURN
8BJW ... CLOSETOP
8BSN ... VOP ,JWACCESS
8B^J ...UP UP
8C6D ...[
8C8B ...[ DELETE AN ENTRY....
8C=# ...[
8C## ...XK4 STOZ AWORK4(2)
8CJ6 ... JBC XK44,2,EXABTEMP [ SET TEMP IF TEMP AB
8CRY ... BS 2,TEMP
8D3Q ... BRN XK44
8D5N ...[
8D7L ...[ TEMPORARY DELETE AN ENTRY - ENTRY FROM AB (NB ALREADY POPPED)
8D9J ...[
8D?J ...XK6 STOZ AWORK4(2)
8DBN ... MBS 2,TEMP,POPPED [ TEMP AB ENTRY
8DFS ... BZE 5 XK44 [J IF FROM AB COMMAND
8DGM ... BPZ 5 NFZ3
8DGY ... BS 2,XFROZEN
8DH9 ... BRN NFZ4
8DH* ...[
8DHG ...NFZ3 BS 2,MONEY
8DHR ...NFZ4
8DN4 ... BRN XK44A
8DNT ...[
8DPL ...XK7 STOZ AWORK4(2)
8DQC ... BS 2,POPPED
8DR8 ...XK44 CALL 4 TRAP [ POP AND OPEN JOBLIST
8F6X ...XK44A CALL 7 SCRUBJOB [ USING JWELL/COPYSYS DELETE ENTRY
8FGL BRN SEND
8G2= [
8GFW XK5 STOZ AWORK1(2)
8GPN ... STOZ AWORK4(2)
8G^G CALL 7 SCRUBUSER [ DELETE USER JOBLIST ENTRY
8HF6 UP [ GIVEN JWELL/COPYSYS BLOCK
8HHT ...[ ENTRY FOR JLASSOCS MACRO
8HJQ ...XK8 STOZ AWORK4(2)
8HJR ... LDN 7 0 [INDICATES JLASSOCS MACRO
8HKJ ...XK8A
8HKM ... CALL 4 TRAP
8HLJ ... LDX 6 JOBNO(2)
8HMF ... GETJOB 6,SYSTEM
8HNB ... READAGAIN
8HP? ... MHUNTW 3,FILE,FRB
8HQ8 ... NAME 3,JWELL,COPYSYS
8HQL ... BNZ 7 XK8B [J IF NOT JLASSOCS MACRO
8HR5 ... CALL 5 SETASSOCS
8HR6 ... BRN XK8C
8HR7 ...[
8HR8 ...XK8B
8HR9 ...[ JLASLOST MACRO - SHOULD BE IN 'A'
8HR= ...[ ZEROISE ANY ASSOCIATIONS IN :SYSTEM.JOBLIST
8HR* ... JLADJUST 3
8HRB ... STOZ JLASSOCS(3)
8HRC ... STOZ JLASSOCS+1(3)
8HRD ... STOZ JLASSOCS+2(3)
8HRN ...[
8HRP ...XK8C
8HRQ ...[ WRITE UPDATE AWAY
8HS2 ... MHUNTW 3,JWELL,COPYSYS
8HSX ... NAME 3,FILE,FWB
8HTS ... REWRITE
8HWP ... BRN RETURN
8HXT ...[ KEEP USER AND SYSTEM JOBLISTS CONSISTENT
8HXX ...XK9
8HY2 ... STOZ AWORK1(2)
8HY5 ... STOZ AWORK2(2)
8HY8 ... STOZ AWORK4(2)
8HY? ... BS 2,XJLCH
8HYB ... CALL 7 SCRUBUSER
8HYF ... UP
8JD8 ...[
8JXS ...XK10
8KCD ...[ ENTRY FOR JLASLOST MACRO
8KX4 ...[ THIS MACRO (USED BY DEWELL) ASSUMES THAT
8LBN ...[ IT IS ISSUED IN THE 'A' MACHINE
8MTJ ... STOZ AWORK4(2)
8N*8 ... LDN 7 1 [INDICATES JLASLOST MACRO
8NSS ... BRN XK8A
8SPS ...[
8T9D ...#END
^^^^ ...07206162000300000000