{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LISTLOOP867)}}
====== LISTLOOP867 ======
(George Source)

**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:ALTLEND|ALTLEND]], [[george:macro:CLHLFDON|CLHLFDON]], [[george:macro:COOR1|COOR1]], [[george:macro:DCA|DCA]], [[george:macro:DEMAND|DEMAND]], [[george:macro:DISENGPER|DISENGPER]], [[george:macro:DOWN|DOWN]], [[george:macro:ENGPER|ENGPER]], [[george:macro:FI|FI]], [[george:macro:FILEMOVE|FILEMOVE]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOPACK|GEOPACK]], [[george:macro:GPERI|GPERI]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IF|IF]], [[george:macro:JBUSY|JBUSY]], [[george:macro:JNHLFDON|JNHLFDON]], [[george:macro:JUNBUSY|JUNBUSY]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LADDP|LADDP]], [[george:macro:LFBBS|LFBBS]], [[george:macro:LFBBUS|LFBBUS]], [[george:macro:LFBITCLR|LFBITCLR]], [[george:macro:LFBITSET|LFBITSET]], [[george:macro:LFEND|LFEND]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LPUNSET|LPUNSET]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OUTPER|OUTPER]], [[george:macro:PHOTO|PHOTO]], [[george:macro:REWIND|REWIND]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:THEN|THEN]], [[george:macro:UNLOCK|UNLOCK]]

