{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LIBREQC867)}}
====== LIBREQC867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:CREATEB|CREATEB]], [[george:macro:DFCLEAR|DFCLEAR]], [[george:macro:DFJUMPN|DFJUMPN]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DFSET|DFSET]], [[george:macro:DOWN|DOWN]], [[george:macro:FINDPEREC|FINDPEREC]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GROPEREC|GROPEREC]], [[george:macro:HUNT|HUNT]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JBC|JBC]], [[george:macro:JENV|JENV]], [[george:macro:JWPR|JWPR]], [[george:macro:JWRONG|JWRONG]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGON|LONGON]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LPROP|LPROP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOCH|MOCH]], [[george:macro:MOCHAS|MOCHAS]], [[george:macro:MONICA|MONICA]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MTCHAR|MTCHAR]], [[george:macro:MTREQUEST|MTREQUEST]], [[george:macro:NAME|NAME]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTMTPROP|OUTMTPROP]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OUTPAUSE|OUTPAUSE]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP|PUTREP]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REPEAT|REPEAT]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SETUPMODE|SETUPMODE]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:TEMPDIRA|TEMPDIRA]], [[george:macro:TESTREP|TESTREP]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VFREE|VFREE]]
229S #OPT K0LIBREQC=0
22CW ... SEG LIBREQC,867,FILE,,G206
22KY ...[
22S2 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
2324 ...[ THIS EXCLUDES CODE UNDER #SKI G206
2386 ...[
23B8 ...#OPT G206 = 0
23J= ...#SKI G206&1
23Q# ...# WITH UGUG EDIT M206 (INCLUDE JOB NUMBER IN MAG TAPE REQUESTS)
23YG #
24D6 SEGENTRY K1LIBREQC,QK1LIBR
24XQ SEGENTRY K4LIBREQC,QK4LIBR
257J FSHENTRY K5LIBREQC,QK5LIBR,,QK5LIBR
25CB #
25X2 # A. PURPOSE OF SEGMENT.
26BL # TO GET A TAPE FROM THE
26W= # POOL, AND MARK THE DECK THAT THE TAPE IS LOADED ON ONLINE TO
27*W # THE USER.
27TG # B. GENERAL DESCRIPTION OF MECHANICS.
28*6 # 1. CHECK WHETHER TAPE IS LOADED. IF SO, GO TO STATEMENT 6
28SQ # 2. IF NOT & A REQUEST HAS ALREADY BEEN OUTPUT,GO TO STATEMEN
29#B # 3. IF NO REQUEST HAS YET BEEN OUTPUT TO OPERATORS, DO SO.
29S2 # 4. PUT THE ACTIVITY TO SLEEP AWAITING A TAPE
2=?L # 5. LIBLOAD REACTIVATES THE ACTIVITY WHEN A TAPE IS LOADED
2=R= # TO STATEMENT 1
2?=W # 6. CHECK WHETHER THE CORRECT CONDITIONS ARE SET FOR THE TAPE
2?QG # BE USED. (E.G. IF NECESSARY ASK FOR A CHANGE OF WPR CONDI
2#=6 # & GO TO STATEMENT 4 AFTER UNLOADING THE TAPE)
2#PQ # 7. MARK DECK ON-LINE TO USER & GO UP INFORMING HIM WHICH IT
2*9B # C. ENTRY POINT
2*P2 # K1LIBREQC - X4 CONTAINS MODES
2B8L # B23 SET - WORK TAPE REQUIRED
2BN= # B22 SET - MARK AS ONLINE
2C7W # B21 SET - SET UP FABSNB FOR WORK TAPE
2CMG # D. EXITS & ERROR REPLIES.
2D76 # OK :TAPE LOADED ON DECK INDICATED IN EXEC1.
2DLQ # NOTAV :TAPE NOT AVAILABLE. CANTDO COMMAND HAS BEEN ISSU
2F6B # THE OPERATORS
2FL2 # E. LIBREQC IS ENETRERED FROM:-
2G5L # GET,OLMTA,OLMTC
2GK= SLAN 4HC1 [TEMPORARY DIRECTORY LANGIAGE
2H4W PLONE #20000001
2HJG QFAST 4HFAST
2J46 QSLOW 4HSLOW
2JHQ PENRZI #201
2JNY ZGCR +HWPGCR
2QWW #
2RBG #
2RW6 QK1LIBR [SEE HEADING FOR THIS ENTRY
2S*Q LDX 0 ACOMMUNE1(2)
2STB STO 0 AWORK3(2) [SPECIAL PROPERTY DESCRIPTION
2SXH ANDN 0 #40
2SY= BZE 0 NOMODE [J IF NO MODE GIVEN
2SY^ HUNT 3,CPAR,GPERCON
2S^N BPZ 3 XGPER
2T2C SETNCORE 3,3,CPAR,GPERCON [SET UP CPAR,GPERCON
2T36 LDCT 0 5 [IF NONE ALREADY EXISTS
2T3T STO 0 A1(3)
2T4J STOZ A1+1(3)
2T5? STOZ A1+2(3)
2T62 XGPER
2T6P LDX 0 AWORK3(2)
2T7D SRL 0 18 [GET MODE REQUIRED
2T87 ORN 0 1 [SET WPR BIT
2T8W ORS 0 A1+1(3)
2T9K LDN 0 #75
2T=# ORS 0 A1+2(3)
2T?3 NOMODE
2T*2 #SKI K6LIBREQC>199-199
2TSL SWITRACE 0,LBRQCSPD
2W#= LDX 0 4
2WRW ANDN 0 4
2X?G BZE 0 NWT [BRANCH UNLESS FABSNB TO BE SET UP
2XR6 SETNCORE 18,3,FILE,FABSNB [SET UP A FILE/FABSNB BLOCK
2Y=Q LDN 0 16
2YQB STO 0 HDREC(3)
2^=2 LDN 0 WORK(1)
2^PL LDN 1 A1+10(3)
329= MOVE 0 7
32NW FJOCA 1,2 [FIND SOB BLOCK
338G MHUNT 3,FILE,FABSNB
33N6 LDN 0 JUSER(1)
347Q LDN 1 A1+1(3)
34MB MOVE 0 3 [USER NAME
3572 SBN 0 JUSER-JNAME
35LL LDN 1 A1+4(3)
366= MOVE 0 3 [SOB NAME
36KW STOZ A1+7(3) [REEL NO.
375G STOZ A1+8(3) [GENERATION NO.
37K6 SMO FX1
384Q LDX 0 SLAN [C1
38JB STO 0 A1+9(3)
3942 QK4LIBR
39HL NWT
3=3= LDX 0 4
3=GW ANDN 0 1
3?2G BZE 0 NWT1 [BRANCH UNLESS WORKTAPE
3?G6 TEMPDIRA XBRKIN,TEMPA [ENSURE TEMPORARY DIRECTORY IS SET UP
3?^Q NWT1
3#FB STOZ 5 [FIRST TIME THROUGH OUTPAUSE
3#P8 STOZ AWORK4(2)
3#^2 # SEARCH THE DEVICE LISTS FOR A FREE WORK/POOLTAPE
3*DL SERCH
3*Y= LDX 0 4
3BCW ANDN 0 1
3BXG BNZ 0 SER [BRANCH IF WORKTAPE
3CC6 LONGSET #56,WTSTYLE
3CWQ BRN SER0
3DBB SER
3DW2 LONGSET #63,WTSTYLE
3F*L SER0
3FT= MTCHAR AWORK3(2) [SET UP HARDWARE PROPERTY CODE
3G#W LDX 6 ACOMMUNE1(2)
3GSG #SKI K6LIBREQC>199-199
3H#6 SWITRACE 6,LBQCCHA
3HRQ LDX 0 GSIGN
3J?B ORS 0 AWORK4(2)
3JR2 STOZ CPPTR(2)
3K=L LDN 7 5
3KQ= FINDPEREC 3,APFOTY,7,SER1
3L9W BPZ 3 SER1A [BRANCH IF ANOTHER DECK
3LPG LDX 0 CPPTR(2)
3M96 BNZ 0 SER6 [BRANCH IF TAPE OBTAINED
3MNQ LDX 0 AWORK4(2)
3MTL BPZ 0 NOTAPE
3N2G ... JENV SER3A,CME,EXCL
3N7B SER2A
3NM2 ... BRN NOT1
3P6L ...
3PN9 [
3PP8 [ CME ENVIRONMENT - SO GROPE FOR DECKS
3PQ7 SER3A LDCT 0 #200
3PR6 ANDX 0 AWORK4(2)
3PS5 BNZ 0 SER2A
3PT4 LDN 3 GPDA
3PW3 LDX 0 16(3)
3PX2 BZE 0 SER2A [NO ANONYMOUS DEVICES
3PX^ LDN 7 5
3PYY GROPEREC 3,APTYPE,7
3P^X LDCT 0 #200
3Q2W ORS 0 AWORK4(2) [MARK ALREADY GROPED
3Q3T BPZ 3 SERCH [SOME DECKS FOUND SO REPEAT SEARCH
3Q4S BRN SER2A
3Q5R [
3Q6W SER1A
3QLG JWRONG 3,SER1
3R66 BNG 6 SER1B [BRANCH IF NO SPECIAL CHAR.
3RKQ LPROP 3,0
3S5B SMO FX1
3SK2 BXL 6 PENRZI,SER1C
3SSS LDX 1 0
3T4L ANDN 0 #203
3T#D ANDN 1 4 [X1 NON-ZERO IF 2510 DECK
3TJ= BRN SER1D
3W3W SER1C
3W?N STOZ 1
3WHG ANDN 0 #200
3X36 SER1D
3X9B BXE 0 6,SER1B
3XCL BZE 1 SER1 [BRANCH UNLESS 2510
3XF# [ SOFTWARE SWITCHABLE DECK - IS GCR REQUESTED
3XFW SMO FX1
3XGD TXU 6 ZGCR
3XH2 BCS XNGCR
3XHJ [ GCR TAPE REQUESTED - IS THE DECK CAPABLE OF GCR MODE
3XJ6 JBC SER1,3,CAPMODGCR
3XJN XNGCR
3XLH LDX 0 GSIGN
3XNB ORS 0 AWORK4(2)
3XQ9 ERS 0 AWORK4(2)
3XS6 BRN SER1 [NOT THE TAPE
3Y2B SER1B
3Y69 HUNT 1,CPAR,GPERCON
3Y7G BNG 1 SER1E
3Y8R LDN 0 1
3Y=4 ORS 0 A1+2(1) [SET WRITE BITS
3Y?* ORS 0 A1+3(1) [IN CPAR,GPERCON
3Y#L MOCH 3 [CHECK DECK IS SWITCHABLE TO
3Y*X TESTREPN OK,SER1 [ REQUIRED MODE
3YC8 SER1E
3YHR LDX 0 GSIGN
3YNB ORS 0 AWORK4(2)
3YS^ ERS 0 AWORK4(2)
3Y^L DFJUMPN 3,LOAD,SER1
3^F= LDX 0 4
3^YW ANDN 0 1
42DG BZE 0 SER2 [BRANCH IF POOLTAPE REQUIRED
42Y6 DFJUMPS 3,WORK,SER3 [BRANCH IF WORKTAPE FOUND
43CQ BRN SER1
43XB SER2
44C2 DFJUMPN 3,POOL,SER1 [BRANCH IF NOT POOLTAPE
44WL SER3
45B= JALLOC 3,SER1 [BRANCH IF ALREADY ALLOCATED
45TW JWPR 3,SER5 [BRANCH IF WPR
46*G SETALLOC 3
46T6 STO 3 CPPTR(2)
47#Q BRN REL
47SB SER5
48#2 LDX 0 AWORK3(2)
48RL ANDN 0 +GLIBFAST+GLIBSLOW
49?= BNZ 0 SPEED [BRANCH IF SPEED REQUIREMENT
49QW SETALLOC 3
4==G VFREE GMON,AOUT
4=Q6 STO 3 CPPTR(2)
4?9Q HUNT 1,CPAR,GPERCON
4?PB BNG 1 SER6 [BRANCH IF NO MODE REQUIREMENT
4#92 MOCHAS [TRY TO SWITCH DECK TO REQUIRED MODE
4#NL TESTREP OK,SER6,SWITCHED,SER6
4*8= REL
4*MW UNLOAD ,,,UNL,AUT
4B7G BRN SER1
4BM6 SER6 [UNSET POOL/WORKTAPE BIT NOW
4C6Q LDX 0 4
4CLB ANDN 0 1
4D62 BZE 0 SER7 [BRANCH IF POOLTAPE
4DKL DFCLEAR ,WORK [UNSET WORKTAPE BIT
4F5= BRN SER8
4FJW SER7
4G4G DFCLEAR ,POOL [UNSET POOLTAPE BIT
4GJ6 SER8
4H3Q DFLOAD ,TSN,6 [X6=TSN
4HHB LONGOFF
4J32 BRN W5
4JGL SPEED
4K2= LDX 0 CPPTR(2)
4KFW BZE 0 SP3 [BRANCH IF NO POOL/WORK TAPE AS YET
4K^G LPROP ,1 [PROPERTIES OF CURRENT FAVOURITE
4LF6 ANDN 1 #140 [EXTRACT SPEED
4LYQ LPROP 3,0 [PROPERTIES OF CANDIDATE
4MDB ANDN 0 #140
4MY2 SBX 1 0
4NCL LDX 0 AWORK3(2)
4NX= ANDN 0 +GLIBFAST
4PBW BZE 0 SP1 [BRANCH UNLESS FAST
4PWG BNG 1 SP2 [BRANCH IF CANDIDATE FASTER
4QB6 BRN SER1
4QTQ SP1
4R*B BNG 1 SER1
4RT2 BZE 1 SER1
4S#L SP2
4SS= LDX 0 CPPTR(2)
4T?W SP3
4TRG STO 3 CPPTR(2)
4W?6 LDX 3 0
4WQQ SETALLOC
4X=B HUNT 1,CPAR,GPERCON
4XQ2 BNG 1 SP4 [BRANCH IF NO MODE REQUIREMENT
4Y9L MOCHAS
4YP= TESTREP OK,SP4,SWITCHED,SP4
4^8W UNLOAD ,,,AUT,RET
4^NG STO 3 CPPTR(2)
5286 BRN SER1
52MQ SP4
537B BZE 3 SP4A
53M2 UNLOAD 3,,,AUT,RET
546L SP4A
54L= LDX 3 CPPTR(2)
555W BRN SER1
55KG # NO POOL/WORKTAPE FOUND - OUTPUT REQUEST
5656 NOTAPE
56JQ SETUPMODE ,0,TAPEUP
574B SMO FX2
57J2 ANDX 0 AWORK2
583L BZE 0 NOT1 [BRANCH IF TAPE TO BE REQUESTED
58H= LONGOFF
592W SETREP NOTUP
59GG UPPLUS 1
5=26 NOT1
5=FQ LDX 0 AWORK1(2)
5=^B STO 0 ACOMMUNE9(2)
5?F2 BNZ 5 REENT2 [BRANCH IF OUTPAUSE LEFT - NON EVENT
5?YL REPEAT
5#D= LDX 0 4
5#XW ANDN 0 1
5*CG BNZ 0 NOT3 [BRANCH IF WORKTAPE
5*X6 MONOUT HWAITP
5BBQ BRN NOT4
5BWB NOT3
5CB2 MONOUT HWAITW
5CTL NOT4
5D*= HUNT 3,CPAR,GPERCON
5DSW BNG 3 NOT5
5F#G NGN 0 2
5FS6 ANDX 0 A1+2(3)
5G?Q BZE 0 NOT5
5GRB OUTMESS HMODE2
5H?2 MONICA
5HQL HUNT 3,AONBS,GROT
5J== OUTPARAM A1(3),A1+1,AONBS,GROT
5JPW MFREE AONBS,GROT
5K9G BRN NOT6
5KP6 NOT5
5L8Q OUTNULL
5LNB OUTNULL
5M82 NOT6
5MML LDX 0 AWORK3(2)
5N7= ANDN 0 +GLIBFAST
5NLW BZE 0 NOT62
5P6G LDX 0 QFAST(1)
5PL6 NOT61
5Q5Q STO 0 ACOMMUNE1(2)
5QKB LDN 3 4
5R52 OUTPARAM 3,ACOMMUNE1
5RJL BRN NOT64
5S4= NOT62
5SHW LDX 0 AWORK3(2)
5T3G ANDN 0 +GLIBSLOW
5TH6 BZE 0 NOT63
5W2Q LDX 0 QSLOW(1)
5WGB BRN NOT61
5X22 NOT63
5XFL OUTNULL
5X^= NOT64
5YDW LDX 0 AWORK3(2)
5YYG STO 0 ACOMMUNE1(2)
5^D6 DOWN TRANSPOT,2
5^XQ TESTREP NOTAV,NOT9
624Y ...#SKI G206&1
62=6 ... OUTNUM JOBNO(2),0
62CB LDX 0 4
62X2 ANDN 0 1
63BL BNZ 0 NOT7
63W= MTREQUEST HLOPT
64*W BRN NOT8
64TG NOT7
65*6 MTREQUEST HLOWT1
65SQ NOT8
66#B BRN OUTP
66S2 NOT9
66^8 OUTMTPROP AWORK3(2)
67DS ...#SKI G206&1
67YD ... OUTNUM JOBNO(2),0
6GH2 LDX 0 4
6H2L ANDN 0 1
6HG= BNZ 0 NOT10
6H^W MTREQUEST HLOWHP
6JFG BRN OUTP
6J^6 NOT10
6KDQ MTREQUEST HLOWHW
6KYB OUTP
6LD2 OUTPAUSE XBRKIN,WOKEN,YCANTDO,2,REENT2
6LXL BRN REPEAT
6MC= WOKEN
6MWW LDX 0 ACOMMUNE9(2)
6NBG STO 0 AWORK1(2)
6NW6 LDN 5 1 [OUTPAUSE HAS BEEN ENTERED
6P*Q BRN SERCH
6PTB W5
6PW4 [
6PWQ [ ****************************************************************
6PXD [
6PY6 QK5LIBR
6PYS [
6P^G [ *****************************************************************
6Q28 [
6Q2W [ UPDATING SYSTEM SERIAL AND CREATING DIRECTORY ENTRY
6Q3J [ DO IT IN THE A MACHINE FOR SAFETY
6Q4= [
6Q*2 MHUNT 3,FILE,FABSNB
6QSL SMO A1(3)
6R#= STO 6 A1+1(3) [INSERT TSN TO ABSNB
6RRW LDN 0 #2001 [NONFILESTORE TYPE - TSN GIVEN
6S?G ORS 0 ATYPE(3) [BIT FOR LIBRARIAN OBJECT
6SR6 OPENSYS VBRKIN,SERIAL,GENERAL [TO UPDATE ENTRY
6S^B SSEARCH NOSER,6 [TAPE MAY HAVE BEEN DEADED
6T7L LDX 0 5(3) [IN THE MEANTIME
6T*W SLL 0 2
6TJ6 BNG 0 NOSER
6TQB READAGAIN
6W=2 HUNT 3,FILE,FRB
6WPL LDX 0 4
6X9= ANDN 0 2
6XNW BZE 0 YA1 [BRANCH UNLESS UPDATE COUNT
6Y8G LDN 0 1
6YN6 ADS 0 A1+5(3)
6^7Q YA1
6^MB MHUNT 2,FILE,FABSNB
7272 LDX 0 ATYPE(2)
72LL ANDN 0 #200
736= BZE 0 YA2 [BRANCH UNLESS NAMED WORKTAPE
73KW LDCT 0 #40 [NAMED BIT
745G ORS 0 A1+5(3)
74K6 LDX 0 PLONE(1) [LATEST PLUS ONE
754Q SMO A1(2)
75JB STO 0 A1-2(2)
7642 YA2
76HL NAME 3,FILE,FWB
773= LDX 0 4
77GW ANDN 0 1
782G BZE 0 NOTEMP2 [BRANCH UNLESS WORK TAPE
78G6 CREATEB
78^Q HUNT 3,FILE,CREATE
79FB LDCT 0 #220 [TEMPORARY BIT & NOT IN FILESTORE
79^2 STO 0 CEINF2(3)
7=DL NOTEMP2
7CM= USEROPEN YBRKIN,CREATE,REPLY,FROZEN [SET UP DIRECTORY ENTRY
7CSG TESTREPN OK,TESTALREADY
7CTF OPENDIR YBRKIN,GENERAL,ERASING,QUERY [OPEN DIRECTORY ENTRY
7CWD TESTREPN OK,(GEOERR) [GEOERR IF NOT OKAY
7CXC MHUNTW 3,FILE,ENT [X3 -> NAME RECORD FOR TAPE
7CYB LDX 2 EDATE [X2 => DATE
7C^* LDX 1 CLEANCT [X1 => TIME SINCE MIDNIGHT
7D2# STO 2 EDLA(3) [DATE LAST ACCESSED
7D3? STO 1 ETLA(3) [TIME LAST ACCESSED
7D4= STO 2 EWRITDAY(3) [DATE LAST WRITTEN
7D59 STO 1 EWRITTIME(3) [TIME LAST WRITTEN
7D68 LDX 0 GMTNOW [X0 => GEORGE MEAN TIME
7D77 STO 0 EGMTLA(3) [GMT LAST ACCESSED
7D86 NAME 3,FILE,FWB [RENAME NAME RECORD
7D95 REWRITE [REWRITE UPDATED NAME RECORD
7D=4 MFREEW FILE,FWB [FREE ENT BLOCK
7D?3 CLOSETOP [CLOSE DIRECTORY
7D#6 LDX 0 4
7DRQ ANDN 0 1
7F?B BNZ 0 VW1 [BRANCH IF WORKTAPE
7FR2 HUNT 2,FILE,ADICT [AS LEFT BY USEROPEN CONTAINING USER
7G=L ADN 2 A1 [NAME OF SUPERIOR DIRECTORY
7GQ= BRN VW2
7H9W VW1
7HPG FJOCA 2
7J96 ADN 2 JUSER
7JNQ VW2
7K8B HUNT 3,FILE,FWB
7KN2 ADN 3 A1+2
7L7L MOVE 2 3 [MOVE IN USER NAME
7LM= REWRITE [ ENTRY IN SYSTEM.SERIAL
7M6W MFREE FILE,ADICT [AS LEFT BY USEROPEN
7MLG MFREE FILE,FWB
7N66 CLOSETOP [SYSTEM.SERIAL
7N7H [
7N8Y XNOTB1
7NKQ ACROSS LIBREQCA,1 [GO TO CONTINUATION SEGMENT
7NNW NOSER
7NS2 CLOSETOP [SERIAL
7NS? [
7NSJ XNOTB2
7NX6 UNLOAD ,,,UNL
7P2= BRN SERCH
7P5B TESTALREADY
7PK2 PICKREP 5
7Q4L TESTREP ALREADY,SETREP
7QJ= TESTREP NAME,TEMP
7R3W TESTREP WRGEN,SETREP
7RHG TESTREP VRYWRONG,SETREP
7S36 GEOERR 1,TAPESER [ANY REPLY OTHER THAN ABOVE IS A SYST
7SGQ WORK 12HWORK TAPE
7T2B +0
7TG2 +0
7T^L #20202020
7WF= +0
7WYW WTSTYLE
7XDG GEOERR 1,WTSTYLE
7XY6 UBRKIN
7YCQ CLOSETOP
7YXB VBRKIN
7^C2 CALL 7 MTFREE
7^WL XBRKIN
82B= HUNT 1,FILE,FTRAP
82TW BNG 1 XBRKA
83*G FREECORE 1
83T6 BRN XBRKIN
84#Q XBRKA
84SB UP [BREAKIN
85#2 YBRKIN
85RL GEOERR 1,NOBRKIN [BREAKIN ON OPENING DIRECTORY
86?= TEMP
86QW KEEPREP 5,TEMP
87=G SETREP
87Q6 MFREE FILE,FWB
889Q CLOSETOP
88?7 [
88#J XNOTB3
88PB CALL 7 MTFREE [FREE DECK AGAIN
8992 PUTREP 5
89NL UPPLUS 1 [& EXIT
8=8= YCANTDO
8=MW SETREP NOTAV
8?7G UPPLUS 1
8?M6 TEMPA
8#6Q SETREP TEMP
8#LB UPPLUS 1
8BJW MTFREE
8C4G CLALLOC [DE-ALLOCATE DECK
8CJ6 LDX 0 4
8D3Q ANDN 0 1
8DHB BNZ 0 MTFR1 [BRANCH IF WORKTAPE
8F32 DFSET ,POOL
8FGL LONGON #56 [MAKE TAPE AVAILABLE AS A POOL TAPE
8G2= BRN MTFR2
8GFW MTFR1
8G^G DFSET ,WORK
8HF6 LONGON #63 [MAKE TAPE AVAILABLE AS A WORK TAPE
8HYQ MTFR2
8JDB EXIT 7 0
8JY2 MENDAREA 50,K99LIBREQC
8KCL #END
^^^^ ...42133223000400000000