{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LIBSEC867)}}
====== LIBSEC867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:CONSERNO|CONSERNO]], [[george:macro:DFJUMPN|DFJUMPN]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DOWN|DOWN]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JWPR|JWPR]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LOGACCESS|LOGACCESS]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGON|LONGON]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGWAIT|LONGWAIT]], [[george:macro:MBS|MBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOCHAS|MOCHAS]], [[george:macro:MT21SMES|MT21SMES]], [[george:macro:MTSERSPD|MTSERSPD]], [[george:macro:NAME|NAME]], [[george:macro:NOTALLOC|NOTALLOC]], [[george:macro:OFF|OFF]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:PERON|PERON]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP|PUTREP]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SDSEARCH|SDSEARCH]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SETUPMODE|SETUPMODE]], [[george:macro:SSCOR|SSCOR]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:TESTMODE|TESTMODE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:USEROPEX|USEROPEX]], [[george:macro:VFREE|VFREE]]
22FL ... SEG LIBSEC,860,C.R.JOHNSON,LIBRARY
22^= # ENTRY POINTS:-
23DW # K1 IS USED BY USEROPEN WHEN THE TAPE HAS BEEN FOUND IN THE
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23SK ...[
23YG # DIRECTORY. SYSTEM.SERIAL IS OPEN AND THE DIRECTORY CLOSED
24D6 # A FILE/ENT BLOCK CONTAINS A COPY OF THE DIRECTORY ENTRY
24XQ # K2 IS USED WHEN A TAPE HAS BEEN FOUND WHICH FITS REQUIREMENT
25CB # X4 CONTAINS THE GEOGRAPHIC NO OF THE DECK
25X2 # X6 CONTAINS THE TSN AND A FLIB/FTSN IS PRESENT
26BL # K3 IS USED WHEN A TAPE WITH A SPECIFIC TSN IS REQUIRED
26W= # X4 & X5 SHOULD BE ZERO
27*W # K4 IS USED BY TAPEOPEN MACRO
27H4 ...# K5 IS USED IN MACHINE B WHEN ENTERED FROM LIBMANY TO AVOID
27N= ...# THE FSHMOVE END AT K1.
27TG #
28*6 SEGENTRY K1LIBSEC,QK1LIBSEC
28SQ SEGENTRY K2LIBSEC,QK2LIBSEC
29#B SEGENTRY K3LIBSEC,QK3LIBSEC
29S2 SEGENTRY K4LIBSEC,QK4LIBSEC
2=?L #
2=BQ ... FSHENTRY K5LIBSEC,,QK5LIBSEC,QK5LIBSEC
2=FW ...#
2=K2 ... SEGENTRY K7LIBSEC,NOTALLOC
2=KR ...[
2=LJ ... FSHENTRY K8LIBSEC,QK8LIBSEC,,QK8LIBSEC
2=M* ... FSHENTRY K9LIBSEC,QK9LIBSEC,,QK9LIBSEC
2=N6 ...#
2=R= UWRONG #2000000
2?=W OWRONG #1000000
2?QG SQUE #400000
2#=6 UNITNO #777000
2#PQ SDUMP 12HDUMPER
2#TM ...#UNS JMODGCR
2#^J ...#SKI
2*5F ...(
2*9B TCHAR +GLIBNRZI
2*P2 +GLIBPE
2B8L +GLIBTRA7
2BN= +0
2BY4 ...)
2C7W WORK 12HWORK TAPE
2FL2 TIDY
2G5L VFREE GMON,AOUT
2GK= VFREE ADATA,ADEMAND
2H4W VFREE FLIB,FTSN
2HJG VFREE FLIB,FSPD
2J46 EXIT 3 0
2JHQ QK1LIBSEC
2K3B STOZ AWORK3(2) [NOT TAPEOPEN
2KH2 STOZ CPPTR(2)
2L2L HUNT 3,FILE,ENT
2LG= LDX 6 ESER(3) [TSN
2L^W BRN START
2MFG QK2LIBSEC
2M^6 STOZ AWORK3(2) [NOT TAPEOPEN
2NDQ CONSERNO 6
2NYB BRN OFF
2PD2 QK3LIBSEC
2PXL CONSERNO 6
2QC= STOZ AWORK3(2) [NOT TAPEOPEN
2QWW STOZ CPPTR(2)
2RBG WAIT
2RHN ...#UNS FIRSTR
2RNW ... TESTMODE AWORK2(2),X1,,INFORM [LONGSET NOT REQD IN INFORM
2RW6 LONGSET #61,WTSTYLE,6
2S*Q BRN X1
2STB QK4LIBSEC
2T*2 STOZ CPPTR(2)
2TSL LDX 0 ACOMMUNE1(2)
2W#= STO 0 AWORK1(2)
2WRW LDX 0 ACOMMUNE2(2)
2X?G STO 0 AWORK2(2)
2XR6 LDN 0 1
2Y=Q STO 0 AWORK3(2) [TAPEOPEN
2YQB LDX 6 ACOMMUNE3(2) [TSN
2YRC ...#UNS IDC
2YSD ...(
2YTF ... SETNCORE 12,3,FILE,FABSNB [USED EVENTUALLY TO UPDATE DATE & TIM
2YWG ... LDN 0 10 [LAST ACCESSED.
2YXH ... STO 0 HDREC(3) [SET UP RECORD HEADER
2YYJ ... LDN 0 0 [SET LOCAL NAME ZERO
2Y^K ... STO 0 A1+1(3) [BECAUSE WE DONT KNOW
2^2L ... LDN 0 A1+1(3) [IT
2^3M ... LDN 1 A1+2(3) [
2^4N ... MOVE 0 8 [
2^5P ... LDN 0 1 [
2^6Q ... NGS 0 A1+10(3) [RETENTION PERIOD
2^7R ... STO 6 A1+11(3) [TSN INTO FABSNB
2^8S ...)
2^=2 SETNCORE 3,3,CPAR,GPERCON
2^PL LDCT 0 #50
329= STO 0 A1(3)
32NW LDX 0 ACOMMUNE4(2)
338G STO 0 A1+1(3)
33N6 LDX 0 ACOMMUNE5(2)
347Q STO 0 A1+2(3)
34MB SETUPMODE ,0,NOSS
3572 ANDX 0 ACOMMUNE2(2)
35LL BNZ 0 START [J IF S.S NOT TO BE OPENED
366= OPENSYS UP1,SERIAL,GENERAL
36KW BRN START1
375G START
37K6 LDX 0 ACOMMUNE1(2) [PRESERVE MODE WORDS FROM
384Q STO 0 AWORK1(2) [USEROPEN
38JB LDX 0 ACOMMUNE2(2)
3942 STO 0 AWORK2(2)
39HL START1
3=3= STOZ 4 [FOR LIBREQ
3=GW STOZ 5 [FOR LIBREQ
3?2G CONSERNO 6 [CONVERT IT TO CHARS
3?G6 SETUPMODE ,0,NOSS
3?^Q ANDX 0 AWORK2(2)
3#FB BNZ 0 WAIT [J IF S.S NOT TO BE UPDATED
3#^2 SSEARCH NOTOW,6 [FIND ENTRY IN :SYSTEM.SERIAL
3*DL SETUPMODE ,0,NOWRONG
3*Y= ANDX 0 AWORK2(2)
3BCW BNZ 0 NOUW [J IF USER WRONGED NOT WANTED
3BXG LDX 0 UWRONG(1)
3CC6 ANDX 0 5(3)
3CWQ BNZ 0 UWR [J IF USER WRONGED
3DBB NOUW
3DW2 LDX 0 OWRONG(1)
3F*L ANDX 0 5(3)
3FT= BNZ 0 OWR [J IF OPERATOR WRONGED
3G#W SETUPMODE ,0,NOQUERY
3GSG ANDX 0 AWORK2(2)
3H#6 BNZ 0 NQUE [J IF QUERY STATUS NOT WANTED
3HRQ LDX 0 SQUE(1)
3J?B ANDX 0 5(3)
3JR2 BNZ 0 QUE [J IF QUERY STATUS.
3K=L NQUE
3KQ= SETUPMODE ,0,DUMPER
3L9W ANDX 0 AWORK2(2)
3LPG BZE 0 NNOT [J IF NOT DUMPER
3M96 LDX 0 2(3)
3MNQ BZE 0 NOTO [J IF NOT OWNED
3N8B BXU 0 SDUMP(1),NOTO [J IF NOT OWNED BY :DUMPER
3NN2 LDX 0 3(3)
3P7L BXU 0 SDUMP+1(1),NOTO [" " " " " "
3PM= LDX 0 4(3)
3Q6W BXU 0 SDUMP+2(1),NOTO [" " " " " "
3QLG NNOT
3QMX ...#UNS IDC
3QP# ...(
3QQP ... LDX 0 AWORK3(2) [
3QS6 ... BZE 0 NNOTA [J IF NOT TAPEOPEN
3QTH ... MHUNTW 2,FILE,FABSNB [FIND FABSNB
3QWY ... LDN 0 2(3) [X0 -> USERNAME
3QY* ... LDN 1 A1+1(2) [X1 -> POSITION IN FABSNB
3Q^Q ... MOVE 0 3 [MOVE IN USERNAME
3R37 ...NNOTA [
3R4J ...)
3R66 READAGAIN
3RKQ HUNT 3,FILE,FRB
3RTJ ...#UNS FIRSTR
3S5B ... TESTMODE AWORK2(2),PAIN1A,,INFORM
3S*8 ... LDN 0 1
3SK2 ADS 0 A1+5(3) [ADD ONE TO REQUESTERS COUNT
3SSS ...PAIN1A
3T4L NAME 3,FILE,FWB
3T79 ...#UNS JMODGCR
3T9S ... MTSERSPD GSERPROP(3)
3T#C ...#UNS JMODGCR
3TC2 ...#SKI
3TFK ...(
3TJ= HUNT 2,FLIB,FSPD
3W3W LDN 0 0
3WHG BNG 2 NNOT0
3X36 LDX 0 A1(2)
3XGQ ANDN 0 GLIBTRA7+GLIBTRA9+GLIBPE+GLIBNRZI
3Y2B NNOT0
3YG2 BNZ 0 NNOT2 [BRANCH IF CHAR. SPECIFIED
3Y^L LDX 3 A1+5(3)
3^F= SRL 3 13
3^YW ANDN 3 7
42DG BZE 3 NNOT2 [BRANCH IF CHAR. NOT KNOWN
42Y6 BPZ 2 NNOT1
43CQ SETNCORE 1,2,FLIB,FSPD
43XB STOZ A1(2)
44C2 NNOT1
44WL SRL 3 1
45B= SMO 3
45TW LDX 0 TCHAR(1)
46*G ORS 0 A1(2)
46T6 #SKI K6LIBSEC>199-199
47#Q SWITRACE A1(2),LBSCCHAR
47SB NNOT2
4848 ...)
48#2 REWRITE [REWRITE THE RECORD
48F8 ...#UNS FIRSTR
48LB ... TESTMODE AWORK2(2),PAIN1,,INFORM
48RL LONGSET #61,WTSTYLE,6 [SET WAITING STYLE GIVING TSN
493D ...PAIN1
49?= CLOSETOP [SYSTEM.SERIAL
49QW MFREE FILE,FWB
4==G X1
4=Q6 FINDPERE 3,APTSER,6
4?9Q BNG 3 NOTUP [J IF TAPE NOT LOADED
4?PB JALLOC 3,USED [J. IF ALREADY IN USE
4?^8 ... TESTMODE AWORK2(2),PAIN2A,,INFORM
4#92 SETALLOC 3 [MARK ALLOCATED
4#DS ...PAIN2A
4#NL STO 3 CPPTR(2)
4*8= OFF
4**D ...#UNS FIRSTR
4*GL ... TESTMODE AWORK2(2),PAIN2,,INFORM
4*MW LONGOFF [UNSET ANY WAITING STYLE
4*XN ...PAIN2
4B7G HUNT 1,CPAR,GPERCON
4BM6 LDX 0 A1+2(1)
4C6Q ANDN 0 1
4CLB BZE 0 WPROK [J IF NULL WPR REQUIREMENT
4D62 LDN 7 1
4DKL JWPR ,WPR
4F5= LDN 7 0 [X7=WPR STATE
4FJW WPR
4G4G LDX 0 A1+1(1)
4GJ6 ANDN 0 1 [LOAD WPR NEED
4H3Q BXU 0 7,WPRNOK [J IF PRESENT STATE NOT OK
4HHB WPROK
4J32 # CHECK MODE PROPERTIES HERE
4JGL MOCHAS
4K2= TESTREP NOTAV,XWRM,FAILED,XWRM
4KFW OPENSYS XBRKIN,DOCUMENT,READ
4K^G SDSEARCH SDERR,TSN,6
4LF6 SETUPMODE ,0,INSEC
4LYQ ANDX 0 AWORK2(2)
4MDB BNZ 0 PINSEC [J IF INSECURE TAPE WANTED
4MY2 SETUPMODE ,0,NOQUERY
4NCL ANDX 0 AWORK2(2)
4NX= BNZ 0 NOQ [J IF QUERY STATUS NOT WANTED
4PBW LDX 0 21(3)
4PWG ANDX 0 SQUE(1)
4QB6 BNZ 0 QUOL
4QTQ NOQ
4R*B LDX 0 AWORK3(2)
4RT2 BNZ 0 OKHDDR [J IF TAPEOPEN
4S#L HUNT 1,FILE,FABSNB
4SS= LDX 0 ATYPE(1)
4T?W ANDN 0 #200
4TRG BNZ 0 OKHDDR [BRANCH IF NAMED WORKTAPE
4W?6 LDX 7 ATYPE(1)
4WQQ ANDN 7 #2000 [TSN BIT
4X=B SMO A1(1)
4XQ2 ADN 1 A1-6
4Y9L LDX 0 0(1)
4YP= BZE 0 OKHDDR [J IF NAME NOT GIVEN
4^8W BXU 0 3(3),XHDDRDIS
4^NG LDX 0 1(1)
5286 BXU 0 4(3),XHDDRDIS
52MQ LDX 0 2(1)
537B BXU 0 5(3),XHDDRDIS
53M2 LDX 0 3(1)
546L ANDN 0 #777 [TRUNCATE REEL NO.
54L= BXU 0 6(3),XHDDRDIS [J IF REEL NO DISAGREES
555W XCH2
55KG LDX 0 4(1)
5656 BZE 0 OKHDDR [J IF FGN NOT SPECIFIED
56JQ BNG 0 XHDDRDIS [J IF -VE FGN GIVEN
574B SLL 0 1
57J2 BNG 0 XHDDRDIS [J IF +VE FGN GIVEN
583L SRL 0 1
58H= ERX 0 7(3)
592W ANDN 0 #7777
59GG BNZ 0 XHDDRDIS [J IF FGN DISAGREES
5=26 OKHDDR
5=FQ SETUPMODE ,0,HDDRLAB [IF MODE SET
5=^B ANDX 0 AWORK2(2) [SET UP FLIB/GOLMT CONTINING
5?F2 BZE 0 NHDDR [HEADER LABEL
5?YL SETNCORE 11,1,FLIB,GOLMT
5#D= STEPAGAIN
5#XW MHUNT 1,FLIB,GOLMT
5*CG LDN 0 2(3)
5*X6 LDN 1 A1+3(1)
5BBQ MOVE 0 8
5BWB NHDDR
5CB2 LDX 0 AWORK3(2)
5CTL BNZ 0 OK1
5D*= HUNT 1,FILE,FABSNB
5DSW LDN 2 3(3)
5F#G SMO HDREC(1)
5FS6 LDN 3 A1-6(1)
5G?Q MOVE 2 5
5GRB OK1
5H?2 CLOSETOP [SYSTEM.DOCUMENT
5HQL OK2
5J== # CHECK WHETHER TAPE IS TO BE MARKED ONLINE
5JPW SETUPMODE ,0,NOTOL
5K9G ANDX 0 AWORK2(2)
5KP6 BNZ 0 POL [J IF TAPE NOT TO BE PUT ONLINE
5L8Q PERON [MARK ONLINE
5LNB POL
5M82 LDX 0 AWORK3(2)
5M?6 ...#UNS IDC
5MB= ... BNZ 0 XFABCHECK [J IFTAPEOPEN
5MFB ...#UNS IDC
5MJG ...#STR
5MML BNZ 0 TSNOK [J IF TAPEOPEN
5N7= HUNT 3,FILE,FABSNB
5NLW LDX 0 ATYPE(3)
5P6G ANDN 0 #2000
5PL6 BNZ 0 TSNOK [J IF TSN ALREADY PRESENT
5Q5Q LDX 7 ALOGLEN(3)
5QKB BXU 7 HDREC(3),PLUS1 [J IF RET. PERIOD SPECIFIED
5R52 ADN 7 1
5RJL PLUS1 ADN 7 1
5S4= ALTLEN 3,7,FILE,FABSNB [ALTER FILE/FABSNB
5SHW HUNT 3,FILE,FABSNB
5T3G SMO A1(3)
5TH6 STO 6 A1+1(3) [INSERT TSN
5THL ... LDN 0 #2000 [SET TSN GIVEN BIT IN FABSNB
5TJ6 ... ORS 0 ATYPE(3)
5TJN ...#UNS IDC
5TL= ...(
5TMS ... BRN TSNOK [
5TPB ...XFABCHECK [
5TQY ... MHUNT 3,FILE,FABSNB [CHECK FABSNB
5TSG ... LDX 0 A1+1(3) [FOR PRESENCE OF
5TW4 ... BZE 0 XFABFREE [USERNAME
5TXL ... MBS 3,BFABTSN,BFABLIB [SET BITS FOR OPENDIR
5T^8 ...)
5W2Q TSNOK
5WGB CALL 3 TIDY [GET RID OF UNWANTED BLOCKS
5WGX ...#UNS IDC
5WHD ...(
5WHG ... MHUNT 3,FILE,FABSNB [NOW TRUNCATE GENERATION NUMBER
5WHJ ... SMO A1(3) [BECAUSE GETDIR WILL BREAK REELGEN
5WHL ... LDX 0 A1-2(3) [IF GEN > 4095 IS FOUND
5WHN ... ANDN 0 #7777 [
5WHQ ... SMO A1(3) [
5WHS ... STO 0 A1-2(3) [STORE IT
5WH^ ... OPENDIR (GEOERR),GENERAL,ERASING,QUERY
5WJG ... TESTREPN2 OK,XFABFREE
5WK3 ... MHUNTW 3,FILE,ENT [X3 -> NAME RECORD FOR TAPE
5WKJ ... LDX 6 EDATE [X6 -> DATE
5WL5 ... LDX 7 CLEANCT [X7 -> TIME SINCE MIDNIGHT
5WLL ... STO 6 EDLA(3) [DATE LAST ACCESSED
5WM7 ... STO 7 ETLA(3) [TIME LAST ACCESSED
5WMN ... LDX 0 GMTNOW [GEORGE MEAN TIME
5WN9 ... STO 0 EGMTLA(3) [STORE IT
5WNQ ... MHUNTW 1,CPAR,GPERCON [OPEN FOR WRITING?
5WNX ...#UNS ILOGACC
5WP4 ... LDN 4 CREAD
5WP? ... LDX 0 GPER2(1) [QUALIFIERR
5WPS ... ANDN 0 1 [
5WQ* ... BZE 0 XREWRITE [J IF NOT WRIT MODE
5WQW ... STO 6 EWRITDAY(3) [DATE LAST WRITTEN
5WRC ... STO 7 EWRITTIME(3) [TIME LAST WRITTEN
5WRJ ...#UNS ILOGACC
5WRP ... LDN 4 CWRITE
5WRY ...XREWRITE [
5WR^ ...#UNS ILOGACC
5WS2 ...(
5WS3 ... LDX 0 AWORK3(2)
5WS4 ... BNZ 0 XREW [NO LOGACCESS FOR TAPEOPEN
5WS5 ... LOGACCESS 2,4
5WS6 ... MHUNTW 3,FILE,ENT
5WS7 ...XREW
5WS8 ...)
5WSF ... NAME 3,FILE,FWB [RENAME ENT BLOCK
5WT2 ... REWRITE [REWRITE NAME RECORD
5WTH ... MFREEW FILE,FWB [FREE ENT BLOCK
5WW4 ... CLOSETOP [CLOSE DIRECTORY
5WWK ...XFABFREE [
5WX6 ... LDX 0 AWORK3(2) [
5WXM ... BZE 0 SETREPOK [J IF NOT TAPEOPEN
5WY8 ... MFREE FILE,FABSNB [FREE FABSNB IF TAPEOPEN
5WYP ...SETREPOK [
5W^= ...)
5X22 SETREP OK
5XFL UPPLUS 1
5X^= SDERR GEOERR 1,NOSYSDOC
5YDW PINSEC
5YYG LDCT 0 #200
5^D6 ANDX 0 21(3)
5^XQ BNZ 0 NOQ [J IF TAPE IS INSECURE
62CB SETUPMODE ,0,NOSS,INSEC
62X2 ERX 0 AWORK2(2)
63BL ANDS 0 AWORK2(2) [UNSET INSEC MODE & NOSS MODE
63W= CLOSETOP [SYSTEM.DOCUMENT
64*W CLALLOC [DEALLOCATE DECK
64TG STOZ CPPTR(2)
652N ...#UNS FIRSTR
657W ... TESTMODE AWORK2(2),PAIN3,,INFORM
65*6 LONGON #61,6 [WAKE UP ACTIVITIES WAITING FOR TAPE
65SQ LONGON #61
664J ...PAIN3
66#B USEROPEX UP1,AWORK1(2),AWORK2(2) [TRY AGAIN
66S2 UPPLUS 1
67?L XWRM
67DS ...#UNS JMT21
67L2 ... MT21SMES
67R= UNLOAD ,,,UNL,AUT
68=W LDN 5 0
68QG LDN 4 0
68XN ...#UNS FIRSTR
694W ... TESTMODE AWORK2(2),NOTUP,,INFORM
69=6 LONGSET #61,WTSTYLE,6
69PQ BRN NOTUP
6=9B WPRNOK
6=P2 CLALLOC [DEALLOCATE DECK
6?8L LDX 3 CPPTR(2)
6?N= STOZ CPPTR(2)
6?TD ...#UNS FIRSTR
6#2L ... TESTMODE AWORK2(2),PAIN4,,INFORM
6#7W LONGON #61,6 [WAKE UP ANY ACTIVITIES
6#MG LONGON #61 [THAT MAY BE WAITING FOR IT
6*76 LONGWAIT ZBRKIN,#62
6*BY ...PAIN4
6*LQ DFJUMPN 3,LOAD,X1
6B6B JALLOC 3,X1
6BL2 DFLOAD 3,TSN,0
6C5L BXU 0 6,X1
6CK= STO 3 CPPTR(2)
6D4W SETALLOC
6DJG LDN 7 1
6F46 JWPR ,WPR1
6FHQ LDN 7 0
6G3B WPR1 HUNT 1,CPAR,GPERCON
6GH2 LDX 0 A1+1(1) [FINALLY CHECK IF WPR
6H2L ANDN 0 1
6HG= BXE 0 7,WPROK [STILL NOT OK
6H^W DOWN LIBREQ,3
6JFG BRN ZBRKIN
6J^6 BRN X2
6KDQ NOTUP
6KYB DOWN LIBREQ,2 [ASK FOR TAPE TO BE LOADED
6LD2 BRN ZBRKIN [BREAKIN OR CANTDO
6LXL X2 LDX 4 ACOMMUNE4(2) [REINSTATE X4&5
6MC= LDX 5 ACOMMUNE5(2)
6MWW TESTREP OK,X1 [J TO SEE IF TAPE UP IF WOKEN UP
6MYS ...#UNS FIRSTR
6N2Q ...(
6N4N ... TESTMODE AWORK2(2),NINF,NOT,INFORM [INFORM MODE REQUIRES NO FURTHE
6N6L ... CALL 3 TIDY
6N8J ... UPPLUS 1
6N=G ...NINF
6N#D ...)
6NBG PICKREP 7 [LOAD REPLY
6NW6 LDN 5 1 [INDICATE REPLY
6P*Q STOZ 4 [INDICATE NOT ALLOCATED
6PTB BRN XDEAL
6Q*2 USED
6QSL DOWN LIBREQ,1 [WAIT FOR TAPE
6R#= BRN ZBRKIN [BRKIN OR CANTDO
6RRW BRN X2
6S?G UWR
6SR6 KEEPREP 7,USWRONG
6T=Q BRN UPT
6TQB OWR
6W=2 KEEPREP 7,OPWRONG
6WPL BRN UPT
6X9= QUE
6XNW KEEPREP 7,QUERY
6Y8G BRN UPT
6YN6 WTSTYLE
6^7Q GEOERR 1,WTSTYLE
6^MB QUOL LDN 5 1
7272 KEEPREP 7,QUERY
72LL CLOSETOP [SYSTEM.SERIAL
736= BRN XDEAL
73KW ZBRKIN
745G STOZ 4 [NOT ALLOCATED
74K6 XBRKIN
754Q STOZ 5 [NO REPLY
75JB BRN XDEAL
7642 XHDDRDIS
76HL DFJUMPN ,PWORK,XHD1 [J UNLESS TAPE IS WORKTAPE
773= LDX 2 FX1
77GW LDX 0 0(1)
782G BXU 0 WORK(2),XHD1
78G6 LDX 0 1(1)
78^Q BXU 0 WORK+1(2),XHD1
79FB LDX 0 2(1)
79^2 BXU 0 WORK+2(2),XHD1
7=DL LDX 0 3(1)
7=Y= ANDN 0 #777
7?CW BNZ 0 XHD1
7?XG LDX 0 4(1)
7#C6 ANDN 0 #7777
7#WQ BNZ 0 XHD1
7*BB LDX 2 FX2
7*W2 BRN OKHDDR [NAME IN DIRECTORY SPECIFIED
7B*L XHD1
7BT= CLOSETOP [SYSTEM.DOCUMENT
7C#W KEEPREP 7,HDDRDIS
7CSG LDN 5 1
7D#6 XDEAL
7DRQ LONGOFF
7F?B SETUPMODE ,0,NOSS
7FR2 ANDX 0 AWORK2(2)
7G=L BNZ 0 UP2 [J IF S.S NOT TO BE UPDATED
7G?K ... TESTMODE AWORK2(2),UP2,,INFORM
7GN8 ...QK8LIBSEC
7GQ= OPENSYS XBRKIN,SERIAL,GENERAL
7H9W SSEARCH ,6 [FIND ENTRY IN :SYSTEM.SERIAL
7HPG READAGAIN
7J96 HUNT 3,FILE,FRB
7JNQ SSCOR A1(3),DEC [DECREASE COUNT OF REQUESTERS
7JYJ ... LDX 4 0
7K5= ... NAME 3,FILE,FWB
7K9Y ... REWRITE
7KBL ... MHUNT 3,FILE,FWB
7KH# ... BNZ 4 REWRITE [J IF MORE USERS WANT THIS TAPE
7KN2 LDX 0 A1+5(3)
7L7L BNG 0 RETURN [J IF TO BE RETURNED
7LM= SLL 0 2
7M6W BNG 0 YDEAD
7N66 REWRITE
7PK2 MFREE FILE,FWB
7Q4L CLOSETOP [SYSTEM.SERIAL
7QJ= UP2
7QWJ ... BNZ 4 UP3
7QY? ... LONGON #57,6
7R22 ...UP3
7R3W LDX 4 CPPTR(2)
7RHG BZE 4 NOTALLOC
7S36 CLALLOC
7SGQ STOZ CPPTR(2)
7T2B LONGON #61,6
7TG2 LONGON #61
7T^L NOTALLOC
7WF= CALL 3 TIDY
7WYW BNZ 5 UPPL [J IF NOT BRKIN
7XDG UP1
7XY6 UP
7YCQ NOTOW
7YXB SETUPMODE ,0,DUMPER
7^C2 ANDX 0 AWORK2(2)
7^WL BNZ 0 NOTO
82B= GEOERR 1,LIBDISAG
82TW NOTO
83*G KEEPREP 7,NOTOWN
83T6 UPT CLOSETOP
84#Q CALL 3 TIDY
84SB UPPL
85#2 PUTREP 7 [SET REPLY
85RL UPPLUS 1
86?= RETURN
86QW ... ACROSS LIBREQCA,5
8F32 YDEAD
8FGL ... ACROSS LIBREQCA,7
8KX= MENDAREA 50,K99LIBSEC
8LBW #END
^^^^ ...06657013000100000000