{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LIBLOAD867)}}
====== LIBLOAD867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:APPEND|APPEND]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLCOUNT|CLCOUNT]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COOR1|COOR1]], [[george:macro:DCA|DCA]], [[george:macro:DELETE|DELETE]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DFSET|DFSET]], [[george:macro:DOWN|DOWN]], [[george:macro:FDTENT|FDTENT]], [[george:macro:FINDPEREC|FINDPEREC]], [[george:macro:FREETAB|FREETAB]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETDIR|GETDIR]], [[george:macro:GPERI|GPERI]], [[george:macro:GSCAN|GSCAN]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:INSERT|INSERT]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JWPR|JWPR]], [[george:macro:JWTBWR|JWTBWR]], [[george:macro:LADDP|LADDP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LONGON|LONGON]], [[george:macro:LPROP|LPROP]], [[george:macro:MBC|MBC]], [[george:macro:MBSXD|MBSXD]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MTHWSER|MTHWSER]], [[george:macro:MTINFORM|MTINFORM]], [[george:macro:NAME|NAME]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPACKB|OUTPACKB]], [[george:macro:OUTPARB|OUTPARB]], [[george:macro:READ|READ]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPTAB|SETUPTAB]], [[george:macro:SKIP|SKIP]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:STARTACT|STARTACT]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:TABSET|TABSET]], [[george:macro:TABULATE|TABULATE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:UNLOCK|UNLOCK]]
22FL #LIS K0LIBLOAD>K0LIBRARY>K0ALLGEO
22^= #SEG LIBLOAD65 [N.R.BOULT
23DW 8HLIBLOAD
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23SK ...[
23YG SEGENTRY K1LIBLOAD,QK1LIBLOAD
24D6 #
24XQ # THIS SEGMENT IS ENTERED FROM ENGAGE WHEN AN INTERRUPT OCCURS
25CB # ON AN UNALLOCATED TAPE DECK.
25X2 # THE TAPE IS REWOUND AND THE HEADER LABEL READ.
26BL # THE PERIPHERAL LIST ENTRY IS UPDATED AND AN ENTRY FOR THE
26W= # TAPE IS MADE IN :SYSTEM.DOCUMENT.
27*W # FURTHER,CHECKS ARE MADE THAT THE TAPE HEADER LABEL
27TG # (A) HAS THE STANDARD 1900 FORMAT,
28*6 # (B) AGREES WITH OUR RECORDS.
28SQ #
29#B #
29S2 # CONSTANTS
2=?L #
2=R= THDDR 4HHDDR [FIRST WORD OF TAPE LABEL
2?=W TEXCH #74 [LOWEST DISALLOWED CHARACTER
2?QG REELMAX +512 [REEL NRS <512
2#=6 REMASK #777777
2#PQ TINS #20000000
2*9B TQU #400000
2*P2 TPOOL 12HPOOL TAPE
2*W8 ...#UNS JMODGCR
2B3B ...#SKI
2B8L TCHARM #77617777
2BN= #
2C7W # LOCAL IDENTIER DEFINITIONS
2CMG #
2D76 #DEF STM=HTM
2DLQ #DEF SSB=HSB
2F6B #DEF SWR=HFREE4
2FL2 #DEF SHORTPM=1
2G5L #
2GK= # ENTRY POINT 1
2H4W #
2HJG QK1LIBLOAD
2J46 #SKI K6LIBLOAD>99-99
2JHQ SWITRACE CPPTR(2),K1LIBLOD
2K3B DFJUMPS ,LOAD,TALDED
2KH2 CLCOUNT ,FAIL [FAILS MAY HAVE..
2L2L CLCOUNT ,REPEAT [..OCCURRED ON UNLOADING
2LG= LDCT 0 #200 [SET PRIVILEGE TO OPEN FILES
2L^W ORS 0 CLONG1(2) [. IN A JAM
2MFG # A REWIND THE TAPE
2M^6 LDN 4 7 [REWIND MODE
2NDQ DCA ,DLA,4,MODE
2NYB LOCKC 2,£
2PD2 GPERI ,2 [REWIND TAPE
2PXL COOR1
2QC= UNLOCK 2
2QWW # B CHECK REWIND REPLY
2RBG LDCH 0 CPRW1(2) [REPLY
2RW6 BNZ 0 PK [FAIL REPLY
2S*Q # C READ HEADER LABEL
2STB SETNCORE 27,3,FLIB,FMAGH,1
2T3L ... LDN 0 18
2T9W ...Q1CY SMO 0
2TD6 ... STOZ A1+8(3)
2TLB ... BCT 0 Q1CY
2TSL LDN 4 0 [READ MODE
2W#= DCA ,DLA,4,MODE
2WRW LDN 4 20 [COUNT
2X?G DCA ,STO,4,COUNT
2XR6 LOCKC 3,SERCHF
2Y=Q MHUNT 3,FLIB,FMAGH
2YQB LDN 4 A1+1(3) [ADDRESS
2^=2 DCA ,STO,4,CTSA
2^PL LOCKC 2,£
329= GPERI ,2 [READ HEADER
32NW COOR1
338G UNLOCK 3
33N6 UNLOCK 2
347Q MHUNT 3,FLIB,FMAGH
34MB # D CHECK READ REPLY
3572 #SKI K6LIBLOAD>199-199
35LL SWITRACE CPRW1(2),LBLDREP
366= LDCH 0 CPRW1(2) [REPLY CHARACTER
36KW ANDN 0 #57 [REMOVE LONG BLOCK BIT
375G BZE 0 PE [SUCCESS REPLY
37K6 ANDN 0 #75 [TAPEMARK BIT
384Q LDN 7 0
38JB BNZ 0 PF
3942 LDN 7 1 [MARKER 1
39HL BRN PG
3=3= # E CHECK HEADER LABEL FORMAT
3=GW PE LDX 0 CPRW1(2) [REPLY WORD
3?2G ANDX 0 REMASK(1)
3?G6 DCA ,SBX,0,CTSA
3?^Q ANDX 0 REMASK(1) [NUMBER OF WORDS TRANSFERRED
3#FB SBN 0 9
3#^2 BPZ 0 PE3
3*DL NGN 7 1 [MARKER 1
3*Y= BRN PG
3BCW PE3 LDX 0 A1+1(3) [FIRST WORD OF LABEL
3BXG TXU 0 THDDR(1) [ 'HDDR' ?
3CC6 BCC PE4
3CWQ PE7 LDN 7 0 [MARKER 1
3DBB BRN PG
3DW2 PE4 LDX 4 A1+2(3) [TSN
3F*L #SKI K6LIBLOAD>199-199
3FT= SWITRACE 4,LBLDTSN
3G#W BNG 4 PE7 [POSITIVE
3GSG BZE 4 PE7
3H#6 LDN 5 12 [TEST 12 CHARACTERS OF
3HRQ LDX 2 3 [. TAPE NAME
3J?B PE5A LDCH 0 A1+3(2)
3JR2 TXL 0 TEXCH(1)
3K=L BCC PE7
3KQ= BCHX 2 £
3L9W BCT 5 PE5A
3LPG LDX 2 FX2 [RESET X2
3M96 LDX 5 A1+3(3)
3MNQ LDX 6 A1+4(3)
3N8B LDX 7 A1+5(3)
3NN2 TXU 5 ACES
3P7L TXU 6 ACES
3PM= TXU 7 ACES
3Q6W BCC PE7 [J IF HDDR ALL SPACES
3QLG LDX 0 A1+6(3) [REEL
3R66 TXL 0 REELMAX(1)
3RKQ BCC PE7 [>512
3S5B # H LONG BLOCK ?
3SK2 LDCH 0 CPRW1(2) [REPLY CHARACTER
3T4L ANDN 0 #20
3TJ= BZE 0 PJ [NOT LONG HEADER
3W3W # I LONG BLOCK MESSAGE
3WHG LGEOG ,0 [LOAD GEOGRAPHIC NO. OF DECK
3X36 OUTNUM 0,0
3XGQ MTINFORM HELONG
3Y2B # J OPEN SERIAL AND DOCUMENT
3YG2 PJ OPENSYS XBRKIN,DOCUMENT,GENERAL
3Y^L FINDPEREC 3,APTSER,4
3^F= BNG 3 PJ1 [BRANCH IF TSN NOT RECORDED IN DL
3^YW BXU 3 CPPTR(2),PAC [BRANCH IF TAPE ON ANOTHER DECK
42DG DFLOAD 3,LOAD,0
42Y6 BNZ 0 PAC [BRANCH UNLESS GENERAL RESTORE TAPE
43CQ PJ1
43XB OPENSYS XBRKIN,SERIAL,GENERAL
44C2 # N SEARCH :SYSTEM.SERIAL
44WL SSEARCH PINS,4 [CHECK FOR AN ENTRY IN :SYSTEM.SERIAL
45B= # P TEST STATUS OF TAPE
45TW LDX 0 5(3)
46*G #SKI K6LIBLOAD>99-99
46T6 SWITRACE 0,LBLDSS5
47#Q SLC 0 5
47SB BNG 0 PQ [TAPE WRONGED BY OPERATOR
48#2 LDX 6 0
48RL SLC 6 1 [<0 IF QUERY STATUS
49?= LDX 0 5(3)
49QW SLC 0 1
4==G BNG 0 PN4 [WORK TAPE
4=Q6 LDX 0 2(3) [USER NAME
4?9Q BNZ 0 PR [TAPE OWNED
4?PB BRN PS [MUST BE POOL
4#92 PN4
4#NL DFSET ,PWORK [PERMANENT WORKTAPE BIT
4*8= LDN 6 0
4*MW LDX 0 2(3)
4B7G BNZ 0 POA [BRANCH IF WORKTAPE IN USE
4BM6 LDN 6 1 [MARKER 3
4C6Q JWPR ,POA
4CLB BRN PF1 [J IF WPR NOT LOADED
4D62 # S TEST IF POOL TAPE IS CORRECTLY NAMED
4DKL PS
4F5= BPZ 6 PS2 [BRANCH UNLESS Q STATUS
4FJW LDX 0 5(3)
4G4G ANDN 0 #7777
4GJ6 BNZ 0 PNQ [J IF COUNT OF REQUESTERS NON-ZERO
4H3Q MHUNT 3,FLIB,FMAGH
4HHB LDX 0 A1+3(3)
4J32 TXU 0 TPOOL(1)
4JGL BCS PNQ
4K2= LDX 0 A1+4(3)
4KFW TXU 0 TPOOL+1(1)
4K^G BCS PNQ
4LF6 LDX 0 A1+5(3)
4LYQ TXU 0 TPOOL+2(1)
4MDB BCS PNQ
4MY2 LDN 6 2 [MARKER 3
4NCL BRN PAD [REMOVE QUERY STATUS
4NX= PNQ
4PBW LDX 6 TQU(1)
4PWG BRN PINS1
4QB6 PINS
4QTQ LDX 6 TINS(1)
4R*B PINS1
4RT2 MHUNT 3,FLIB,FMAGH
4S#L #SKI K6LIBLOAD>199-199
4SS= SWITRACE 6,LBLDSD21
4T?W ORS 6 A1+21(3)
4TRG LDN 6 0
4W?6 BRN PO
4WQQ # T PUT TAPE TO QUERY STATUS
4X=B PT DOWN LIBQUERY,1
4XQ2 LDX 6 ACOMMUNE1(2)
4Y9L BRN PV
4YP= PS2 LDN 6 2 [MARKER 3
4^8W JWPR ,POA
4^NG BRN PF1 [J IF WPR NOT LOADED
5286 POA
52MQ # STORE TAPE CHARACTERISTICS IF NOT ALREADY CORRECTLY KNOWN
537B STEPAGAIN
538R ...#UNS JMODGCR
53=8 ...(
53?K ... MBSXD 5,GSERRBTRA7,GSERRBPE,GSERRBNRZI,GSERRBGCR
53*2 ... ANDX 5 GSERRPROP(3)
53BC ... LPROP ,0
53CS ... MTHWSER 0,4
53F9 ...)
53GL ...#UNS JMODGCR
53J3 ...#SKI
53KD ...(
53M2 LDX 5 5(3)
546L SRL 5 13
54L= ANDN 5 7
555W LPROP ,4
55KG LDX 0 4
5656 ANDN 0 #200
56JQ BZE 0 PCHAR1 [BRANCH IF 7 TRACK
574B ANDN 4 3
57J2 BRN PCHAR2
583L PCHAR1
58H= LDN 4 4
592W PCHAR2
59=N ...)
59GG BXE 4 5,PCHAR3 [BRANCH IF CHAR ALREADY KNOWN
5=26 READAGAIN
5=FQ HUNT 3,FILE,FRB
5=J* ...#UNS JMODGCR
5=LY ... MBC 3,GSERBTRA7,GSERBPE,GSERBNRZI,GSERBGCR
5=PH ...#UNS JMODGCR
5=S6 ...#SKI
5=WP ...(
5=^B LDX 0 TCHARM(1)
5?F2 ANDS 0 A1+5(3) [CLEAR ANY OLD TAPE CHAR.
5?YL SLL 4 13
5#8D ...)
5#D= ORS 4 A1+5(3) [SET CHAR.
5#XW NAMETOP 3,FILE,FWB
5*CG #SKI K6LIBLOAD>199-199
5*X6 (
5BBQ SWITRACE 4,LBLDNCHA
5BWB SWITRACE 5,LBLDOCHA
5CB2 )
5CTL LDX 4 A1+1(3)
5D*= REWRITE
5DSW MFREE FILE,FWB
5F#G PCHAR3
5FS6 # O CLOSE :SYSTEM.SERIAL
5G?Q PO CLOSETOP [:SYSTEM.SERIAL
5GRB # V SET UP ENTRY FOR :SYSTEM.DOCUMENT
5H?2 PV
5HQL #SKI K6LIBLOAD>199-199
5J== SWITRACE 6,LBLDTYPE
5JPW MHUNT 3,FLIB,FMAGH
5K9G LDN 0 27
5KP6 STO 0 A1(3) [RECORD HEADER
5L8Q LGEOG ,0 [LOAD GEOGRAPHIC NO. OF DECK
5LNB STO 0 A1+23(3)
5M82 LDX 1 CPPTR(2)
5MML STO 1 A1+22(3)
5N7= LDX 4 A1+2(3) [TSN
5NLW NAME 3,FILE,FAPB
5P6G # W APPEND DOCUMENT ENTRY
5PL6 APPEND [INSERT DOC RECORD
5Q5Q # X UPDATE PERIPHERAL LIST
5QKB BZE 6 PV1
5R52 LDX 0 6
5RJL SBN 0 1
5S4= BNZ 0 PV2
5SHW DFSET ,WORK
5T3G BRN PV1
5TH6 PV2
5W2Q DFSET ,POOL
5WGB PV1
5X22 DFSET ,TSN,4
5XFL DFSET ,LOAD
5X^= # Y CLOSE :SYSTEM.DOCUMENT
5YDW CLOSETOP [:SYSTEM.DOCUMENT
5YYG LGEOG ,5
5^D6 SJ1
5^XQ OUTPACK 5,1,GEOPER,SJ1
62CB SJ2
62X2 OUTPACKB 4,1,TSN,SJ2
63BL SJ4
63W= HUNT 3,FILE,FAPB
64*W OUTPACKB A1+3(3),3,LOCNAME,SJ4
64TG SJ5
65*6 MHUNT 3,FILE,FAPB
65SQ OUTPACKB A1+6(3),1,REELNUM,SJ5
66#B SJ6
66S2 MHUNT 3,FILE,FAPB
67?L OUTPACKB A1+7(3),1,GENNUM,SJ6
67R= MFREE FILE,FAPB
68=W OUTPARB SKIP
68QG MONOUT HLOADED
69=6 # Z DE-ALLOCATE DECK
69PQ JWTBWR ,TALDED
6=9B CLALLOC
6=P2 #SKI K6LIBLOAD>299-299
6?8L (
6?N= LADDP ,1
6#7W SWITRACE 1(1),LBLDAUX1
6#MG )
6#SN ... LADDP ,3
6#^W ... STOZ BMTELCT(3) [CLEAR ERROR LOGGING COUNT IN APIA(+4)
6*76 STOZ CPPTR(2)
6*LQ STOZ CPRW1(2)
6B6B STOZ CPRW2(2)
6BL2 STOZ CPRSW(2)
6C5L # AA WAKE UP APPROPRIATE ACTIVITIES
6CK= SBN 6 2
6D4W BNZ 6 PAA2
6DJG LONGON #56 [WAKE UP ACTIVITIES
6F46 BRN PAB [WAITING FOR A POOL TAPE
6FHQ PAA2 ADN 6 1
6G3B BNZ 6 PAA6
6GH2 LONGON #63 [WAKE UP ACTIVITIES
6H2L BRN PAB [. WAITING FOR A WORK TAPE
6HG= PAA6
6HH? ...#UNS FIRSTR
6HJ# ...(
6HK* ... FDTENT 2,4,XNOFDT [IS THIS TSN IN FDT??
6HLB ... JBCC XDTA,2,BIFDTO [J IF ENTRY ALREADY LOOKED AT
6HMC ... [OTHERWISE CLEAR BIT.
6HND ... BS 2,BIFDTJL [SET 'TAPE JUST LOADED' BIT
6HNY ... BS BOLC,BIFDTLMEF [SET 'LOOK AT FDT FIRST' BIT
6HPF ... STARTACT RET [KICK DTS ACTIVITY
6HQG ... BRN PAB [RETRIEVAL SYSTEM WILL DEAL WITH THIS
6HRH ...XDTA [FDT ENTRY BUT BIFDTO IS CLEAR
6HSJ ... JBS PAB,2,BIFDTJL [J IF NO DTA SET UP YET BY DTSA
6HTK ... [DTA HAS BEEN SET UP - KICK IT
6HWL ... [......MOST PROBABLY IT IS DUMPER'S D
6HXM ...XNOFDT [NO FDT ENTRY - SO CONTINUE
6HYN ...)
6H^W LONGON #61,4 [. OR FOR THIS TSN
6JFG LONGON #61 [. OR FOR ANY TSN
6J^6 # AB TERMINATE
6KDQ PAB
6KYB #SKI K6LIBLOAD>99-99
6LD2 GSCAN 4,TAPEUP
6LXL SUICIDE
6MC= # G OUTPUT NON-STANDARD HEADER MESSAGE
6MWW ...PG ACROSS LIBLOADB,1
6NBG ...PF1 ACROSS LIBLOADB,2
7272 # F ATTEMPT REWIND
72LL ...PF ACROSS LIBLOADB,3
77GW # K RECORD FAILURE AND INFORM OPERATORS
782G ...PK ACROSS LIBLOADB,4
7B*L # Q OUTPUT 'WRONGED' MESSAGE
7BT= ...PQ ACROSS LIBLOADB,5
7JNQ # R OPEN USERS DIRECTORY
7K8B PR
7KN2 LDN 0 2(3)
7L7L LDN 1 AWORK1(2)
7LM= MOVE 0 3 [REMEMBER USER NAME
7M6W SETNCORE 12,3,FILE,FABSNB
7MLG LDN 0 10
7N66 STO 0 A1(3) [RECORD HEAD
7NKQ LDN 0 #2001
7P5B ORS 0 ATYPE(3)
7PK2 LDN 0 AWORK1(2)
7Q4L LDN 1 A1+1(3)
7QJ= MOVE 0 3 [USER NAME
7R3W STOZ A1+4(3)
7RHG LDN 0 A1+4(3) [LOCAL NAME,REEL AND
7S36 LDN 1 A1+5(3) [. GENERATION ALL
7SGQ MOVE 0 5 [. SET ZERO
7T2B NGN 0 1
7TG2 STO 0 A1+10(3)
7T^L STO 4 A1+11(3)
7WF= OPENDIR XBRKIN,GENERAL,ERASING
7WYW TESTREPNOT OK,XLIB
7XDG # U FIND DIRECTORY ENTRY,TEST IF TAPE IS 'NEW'
7XY6 MHUNT 3,FILE,ENT
7YCQ MHUNT 2,FLIB,FMAGH
7YXB LDX 0 ELOC1(3)
7^C2 #SKI K6LIBLOAD>199-199
7^WL SWITRACE 0,LBLDDENT
82B= BNZ 0 PU6
82TW MFREE FILE,FABSNB
83*G SETNCORE 6,1,FILE,FLOCNB [SET UP LOCAL NAME BLOCK
83T6 STOZ A1+3(1)
84#Q STOZ A1+4(1)
84SB STOZ A1+5(1)
85#2 MHUNT 2,FLIB,FMAGH [MOVE TAPE NAME INTO BLOCK
85RL LDN 0 A1+3(2)
86?= LDN 1 A1(1)
86QW MOVE 0 3
87=G SETUPTAB
87Q6 TABSET
889Q GETDIR 2
88PB TESTREP NOFILE,PU4,VRYWRONG,PU4
8992 MFREE FILE,ENT
89NL BRN PU7A [FILE ALREADY EXISTS
8=8= PU4
8=MW TABULATE
8?7G FREETAB
8?M6 MHUNT 3,FILE,ENT
8#6Q MHUNT 2,FLIB,FMAGH
8#LB LDN 0 A1+3(2)
8*62 LDN 1 ELOC1(3)
8*KL MOVE 0 4
8B5= MHUNT 1,FILE,FLOCNB
8BJW LDN 5 1
8C4G ORS 5 ATYPE(1) [SET MAG TAPE BIT
8CJ6 LDN 4 A1+3(2) [POINTER TO FMAGH
8D3Q LDN 5 A1(1) [POINTER TO FLOCNB
8DHB MOVE 4 5 [SET UP DETAILS FOR GETDIR
8F32 LDN 0 #7777
8FGL ANDX 0 A1+4(1) [GEN. NO.
8G2= BNZ 0 PU41 [J IF NOT ZERO OTHERWISE
8GFW LDCT 0 #100 [SET BIT INDICATING ZERO GEN.
8G^G PU41 STO 0 A1+4(1)
8HF6 LDX 0 A1+7(2) [TRUNCATE GENERATION NUMBER
8HYQ ANDN 0 #7777
8JDB STO 0 EGEN(3)
8JY2 NAMETOP 3,FILE,FRB
8KCL LDX 3 ENUSE(3)
8KX= LDN 5 1(3)
8LBW BZE 3 PU52 [J IF NO TRAP RECORDS
8LWG PU51
8MB6 READ [READ TRAP RECORDS
8MTQ BCT 3 PU51
8N*B PU52
8NT2 LDX 3 5
8P#L PU51A
8PS= DELETE [DELETE DIRECTORY ENTRY
8Q?W BCT 3 PU51A
8QRG GETDIR 2
8R?6 TESTREP OK,PU53,NOFILE,PU53
8RQQ GEOERR 1,LIBLOAD
8S=B PU53
8SQ2 MFREE FILE,FLOCNB
8T9L PU54
8TP= LDX 3 5
8W8W PU55
8WNG HUNT2 2,FILE,FRB
8X86 BCT 3 PU55
8XMQ NAMETOP 2,FILE,FWB
8Y7B INSERT
8YM2 TESTREP OK,PU56,FNEARLY,PU56
8^6L GEOERR 1,LIBLOAD
8^L= PU56
925W MFREE FILE,FWB
92KG BCT 5 PU54
9356 BRN PU7
93JQ PU6 LDN 1 3 [TEST EQUALITY OF NAMES
944B PU6A SMO 1
94J2 LDX 0 A1+3(2)
953L SMO 1
95H= TXU 0 ELOC1(3)
962W BCS PU8
96GG SBN 1 1
9726 BPZ 1 PU6A
97FQ LDX 0 A1+7(2) [GENERATION
97^B ANDN 0 #7777 [TRUNCATE
98F2 TXU 0 EGEN(3)
98YL BCS PU8
99D= BPZ 6 PU9
99XW CLOSETOP
9=CG LDN 6 0
9=X6 BRN PAD
9?BQ PU9
9?WB NAME 3,FILE,FWB
9#B2 PU7
9#TL PU7A CLOSETOP
9**= LDN 6 0
9*SW BRN POA
9B#G PU8 BPZ 6 PT [REPORT QUERY STATUS
9BS6 CLOSETOP
9C?Q BRN PNQ
9CRB # AC DUPLICATE TSN
9D?2 ...PAC LGEOG 3,5
9DQL ... ACROSS LIBLOADB,8
9KLW # AD REMOVE QUERY STATUS
9L6G PAD READAGAIN
9LL6 MHUNT 3,FILE,FRB
9M5Q LDX 0 TQU(1)
9MKB ERS 0 A1+5(3)
9N52 #SKI K6LIBLOAD>99-99
9NJL SWITRACE A1+5(3),LBLDREMQ
9P4= NAME 3,FILE,FWB
9PHW REWRITE
9Q3G MFREE FILE,FWB
9QH6 BZE 6 POA
9R2Q BRN PS2
9RGB TALDED
9S22 UNLOAD ,,,UNL
9SFL SUICIDE
9S^= SERCHF
9TDW HUNT 2,FLIB,FMAGH
9TFW ... EXIT 1 0
9WD6 #
9WXQ # GEOERRS
9XCB #
9XX2 XBRKIN GEOERR SHORTPM,XBRKIN
9YBL XLIB GEOERR SHORTPM,XLIB
9YW= XGDE GEOERR 1,GETDIR
9^*W #
9^TG MENDAREA 1023-0?,K99LIBLOAD
=2*6 #END
^^^^ ...25003065000200000000