<code - LISTLOOP867.txt>22FL    #OPT  K0LISTLOOP=0  
22PD ...#OPT ENHPLOW=0  
22^=    #OPT  AERRSIM=0 
23DW ...#OPT           HATP=0   
23YG ...#OPT           ATPOLTR=0
24D6 ...#OPT           ATPOLTRP2=0  
25CB    #LIS  K0LISTLOOP>K0LISTFILE>K0ALLGEO>K0GREATGEO>K0COMMAND   
25X2    #SEG  LISTLOOP  
26BL                   8HLISTLOOP   
26LD ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
26W=          SEGENTRY K1LISTLOOP,POINT1
27TG    [   
28*6    [CENTRAL LINE PRINTER CODE  
28SQ    [THIS SEGMENT CONTAINS THE INNER LOOP OF LISTFILE WHICH READS RECORDS   
29#B    [FROM THE SPECIFIED FILE  DOES ANY SIMPLE CONVERSION NECESSARY AND  
29S2    [OUTPUTS THE RECORD ON THE SPECIFIED PRINTER
2=?L    [EXTRA CODE SHOULD NOT BE INSERTED IN THE MAIN PATH WITHOUT 
2=R=    [CAREFUL CONSIDERATION OF THE OVERHEAD. 
2?=W    [THE CONVERSION IMPLEMENTED IS AS FOLLOWS:  
2?QG    [IF A SHIFT FILE IS LISTED  
2#=6    [DATA IS FIRST CONVERTED TO GRAPHIC,UNLESS 'SPECIAL' WAS
2#PQ    [ONE OF THE COMMAND PARAMETERS,WHEN NO CONVERSION IS DONE.  
2*9B    [THE DATA IS CONVERTED ONE RECORD AT A TIME BY DECANTING
2*P2    [THE RECORD FROM THE USAGE BLOCK INTO AN ADATA/ACONV BLOCK  
2B8L    [AND USING THE TRANSFORM MACRO.THE FLAG K IS USED TO SHOW   
2BN=    [THE PRESENCE OF AN ADATA/ACONV BLOCK TO AVOID THE HUNT 
2C7W    [OVERHEAD FOR THE NORMAL,NO-CONVERSION PATH.
2CMG    [   
2D76    [IF THE RECORD IS LONGER THAN CAN BE ACOMODATED IN ONE TRANSFER 
2DLQ    [THEN THE RECORD IS SPREAD  
2F6B    [OVER MANY TRANSFERS WITH SUITABLE CONTINUATION LINES FOR LP OUTPUT.
2FL2    [THE FLAG H IS SET TO INDICATE THAT THE CURRENT TRANSFER IS ONE 
2G5L    [OF THE SUBSEQUENT COMPONENTS OF A MULTI-TRANSFER RECORD.   
2GK=    [   
2H4W    [THE  BUFFER FOR A TRANSFER IS CONTAINED IN THE ACTLF AND STARTS
2HJG    [AT THE IDENTIFIER GZDATA.WHILE THE TRANSFER IS IN PROGRESS THE 
2J46    [ACTLF MUST REMAIN LOCKED [SO THAT EXECUTIVE CAN FIND IT] AND OFF   
2JHQ    [THE LIST OR THE QUEUE (ACHIEVED BY COOR1).WHEN THE TRANSFER HAS
2K3B    [FINISHED EXECUTIVE RESTARTS THE ACTLF. 
2KH2    [   
2L2L    [DATA MANIPULATION IS CONTROLLED BY INFORMATION CONTAINED IN
2LG=    [THE FOLLOWING LOCATIONS IN THE ACTLF   
2L^W    [   
2MFG    [     GZPOINT  CONTAINS A POINTER RELATIVE TO THE START OF THE  
2M^6    [              RECORD,INDICATING HOW MUCH DATA HAS ALREADY BEEN TRANSFER
2NDQ    [   
2NYB    [     GZDUMP   CONTAINS THE DUMP ADDRESS RELATIVE TO THE START  
2PD2    [              OF THE BUFFER.   
2PGK ...#UNS  ANIP  
2PK8 ...(   
2PMR ...[              ALSO, JUST BEFORE THE PERI,CONTAINS THE NUMBER OF
2PQB ...[              CHARS FOR CURRENT TRANSFER   
2PS^ ...)   
2PXL    [   
2QC=    [     GZTRANS  CONTAINS THE NUMBER OF CHARACTERS OF DATA FOR
2QWW    [              CURRENT TRANSFER.
2RBG    [   
2RW6    [     GZLENGTH CONTAINS THE NUMBER OF CHARACTERS OF DATA IN 
2S*Q    [              THE CURRENT RECORD   
2STB    [   
2T*2    [   
2TSL    [***********************************************************************
2W#=    [DATA AREA  
2WRW    [              ---------------------------------------- 
2X?G    [   
2XR6    TLP2           +2   
2Y=Q    SM             #07777777           [EQUAL MASK  
2YQB    TLP            +1                  [LP COMPARISON WORD  
2^=2    SMLP           +7036875            [LP MAGIC CONVERSION NUMBER  
2^PL    NUMLP          +8000000            [LP MAXIMUM LINE NUMBER  
329=    TCA            +0.3                [LP BUFFER MODIFIER  
32NW    XCONT          4H  -           [CONTINUATION LINE MARK-OUTPUT AT END OF 
338G                   [EACH LINE OF A MULTILINE RECORD 
33N6    [   
347Q    SETUPBIT       #10000000
34MB    PAGELEN        +66  
3572    [   
35LL    [***********************************************************************
366=    [SUBROUTINE AREA
36KW    TIDYUP  
375G    [THIS S/R TIDIES UP WHEN A LISTING IS TO END
37K6          LFBBUS   K,2,NOADATA         [J IF NO CONVERSION BLOCK
384Q          MHUNTW   1,ADATA,ACONV
38JB          FREECORE 1
3942          LFBITCLR K,2                 [CLEAR CONVERSION FLAG   
39HL    NOADATA 
3=3= ...      MHUNTW   1,GOUT,INFOLIST  
3=GW          LDX   4  GREST(1) 
3?2G          LDX   0  AWORK4(2)
3?G6          BPZ   0  NLSU                [J IF NOT CURRENTLY LISTING SETUP
3?^Q          STOZ     GREST(1) 
3#FB          STOZ     GNUM(1)  
3#^2          EXIT  3  0
3*DL    NLSU  FREECORE 1
3*H9 ...#SKI ENHPLOW
3*KS ...(   
3*NC ...      LFBITCLR U,2                 [CLEAR ANY PAPER LOW BITS SET
3*R2 ...      LFBITCLR V,2  
3*TK ...)   
3*Y=          LDX   0  SETUPBIT(1)  
3BCW          ANDX  0  AWORK2(2)
3BXG          BZE   0  NSUA                [J IF NO SETUP FILE AT ALL   
3CC6 ...      MHUNTW   1,GOUT,INFOSET   
3CWQ          FREECORE 1
3DBB    NSUA  EXIT  3  1
3DW2    [   
3F*L    SLOCKC  
3FT=    [THIS S/R IS USED BY THE LOCK MACRO TO SET X2=FX2   
3G#W          LDX   2  FX2  
3GSG          EXIT  1  0
3H#6    [THIS IS A SUBROUTINE FOR CONVERTING THE BINARY NUMBER IN X5 TO DECIMAL 
3HRQ    [CHARACTERS STORING THE RESULT IN THE LOCATION WHOSE ADDRESS IS IN X2   
3J?B    [   
3JR2    SEQUENCE
3K=L          MODE     1
3KQ=    SCBD  CBD   4  0(2) 
3L9W          BCHX  2  £
3LPG          BCT   3  SCBD 
3M96          MODE     0                   [DON'T SUPPRESS ZEROES FOR LAST  
3MNQ          CBD   4  0(2)                [CHARACTER   
3N8B          BCHX  2  £
3NN2          DCH   1  0(2) 
3P7L          LDX   1  FX1  
3PM=          LDX   2  FX2  
3Q6W          EXIT  0  0
3QLG    [   
3R66    [THIS ROUTINE PERFORMS THE PERI ON THE DEVICE AND CHECKS THE REPLY FOR  
3RKQ    [DISENGAGED AND INOPERABLE STATES   
3S5B    [   
3S6C ...#UNS  ANIP  
3S7D ...(   
3S8F ...[ ENTRY FROM SRER SUBROUTINE (CORRUPT FILE) IF NIP ACTLF
3S9G ...PERI4 KEEPREP 0,CORRUPT 
3S=H ...[ ENTRY TO GIVE CHANGED REPLY   
3S?J ...PERI5 ORX   0  GSIGN
3S#K ...      STO   0  GZDUMP(2)
3S*L ...      SBX   5  FX1  
3SBM ...XLPS  DOWN     LISTPREP,4   
3SCN ...      LDX   0  GZDUMP(2)
3SDP ...      BNG   0  NOT  
3SFQ ...      BRN      XNIP                 [NORMAL ENTRY - ADD TO ALFTRANS ETC 
3SGR ...[   
3SHS ...)   
3SK2    PERI  SBX   5  FX1                 [ADJUST LINK 
3SLC ...#UNS  ANIP  
3SMS ...(   
3SP9 ...[ IF NIP ACTLF GO DOWN TO LISTPREP TO DO PERI   
3SQL ...      LDX   2  FX2  
3SS3 ...      LDX   4  GZDUMP(2)
3STD ...      BZE   4  NOT                  [ZERO CHAR COUNT - DO NOT PRINT 
3SWT ...      LDX   0  CPPTR(2) 
3SY= ...      BZE   0  XLPS 
3S^M ...      DCA      ,STO,4,COUNT         [STORE CHAR COUNT IN CONTROL AREA   
3T34 ...)   
3T4L    REP   DCA ,LDX,4,COUNT  
3TJ=          BZE   4  NOT  
3W3W          LDX   1  FX1  
3WHG          LDX   4  TCA(1)   
3X36          LOCKC    2,SLOCKC 
3XGQ          ADN   4  GZDATA(2)
3Y2B          DCA      ,STO,4,CTSA  
43CQ          GPERI ,2  
43XB          COOR1 
44C2          UNLOCK   2
45TW          LDX   4  FINISH   
46*G          SLL   4  2
46T6          BNG   4  SCANTY              [ 'FINISH NOW'   
47#Q          LDCT  4  #50  
47SB          ANDX  4  CPRW1(2) 
48#2          BNZ   4  NOTENG              [J IF FAIL OR DISENGAGED 
48F8 ...#UNS  ANIP  
48LB ...XNIP
48RL          LDN   0  1
49?=          ADS   0  ALFTRANS(2)  
49BB ...#UNS  ANIP  
49FG ...      LDX   4  GZDUMP(2)
49JL ...#UNS  ANIP  
49MQ ...#SKI
49QW          DCA      ,LDX,4,COUNT 
4==G          SRL   4  2
4=Q6          ADS   4  ALFWORDS(2)  
4?9Q    NOT   ADX   5  FX1  
4?PB          EXIT  5  0                   [EXIT
4#92    #   
4#NL    # THE FOLLOWING DEALS WITH RESTARTS 
4*8=    #   
4*MW    [ MULTIPAGE RESTARTS
4B7G    [ IF GLEN=0 THEN NO MULTIPAGE RESTART IS REQUIRED   
4BM6    [ GLEN=IPAGE-1 AND IS SET UP IN LISTPREP. IPAGE IS MAX NUMBER OF PAGES  
4C6Q    [ THAT CAN BE REPEATED  
4CLB    [ GNEXT IS A POINTER TO THE NEXT GREST TO BE SET
4D62    [ IF GREST+1=0 THEN NO MULTIPAGE RESTART IS REQUIRED AS ONLY ONE PAGE   
4DKL    [ HAS BEEN LISTED.  
4F5=    [ ALPSETUP IS SET EQUAL TO IPAGE BEFORE THE REQUEST 
4FJW    [ AFTER THE PAGES COMMAND ALPSETUP IS EQUAL TO THE NUMBER-1 
4G4G    [   
4GJ6    PAGEREST
4H3Q          SBX   3  FX1  
4HHB ...      MHUNTW   1,GOUT,INFOLIST  
4J32          LDXC  4  GREST(1) 
4JGL          BCC      PAGES1              [J NOT PAGE RESTART  
4JHX ...#SKI ENHPLOW
4JK8 ...(   
4JLF ...      LFBBUS   U,2,SUSU            [J IF PAPER LOW NOT BEEN FOUND   
4JMQ ...      LFBITCLR U,2                 [OTHERWISE CLEAR PAPER LOW BITS  
4JP3 ...      LFBITCLR V,2                 [AND OUTPUT RELOAD MESSAGE BEFORE
4JQ# ...      LDCT  6  #100                [IF NO PLOW REPLY ON LAST TRANSFER   
4JRK ...      ANDX  6  CPRW1(2)            [THEN ASSUME OPERATORS HAVE BEATEN   
4JSW ...      BZE   6  SUSU                [US TO IT
4JW7 ...      DOWN     LISTNEXT,10         [CONTINUING RESTART ACTION   
4JXD ...SUSU
4JYP ...)   
4K2=          LDX   6  GLEN(1)  
4KFW          BZE   6  PAGES1              [J IPAGE=1   
4K^G          LDX   5  GREST+1(1)   
4LF6          BZE   5  PAGES1              [J ONLY 1 PAGE LISTED
4LYQ          LDX   6  GLEN(1)  
4MDB          ADN   6  1                   [THIS LISTFILE (FOR PAGES COMMAND)   
4MY2          STO   6  ACOMMUNE6(2)        [THEN PUT IT IN ACOMMUNE6
4PBW          GEOPACK  1
4PWG          LONGSET  #104,XGEOER,1
4RT2          OUTPER
4S#L          DEMAND   ,JPAGES,PAGES2,XGEOER,REE,1  
4SS=                       [PLEASE GIVE PAGES FOR ERROR RESTART ON UNIT %A  
4T?W    PCD 
4TRG ...      MHUNTW   1,GOUT,INFOLIST  
4W?6          LDX   5  GNEXT(1) 
4WQQ          LDX   6  ACOMMUNE6(2)        [SET X6=NO OF PAGES FOR ERROR RESTART
4X=B          SBN   6  1                   [MINUS 1 
4XQ2          SBX   5  6
4Y9L          BPZ   5  OK   
4YP=          ADX   5  GLEN(1)  
4^8W          ADN   5  1
4^NG    OK    SMO      5                   [PICK UP CORRECT RESTART LINE NUMBER 
5286          LDX   5  GREST(1) 
52MQ          BNZ   5  YOK                 [NO OF PAGES GIVEN MIGHT BE<IPAGE
537B          LDX   5  GREST(1) 
53M2    YOK   STO   5  GREST(1) 
546L          LDX   5  GNUM(1)             [CURRENT LINE NO.
54G*          LDX   4  GREST(1)            [RESTART LINE NO.
54W4          ANDX  4  BITS22LS 
559R          SBX   5  4
55KG          LDXC  4  GLNO(1)  
5656          BCS      SDT                 [J IF LIST TO END OF FILE
56JQ          ADN   5  2
574B          ADS   5  GLNO(1)             [UPDATE NO REMAINING 
57J2          SBN   5  2
583L    SDT   SBS   5  GNUM(1)             [SET NEW START LINE NO   
58H=          STOZ     GPREM(1) 
592W          LFBITSET J,2                 [PAGE RESTART SWITCH 
594D ...      STOZ     GNEXT(1)            [ZEROISE GREST POINTER   
5962 ...      STOZ     GREST+1(1)   
597J ...      LDX   6  GLEN(1)                 [LOAD LENGTH OF GREST AREA   
5996 ...      SBN   6  1
59=N ...      BZE   6  PAGES1              [J IF ONLY 2 GREST WORDS 
59#= ...      LDN   4  GREST+1(1)          [OTHERWISE ZEROISE OTHER GREST   
59*S ...      LDN   5  GREST+2(1)          [WORDS   
59CB ...      SMO      6
59DY ...      MOVE  4  0
59GG    PAGES1  
5=26          LDX   1  FX1  
5=FQ          ADX   3  1
5=^B          EXIT  3  0
5?F2          [THIS S/R TRANSFERS DATA FROM FILE TO BUFFER  
5?YL    TRANSFER
5#D=          SLL   3  2
5#XW          ADX   3  GZPOINT(2)   
5*CG          SRC   3  2
5*X6          LDN   4  GZDATA+1(2)  
5BBQ          SLL   4  2
5BWB          ADX   4  GZDUMP(2)
5CB2          SRC   4  2
5CTL          LDX   2  GZTRANS(2)   
5D*=          BZE   2  NODATA   
5DSW          SMO      2
5F#G          MVCH  3  0
5FS6    NODATA  
5G?Q          LDX   2  FX2  
5GRB          EXIT  0  0
5H?2    NOTENG  
5H#3 ...#UNS AR1
5H*4 ...(   
5HB5 ...      LDX   4  CPPTR(2) 
5HC6 ...      JNHLFDON 4,NOTENC 
5HD7 ...      ENGPER   NOTENA,4,NOTENB,0
5HF8 ...      BRN      REP  
5HG9 ...NOTENB  
5HH= ...      CLHLFDON 4
5HJ? ...      BRN      SCANTY   
5HK# ...NOTENA  
5HL* ...      CLHLFDON 4
5HMB ...      BRN      SBRKIN   
5HNC ...NOTENC  
5HPD ...)   
5HQL          LDCT  0  #40  
5J==          ANDX  0  CPRW1(2) 
5KP6          BNZ   0  XERREST  
5L8Q          LDN   4  0
5LNB          STOZ     ACOMMUNE7(2) 
5M82    YESINVALID  
5MML          LDX   0  ACOMMUNE7(2) 
5N7=          BNG   0  TEND                [J IF INV CHAR ON LAST REC OF FILE   
5NLW          ENGPER   SBRKIN,,SCANTY   
5P6G          BZE   4  REP                 [J IF NOT INVALID CHAR ERROR 
5PL6          ANDX  4  BITS22LS            [REMOVE B0   
5Q5Q          BNZ   4  SAMEREC             [J IF STILL ON SAME REC AS BEFORE CHE
5QKB ...      MHUNTW   3,GOUT,INFOLIST     [ELSE UPDATE GNUM=CURRENT RECORD 
5R52          LDN   0  1
5RJL          ADS   0  GNUM(3)  
5S4=          LDX   4  GLNO(3)  
5SHW          BNG   4  SAMEREC             [J IF LIST TO EOF
5T3G          SBN   4  1
5TH6          STO   4  GLNO(3)  
5W2Q          BZE   4  TEND                [J IF LAST REC OF LISTING INVALID
5XFL    SAMEREC 
5X^=          BRN      NOTP1
5YDW    SCANTY  
5YYG          CALL  3  PAGEREST 
5^D6          BRN      SCANT
5^XQ    XERREST 
6296 ...      LADDP   ,0
62GG ...      SMO      0
62RW ...      LDX   0  AREPERT  
635= ...      SLL   0  13   
63BL          BPZ   0  NOTECCP             [J IF NOT 48 CHAR REP
64TG          DOWN  LISTEXCP,3             [ELSE TEST FOR INVALID CHARACTER 
65*6    TOINVTEST   
65SQ          LDX   4  ACOMMUNE8(2) 
68=W          BNZ   4  YESINVALID          [J IF INVALID CHARACTER  
68QG          BRN      NOTINV              [J IF NO INVALID CHAR
69=6    NOTECCP 
69PQ          LDN   0  #1000
6=9B          ANDX  0  AWORK1(2)
6=P2          BZE   0  NOTINV              [J IF NOT MODE 4 
6?8L          DOWN     LISTEXCP,5          [ELSE TEST FOR INVALID CHAR  
6?N=          BRN      TOINVTEST
6#7W    NOTINV  
6#MG          CALL  3  PAGEREST 
6*76          ENGPER   SBRKIN,,SCANT
6BL2 ...      MHUNTW   1,GOUT,INFOLIST  
6C5L          LDX   4  AWORK4(2)
6DJG          ADX   5  FX1  
6F46          BNG   4  PERI                [J IF SETUP LISTING  
6FHQ          LDXC  0  GREST(1) 
6G3B          BCC      NPAGE               [J IF NOT PAGE RESTART   
6GH2          REWIND
6GN8 ...      MHUNT    1,GOUT,INFOLIST  
6GTB ...      LDX   4  GNUM(1)  
6H57 ...      ADN   4  1
6H#Y ...SKIPLOOP
6HG6 ...      STEP                         [ TO RESTART POINT   
6HM# ...      BCT   4  SKIPLOOP 
6HSG ...      LDX   0  SETUPBIT(1)  
6H^W          ANDX  0  AWORK2(2)
6JFG          BZE   0  K1LISTLOOP          [J IF NO SETUP FILE  
6J^6          LPUNSET   
6KDQ          LFBITCLR I,2                 [LINE-UP MESSAGE SWITCH IN LISTPREP  
6KYB ...      MHUNTW   1,GOUT,INFOSET      [REPEAT SETUP FILE   
6LD2 ...      NAME     1,GOUT,INFOLIST  
6LXL          FILEMOVE 1,0  
6MC=          LDX   3  GSIGN               [SETUP FILE  
6MWW          ORS   3  AWORK4(2)           [INDICATOR   
6NBG          REWIND
6NW6          BRN      K1LISTLOOP   
6P*Q    NPAGE SMO      FX1  
6PTB          LDX   0  SETUPBIT 
6Q*2          ANDX  0  AWORK2(2)
6QSL          BZE   0  NSET 
6R#=          LPUNSET   
6RRW    NSET  LDCT  4  #200 
6S?G          ANDX  4  GREST(1) 
6SR6          BZE   4  PERI                [J IF LINE RESTART   
6T=Q          BRN      SCANT               [ALL RESTART=CANTDO  
6TQB    #                              WE WANT TO ISOLATE THE CONDITION OF PAGE 
6W=2    #                              RESTART ON A MAIN SPEC STAT FILE SO THAT 
6WPL    #                              WE CAN REALIGN THE PAPER 
6X9=    PAGES2  
6XNW          LDN   6  1
6Y8G          STO   6  ACOMMUNE6(2) 
6YN6          BRN      PCD  
6^7Q    SBRKIN  
6^MB          CALL  3  TIDYUP   
7272          BRN      QSETUP              [LISTING SETUP FILE  
72BS          DOWN     LISTINIT,3          [ TERMINATORS
72LL          LFEND    TE   
736=    QSETUP  
73KW          ACROSS   LISTPREP,3   
73M5    [   
73MG    [  THE FOLL. S/R IS PART OF THE LISTFILE ENHANCEMENT TO 
73MX    [  READ ERROR RESILIENCE.   
73N#    [  THE S/R IS CALLED IF STEP ENCOUNTERS A CORRUPT BLOCK 
73NP    [  (INDICATED BY FLAG 'M' BEING SET IN THE ACTLF)   
73P6    [  THE DEVICE IS DISENGAGED WITH THE MESSAGE :- 
73PH    [  'PSE ENGAGE UNIT N IF COMPLETION OF CORRUPT LISTING REQUIRED '   
73PY    [   
73Q*    [   
73QQ    SRER
73QR ...#UNS  ANIP  
73QS ...(   
73QT ...[ IF NIP ACTLF GO TO TELL NIP PROGRAM   
73QW ...      LDX   2  FX2  
73QX ...      LDX   0  CPPTR(2) 
73QY ...      BZE   0  PERI4
73Q^ ...)   
73R2 ...#UNS G3SIGNET   
73R3 ...(   
73R4 ...      SMO      FX2  
73R5 ...      LDX   0  CPPTR
73R6 ...      IF  0,U,ASIGNETPTR
73R7 ...      THEN  
73R8 ...)   
73R9 ...      SBX   5  FX1  
73RJ    XBSY  JUNBUSY  ,NOTBSY             [WAIT UNTIL DEVICE NOT BUSY  
73R^          BRN      XBSY 
73SB    NOTBSY  
73SR          DISENGPER                    [THEN DISENGAGE IT   
73T8          OUTPER                       [PSE ENGAGE MESSAGE  
73TK          ENGPER   STERM,,SCDE,5      [APP. JUMPS IF TERM OR CD 
73W2          ADX   5  FX1  
73W4 ...#UNS G3SIGNET   
73W6 ...(   
73W8 ...      FI
73W= ...)   
73WC          EXIT  5  0
73WS    [   
73X9    [   
73XL    [  TERMINATING ACTION   
73Y3    STERM   
73YD          CALL  3  TIDYUP   
73YT          NULL                         [TO SATISFY EXIT FROM TIDYUP S/R 
73^3          DOWN     LISTINIT,3          [ TERMINATORS
73^=          LFEND    TE   
73^M    [  IF CD REPLY GIVEN WE MUST RE-SCHEDULE
7424    [  THE REQUEST FROM BEGINNING...
742F    [   
742W    SCDE
743?          CALL  3  TIDYUP   
743N          NULL  
7445          LFEND    CD   
745G    [***********************************************************************
74K6    [MAIN BODY OF SEGMENT   
754Q    [***********************************************************************
75JB    POINT1  
75JJ ...#UNS  ANIP  
75JQ ...(   
75JY ...[ IF NIP ACTLF OUTPUT CHANGED REPLY BEFORE LISTING PROPER   
75K6 ...      LDX   0  CPPTR(2) 
75K# ...      BNZ   0  NOTNP
75KG ...      KEEPREP  0,CHANGED
75KN ...      CALL  5  PERI5
75KW ...NOTNP   
75L4 ...)   
75L# ...      MHUNT    1,GOUT,INFO  
75N= ...      LDX   0  GMODE(1) 
75Q8 ...      STO   0  AWORK2(2)
75S8          LFBITCLR N,2  
7642          LDN   7  0
76HL          LDX   0  ALOGLEN(2)          [HAS ACTLF   
773=          SBN   0  120                 [BEEN EXTENDED?  
7758 ...#UNS  ANIP  
7776 ...(   
7794 ...      LDX   5  CPPTR(2) 
77?2 ...      BNZ   5  NOTNIP   
77#Y ...      SBN   0  70                   [NIP BLOCK LONGER   
77BW ...NOTNIP  
77DS ...)   
77GW          BNG   0  NOTEXTENDED         [IF NOT JUMP 
782G          LDN   7  1                   [ELSE SET KEY
78G6    NOTEXTENDED 
78RP ...      MHUNTW   3,GOUT,INFOLIST  
795#    [  THIS CODE IS FOR THE RER ENHANCEMENT 
796G    [  IF B11 SET IN GQUAL...THEN A CORRUPTION WAS  
797N    [  DETECTED WHEN DOING CONTEXT SEARCH IN LISTOPEN   
798W    [  IF SO WE MUST CALL S/R SRER...   
79=4          LDX   0  GQUAL(3) 
79?=          ANDX  0  BIT11
79#D          BZE   0  NORERR              [J IF NO ERROR   
79*L          CALL   5  SRER
79BS    NORERR  
79^2          LDX   0  GQUAL(3) 
7=DL          STO   0  AWORK1(2)
7=Y=          ANDN  0  1                   [SPECIAL?
7?CW          BNZ   0  NOTMODE4            [J IF YES
7?XG          LDN   0  #700 
7#C6          ANDX  0  AWORK1(2)
7#WQ          BZE   0  NOTMODE4            [J IF NOT SHIFT FILE 
7#YF ...#UNS  ANIP  
7*28 ...(   
7*3X ...      LDX   0  JSOURCE3(2)  
7*5L ...      SLL   0  12   
7*7* ...)   
7*94 ...#UNS  ANIP  
7*=R ...#SKI
7*#G ...(   
7*FJ ...      LADDP      ,0 
7*LL ...      SMO      0
7*RN ...      LDX   0  AREPERT  
7*YQ ...      SLL   0  13   
7B5S ...)   
7B*L          BNG   0  NOTMODE4            [J IF
7BT=          SLL   0  1                   [NOT 96  
7C#W          BPZ   0  NOTMODE4            [CHARACTER REPERTOIRE PRINTER
7DRQ          LDN   0  #1000
7F?B          ORS   0  GQUAL(3) 
7FR2          ORS   0  AWORK1(2)
7F^= ...      BNZ   7  TOK2                [J IF KEY SET
7G7G ...#UNS  ANIP  
7G*Q ...(   
7GJ2 ...      LDX   0  CPPTR(2) 
7GQ= ...      BNZ   0  NOTNIP1  
7GYG ...      ALTLEND  FX2,320  
7H6Q ...      BRN      TOK2 
7H*2 ...NOTNIP1 
7HH= ...)   
7HPG          ALTLEND  FX2,141             [EXTEND ACTLF FOR MODE 4 PRINTING
7JYJ ...TOK2  LDN   5  4                     [MODE 4
7K8B          BRN      TOKEY
7L7L    NOTMODE4
7L*W ...      BZE   7  TOK3                [J IF KEY NOT SET
7LJ6 ...#UNS  ANIP  
7LQB ...(   
7LYL ...      LDX   0  CPPTR(2) 
7M6W ...      BNZ   0  NOTNIP2  
7M*6 ...      ALTLEND  FX2,187  
7MHB ...      BRN      TOK3 
7MPL ...NOTNIP2 
7MXW ...)   
7N66          ALTLEND  FX2,100             [AND SHORTEN ACTLF   
7N*Y ...TOK3  LDN   5  0                     [MODE 0
7NKQ    TOKEY   
7P5B          LDX   0  GCATBITS(3)  
7PK2          STO   0  AWORK3(2)
7PL? ...#UNS  ANIP  
7PMJ ...(   
7PNT ...      LDX  0  CPPTR(2)  
7PQ6 ...      BZE  0  XNIP2                [NIP ACTLF   
7PRC ...)   
7PSN ...      DCA     ,DEX,5,MODE          [STORE MODE  
7PT^ ...#UNS  ANIP  
7PX= ...XNIP2 LDEX 6  JSOURCE3(2)          [GET PRINT WIDTH 
7PYH ...#UNS  ANIP  
7P^S ...#SKI
7Q35 ...(   
7Q4L          LADDP    ,4                  [GET POINTER TO APIA 
7QJ=          SMO      4
7R3W          LDEX  6  AREPERT             [SET UP X6 WITH PRINT WIDTH  
7RHG ...)   
7TG2 ...      STOZ     GZDUMP(2)
7T^L ...      LDX   0  AWORK4(2)
7WF= ...      BNG   0  SETUP               [ J IF LISTING SETUP FILE
7WYW ...NOTP1   
7XDG ...      STEPAGAIN 
7XY6 ...      BRN      STARTED  
7YCQ ...SETUP   
7YXB ...      STEP  
7^C2 ...      BZE   3  SERT                [ J IF SETUP FILE EMPTY  
86QW          BRN      STARTED  
87=G    START   
87Q6          STEP  
87X?          LFBBUS   M,2,NOCOR3          [J IF NO ERROR   
87^2          LFBITCLR M,2  
882P          CALL  5  SRER 
884D          STEPAGAIN 
8867    NOCOR3  
889Q          BZE   3  TEND                [J IF END OF FILE
88PB    STARTED 
8992          LDEX  5  FRH(3)              [PICK UP NUMBER OF WORDS IN RECORD   
89NL          LDN   0  #40  
8=8=          ANDX  0  AWORK1(2)
8=MW          LDN   4  4                   [INITIALISE PICKUP ADDRESS   
8?7G          BNZ   0  PERIFILE            [J IF BASIC PERIPHERAL FILE  
8?M6          LDN   0  4
8#6Q          ANDX  0  AWORK1(2)
8#LB          BZE   0  OK1                 [J IF NOT MONFILE
8*62          ADN   4  4                   [INCREMENT PICKUP ADDRESS TO 
8*KL                                       [ALLOW FOR CATEGORY WORD.
8B5=          LDX   0  FRH+1(3)            [PICK UP RED-TAPE(CATEGORY WORD) 
8BJW          ANDX  0  AWORK3(2)
8C4G          BNZ   0  OK1                 [J IF THIS CATEGORY TO BE LISTED 
8CJ6 ...      MHUNTW   1,GOUT,INFOLIST  
8D3Q          LDN   0  1
8DHB          ADS   0  GNUM(1)             [UPDATE CURRENT LINE NUMBER  
8F32          LDX   2  GLNO(1)  
8FGL          BNG   2  START               [J IF LIST TO END OF FILE
8G2=          SBS   0  GLNO(1)  
8GFW          BRN      START               [TRY NEXT RECORD 
8G^G    PERIFILE
8HF6          LDN   0  1
8HYQ          ANDX  0  AWORK1(2)
8JDB          BNZ   0  SPECIAL             [J IF SPECIAL LISTING
8JY2          LDN   0  #1000
8KCL          ANDX  0  AWORK1(2)
8KX=          BNZ   0  NOCONV              [J IF MODE 4 PERIS   
8LBW          LDN   0  #700 
8LWG          ANDX  0  AWORK1(2)
8MB6          BZE   0  NOCONV              [J IF NOT SHIFT FILE 
8MTQ          LFBBS    K,2,OLDCONV         [J IF ALREADY AN ACONV BLOCK 
8N*B          SETUPCORE 5,3,ADATA,ACONV    [BLOCK FOR SHIFT CONVERSION  
8NT2          LFBITSET K,2  
8P#L          PHOTO    7
8PS=          LDN   4  A1(3)
8Q?W          STEPAGAIN 
8QRG          BRN      TMOVEMENT
8R?6    OLDCONV 
8RQQ          MHUNTW   3,ADATA,ACONV
8S=B          LDN   4  A1(3)
8SQ2          PHOTO    7
8T9L          ALTLEN   3,5,ADATA,ACONV  
8TP=          STEPAGAIN 
8W8W    TMOVEMENT   
8WNG          TESTMOVE 7,NOMOVE1           [J IF NO BLOCKS MOVED
8X86          MHUNTW   1,ADATA,ACONV
8XMQ          LDN   4  A1(1)
8Y7B    NOMOVE1 
8YM2          SMO      5
8^6L          MOVE  3  0
8^L=          LDN   1  #26                 [SET MODES FOR ALLCHAR TO
925W          LDX   0  AWORK1(2)
92KG          ANDN  0  #100 
9356          BZE   0  NOTNORM  
93JQ          LDN   1  6
944B    NOTNORM 
94J2          LDN   2  #10                 [GRAPHIC CONVERSION. 
953L          TRANSFOR 1,2  
95H=          MHUNTW   3,ADATA,ACONV
962W          ADN   3  A1-FRH              [SET X3 TO POINT TO RECORD HEADER
96GG          LDEX  5  FRH(3)              [RESET LENGTH OF RECORD  
9726    NOCONV  
97FQ          LDN   4  8                   [SET PICKUP ADDRESS  
97^B    SPECIAL 
98F2          LDEX   0 FRH(3)              [CHECK FOR EMPTY RECORD  
98YL          SBN   0  2
99D=          BZE   0  OK2  
99XW          LDX   0  FRH+1(3)            [CALCULATE NUMBER OF CHARACTERS  
9=CG          SLC   0  2                   [IN LAST WORD OF RECORD  
9=X6          ANDN  0  3
9?BQ          BZE   0  OK2  
9?WB          SBN   5  1                   [ADJUST CHARACTER COUNT  
9#B2          BRN      OK2  
9#TL    OK1   LDN   0  0                   [NO ADJUSTMENT NECESSARY 
9**=    OK2   SLL   5  2                   [CONVERT TO CHARS.   
9*SW          ADX   5  0                   [ADJUST IF NEC.  
9B#G          SBX   5  4                   [SUBTRACT P.U.ADDRESS TO GIVE
9BS6                                       [NO OF CHARS OF DATA IN X5.  
9C?Q          STO   5  GZLENGTH(2)         [RECORD LENGTH (I.E. DATA)   
9CRB          STO   4  GZPOINT(2)          [PICK UP ADDRESS 
9D?2          LDX   7  FRH+1(3)            [GET 
9DQL          SRL   7  6                   [CURRENT 
9F==          ANDN  7  #77                 [SHIFT   
9FPW          LDN   0  2
9G9G          ANDX  0  AWORK1(2)           [TEST FOR NUMBER 
9GP6          SLL   0  2
9H8Q          STO   0  GZDUMP(2)           [DUMP ADDRESS
9HNB          BZE   0  NOSEQ
9J82          STO   3  ACOMMUNE9(2) 
9JML          LDN   2  GZDATA+1(2)  
9K7= ...      MHUNTW   1,GOUT,INFOLIST  
9KLW          LDX   4  GNUM(1)  
9L6G          LDX   1  FX1  
9LL6          TXL   4  NUMLP(1)            [TEST DOES NOT EXCEED MAXIMUM
9M5Q          BCC      NOSEQ1   
9MKB          LDN   3  6
9N52          MPY   4  SMLP(1)  
9NJL          LDN   1  #20  
9P4=          CALL  0  SEQUENCE 
9PHW    NOSEQ1  
9Q3G          LDX   3  ACOMMUNE9(2)        [RESET POINTERS  
9QH6    NOSEQ   
9R2Q          LDN   4  #51                 [ HEAD OF FORM PFCC  
9RGB          LFBBS    J,2,NEWPFCC         [ J IF PAGE RESTART  
9S22          LDN   4  #41                 [ NORMAL PFCC
9SFL          LDX   0  AWORK1(2)
9S^=          ANDN  0  #340 
9TDW          BZE   0  PFCCAM              [ J IF AMORPHOUS OR TAPE PUNCH FILE  
9TYG          LDX   0  AWORK1(2)
9WD6          ANDN  0  1
9WXQ          BNZ   0  PFCC                [ J IF SPECIAL   
9XCB          LFBBS    H,2,PFCC            [ J IF CONTINUED RECORD  
9XX2          LDX   4  FRH+1(3) 
9YBL          ANDN  4  #77                 [ PFCC FROM FILE 
9YW=    PFCC
9^8M ...      SEGENTRY K50LISTLOOP  
9^H4 ...      BRN      NEWPFCC            [BRN NOT LFBASOVERFLO 
9^TG          LDX   0  4
=2*6          SBN   0  #41  
=2SQ          BZE   0  NUPFCC              [ J IF NOT USER SUPPLIED PFCC
=3#B          LFBITSET N,2                 [ SET USER FORMATTED FILE
=3S2    NUPFCC  
=3^8 ...      SEGENTRY K51LISTLOOP  
=46B ...      BRN      PFCCAM            [J IF USER FORMATTED FILE  
=4?L          LFBBS    N,2,NEWPFCC         [ J IF USER FORMATTED FILE   
=4CH          SEGENTRY K61LISTLOOP  
=4HD    PFCCAM  
=4JP ...#UNS  ANIP  
=4L2 ...(   
=4M? ...      LDX   0  CPPTR(2) 
=4NJ ...      BZE   0  NEWPFCC  
=4PT ...)   
=4R=          LDCT  0  #200 
=5=W          ANDX  0  CPRW1(2)            [ REPLY WORD 
=5QG          BZE   0  NEWPFCC             [ J IF NOT PAGE OVERFLOW 
=6=6          LDN   4  #51  
=6PQ          SEGENTRY K60LISTLOOP  
=JWW    NEWPFCC 
=JXN ...#SKI ENHPLOW
=JYG ...(   
=J^# ...      LFBBUS   U,2,SNPTH           [J IF PAPER LOW NOT BEEN FOUND   
=K26 ...      LFBBS    V,2,SNPTH           [J IF PRINTING CONTINUATION LINE 
=K2Y ...      LDN   0  #51  
=K3Q ...      SBX   0  4
=K4J ...      BZE   0  TISPL               [J IF THROW TO HEAD OF FORM PFCC TO  
=K5B ...      SBN   0  #40                 [TAKE PAPER LOW ACTION   
=K68 ...      BZE   0  TISPL
=K72 ...      LADDP    ,1                  [J IF NO OF LINES SHOWS FULL PAGE
=K7M ...      LDX   5  AREPERT(1)          [LISTED TO TAKE PAPER LOW ACTION 
=K8# ...      SRL   5  12   
=K8^ ...      MHUNTW   1,GOUT,INFOLIST  
=K9L ...      LDX   1  GPREM(1) 
=K=? ...      TXL   1  5
=K?4 ...      BCC      TISPL
=K?W ...      LDX   1  FX1  
=K#N ...SNPTH                              [OTHERWISE CONTINUE  
=K*G ...)   
=KBG          STO   4  GZDATA(2)
=KW6          LDX   0  6                   [MAX PERMISSABLE TRANSFER
=L*Q          SBX   0  GZDUMP(2)           [MAX ROOM FOR DATA IN X0 
=LTB          TXL   0  GZLENGTH(2)         [IS THERE ROOM?  
=M*2          BCS      XLONG               [NO! 
=MSL          LDX   0  AWORK1(2)
=N#=          ANDN  0  #1000
=NRW          BZE   0  NOTM4               [J IF NOT MODE 4 
=Q=Q          LDX   0  GZDUMP(2)
=QQB          SRL   0  2
=RTH          BNZ   7  NMOBM4   
=R^D          LDN   7  #74                 [GRAPHIC SHIFT   
=S5*    NMOBM4  
=S9=          SMO      0
=SNW          DCH   7  GZDATA+1(2)         [MOVE IN CURRENT SHIFT   
=T8G          LDN   0  1
=TN6          ADS   0  GZDUMP(2)
=WMB    NOTM4   
=X72          LDX   5  GZLENGTH(2)         [TRANSFER WHOLE LOT  
=XLL          STO   5  GZTRANS(2)   
=Y6=          CALL  0  TRANSFER 
=YKW          LDN   0  #20  
=^5G          ANDX  0  AWORK1(2)           [J IF SPACE FILLING NOT REQUIRED.
=^K6          BZE   0  NOSP1
?24Q          LDX   3  6
?2JB          SBX   3  GZDUMP(2)
?342          SBX   3  5                   [X3 = NO OF UNUSED CHARS 
?3HL          BZE   3  NOSP1               [J IF BUFFER FULL
?43=          LDX   2  4
?4GW    PUTSP DCH   0  0(2) 
?52G          BCHX  2  £
?5G6          BCT   3  PUTSP
?5^Q          LDX   2  FX2  
?6FB ...      BRN      STCNT
?7DL    XLONG                              [DEAL WITH LONG RECORD   
?7Y=          LDX   5  AWORK1(2)
?8CW          ANDN  5  #1000
?8XG          BZE   5  NOTM4HERE           [J IF NOT MODE 4 
?=BB          DOWN     LISTEXCP,4          [ELSE ALLOW FOR EXTENDED COUNT   
?=W2          LDX   7  ACOMMUNE2(2)        [GET TRACED SHIFT
?##W          BRN      SPACED   
?*#6    NOTM4HERE   
?*RQ          LDX   5  0                   [MAXIMUM 
?B?B          SBN   5  4                   [MINUS 4 FOR CONTINUATION
?BR2          STO   5  GZTRANS(2)   
?C=L          CALL  0  TRANSFER 
?CQ=          SMO      FX1  
?D9W          LDN   3  XCONT
?DPG          MVCH  3  4
?DS5 ...STCNT   
?DWN ...#UNS  ANIP  
?D^? ...      STO   6  GZDUMP(2)
?F3W ...#UNS  ANIP  
?F6F ...#SKI
?F96          DCA      ,STO,6,COUNT 
?FNQ          BRN      SPACED   
?G8B    NOSP1 LDX   3  5
?GN2          ADX   3  GZDUMP(2)
?GR6 ...#UNS  ANIP  
?GW= ...      STO   3  GZDUMP(2)
?G^B ...#UNS  ANIP  
?H4G ...#SKI
?H7L          DCA      ,STO,3,COUNT 
?HM=    SPACED  
?J6W          LDN   3  1
?J=2 ...#UNS  ANIP  
?J*6 ...      ADS   3  GZDUMP(2)
?JD= ...#UNS  ANIP  
?JHB ...#SKI
?JLG          DCA      ,ADS,3,COUNT        [FOR PFCC
?K66    RPERI   
?KKQ    [OUTPUT RECORD AND UPDATE COUNTS ETC
?L5B    [OUTPUT RUNOUT IF REQUIRED FOR PAPER TAPE   
?LK2          CALL  5  PERI 
?M4L          LFBITCLR J,2                 [UNSET PAGEREST MARKER   
?MJ= ...      MHUNTW   3,GOUT,INFOLIST  
?N3W          LDX   0  GZDATA(2)           [UPDATE  
?NHG          ANDN  0  7                   [LINE
?P36          ADS   0  GPREM(3)            [COUNT   
?P73          LDX   0  GZDATA(2)
?P=Y          ANDN  0  #50  
?PBT          BZE   0  XFIN                [ J IF NO PRINT PFCC 
?PGQ          LDX   0  GZLENGTH(2)  
?Q2B          SBX   0  GZTRANS(2)   
?QG2          BZE   0  XFIN 
?Q^L          STO   0  GZLENGTH(2)  
?RF=          LDX   0  GZTRANS(2)   
?RYW          ADS   0  GZPOINT(2)   
?SDG          LDN   0  2
?SY6          ANDX  0  AWORK1(2)           [CHECK FOR NUMBER
?TCQ          SLL   0  2
?TXB          ADN   0  4                   [INDENTATION 
?WC2          STO   0  GZDUMP(2)
?WWL          LDX   0  ACES 
?XB=          STO   0  GZDATA+1(2)  
?XTW          STO   0  GZDATA+2(2)  
?Y*G          STO   0  GZDATA+3(2)  
?YT6          LFBITSET H,2  
?YX* ...#SKI ENHPLOW
?Y^J ...(   
?^3R ...      LFBBUS   U,2,SSSS            [J PAPER LOW NOT FOUND   
?^62 ...      LFBITSET V,2                 [OTHERWISE SET CONTINUATION LINE BIT 
?^89 ...SSSS
?^=D ...)   
?^#Q          LFBBS    K,2,NOSTEP          [J IF ACONV BLOCK
?^SB          STEPAGAIN 
#2#2          BRN      NOSEQ
#2RL    NOSTEP  
#3?=          MHUNTW   3,ADATA,ACONV
#3QW          ADN   3  A1-FRH   
#4=G          BRN      NOSEQ
#4Q6    XFIN  LFBITCLR H,2                 [UNSET ANY LONG RECORD MARKERS   
#59Q    RPERI2  
#5PB ...      MHUNTW   3,GOUT,INFOLIST  
#692          LDN   4  1
#6NL          ADS   4  GNUM(3)  
#78=          LDX   4  GLNO(3)             [TEST AND J IF LAST LINE OUTPUT  
#7MW          BNG   4  TOEND
#87G          SBN   4  1
#8M6          STO   4  GLNO(3)  
#96Q          BZE   4  TEND                [LAST LINE OUTPUT
#9LB    TOEND   
#=62          LDX   4  GREST(3)            [J IF PAGE RESTART   
#=KL          BNG   4  PAGE 
#?5=          LDCT  4  128                 [J IF ALL RESTART
#?JW          ANDX  4  GREST(3) 
##4G          BNZ   4  SPLIT
##J6          LDX   4  GNUM(3)             [OTHERWISE SET LINE NUMBER FOR   
#*3Q          STO   4  GREST(3)            [RESTART 
#*HB    SPLIT   
#*M? ...SLPH
#*R8 ...#UNS  ANIP  
#*X5 ...(   
#B32 ...      LDX   0  CPPTR(2) 
#B6X ...      BZE   0  START               [J IF NIP ACTLF  
#B=S ...)   
#BBP ...      LDCT  4  #100                [TEST FOR PAPER LOW  
#BGL          ANDX  4  CPRW1(2) 
#C2=          BNZ   4  PLOW                [J IF LOW
#CFW    SCARD BRN      START               [J TO OUTPUT NEXT RECORD 
#C^G    PAGE  LDX   4  GZDATA(2)
#DF6          ANDN  4  63   
#DYQ    SPERI   
#FDB          LDN   0  #51  
#FY2          SBX   0  4
#GCL          BZE   0  PAGRE
#GX=          SBN   0  #40  
#HBW          BZE   0  PAGRE
#HWG          LDX   4  GPREM(3) 
#J2Y          LADDP    ,1   
#J7B          LDX   0  AREPERT(1)   
#J?S          SRL   0  12   
#JD=          ADN   0  1
#JJN          LDX   1  FX1  
#JP6          TXL   4  0
#JTQ          BCC      PAGRE
#K*B          BRN      SLPH 
#KT2    PAGRE   
#L#L          LDN   4  0                   [INITIALISE GREST TABLE POINTER  
#LS=          LDX   5  GLEN(3)             [GLEN=N WHERE GREST+N IS LAST WORD   
#M?W          BZE   5  PAGE1               [J IF GOUT NOT LENGTHENED FOR MULTIP 
#MRG          LDX   4  GNEXT(3) 
#N?6          TXL   4  5
#NQQ          BCS      XOK1                [J GNEXT<N   
#P=B          NGN   4  1
#PQ2    XOK1  ADN   4  1
#Q9L          STO   4  GNEXT(3)            [GNEXT=0 OR GNEXT+1  
#QP=    PAGE1   
#R8W          LDCT  5  256  
#RNG          ORX   5  GNUM(3)  
#S86          SBN   5  1                   [ADJUST TO GET RIGHT LINE NO.
#SMQ          SMO      4
#T7B          STO   5  GREST(3) 
#TM2          LDN   0  1
#W6L          STO   0  GPREM(3)            [ONE LINE PRINTED ON NEW PAGE
#WL=          BRN      SLPH 
#X5W    PLOW
#X6R ...#SKI ENHPLOW
#X7N ...(   
#X8K ...      LDX   4  GREST(3)            [J TO TAKE PLOW ACTION IF NOT PAGE   
#X9G ...      BPZ   4  TISPL               [RESTART 
#X=C ...      LFBBS    V,2,PLOW3           [ALSO J IF CONTINUATION LINES OR 
#X?# ...      JBUSY    ,PLOW3              [BUSY PRINTER ENCOUNTERED
#X#9 ...      LFBITSET U,2                 [ELSE SET PAPER LOW BIT  
#X*6 ...      BRN      START               [J TO CONTINUE PRINTING PAGE 
#XB3 ...PLOW3   
#XBY ...      LFBITCLR V,2                 [CLEAR MARKER BITS   
#XCT ...      LFBITCLR U,2  
#XDQ ...TISPL   
#XFM ...      LDCT  4  #100                [IF NO PLOW REPLY TO LAST PERI   
#XGJ ...      ANDX  4  CPRW1(2)            [THEN ASSUME OPERATORS HAVE BEATEN   
#XHF ...      BZE   4  OPSAL               [US TO IT
#XJB ...)   
#XKG          DOWN     LISTNEXT,10         [INFORM OPERATOR OF PAPER LOW
#XPC ...
#XT# ...#SKI ENHPLOW$1  
#X^9 ...(   
#Y56          ENGPER   SBRKIN,,SCANTY   
#Y74 ...      BRN      START
#Y92 ...)   
#Y=Y ...#SKI ENHPLOW
#Y#W ...(   
#YBS ...      ENGPER   SBRKIN,,SCANTY1  
#YDQ ...OPSAL   
#YGN ...      LFBBUS   U,2,START           [IF NOT STARTING SAME PAGE J 
#YJL ...      LFBITCLR U,2                 [ELSE CLEAR PLAN BIT 
#YLJ ...      STEPAGAIN                    [AND J TO PRINT RECORD WE WERE   
#YNG ...      BRN      STARTED             [PRINTING
#YQD ...SCANTY1 
#YSB ...      LFBBUS   U,2,SCANTY          [CLEAR PLOW BIT IF SET SO PLOW   
#YW# ...      LFBITCLR U,2                 [MESSAGE ISN'T OUTPUT TWICE IE BY
#YY= ...      BRN      SCANTY              [PAGEREST ROUTINE
#^28 ...)   
#^4B    SCANT CALL  3  TIDYUP   
#^J2          BRN      SLIST               [LISTING SETUP FILE  
*23L          ANDX  4  BITS22LS 
*2H=          LFEND    CD,4 
*2MN ...SLIST          HUNTW 3,GOUT,INFOLIST
*2S6          BNG   3  SLIST1   
*2YJ          FREECORE 3
*352          BRN      SLIST
*39D    SLIST1  
*3*W          LFEND    CD   
*3GG    [   
*4^B    SERT
*5F2 ...[ SETUP FILE EMPTY  
*5YL ...      DOWN     LISTINIT,6   
*85B    TEND
*8?L          LDX   2  FX2  
*8FW          LFBITCLR N,2                 [ CLEAR USER FORMATTED FILE  
*8N6          CALL  3  TIDYUP   
*8WB          BRN      TLIS                [CURRENTLY LISTING SETUP FILE
*9B2          STO   2  AWORK1(2)           [SWITCH  
*9TL          DOWN     LISTINIT,3          [OUTPUT TERMINATORS. 
*=*=          LFEND 
*=SW    TLIS  LDN   6  1                   [SWITCH FOR LISTPREP 
*=XF ...TLIST   
*?24 ...#UNS G3SIGNET   
*?4M ...(   
*?7= ...      SMO      FX2  
*?9T ...      LDX   0  CPPTR
*?#D ...      IF  0,E,ASIGNETPTR
*?C3 ...      THEN  
*?FL ...        ACROSS  LISTPREP,3  
*?J9 ...      FI
*?LS ...)   
*?PC ...      REWIND
*?S6          ACROSS   LISTPREP,2   
*#?Q    XGEOER  
*#RB          GEOERR   1,BREAK IN   
**?2    #END
^^^^ ...42107625000100000000
</code>