{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LIBMANY867)}}
====== LIBMANY867 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DOWN|DOWN]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JONL|JONL]], [[george:macro:LJOBNO|LJOBNO]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGON|LONGON]], [[george:macro:LONGSET|LONGSET]], [[george:macro:MBSXD|MBSXD]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MOCH|MOCH]], [[george:macro:MT21SMES|MT21SMES]], [[george:macro:MTSERSPD|MTSERSPD]], [[george:macro:NAME|NAME]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:STEP|STEP]], [[george:macro:TESTREP|TESTREP]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREE|VFREE]], [[george:macro:WRONG|WRONG]]
22FL SEG LIBMANY,6,N.R.BOULT,LIBRARY
22^= #
23DW SEGENTRY K1LIBMANY,QK1LIBMANY
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23SK ...[
23YG #
24D6 OWRONG #1000000
24XQ UWRONG #2000000
25CB SQUE #400000
25X2 OUWRONG #3000000
25XL ...#UNS JMODGCR
25Y= ...#SKI
25YW ...(
25^K ...SPCHAR #160000
2648 ...TCHAR +GLIBNRZI
266R ... +GLIBPE
269B ... +GLIBTRA7
26?^ ... +0
26*? ...)
26BL #
26W= #
27*W QK1LIBMANY
27TG STOZ AWORK4(2) [ZEROISE CANTDO MARKER
28*6 LDX 0 ACOMMUNE1(2) [STORE MODES FROM USEROPEN
28SQ STO 0 AWORK1(2)
29#B LDX 0 ACOMMUNE2(2)
29S2 STO 0 AWORK2(2)
2=?L LDN 7 0
2=HD ... STOZ AWORK3(2) [ZEROISE TAPE CHARACTERISTIC
2=R= MHUNT 2,AONBS,GLIST
2?=W NEXT
2?QG ADN 7 1
2#=6 BXE 7 ALOGLEN(2),NEXT3 [BRANCH IF ALL TSNS DEALT WITH
2#PQ SMO 7
2*9B LDXC 6 A1(2)
2*P2 BRN £
2B8L BZE 6 NEXT
2BN= SSEARCH ,6 [LOOK FOR ENTRY IN :SYSTEM.SERIAL
2C7W MHUNT 2,AONBS,GLIST
2CMG LDX 0 OUWRONG(1)
2D76 ANDX 0 5(3)
2DLQ BNZ 0 WRONG [J IF OPERATOR OR USER WRONGED
2F6B LDX 0 SQUE(1)
2FL2 ANDX 0 5(3)
2G5L BNZ 0 WRONG [J IF QUERY STATUS
2GK= LDX 0 5(3)
2H4W BNG 0 WRONG [J IF TO BE RETURNED
2HJG SLL 0 2
2J46 BNG 0 WRONG [J IF TO BE DEADED
2JHQ SMO 7
2K3B LDX 0 A1(2)
2KH2 ... BNG 0 NEXT1 [BRANCH IF TAPE HAS WRITE TRAP
2L2L HUNT 1,CPAR,GPERCON
2LG= LDX 0 A1+2(1)
2L^W ANDN 0 1
2MFG ... BZE 0 NEXT1 [BRANCH IF WPR NOT NEEDED
2M^6 LDX 0 A1+1(1)
2NDQ ANDN 0 1
2NYB BNZ 0 WRONG
2N^F ...NEXT1
2N^L ...#UNS JMODGCR
2N^R ... MBSXD 0,GSERBTRA7,GSERBPE,GSERBNRZI,GSERBGCR
2N^Y ...#UNS JMODGCR
2P25 ...#SKI
2P2= ...(
2P2J ... SMO FX1
2P3M ... LDX 0 SPCHAR
2P48 ...)
2P4Q ... ANDX 0 5(3)
2P5T ... BZE 0 NEXT [J IF NO TRACK PROPERTIES
2P6Y ... LDX 3 FX2
2P83 ... LDX 4 AWORK3(3)
2P96 ... BZE 4 NEXT2 [J IF NO PROPS YET
2P=9 ... BXE 0 4,NEXT [J IF THIS TAPE HAS SAME PROPS
2P?# ... NGS 0 AWORK3(3) [SET -VE TO INDICATE CONFLICT
2P#C ... BRN NEXT
2P*G ...NEXT2
2PBK ... STO 0 AWORK3(3) [SAVE TRACK PROPERTY
2PD2 BRN NEXT
2PXL WRONG
2QC= SMO 7
2QWW STOZ A1(2)
2RBG LDN 0 1
2RW6 SBS 0 A1(2)
2S*Q BRN NEXT
2STB NEXT3
2T*2 CLOSETOP [SYSTEM.SERIAL
2T*4 ...#UNS JMODGCR
2T*6 ...(
2T*8 ... LDX 0 AWORK3(2)
2T*= ... BNG 0 PROPS
2T*# ... MTSERSPD AWORK3(2)
2T*B ...)
2T*D ...#UNS JMODGCR
2T*G ...#SKI
2T*J ...(
2T*S ... HUNT 1,FLIB,FSPD
2TBL ... BNG 1 NOFSPD
2TCD ... LDX 0 A1(1)
2TD= ... ANDN 0 GLIBTRA7+GLIBTRA9+GLIBPE+GLIBNRZI
2TF4 ... BNZ 0 PROPS [J IF TRACK PROP. ALREAY GIVEN
2TFW ...NOFSPD
2TGN ... LDX 3 AWORK3(2)
2THG ... BZE 3 PROPS [J IF NO PROPS OR CONFLICTING
2TJ# ... BNG 3 PROPS [PROPS FOUND IN :SYSTEM.SERIAL
2TK6 ... BPZ 1 OKFSPD
2TKY ... SETNCORE 1,1,FLIB,FSPD [SET UP FSPD IF NONE ALREADY
2TLQ ... STOZ A1(1)
2TMJ ...OKFSPD
2TNB ... SRL 3 14
2TP8 ... SMO FX1
2TQ2 ... LDX 0 TCHAR(3) [SET TRACK PROPERTY
2TQS ... ORS 0 A1(1) [INTO FSPD
2TR9 ...)
2TRL ...PROPS
2TSL STOZ 5 [FOR LIBREQ
2W#= STOZ AWORK3(2) [ZEROISE DAPEUP MARKER
2WRW T1
2X?G HUNT 2,AONBS,GLIST
2XR6 LDX 7 A1(2) [NO. OF VALID TSNS LEFT
2Y=Q BZE 7 XERR [J IF NONE LEFT
2YQB SBN 7 1
2^=2 BZE 7 SETUP [J IF ONLY ONE LEFT
2^PL STOZ 7
329= HUNT 1,FLIB,FNOS [SERIAL NO BLOCK PRESENT
32NW BPZ 1 PRE
338G SETNCORE 2,1,FLIB,FNOS [SETONE UP
33N6 HUNT 2,AONBS,GLIST
347Q PRE STOZ A1(1) [ZEROISE 1ST TWO WORDS
34MB STOZ A1+1(1)
3572 LDX 3 ALOGLEN(2) [NO. OF WORDS IN LIST
35LL SBN 3 1
366= SEARCH
36KW SMO 3
375G LDXC 6 A1(2)
37K6 BRN £ [CLEAR C
384Q BZE 6 UPC [ZERO ENTRY
38JB FINDPERE 1,APTSER,6
3942 BPZ 1 TFOUND [J IF TAPE UP
39?S ...STOR
39HL MHUNT 1,FLIB,FNOS
3=3= LDX 0 A1(1) [AN UNLOADED TAPE FOUND ALREADY
3=GW BZE 0 UP1 [J. IF NO
3?2G STO 6 A1+1(1) [STORE AS SECOND TSN
3?G6 BRN UPC
3?^Q UP1 STO 6 A1(1) [1ST TSN
3#FB UPC
3#^2 BCT 3 SEARCH
3*DL MHUNT 1,FLIB,FNOS
3*Y= LDX 0 A1(1) [IF NO UNLOADED TAPES
3BCW BNZ 0 TREQ [GO WAITING FOR A TAPE
3BXG STOZ 6
3CC6 LONGSET #61,WTSTYLE
3CWQ DOWN LIBREQ,1
3DBB BRN XBRKIN
3DW2 BRN RES
3F*L TREQ
3FT= STOZ 4 [TAPE NOTUP
3G#W STOZ 6 [TSN NOT KNOWN
3GSG LDX 2 FX2
3H#6 LDX 0 AWORK4(2)
3HRQ BNZ 0 T2 [J IF CANTDO MARKER SET
3J?B LONGSET #61,WTSTYLE,6 [SET WAITING STYLE
3JR2 DOWN LIBREQ,2 [FOR PLEASE LOAD MESSAGE
3K=L BRN XBRKIN [BREAKIN
3KQ= RES
3L9W LDX 4 ACOMMUNE4(2) [RESTORE X4 & X5
3LPG LDX 5 ACOMMUNE5(2)
3M96 TT3
3MNQ TESTREPN OK,T3 [J IF NOT WOKEN
3N8B T6 LONGOFF
3NN2 BRN T1 [J TO SEE IF TAPE LOADED
3P7L T3 TESTREPN NOTAV,T4 [J IF NOT CANTDO
3PM= LDN 0 1
3Q6W STO 0 AWORK4(2) [INDICATE CANTDO
3QLG BRN T1
3R66 T5
3RKQ SETREP NONEAV
3S5B T4 MFREE AONBS,GLIST
3SK2 VFREE FLIB,FNOS
3T4L T41 LONGOFF
3TJ= UPPLUS 1
3W3W T2 LDX 0 AWORK3(2)
3WHG BZE 0 T5 [J IF TAPE NOTUP
3X36 BZE 7 T2A
3XGQ STOZ 6
3Y2B LONGSET #61,WTSTYLE,6
3YG2 DOWN LIBREQ,1 [WAIT FOR A TAPE
3Y^L BRN XBRKIN
3^F= LDX 4 ACOMMUNE4(2)
3^YW LDX 5 ACOMMUNE5(2)
42DG BRN TT3
42Y6 T2A
43CQ STOZ 4
43XB STOZ 5
44C2 STOZ 6
44WL STOZ AWORK4(2)
45B= LONGSET #61,WTSTYLE,6
45TW DOWN LIBREQ,2
46*G BRN XBRKIN
46T6 LDX 4 ACOMMUNE4(2)
47#Q LDX 5 ACOMMUNE5(2)
47SB TESTREP OK,T6
48#2 TESTREPN NOTAV,T4
48RL STOZ AWORK3(2)
49?= LDN 0 1
49QW STO 0 AWORK4(2)
4==G BRN T1
4=Q6 # CODE TO BE INCLUDED FOR NEW INTERFACE MK6.5
4?9Q TFOUND
4?PB JONL 1,TONL [J. IF ONLINE
4#92 JALLOC 1,TF1 [J. IF ALLOCATED
4#D8 ... SETALLOC 1
4#DX ... SMO FX2
4#FL ... STO 1 CPPTR
4#FN ...#UNS JMT21
4#FQ ...(
4#FS ... STO 1 6 [SAVE X1 - DEVICE LIST POINTER
4#FW ... MOCH 1 [CHECK DECK SWITCHABLE
4#FY ... LDX 1 6
4#G2 ... MHUNT 2,AONBS,GLIST
4#G4 ... TESTREP OK,TNU
4#G6 ... MT21SMES 1 [MT21S MESSAGE IF NECESSARY
4#G* ... UNLOAD ,,,UNL,AUT
4#H4 ... MHUNT 2,AONBS,GLIST
4#HR ... SMO 3
4#JG ... LDX 6 A1(2)
4#K9 ... BRN STOR
4#KY ...)
4#LM ...#UNS JMT21
4#MB ...#SKI
4#NL BRN TNU
4*8= TF1 ADN 7 1
4*MW SMO FX2
4B7G STO 6 AWORK3 [TSN
4BM6 MHUNT 1,FLIB,FNOS
4C6Q LDX 0 A1+1(1) [STORE AS SECOND TSN
4CLB BNZ 0 UPC [IF ONE NOT PRESENT
4D62 STO 6 A1+1(1)
4DKL BRN UPC
4F5= TONL LJOBNO 1,0
4FJW BZE 0 TF1
4G4G SMO FX2
4GJ6 TXU 0 JOBNO [ONLINE TO THIS JOB
4H3Q BCS TF1 [J.IF NOT
4HHB SMO 3
4J32 STOZ A1(2) [ZEROISE ENTRY IN GLIST
4JGL LDN 0 1
4K2= SBS 0 A1(2)
4KFW LDX 0 A1(2) [TEST IF ONLY 1 VALID TSN LEFT
4K^G SBN 0 1
4LF6 BZE 0 SETUPX
4LYQ BRN UPC
4MDB XERR
4MY2 SETREP NONEAV [NONE OF THE TAPES AVAILABLE
4NCL UPPLUS 1
4NX= SETUPX
4PBW STO 2 6 [PRESERVE X2
4PWG MFREEW FLIB,FNOS
4QB6 LDX 2 6 [RESTORE X2
4QTQ SETUP
4R*B ADN 2 1
4RT2 LDX 6 A1(2) [FIND ENTRY IN GLIST
4S#L BZE 6 SETUP
4SS= MFREE AONBS,GLIST
4T?W SETNCORE FRDE,3,FILE,ENT
4TRG STOZ ELOC1(3) [SET UP FILE/ENT FOR LIBSEC
4W?6 STOZ ELOC2(3)
4WQQ STOZ ELOC3(3)
4X=B STOC 6 ESER(3)
4XQ2 BRN £
4Y9L OPENSYS XBRKIN,SERIAL,GENERAL
4YP= LDXC 7 6
4^8W BRN £
4^NG SETUP1
5286 STEP
52MQ BZE 3 SETUP2
537B BXU 7 1(3),SETUP1
53M2 LDX 0 5(3)
546L BNG 0 SETUP2
54L= SLL 0 2
555W BNG 0 SETUP2
55KG LDX 0 AWORK1(2) [RESET ACOMMUNE WORDS FOR LIBSEC
5656 STO 0 ACOMMUNE1(2)
56JQ LDX 0 AWORK2(2)
574B STO 0 ACOMMUNE2(2)
57J2 HUNT 3,CPAR,GPERCON
583L LDX 0 A1+2(3)
58H= ANDN 0 1
592W BNZ 0 WPOK [WPR NEED SPECIFIED
59GG BNG 6 WPOK [J IF WRITE TRAP SET FOR THIS TAPE
5=26 LDN 0 1
5=FQ ORS 0 A1+2(3)
5=^B NGN 0 2
5?F2 ANDS 0 A1+1(3)
5?YL WPOK
5#D= DOWN LIBSEC,1
5#XW BRN XBRKIN
5*CG TESTREP OK,T41
5*X6 TESTREP NOTAV,XERR
5BBQ TESTREP QUERY,XERR
5BWB TESTREP USWRONG,XERR
5CB2 TESTREP OPWRONG,XERR
5CTL TESTREP HDDRDIS,XERR
5D*= UPPLUS 1
5DSW SETUP2
5F#G CLOSETOP
5FS6 BRN XERR
5G?Q TNU
5J== SMO 3
5JPW LDX 6 A1(2) [TSN
5K9G LDXC 7 6
5KP6 BRN £
5L8Q OPENSYS YBRKIN,SERIAL,GENERAL
5LNB SSEARCH WR,7
5M82 LDX 0 2(3)
5MML BZE 0 WR [J IF RETURNED
5N7= LDX 0 OUWRONG(1)
5NLW ANDX 0 5(3)
5P6G BNZ 0 WR [J IF WRONGED
5PL6 LDX 0 SQUE(1)
5Q5Q ANDX 0 5(3)
5QKB BNZ 0 WR [J IF QUERY
5R52 LDX 0 5(3)
5RJL BNG 0 WR [J IF TO BE RETURNED
5S4= SLL 0 2
5SHW BNG 0 WR [J IF TO BE DEADED
5T3G READAGAIN
5TH6 HUNT 3,FILE,FRB
5W2Q LDN 0 1
5WGB ADS 0 A1+5(3) [UPDATE COUNT OF REQUESTERS
5X22 NAME 3,FILE,FWB
5XFL REWRITE [ENTRY IN S.S
5X^= CLOSETOP
5YDW MFREE FILE,FWB
5YYG SETNCORE FRDE,3,FILE,ENT
5^D6 STOZ ELOC1(3) [SET UP FILE/ENT FOR LIBSEC
5^XQ STOZ ELOC2(3)
62CB STOZ ELOC3(3)
62X2 STOC 6 ESER(3)
63BL BRN £ [CLEAR C
63W= HUNT 3,CPAR,GPERCON
64*W LDX 0 A1+2(3)
64TG ANDN 0 1
65*6 BNZ 0 WOK [J IF WPR NEED SPECIFIED
65SQ BNG 6 WOK [J IF WRITE TRAP SET FOR THIS TAPE
66#B LDN 0 1
66S2 ORS 0 A1+2(3) [INDICATE WPR NEED
67?L NGN 0 2
67R= ANDS 0 A1+1(3)
68=W WOK
68QG LDXC 6 6
69=6 BRN £
69PQ DOWN LIBSEC,2
6=9B BRN XBRKIN
6=P2 TESTREP OK,T4
6?8L TESTREP QUERY,WOK2
6?N= TESTREP OPWRONG,WOK2
6#7W TESTREPN USWRONG,T4
6#MG WOK2
6*76 HUNT 3,AONBS,GLIST
6*LQ LDN 0 1
6B6B SBS 0 A1(3)
6BL2 WOK1
6C5L BXE 6 A1+1(3),WOK3
6CK= ADN 3 1
6D4W BRN WOK1
6DJG WOK3
6F46 STOZ A1+1(3)
6FHQ BRN T1
6G3B WR HUNT 3,AONBS,GLIST
6GH2 LDN 0 1
6H2L SBS 0 A1(3) [FROM COUNT OF VALID TSNS
6HG= TA BXE 6 A1+1(3),WF
6H^W ADN 3 1
6JFG BRN TA
6J^6 WF STOZ A1+1(3)
6KDQ CLALLOC [MARK UNALLOCATED
6KYB STOZ CPPTR(2)
6LD2 LDXC 6 6
6LXL BRN £
6MC= CLOSETOP
6MWW LONGON #61,6
6NBG LONGON #61
6NW6 BRN T1
6P*Q YBRKIN
6PTB DFLOAD ,TSN,6
6Q*2 CLALLOC [MARK UNALLOCATED
6QSL STOZ CPPTR(2)
6R#= LONGON #61,6
6RRW LONGON #61
6S?G XBRKIN
6SR6 UP
6T=Q WTSTYLE
6TQB GEOERR 1,WTSTYLE
6W=2 MENDAREA 50,K99LIBMANY
6WPL #END
^^^^ ...10574651000100000000