{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LISTDIRF867)}}
====== LISTDIRF867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:APPEND|APPEND]], [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DATECON|DATECON]], [[george:macro:DUMP|DUMP]], [[george:macro:ELSE|ELSE]], [[george:macro:FI|FI]], [[george:macro:FNORM|FNORM]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:IF|IF]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OFF|OFF]], [[george:macro:ON|ON]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPACECT|SPACECT]], [[george:macro:STEP|STEP]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:THEN|THEN]], [[george:macro:TIMECON|TIMECON]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22FL SEG LISTDIRF,3,GEORGE PORTER,LISTDIR,G233
22HJ ...[
22KG ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22MD ...[ THIS EXCLUDES CODE UNDER #SKI G233
22PB ...[
22R# ...#OPT G233 = 0
22T= ...#SKI G233&1
22X8 ...# WITH UGUG EDIT M233 (COMPACT LISTDIR HIGH)
22^= SEGENTRY K1LISTDIRF,Z1LISTDIRF
2357 ... SEGENTRY K2LISTDIRF,Z2LISTDIRF
2394 ...#SKI G233&1$1
23#^ ...(
23DW UARCH 12H ARCHIVE
23YG MARCH 16H ARCHIVE(M)
24D6 W +1000000
24XQ W1 52H RETENTION PERIOD= WRITTEN AT
25CB 28H ON
25X2 W2 52H TYPE/MODE LAST ACCESS
26BL 28H ON
26W= W3 52H INCREMENT NO. LAST DUMP
27*W 28H ON
27TG W4 52H ONLINE COPIES FILE SIZE BLOCKS
28*6 28H
28SQ TABLE
29#B #40000002
29S2 +TNORM
2=?L #40000012
2=R= +TGRAP
2?=W #40000022
2?QG +TALLC
2#=6 #40500000
2#PQ +TMAGT
2*9B #40600000
2*P2 +TUDAS
2B8L #41100000
2BN= +TDRUM
2C7W #0
2CMG +TAMOR
2D76 #DEF TABLEN=0?-TABLE/2
2DLQ #GAP 4
2F6B TFORMAT 12H FORMAT
2FL2 TNORM 2,8HNORMAL
2G5L TGRAP 2,8HGRAPHIC
2GK= TALLC 2,8HALLCHARS
2H4W TMAGT 1,4H*MT
2HJG TUDAS 1,4H*DA
2J46 TDRUM 1,4H*DR
2JHQ TAMOR 3,12HAMORPHOUS
2K3B
2KH2 PEND
2L2L SBX 3 FX1
2L32 MHUNT 2,FILE,FAPB
2L3B LDX 7 A1(2)
2L3Q LDN 0 2
2L46 BXE 7 0,NULLREC
2L4G SBN 7 1
2L4W NEXTONE
2L5= SMO 7
2L5L LDX 0 A1(2)
2L62 SMO 7
2L6B STO 0 A1+1(2)
2L6Q BCT 7 NEXTONE
2L76 LDN 0 1
2L7G ADS 0 A1(2) [ EXTRA WORD FOR PFCC
2L7W LDX 0 A1(2)
2L8= SBN 0 1
2L8L PREVWORD
2L92 SMO 0
2L9B LDX 7 A1(2)
2L9Q SPACECT 7,6,SPACEALL
2L=6 STOZ 0
2L=G BZE 6 NOSPACES
2L=W LDN 0 4
2L?= SBX 0 6
2L?L SRC 0 2
2L#2 NOSPACES
2L#B LDN 7 #41
2L#Q ADS 7 0
2L*6 STO 0 A1+1(2) [ STORE PFCC
2L*G BRN NOWAPPEND
2L*W SPACEALL
2LB= SBN 0 1
2LBL LDN 6 1
2LC2 SBS 6 A1(2)
2LCB BRN PREVWORD
2LCQ NULLREC
2LD6 LDN 0 #41
2LDG STO 0 A1+1(2)
2LDW NOWAPPEND
2LG= APPEND 1,FORCED
2L^W ADX 3 1
2MFG EXIT 3 0
2M^6 SDATECON
2NDQ SBX 5 FX1
2NYB DATECON 0
2PD2 XCON
2PXL ADX 5 1
2QC= ADN 2 ACOMMUNE1
2QWW MHUNTW 3,FILE,FAPB
2RBG EXIT 5 0
2RW6 TIMECON
2S*Q SBX 5 FX1
2STB TIMECON 0
2T*2 BRN XCON
2TSL [
2W#= Z1LISTDIRF [ENTRY FROM LISTDIR
2WRW [
2X?G HUNT 3,FILE,FAPB [AS LEFT BY LISTDIR
2XR6 LDN 6 2
2Y=Q STO 6 A1(3)
2YQB LDX 6 ACES
2^=2 STO 6 A1+1(3)
2^PL CALL 3 PEND
329= HUNT 3,FILE,FAPB
32NW LDN 6 19
338G STO 6 A1(3)
33N6 LDN 2 W1(1)
347Q ADN 3 A1+1
34MB MOVE 2 20 [MOVE IN TITLES
3572 HUNT 2,FILE,FRB
35LL LDX 5 ERET(2) [RETENTION PERIOD
366= CALL 7 XCONV
36KW STO 5 6(3)
375G LDX 0 EWRITDAY(2)
37K6 BZE 0 W5
384Q CALL 5 SDATECON
38JB ADN 3 A1+16 [SET UP ADDRESS OF OUTPUT AREA
3942 MOVE 2 2 [MOVE TO OUTPUT AREA
39HL HUNT 2,FILE,FRB [RESET ADDRESS OF ENTRY
3=3= LDX 0 EWRITTIME(2)
3=GW CALL 5 TIMECON
3?2G ADN 3 A1+12
3?G6 MOVE 2 2 [STORE IN OUTPUT BLOCK
3?^Q W5
3#FB CALL 3 PEND
3#^2 HUNT 3,FILE,FAPB
3*68 LDN 6 19 [RESET RECORD HEADER
3*?B STO 6 A1(3)
3*DL ADN 3 A1+1
3*Y= LDN 2 W2(1)
3BCW MOVE 2 20 [NEXT LINE TITLES
3BXG HUNT 2,FILE,FRB
3CC6 LDX 5 ETM(2) [TYPE AND MODE
3CWQ LDN 0 TABLEN
3DBB LDN 6 0
3DW2 NEXTTYPE
3F*L SMO 6
3FT= BXE 5 TABLE(1),MATCH
3G#W ADN 6 2
3GSG BCT 0 NEXTTYPE
3H#6 LDN 5 #17
3HRQ DCH 5 5(3)
3J?B BRN XSDATE
3JR2 MATCH
3K=L LDN 2 TFORMAT(1)
3KQ= ADN 3 1
3L9W MOVE 2 3
3LPG ADN 3 3
3M96 SMO 6
3MNQ LDX 1 TABLE+1(1)
3N8B ADX 1 FX1
3NN2 LDN 2 1(1)
3P7L LDX 1 0(1)
3PM= MOVE 2 0(1)
3Q6W MHUNTW 2,FILE,FRB
3QLG XSDATE
3R66 LDX 0 EDLA(2)
3RKQ LDX 4 ESER(2)
3S5B BZE 0 T25
3SK2 CALL 5 SDATECON
3T4L ADN 3 A1+16
3TJ= MOVE 2 2
3W3W HUNT 2,FILE,FRB
3WHG LDX 0 ETLA(2)
3X36 CALL 5 TIMECON
3XGQ ADN 3 A1+12
3Y2B MOVE 2 2
3YG2 T25
3Y^L CALL 3 PEND
3^F= BNZ 4 NOTARCH [OMIT LAST 2 LINES IF LIBRARIAN ENTRA
3^YW MHUNTW 2,FILE,FRB
428N JBS NOTARCH,2,BEEXO
42DG LDX 5 EINC(2)
42Y6 BZE 5 NOTDUMPED
43CQ HUNT 3,FILE,FAPB
43JY LDN 6 19 [RESET RECORD HEADER
43Q6 STO 6 A1(3)
43XB ADN 3 A1+1
44C2 LDN 2 W3(1)
44WL MOVE 2 20 [TITLES FOR FOURTHLINE
45B= LDX 4 ACES
45TW CALL 7 XCONV
46*G STO 4 5(3)
46T6 STO 5 6(3)
47#Q LDX 0 EDLD(2)
47SB CALL 5 SDATECON
48#2 ADN 3 A1+16
48RL MOVE 2 2
49?= HUNT 2,FILE,FRB
49QW LDX 0 ETLD(2)
4==G CALL 5 TIMECON
4=Q6 ADN 3 A1+12
4?9Q MOVE 2 2
4?PB CALL 3 PEND
4#92 NOTDUMPED
4#NL HUNT 3,FILE,FAPB
4*8= ADN 3 A1+1
4*MW LDN 2 W4(1)
4B7G MOVE 2 20 [FIFTH LINE TITLES
4BM6 HUNT 2,FILE,FRB
4C6Q LDX 5 ECOPS(2) [COPIES AND BLOCKS
4CLB SRL 5 15 [COPIES FIRST
4D62 CALL 7 XCONV
4DKL STO 5 10(3) [STORE NUMBER OF BLOCKS
4F5= LDEX 0 ECOPS(2)
4FJW ORX 0 ACES
4G4G ERN 0 #20
4GJ6 STO 0 6(3)
4H3Q CALL 3 PEND
4HHB MHUNTW 3,FILE,FRB
4J32 LDX 0 BIT9
4JGL ORX 0 BIT11
4K2= ANDX 0 EINF2(3)
4KFW BZE 0 NOTARCH
4K^G MHUNTW 2,FILE,FAPB
4LF6 LDN 0 12
4LYQ STO 0 A1(2)
4MDB LDX 0 ACES
4MY2 STO 0 A1+1(2)
4NCL LDN 5 A1+1(2)
4NX= LDN 6 A1+2(2)
4PBW MOVE 5 10
4PWG ADN 2 A1+2
4QB6 LDX 0 EINF2(3)
4QTQ ANDX 0 BIT9
4R*B BZE 0 NOTUSER
4RT2 ADN 1 UARCH
4S#L MOVE 1 3
4SS= SBN 1 UARCH
4T?W NOTUSER
4TRG ADN 2 6
4W?6 LDX 0 EINF2(3)
4WQQ ANDX 0 BIT11
4X=B BZE 0 NOTMAN
4XQ2 ADN 1 MARCH
4Y9L MOVE 1 4
4YP= NOTMAN
4^8W CALL 3 PEND
4^NG NOTARCH
5286 HUNT 3,FILE,FAPB
52MQ LDX 6 ACES
537B STO 6 A1+1(3)
53M2 LDN 6 2
546L STO 6 A1(3)
54L= CALL 3 PEND
555W ACROSS LISTDIR,2
55KG XCONV
5656 STO 7 GEN0 [LINK
56JQ STOZ 6 [BINARY TO DECIMAL CONVERSION
574B SMO FX1 [SUBROUTINE
57J2 DVR 5 W
583L LDCT 7 #200
58H= LDN 2 4
592W ORX 2 GSIGN
59GG MODE 1 [ZERO 1ST 5 CHARS
5=26 LDN 0 5 [
5=FQ T10 CBD 6 0(2) [CONVERT TO DECIMAL
5=^B BCHX 2 T17
5?F2 T17 BCT 0 T10
5?YL MODE 0 [CHANGE MODE TO MON-ZERO SUPPRESION
5#D= CBD 6 0(2) [FOR LAST CHAR AND CONVERT IT
5#XW LDX 7 GEN0 [RESTORE LINK
5*CG HUNT 2,FILE,FRB
5*X6 EXIT 7 0
5BBQ XBRKIN
5BWB ACROSS LISTDIR,4
5CB2 [
5CB3 ...Z2LISTDIRF
5CB4 ... GEOERR 1,G233 OFF
5CB5 ...)
5CB6 ...#SKI G233&1
5CB7 ...(
5CB8 ...#
5CB9 ...# ******************************************************************** #
5CB= ...#
5CB? ...# COMPLETE REWRITE OF LISTDIRF TO GIVE
5CB# ...# MORE THAN OLD HIGH LEVEL FORMAT ON ONE LINE ONLY
5CB* ...#
5CBB ...# ******************************************************************** #
5CBC ...#
5CBD ...POSSTYPES #12.2 [ FILE TYPES
5CBF ... 6:0.2 [ IN LIKELY ORDER OF POPULARITY
5CBG ... 5:0.2
5CBH ... 2.2
5CBJ ... #22.2
5CBK ... 9:0.2
5CBL ... 0
5CBM ...TYPES 12H GRAPHIC
5CBN ... 12HDISC BUCK
5CBP ... 12H TAPE FILE
5CBQ ... 12H NORMAL
5CBR ... 12H ALLCHAR
5CBS ... 12H DRUM FILE
5CBT ... 12H AMORPHOUS
5CBW ...PARS 4H( [ PARENTHESES FOR (FGN/LANG)
5CBX ... 4H /
5CBY ... 4H)
5CB^ ...TEN +10
5CC2 ...UFD 12HULTIFILE DEF
5CC3 ...PEX 7HEXOFILE
5CC4 ...UNDUMPED 28H HAS NEVER BEEN DUMPED
5CC5 ...PARC 4H/A [ ARCHIVED
5CC6 ...PARCM 4H/MA [ MANAGER-ARCHIVED
5CC7 ...POFF 4H OFF
5CC8 ...PON 4H ON
5CC9 ...PTSN 4HTSN
5CC= ...PRSN 8H REEL [ OR 8H--R.S.N. ACCORDING TO TASTE
5CC? ...PRP 8H R.P.
5CC# ...PDASH 8H --
5CC* ...#
5CCB ...XINTCONV [ BIN IN X1 -> CHARS IN X4X5. CALLED ON X6.
5CCC ... [ USES X0. X1 = FX1 ON EXIT.
5CCD ... [ CONVERTS ANYTHING EXCEPT -8388608
5CCF ... LDX 5 ACES
5CCG ... LDCT 4 #400 [ MARKER BIT
5CCH ... ORX 4 5
5CCJ ... STO 1 GEN0
5CCK ... BPZ 1 XPOS
5CCL ... NGXC 1 1 [ -8388608 WILL PRINT AS -0
5CCM ...XPOS SMO FX1
5CCN ... DVS 0 TEN
5CCP ... DCH 0 5
5CCQ ... SRC 45 6
5CCR ... BNZ 1 XPOS
5CCS ... LDX 1 GEN0
5CCT ... BPZ 1 XSLC
5CCW ... ORN 5 #35 [ MINUS SIGN
5CCX ...XSLC SLC 45 6
5CCY ... LDXC 4 4 [ CHECK AND CLEAR MARKER
5CC^ ... BCC XSLC
5CD2 ... LDX 1 FX1
5CD3 ... EXIT 6 0
5CD4 ...#
5CD5 ...SPER UP
5CD6 ...SPBI UPPLUS 1
5CD7 ...#
5CD8 ...Z2LISTDIRF [ SIDE-ENTRY FROM SETPARAM
5CD9 ... BRUSEN SPER
5CD= ... MHUNT 3,CPB,CUNI
5CD? ... NAMETOP 3,FILE,FNAME
5CD# ... FNORM 1
5CD* ... TESTRPN2 OK,SPER
5CDB ... MHUNT 3,FILE,FABSNB
5CDC ... BNG 3 SPER
5CDD ... IF BS,3,BFABWORK
5CDF ... THEN
5CDG ... JBC SPER,3,BFABLIB [ WORKFILE
5CDH ... FI
5CDJ ... BS 3,BFABANY
5CDK ... OPENDIR SPBI,READ,QUERY
5CDL ... TESTRPN2 OK,SPER
5CDN ...OK SETNCORE 32,3,FILE,FAPB
5CDP ... MHUNTW 3,FILE,ENT
5CDQ ... NAME 3,FILE,FRB
5CDR ... BACKSPACE [ FOR STEP TO BLKS RECORD
5CDS ... STOZ AWORK1(2)
5CDT ...# AWORK1 IS -VE IF ENTERED FROM LISTDIR, 0 IF FROM SETPARAM
5CDW ...#
5CDX ...Z1LISTDIRF
5CDY ... MHUNTW 3,FILE,FAPB
5CD^ ... LDN 0 32
5CF2 ... STO 0 A1(3)
5CF3 ... LDN 0 #41
5CF4 ... STO 0 A1+1(3)
5CF5 ... MHUNTW 2,FILE,FRB
5CF6 ... LDN 7 A1+2(3) [ X7 NORMALLY = MVCH DESTINATION
5CF7 ... LDN 0 A1+3(3)
5CF8 ... LDX 6 ACES
5CF9 ... STO 6 A1+2(3)
5CF= ... MOVE 7 29 [ CLEAR BUFFER TO SPACES
5CF? ... LDN 6 ELOC1(2) [ NORMAL COPY TO BUFFER IS MVCH 6 ...
5CF# ... MVCH 6 12 [ LOCAL NAME - CHARS 1-12
5CF* ... LDN 6 PARS(1)
5CFB ... MVCH 6 1 [ ( - CHAR 13
5CFC ... LDX 1 EGEN(2)
5CFD ... CALL 6 XINTCONV
5CFF ... LDN 6 5
5CFG ... LDN 0 4
5CFH ...ZS TXU 4 ACES
5CFJ ... BCS ZE
5CFK ... SLL 45 6
5CFL ... BCT 0 ZS
5CFM ...ZE SRL 45 6
5CFN ... SMO 0 [ FILE GENERATION NUMBER
5CFP ... MVCH 6 1 [ - ZERO-SUPPRESSED
5CFQ ... JBS REALTAPE,2,BELIB [ NO LANGUAGE CODE FOR REAL *MT
5CFR ... JBS XOFIL,2,BEEXO [ OR EXOFILE
5CFS ... LDX 4 ELAN(2)
5CFT ... LDX 5 PARS+1(1)
5CFW ... LDN 6 4
5CFX ... LDN 0 4
5CFY ...YS SRC 45 6
5CF^ ... TXU 5 ACES
5CG2 ... BCS YE
5CG3 ... SBN 0 1
5CG4 ... BCHX 6 YS
5CG5 ...YE SMO 0 [ / LANGUAGE CODE
5CG6 ... MVCH 6 1 [ - TRAILING SPACES REMOVED
5CG7 ... LDN 6 PARS+2(1)
5CG8 ... MVCH 6 1 [ )
5CG9 ... JMBAC XMF,2,BEMDF,BEMULT
5CG= ... LDN 6 #5520 [ M FOR MULTIFILE IN CHAR 23. THERE
5CG? ... DSA 6 A1+7(3) [ IS ROOM SINCE MAX FGN = 128 FOR M/F
5CG# ...XMF LDCT 7 #600
5CG* ... ADN 7 A1+7(3) [ TYPE WILL GO IN CHARS 24-35
5CGB ... LDXC 0 EUSE1(2)
5CGC ... BCC QTY [ TO QTY IF NOT DIRECTORY
5CGD ... LDCT 5 #202 [ TWO SPACES IN CASE NOT PSEUDO
5CGF ... JBC XPS,2,BEPSEUDO
5CGG ... LDCT 5 #602 [ P FOR PSEUDO-USER - CHAR 21
5CGH ...XPS ADN 5 #1220 [ : FOR DIRECTORY IN CHAR 23 - OK AS
5CGJ ... STO 5 A1+7(3) [ FGN/LANG = (1/C1) IN CHARS 13-18
5CGK ... LDN 1 EUSE1(2) [ SET UP TO GIVE USERNAME, NOT TYPE
5CGL ... BRN YDIR
5CGM ...QTY LDX 0 ETM(2)
5CGN ...NTY TXU 0 POSSTYPES(1)
5CGP ... BCC TYF
5CGQ ... LDX 6 POSSTYPES(1)
5CGR ... ADN 1 1
5CGS ... BNG 6 NTY
5CGT ...TYF SBX 1 FX1
5CGW ... LDX 5 1
5CGX ...# [ X5 SET TO 'SIMPLIFIED' TYPE:
5CGY ...# [ 0 GRAPHIC 1 DISC 2 TAPE 3 NORMAL
5CG^ ...# [ 4 ALLCHAR 5 DRUM 6 AMORPHOUS
5CH2 ... SMO 1
5CH3 ... ADN 1 TYPES(1) [ TYPES ADDRESS + 3 * TYPE
5CH4 ... JBC XMFD,2,BEMDF [ IF APPROPRIATE, PRINT
5CH5 ... LDN 1 UFD [ 'ULTIFILE DEF', NOT TYPE
5CH6 ...XMFD ADX 1 FX1
5CH7 ...YDIR LDX 6 1
5CH8 ... MVCH 6 12 [ 'TYPE' IN CHARS 24-35
5CH9 ... ERN 5 1 [ TEST IF DISC
5CH= ... LDX 1 ECOPS(2)
5CH? ... BNZ 5 XBS
5CH# ... LDX 0 EORG(2)
5CH* ... DCH 0 A1+10(3) [ INSERT BUCKET SIZE - CHAR 33
5CHB ...XBS SRL 1 15 [ NO. OF BLOCKS
5CHC ... CALL 6 XINTCONV
5CHD ... LDN 6 5
5CHF ... MVCH 6 4 [ FILE SIZE IN CHARS 36-39
5CHG ... LDX 6 EDLD(2)
5CHH ... BZE 6 XDMPD
5CHJ ... LDX 7 ETLD(2)
5CHK ... DATECON 6
5CHL ... LDX 4 ACOMMUNE1(2) [ SAVE DATE - AVOIDS EXTRA
5CHM ... LDX 5 ACOMMUNE2(2) [ HUNT FOR FILE/FAPB
5CHN ... TIMECON 7
5CHP ... MHUNTW 3,FILE,FAPB
5CHQ ... LDCT 7 #400
5CHR ... ADN 7 A1+12(3)
5CHS ... LDN 6 4
5CHT ... MVCH 6 8 [ DATE/TIME LAST DUMPED IN
5CHW ... LDN 6 ACOMMUNE1(2)
5CHX ... MVCH 6 8 [ CHARS 43-49 AND 51-58
5CHY ... MHUNTW 2,FILE,FRB
5CH^ ... LDX 1 EINC(2)
5CJ2 ... CALL 6 XINTCONV
5CJ3 ... LDCT 6 #200
5CJ4 ... ADN 6 4 [ INCREMENT RIGHT-JUSTIFIED IN
5CJ5 ... MVCH 6 7 [ COLUMNS 59-65. USUALLY IN 62-65.
5CJ6 ... BRN ONOFF
5CJ7 ...XDMPD LDN 6 UNDUMPED(1)
5CJ8 ... MVCH 6 26
5CJ9 ...ONOFF LDEX 6 ECOPS(2)
5CJ= ... LDX 4 POFF(1)
5CJ? ... LDX 5 ACES
5CJ# ... JMBAC QOFF,2,BEARCHIVE,BESYSARCH
5CJ* ... LDX 5 PARCM(1) [ MANAGER-ARCHIVED
5CJB ... JBS QOFF,2,BESYSARCH
5CJC ... LDX 5 PARC(1) [ USER-ARCHIVED ONLY
5CJD ...QOFF BZE 6 OFF
5CJF ... LDX 4 PON(1)
5CJG ... LDCT 1 #600
5CJH ... JBC XALL,2,BEALLINCS
5CJJ ... ORN 4 #32 [ ON* IF DUMP ON ALL INCS
5CJK ... LDN 1 1 [ * DISPLACES ANY SUBSEQUENT '?'
5CJL ...XALL JBC OFF,2,BEDUMP
5CJM ... LDN 0 #17
5CJN ... DCH 0 4(1) [ ON? OR ON*?
5CJP ... BRN OFF
5CJQ ...# DEFER PROCESSING OF (T), (E) ETC. -
5CJR ...# RETURNED TAPES REQUIRE THAT CODE
5CJS ...#
5CJT ...XOFIL LDN 6 PARS+2(1)
5CJW ... MVCH 6 1
5CJX ... LDN 7 A1+8(3)
5CJY ... LDN 6 PEX(1)
5CJ^ ... MVCH 6 7
5CK2 ... BRN NORP
5CK3 ...#
5CK4 ...REALTAPE
5CK5 ... LDN 6 PARS+2(1) [ NO LANG CODE FOR TAPES
5CK6 ... MVCH 6 1
5CK7 ... LDN 7 A1+7(3)
5CK8 ... LDX 0 EWKNAME1(2)
5CK9 ... BPZ 0 TSN
5CK= ... LDN 5 #21 [ ! FOR WORKTAPE
5CK? ... SMO 3
5CK# ... DCH 5 A1+6
5CK* ... LDN 6 EWKNAME1(2)
5CKB ... MVCH 6 12
5CKC ... ADN 7 1
5CKD ...TSN LDN 6 PTSN(1)
5CKF ... MVCH 6 4
5CKG ... LDX 1 7
5CKH ... LDX 5 ESER(2)
5CKJ ... LDN 6 8
5CKK ...TSND LDN 4 0
5CKL ... SLL 45 3
5CKM ... DCH 4 0(1)
5CKN ... BCHX 1 £
5CKP ... BCT 6 TSND
5CKQ ... LDX 7 1
5CKR ... SMO FX1
5CKS ... LDN 6 PRSN
5CKT ... MVCH 6 8
5CKW ... LDX 1 EREEL(2)
5CKX ... CALL 6 XINTCONV
5CKY ... LDN 6 5
5CK^ ... MVCH 6 4
5CL2 ... LDX 0 EWKNAME1(2) [ NO ROOM FOR RETENTION PERIOD ON
5CL3 ... BNG 0 NORP [ WORKTAPES - NOT INTERESTING ANYWAY
5CL4 ... LDN 6 PRP(1)
5CL5 ... MVCH 6 8
5CL6 ... LDX 1 ERET(2)
5CL7 ... CALL 6 XINTCONV
5CL8 ... LDN 6 5
5CL9 ... MVCH 6 4
5CL= ...NORP LDCT 7 #200
5CL? ... LDX 4 ACES
5CL# ... LDX 5 ACES
5CL* ... ADN 7 A1+18(3) [ CHARACTER 65
5CLB ...OFF LDN 6 4
5CLC ... JBS QTE,2,BETEMP
5CLD ... JBS QUF,2,BEUSERFREZ
5CLF ... JBC POL,2,BEERASE
5CLG ... LDN 5 #3045 [ (E)
5CLH ... JBC PTER,2,BELIB
5CLJ ... LDN 5 #3062 [ (R) FOR TO-BE-RETURNED TAPE
5CLK ... BRN PTER
5CLL ...QUF LDN 5 #3046 [ (F)
5CLM ... BRN PTER
5CLN ...QTE LDN 5 #3064 [ (T)
5CLP ...PTER SLL 5 12
5CLQ ... ORN 5 #3120
5CLR ... LDN 0 #57 [ THESE FOUR
5CLS ... ANDX 0 4 [ LINES MAKE
5CLT ... BNZ 0 SL456 [ THE OUTPUT
5CLW ... SRL 4 6 [ PRETTIER
5CLX ...SL456 SLC 45 6 [ KEEP (..) WITHIN 72 CHARS
5CLY ...POL BCHX 7 £
5CL^ ... MVCH 6 6
5CM2 ...# WE HAVE NOW REACHED COLUMN 72
5CM3 ...# - DEFAULT MOP WIDTH WILL BREAK LINE HERE
5CM4 ...#
5CM5 ...# COMMON CODE FOR LAST ACCESS / LAST WRITE
5CM6 ... LDN 4 1
5CM7 ... LDX 5 EDLA(2) [ LAST ACCESS FIRST
5CM8 ... LDX 6 ETLA(2)
5CM9 ...PLW BCHX 7 £
5CM= ... BCHX 7 £
5CM? ... BNZ 5 VALID
5CM# ... LDX 5 PDASH(1) [ DATE NULL - PRINT ' -- '
5CM* ... LDX 6 PDASH+1(1)
5CMB ... LDN 2 5
5CMC ... LDX 0 3
5CMD ... LDX 3 7
5CMF ... BRN NULDT
5CMG ...VALID SBX 7 3
5CMH ... TIMECON 6
5CMJ ... LDX 0 5 [ ACCUMULATOR MANIPULATIONS
5CMK ... LDX 5 ACOMMUNE1(2) [ SAVE 1 OR 2 MHUNTW'S
5CML ... LDX 6 ACOMMUNE2(2) [ AND SIMPLIFY MVCH'S BELOW
5CMM ... DATECON 0
5CMN ... MHUNTW 3,FILE,FAPB
5CMP ... LDX 0 3
5CMQ ... ADX 3 7
5CMR ... LDN 2 ACOMMUNE1(2)
5CMS ...NULDT MVCH 2 8 [ DATE
5CMT ... LDN 2 5
5CMW ... SBN 4 1
5CMX ... MVCH 2 8 [ TIME
5CMY ... LDX 7 3
5CM^ ... LDX 3 0 [ RESET X3 = FILE/FAPB
5CN2 ... MHUNTW 2,FILE,FRB
5CN3 ... BNG 4 RESI [ EXIT LOOP AFTER 'LAST WRITTEN'
5CN4 ... LDX 5 EWRITDAY(2)
5CN5 ... LDX 6 EWRITTIME(2)
5CN6 ... BRN PLW [ BACK AGAIN FOR 'LAST WRITTEN'
5CN7 ...RESI JMBS PRUNE,2,BELIB,BEEXO
5CN8 ... SMO 2
5CN9 ... LDCH 1 EALLOC
5CN= ... BZE 1 XALOC
5CN? ... CALL 6 XINTCONV
5CN# ... SLL 45 12
5CN* ... LDN 4 #2041 [ A FOR ALLOCATED
5CNB ... SRL 45 12
5CNC ... BRN PRES
5CND ...XALOC LDEX 0 ECOPS(2)
5CNF ... LDX 5 ACES
5CNG ... BZE 0 PRES
5CNH ... SBX 7 3
5CNJ ... STEP [ GET RESIDENCE NO. FROM BLKS RECORD
5CNK ... LDX 1 1(3)
5CNL ... CALL 6 XINTCONV
5CNM ... MHUNTW 2,FILE,FRB
5CNN ... MHUNTW 3,FILE,FAPB
5CNP ... ADX 7 3
5CNQ ...PRES LDN 6 5 [ PRINT RESIDENCE NUMBER
5CNR ... MVCH 6 4 [ ... OR BLANK IF OFFLINE
5CNS ...PFORM LDX 0 ECOPS(2)
5CNT ... SRL 0 15
5CNW ... LDX 6 GMTNOW
5CNX ... SBX 6 EGMTLA(2)
5CNY ... ADX 6 EAVACC(2)
5CN^ ... MPY 0 6
5CP2 ... SRA 01 6
5CP3 ... BZE 0 PFN
5CP4 ... NGNC 1 1 [ FORMULA OVERFLOW - SET MAX
5CP5 ...PFN CALL 6 XINTCONV
5CP6 ...PF LDN 6 4
5CP7 ... MVCH 6 8
5CP8 ... BRN PLIN [ PRINT FULL LINE
5CP9 ...#
5CP= ...PRUNE LDX 2 7 [ REMOVE TRAILING SPACES
5CP? ...PRNX LDX 7 2 [ ON MAG. TAPE & EXOFILE LINES
5CP# ... SLC 2 2
5CP* ... SBN 2 1
5CPB ... SRC 2 2
5CPC ... LDCH 0 0(2)
5CPD ... ERN 0 #20
5CPF ... BZE 0 PRNX
5CPG ... SBN 7 A1(3)
5CPH ... LDX 6 7
5CPJ ... SRL 6 18
5CPK ... DCH 6 A1+1(3)
5CPL ... NGXC 6 6
5CPM ... ADN 7 0
5CPN ... DEX 7 A1(3)
5CPP ...PLIN LDX 2 FX2
5CPQ ... IF +AWORK1(2),NZ
5CPR ... THEN
5CPS ... APPEND 1,FORCED
5CPT ... ACROSS LISTDIR,2
5CPW ... ELSE
5CPX ... NAME 3,GMON,AOUT
5CPY ... LDCT 5 #600
5CP^ ... LDX 4 A1(3)
5CQ2 ... ANDX 5 A1+1(3)
5CQ3 ... TXU 5 GZERO
5CQ4 ... SBN 4 2
5CQ5 ... SLL 45 2
5CQ6 ... STO 4 A1(3)
5CQ7 ... CLOSETOP
5CQ8 ... MFREEW FILE,FRB
5CQ9 ... UPPLUS 2
5CQ= ... FI
5CQ? ...)
5CTL MENDAREA 20,K99LISTDIRF
5D*= #END
^^^^ ...20145372000200000000