{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LISTCONK83)}}
====== LISTCONK83 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:APPEND|APPEND]], [[george:macro:BXGE|BXGE]], [[george:macro:MASK|MASK]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MXB|MXB]], [[george:macro:NAME|NAME]], [[george:macro:ON|ON]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:VFREE|VFREE]]
22FL ...#SEG LISTCONK [LEN WAGSTAFF
22^= ...#OPT K0LISTCONK=0
23DW ...#LIS K0LISTCONK>K0ALLGEO>K0GREATGEO>K0COMMAND>K0IDF
23YG ... 8HLISTCONK
24D6 # ENTRY POINTS
24XQ ... SEGENTRY K1LISTCONK,Z1LISTCONK
25X2 [ THIS SEGMENT LISTS INFORMATION WHICH IS PRESENT IN THE IDF.
25^K ...# IT DEALS WITH CONCEPTUALS
2648 ...XMESS2 12HCONCEPTUAL
266R ...XSUB 12HIDENTIFIER
269B ...XLINE 4HLINE
26?^ ...XUNIT 4HUNIT
26BL XNEU 52HLINE/IDENTIFIER RANGE TO NONE ATTACHED.
28*6 MASK #37777777
28SQ #20202020
29#B #7777777
2BN= ON 12HONLINED
2C7W NON 12HNOT ONLINED
2CMG USER 12HUSER NAME
2D76 XNO 4HNONE
2Y=Q XMAJ +10000
4RT2 XEND ACROSS LISTAST,1
4^8W XONX SMO FX1
4^NG LDN 4 ON [ONLINED
5286 BRN XAXA
52MQ ...Z1LISTCONK
9F== SMO FX2 [CHAIN
9FPW STOZ ACOMMUNE3 [ZEROISE REC.NO.
9G9G CALL 7 XMXB [HUNT FOR REC.
9GP6 LDX 6 BCONT(2)
9H8Q BZE 6 XEND [J. NO CONCEPTUAL CHAIN
9HNB XSTAR SMO FX2
9J82 STO 6 AWORK1 [AWORK1 = PTR. TO CONCEPTUAL.
9JML SMO FX2
9K7= STO 6 AWORK3 [STORE AGAIN FOR CALCULATIONS.
9KLW LDX 3 6
9L6G CALL 0 SETUP [SET UP A WRITE BLOCK FOR THE HEADING
9LL6 CALL 0 XHUNT
9M5Q LDN 0 #42 [LD. PFCC
9MKB STO 0 A1+1(1) [ST.
9N52 SMO FX1
9NJL ... LDN 4 XMESS2 [LOAD HEADING
9P4= LDN 5 A1+3(1)
9PHW MOVE 4 3 [MOVE IN THE HEADING
9Q3G SMO 3
9QH6 LDN 4 1(2)
9R2Q LDN 5 A1+6(1)
9RGB MOVE 4 3 [MOVE IN THE NAME
9S22 SMO 2
9SFL LDX 4 4(3)
9S^= BNG 4 XONX [J. IF CONCEPTUAL IS ONLINED.
9TDW SMO FX1
9TYG LDN 4 NON [NOT ONLINED
9WD6 XAXA LDN 5 A1+17(1) [MOVE INTO HEADING
9WXQ MOVE 4 3
9XCB SMO 2
9XX2 LDX 4 4(3) [LD. CT. OF NO. OF LINES.
9YBL ANDN 4 #7777 [MASK OUT CT.
9YW= SMO 2
9^*W LDX 0 6(3)
9^TG ANDN 0 #7777
=2*6 SBN 0 1
=2SQ ADX 4 0
=3#B SMO FX2
=3S2 STO 4 AWORK2 [AWK2= CT.OF NO. OF LNS. + POSIT. DOW
=4?L [CELL.
=4R= SMO 2
=5=W LDX 4 6(3) [LD. INTO
=5QG LDCT 6 #600
=6=6 ANDX 6 4
=6PQ SRL 6 3
=79B SMO FX2
=7P2 ORS 6 AWORK2 [B3&4 INDICATE WHETHER MULT OR IPB OR
=88L LDN 6 #77
=8N= ANDX 6 4
=97W SRL 4 6
=9MG ANDN 4 #77
==76 BZE 4 X63 [J. START OF RANGE =>63.
==LQ LDCT 4 #010 [GREATER THAN 63 THEREFORE SET BIT5
=?6B SMO FX2
=?L2 ORS 4 AWORK2
=#5L BRN X64
=#K= X63 SLL 6 12
=*4W SMO FX2
=*JG ORS 6 AWORK2
=B46 X64 ADX 3 2
=BHQ LDX 5 5(3)
=C3B LDX 7 4(3)
=CH2 LDX 6 7(3)
=D2L LDX 3 6
=DG= CALL 0 XHUNTX
=D^W SMO FX1
=FFG LDN 5 USER
=F^6 LDN 6 A1+10(1)
=GDQ MOVE 5 3 [MOVE IN USER NAME HEADING.
=GYB SMO 2
=HD2 LDX 5 0(3)
=HXL BZE 5 XNUS
=JC= LDN 0 #12 [LOAD :
=JWW LDX 6 1 [PRESERVE PTR. TO OUTPUT BLOCK.
=KBG LDCT 5 #600
=KW6 ADX 1 5
=L*Q DCH 0 A1+12(1) [DEPOSITE : CHAR.
=LTB LDX 1 6
=M*2 SMO 2
=MSL LDN 5 0(3)
=N#= LDN 6 A1+13(1)
=NRW MOVE 5 3 [MOVE USER NAME INTO OUTPUT BLOCK.
=P?G XNUSA SMO 2
=PR6 LDX 6 7(3)
=Q=Q CALL 0 WRITE
=QQB LDX 3 6
=R=2 STO 3 AWORK3(2)
=RPL LDCH 0 AWORK2(2)
=S9= ANDN 0 1
=SNW BZE 0 XONCH [HELD IN ONE CHAR.
=T8G LDX 3 AWORK1(2)
=TN6 LDX 6 3
=W7Q CALL 0 XHUNT
=WMB SMO 2
=X72 LDX 5 6(3)
=XLL ANDN 5 #7777 [MASK
=Y6= SMO FX2
=YKW LDX 3 AWORK3
=^5G LDX 6 3
=^K6 BRN XNUSB
?24Q XONCH LDCT 1 #200
?2JB ADX 1 FX2
?342 LDCH 5 AWORK2(1)
?3HL XNUSB CALL 0 XHUNT
?43= SBN 5 1
?4GW ADX 3 2
?52G LDN 1 0(3)
?5G6 BRN XUS
?5^Q XNUS SMO FX1 [NO USER NAME
?6FB LDX 0 XNO
?6^2 STO 0 A1+13(1) [STORE "NONE"
?7DL BRN XNUSA
?7Y= XUSEA LDX 7 BRECNO(2) [LD. REC.NO.
?8CW SMO FX2
?8XG STO 7 ACOMMUNE3 [ACOMMUNE3=CURRENT REC.NO.
?9C6 XUS
?9WQ ADN 5 1
?=BB LDX 3 0(1)
?=W2 LDX 7 5
??*L CALL 0 SETUP [SET UP A OUTPUT BLOCK
??T= LDX 5 7
?##W LDCH 0 AWORK2(2) [MASK OUT INDICATOR FOR IPB OR MULT
?#SG ANDN 0 #6
?*#6 BVSR XNUTX
?*RQ SBN 0 2
?B?B BNZ 0 XIPBA [J. IPB CONCEPTUAL
?BR2 BZE 3 XUSAB [NO PTR.
?C=L LDX 6 3
?CQ= CALL 0 XHUNT [HUNT FOR LINE CELL.
?D9W XUSAB MHUNTW 1,FILE,FAPB
?DPG SMO FX1
?F96 LDX 4 XLINE
?FNQ STO 4 A1+4(1) [STORE LABEL LINE
?G8B SMO FX2
?GN2 STO 5 ACOMMUNE2
?H7L ADN 1 A1+5
?HM= CALL 7 XCBD
?J6W SBN 1 A1+5
?JLG BZE 3 XBREH
?K66 ADX 3 2
?KKQ SMO FX1
?L5B LDX 4 XUNIT
?LK2 STO 4 A1+7(1) [STORE UNIT HEADING.
?M4L ADN 1 A1+8
?MJ= BCHX 1 £
?N3W LDEX 5 BTYPE(3) [LD. UNIT NO.
?NHG CALL 7 XCBD
?P36 ADN 1 1
?PGQ LDN 5 #36 [STO. A STOP BETWEEN UNIT AND LINE
?Q2B DCH 5 0(1)
?QG2 BCHX 1 £
?Q^L LDN 4 4
?RF= LDX 2 FX1
?RYW XUSAA LDCH 5 XLINE(2) [MOVE IN CHAR. BY CHAR HEADING LINE
?SDG DCH 5 0(1)
?SY6 BCHX 1 £
?TCQ BCHX 2 £
?TXB BCT 4 XUSAA
?WC2 XUSBB BCHX 1 £
?WWL LDX 5 BNO(3)
?XB= CALL 0 XHELP [CONVERT AND STORE LINE NO.
?XTW XBREH SMO FX2
?Y*G LDX 5 ACOMMUNE2
?YT6 CALL 0 WRITE [WRITE AWAY REC.
?^#Q LDX 2 FX2
?^SB LDX 1 FX1
#2#2 LDX 6 AWORK2(2) [LD. CT. OF NO LINES AND POS.DOWN CEL
#2RL LDCT 7 #700
#3?= ANDX 6 7
#3QW SLC 6 3
#4=G ADN 6 1
#4Q6 LDN 7 7
#59Q SBX 7 6 [TEST TO SEE IF WE HAVE COME TO END
#5PB BZE 7 XABX [OF CELL.
#692 LDX 0 6
#6NL SRC 6 3
#78= LDX 4 AWORK2(2)
#7MW SMO FX1
#87G ANDX 4 MASK+2
#8M6 ADX 4 6 [ADD IN THE POSITION DOWN CELL.
#96Q STO 4 AWORK2(2) [ST. BACK AGAIN.
#9LB ANDN 4 #7777
#=62 BXGE 5 4,XITA [J. IF CTS. ARE EQUAL.
#=KL LDX 4 0 [SAVE POSITION DOWN BLOCK
#?5= LDX 3 AWORK3(2) [LD. PTR. TO CURRENT CELL.
#?JW LDX 6 3
##4G CALL 0 XHUNT [CALL HUNT ROUTINE.
##J6 ADX 3 2
#*3Q LDX 1 4 [LD. POSITION DOWN CELL
#*HB ADX 1 3
#B32 BRN XUS
#BGL XITA LDX 3 AWORK1(2) [LD. PTR. TO CONCEPTUAL CELL.
#C2= LDX 6 3
#CFW CALL 0 XHUNT
#C^G SMO 2
#DF6 LDX 6 0(3)
#DYQ BZE 6 XEND [J. TO END.
#FDB BRN XSTAR
#FY2 XABX
#GCL LDX 4 AWORK2(2) [LD. CT. OF NO. OF LNS.
#GX= ANDN 4 #7777
#HBW BXGE 5 4,XITA [BRANCH IF EQUAL.
#HWG SMO FX1
#JB6 LDX 0 MASK+2 [REMOVE POSITION DOWN CELL
#JTQ ANDS 0 AWORK2(2)
#K*B LDX 3 AWORK3(2) [HUNT FOR CURRENT CELL.
#KT2 LDX 6 3
#L#L CALL 0 XHUNT [HUNT FOR BLOCK
#LS= SMO 2
#M?W LDX 6 7(3) [LD. PTR. TO NEXT CELL.
#MRG SMO FX2
#N?6 STO 6 AWORK3
#NQQ LDX 3 6
#P=B CALL 0 XHUNT [HUNT FOR NEXT CELL.
#PQ2 ADX 3 2
#Q9L LDN 1 0(3)
#QP= BRN XUS
#R8W XNUTX LDX 5 0
#RNG XNUT
#S86 SMO FX2
#SMQ LDX 3 AWORK1
#T7B LDX 6 3
#TM2 CALL 0 XHUNT [HUNT BASE CELL
#W6L SMO FX1
#WL= LDN 6 XNEU
#X5W LDN 7 A1+4(1)
#XKG MOVE 6 13
#Y56 BZE 5 XYYA [J. IF NEUTRAL
#YJQ LDX 0 ACES
#^4B SBN 5 2
#^J2 BZE 5 XYYB [J. IF MX, ELSE IPB
*23L STO 0 A1+4(1)
*2H= DCH 0 A1+5(1)
*32W BRN XYYA
*3GG XYYB STO 0 AI+5(1) [ERASE "IDENTIFIER"
*426 STO 0 A1+6(1)
*4FQ STO 0 A1+7(1)
*4^B XYYA SMO 2
*5F2 LDX 5 6(3)
*5YL ANDN 5 #7777
*6D= ADN 1 A1+10
*6XW CALL 7 XCBD
*7CG ADN 1 2
*7X6 SMO 2
*8BQ LDX 5 6(3)
*8WB ANDN 5 #7777
*9B2 SMO 2
*9TL LDX 6 4(3)
*=*= ANDN 6 #7777
*=SW SBN 6 1
*?#G ADX 5 6
*?S6 CALL 7 XCBD
*#?Q CALL 0 WRITE [WRITE BLOCK AWAY.
*#RB BRN XITA
**?2 XIPBA
**QL SMO FX1
*B== LDN 6 XSUB
*BPW LDN 7 A1+4(1)
*C9G MOVE 6 3 [MOVE IN IDENTIFIER
*CP6 SMO FX2
*D8Q STO 5 ACOMMUNE2
*DNB ADN 1 A1+7
*F82 CALL 7 XCBD [CONVERT IDENTIFIER NO.
*FML SBN 1 A1+7
*G7= BZE 3 XBREH [J. LINE IS NOT ATTACHED
*GLW LDX 6 3
*H6G CALL 0 XHUNT
*HL6 ADX 3 2
*J5Q SMO FX1
*JKB LDX 4 XUNIT
*K52 STO 4 A1+9(1) [ST. UNIT
*KJL ADN 1 A1+10
*L4= BCHX 1 £
*LHW LDX 5 BTYPE(3) [LD. UNIT NO.
*M3G ANDN 5 #777
*MH6 CALL 7 XCBD
*N2Q ADN 1 1
*NGB LDN 5 #36 [ST. A STOP BETWEEN UNIT & IDENT.
*P22 DCH 5 0(1)
*PFL BCHX 1 £
*P^= LDN 4 10
*QDW LDX 2 FX1
*QYG XUSBA LDCH 5 XSUB(2) [LD. IDENTIFIER MESSAGE.
*RD6 DCH 5 0(1)
*RXQ BCHX 1 £
*SCB BCHX 2 £
*SX2 BCT 4 XUSBA [J. BACK UNTIL FINISHED
*TBL BRN XUSBB
*TW= WRITE
*W*W SBX 0 FX1
*WTG LDX 2 FX2
*X*6 STO 0 AWORK4(2) [STO LINK
*XSQ APPEND 2,XREFU
*Y#B TESTREP REFUSED,XREFU
*YS2 VFREE FILE,FAPB [FREE BLOCK
*^?L LDX 0 AWORK4(2) [RELOAD LINK
*^R= ADX 0 FX1
B2=W EXIT 0 0
B2QG XMXB SBX 7 FX1
B3=6 LDX 2 FX2
B3PQ MXB 2
B49B ADX 7 FX1
B4P2 MHUNTW 1,FILE,FAPB [HUNT FOR BLOCK DUE TO POSSIBLE COOR
B58L EXIT 7 0
B5N= ...XREFU ACROSS LISTSTAR,30
B67W XHUNTX
B6MG LDXC 0 0
B776 BNZ 5 XHUNT
B7LQ ANDN 7 -1
B86B SBN 7 1
B8L2 BZE 7 XHUNT
B95L ORX 0 GSIGN
B9K= XHUNT
B=4W SBX 0 FX1
B=JG LDX 2 FX2
B?46 STO 0 AWORK4(2) [STO LINK
B?HQ SMO FX1
B#3B ANDX 6 MASK
B#H2 SRL 6 9
B*2L STO 6 ACOMMUNE3(2)
B*G= CALL 7 XMXB
B*^W ANDN 3 #777
BBFG SMO FX2
BB^6 LDX 0 AWORK4 [RELOAD L9NK
BCDQ ADX 0 FX1
BCYB EXIT 0 0
BDD2 SETUP
BDXL SBX 0 FX1
BFC= LDX 2 FX2
BFWW STO 0 AWORK4(2) [STORE LINK
BGBG SETNCORE 26,1,FILE,FAPB [SETUP AN APPEND BLOCK
BGW6 SMO FX1
BH*Q LDX 4 MASK+1
BHTB STO 4 A1+2(1) [SPACEFIL THE DATA AREA.
BJ*2 LDN 4 A1+2(1)
BJSL LDN 5 A1+3(1)
BK#= MOVE 4 24
BKRW LDN 4 26
BL?G STO 4 A1(1) [STORE CT. OF NO. OF WDS.
BLR6 LDN 4 #41
BM=Q STO 4 A1+1(1) [ST. PFCC.
BMQB LDX 0 AWORK4(2)
BN=2 ADX 0 FX1
BNPL EXIT 0 0
BP9= XCBD [CONVERT BINARY TO DECIMAL
BPNW LDN 6 0
BQ8G LDN 4 4
BQN6 SMO FX1
BR7Q DVD 5 XMAJ [MAKE A FRACTION.
BRMB LDX 5 6
BS72 ADN 5 1
BSLL LDN 6 0
BT6= MODE 1
BTKW XUSA
BW5G CBD 5 0(1) [CONVERT FRACTION
BWK6 BCHX 1 £
BX4Q BCT 4 XUSA [J. IF CONVERSION NOT FINISHED.
BXJB SBN 1 1
BY42 EXIT 7 0 [EXIT.
B^GW XHELP
C22G LDX 2 1
C2G6 SMO FX2
C2^Q LDN 1 ACOMMUNE1 [LD. AC. INTO WHICH TO STORE NO.
C3FB CALL 7 XCBD [CALL CONVERTION
C3^2 LDX 1 2
C4DL LDN 4 4 [UP TO 4 CHS ALLOWED
C4Y= LDN 5 0
C5CW SMO FX2
C5XG LDX 6 ACOMMUNE1
C6C6 XLOOP SLL 56 6
C6WQ DCH 5 0(1)
C7BB BCHX 1 £
C7W2 BCT 4 XLOOP
C8*L EXIT 0 0
C8T= #END
^^^^ ...14637764000300000000