{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LISTNIP865)}}
====== LISTNIP865 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CLOSE|CLOSE]], [[george:macro:ENRING|ENRING]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTW|HUNTW]], [[george:macro:LFBBS|LFBBS]], [[george:macro:LFBBUS|LFBBUS]], [[george:macro:LFBITCLR|LFBITCLR]], [[george:macro:LFBITSET|LFBITSET]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCK|LOCK]], [[george:macro:LONGCOOR|LONGCOOR]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGSTOP|LONGSTOP]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MURDER|MURDER]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:PAIR|PAIR]], [[george:macro:POINTACT|POINTACT]], [[george:macro:PROPNO|PROPNO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:STARTACT|STARTACT]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:WRONG|WRONG]]
22FL #OPT K0LISTNIP=0
22^= #LIS K0LISTNIP>K0LISTFILE>K0ALLGEO
23DW #SEG LISTNIP [H.CAMPBELL-GRANT
23YG 8HLISTNIP
24D6 SEGENTRY K1LISTNIP,POINT1 [NIPSTART MACRO
24XQ SEGENTRY K2LISTNIP,POINT2 [NIPRPERT MACRO
25CB SEGENTRY K3LISTNIP,POINT3 [NIPLINES MACRO
25X2 SEGENTRY K4LISTNIP,POINT4 [NIPENDLF MACRO
26BL ... SEGENTRY K5LISTNIP,POINT5 [NIPREL MACRO
26W= [THIS SEGMENT CONTAINS ALL THE CODE OBEYED IN THE CPAT BY THE LF MACROS
27*W [ISSUED BY THE JOB RUNNING THE NIP PROGRAM
27TG [THE JOB ACCESSES THE LISTFILE ROUTINES USING A FORM OF THE ACCESS CMMAN
28*6 [ NIPSTART IS ISSUED AFTER A MODE #201 EXTRACODE
28SQ [ NIPRPERT IS ISSUED AFTER A MODE #202 EXTRACODE
29#B [ NIPLINES IS ISSUED AFTER A MODE #203 EXTRACODE
29S2 [ NIPENDLF IS ISSUED AFTER A MODE #204 EXTRACODE
2=?L [ NIPREL IS ISSUED AFTER A REL EXTRACODE OR WHEN THE PROGRAM IS DE
2=R= [
2?=W [***********************************************************************
2?K? ...[
2?XN ...[ DATA AREA
2#=5 ...[
2#JG ...[******************************************************************
2#WX ...[
2*9B XA #41
2*P2 XZPLUS #73
2B8L X48 48
2BN= X64 64
2C7W X96 96
2CCN ...XHALF #10000
2CMG XINIT PAIR LISTINIT,8 [NIPLINES - AT START OF LISTING
2D4M ...XNXT2 PAIR LISTNEXT,11 [NIPREL
2DFS ...[
2DW^ ...[****************************************************************
2F#6 ...[
2FP? ...[ SUBROUTINE AREA
2G6D ...[
2GHK ...[*********************************************************************
2GYQ ...[
2H*X ...[
2HR4 ...[***********************************************************************
2J89 ...[
2JKB ...[ SUBROUTINE TO SEARCH FOR ACTLF/ALPS14
2K2H ...[ CALLED ON X6 - USES ALL ACCUMULATORS EXCEPT X7 AND AWORK2
2KCN ...[ EXIT +1 IF ACTLF FOUND - X3 REFERENCES ACTLF
2KST ...[ +0 IF ACTLF NOT FOUND
2L=2 ...[ NO COORDINATION
2LM7 ...[
2M4# ...[
2MFG SFINDACT
2M^6 POINTACT OUT,3 [GET ACTLF/BSCHED
2NDQ LDX 5 JOBNO(2) [JOB NUMBER OF ACTLF
2NYB LDX 4 AWORK1(2) [TYPE/UNIT NUMBER IN ACTLF
2PD2 STO 3 AWORK2(2) [KEEP ADDRESS OF BSCHED
2PXL SLOOP LDX 3 JOBRING(3)
2QC= SBN 3 JOBRING
2QWW TXU 5 JOBNO(3)
2RBG TXU 4 JSOURCE1(3)
2RW6 BCC SFND [FOUND ACTLF/ALPS14
2S*Q TXU 3 AWORK2(2)
2STB BCS SLOOP
2T*2 EXIT 6 0
2TSL ...[
2W#= SFND EXIT 6 1
2WRW ...[
2X?G ...[
2XR6 ...[ SUBROUTINE TO FIND THE ACTLF/ALPS14 AND CHECK THE BREAKIN
2Y=Q ...[ BIT.
2YQB ...[ CALLED ON X7 - USES ALL ACCUMULATORS
2^=2 ...[ EXIT +0 IF ACTLF NOT FOUND
2^PL ...[ +1 IF BREAKIN DURING LONGWAIT
329= ...[ +2 IF ACTLF FOUND - X3 REFERENCES ACTLF
32NW ...[ USES SFINDACT
338G ...[
33N6 SCHKBREAK
347Q CALL 6 SFINDACT
34MB EXIT 7 0 [ACTLF NOT FOUND
3535 ...[
35BS ...[
35QH ... LONGSET ANIPBRK,SJMP,JOBNO(2)
366= SACTF LFBBUS B,3,SNSET [CHECK THE BREAKIN BIT
36KW SBX 7 FX1
36WR ... LDX 0 AWORK2(2)
377N ... BZE 0 STOP [J IF NOT NIPREL
37DK ... LONGCOOR [DO NOT BRKIN IF NIPREL
37PG ... BRN SOUT
382C ...STOP LONGSTOP SBRKN [WAIT FOR BREAKIN BIT TO CLEAR
38?# ...SOUT ADX 7 FX1
38JB CALL 6 SFINDACT
3942 BRN SNFND [ACTLF NO LONGER THERE - GEOERR
39HL BRN SACTF [GO TO RECHECK BREAKIN BIT
3=3= SNSET LONGOFF
3=GW EXIT 7 2
3?2G SBRKN LONGOFF
3?G6 ADX 7 FX1
3?^Q EXIT 7 1
3#FB ...[
3#^2 ...[
3*DL SNFND GEOERR 0,ALPS14
3*Y= ...[
3BCW ...[
3BXG SJMP GEOERR 0,LONGSET
3CC6 ...[
3CWQ ...[
3DBB ...[ SUBROUTINE TO LONGWAIT FOR ACTLF TO FINISH WORK
3DW2 ...[ CALLED ON X7 - USES ALL ACCUMULATORS
3F*L ...[ EXIT +0 IF ALL OKAY
3FT= ...[ GOES UP IF BROKEN IN ON
3G#W ...[
3GSG ...[
3H#6 ...[
3HRQ SWAITACT
3J?B SBX 7 FX1
3JR2 LONGSET AWAITNIP,SJMP,JOBNO(2)
3J^N ... LDX 0 AWORK2(2)
3K8B ... BZE 0 STOP2 [J IF NOT NIPREL
3KC4 ... LONGCOOR [DO NOT BKIN IF NIPREL
3KKQ ... BRN SOUT2
3KSD ...STOP2 LONGSTOP SBRK2 [WAIT FOR COMPLETION OF ACTION
3L36 ...SOUT2 LONGOFF
3L9W ADX 7 FX1
3LPG EXIT 7 0
3M96 ...[
3MNQ SBRK2 CALL 6 SFINDACT
3N8B BRN SNFND [ACTLF NOT THERE - GEOERR
3NN2 LFBITSET B,3 [SET BREAKIN BIT
3P7L LONGOFF
3PM= UP [GO TO JUMP TO BREAKIN LABEL OF
3Q6W [CALLING ROUTINE
3QLG ...[
3R66 ...[
3RKQ ...[
3S5B ...[
3SK2 ...[
3T4L ...[ MAIN BODY OF SEGMENT
3TJ= ...[
3W3W ...[
3WHG ...[ THIS IS THE ENTRY POINT FOR THE NIPSTART MACRO
3X36 ...[ EXPECTS THE TYPE/UNIT NUMBER OF THE PROGRAM CHANNEL IN
3XGQ ...[ ACOMMUNE1
3Y2B ...[ THERE MAY BE AN APERI/APROPS BLOCK IN THE ACTIVITY CHAIN
3YG2 ...[
3Y^L ...[ CONVERTS THE APERI/APROPS BLOCK TO A GOUT/GPROPNOS BLOCK
3^F= ...[ WITH THE HELP OF THE PROPNO MACRO OR CREATES A ZERO
3^YW ...[ GOUT/GPROPNOS BLOCK.
42DG ...[ NEXT FINDS ACTLF/ALPS14 ACTIVITY BLOCK FOR CHANNEL
42Y6 ...[ IF IT DOES NOT EXIST,CREATES ONE AND CHAINS IT IN ACTLF
43CQ ...[ JOBRING.
43XB ...[ IF IT DOES EXIST,CHECKS THE BREAKIN BIT AND GOES WAITING
44C2 ...[ IF SET.
44WL ...[ THEN THE GOUT/GPROPNOS BLOCK IS CHAINED AFTER THE ACTLF,
45B= ...[ FLAG G IS SET IN THE ACTLF,THE LF SCHEDULER IS KICKED OFF
45TW ...[ AND THE CPAT LONGWAITS.
46*G ...[ EXPECTS TO FIND THE ACTLF NON-EXISTENT OR BETWEEN
46T6 ...[ LISTINGS
47#Q ...[ LEAVES ACTLF BEFORE FIRST LINE OF LISTING
47SB ...[
48#2 POINT1
48RL LDX 0 ACOMMUNE1(2)
49?= STO 0 AWORK1(2) [KEEP FOR FUTURE USE
49H4 ... STOZ AWORK2(2)
49QW ...[
4==G ... SETNCORE ATTMAX,3,GOUT,GPROPNOS
4=Q6 STOZ GPROPNUM(3)
4?9Q ADN 3 GPROPNUM
4?PB LDX 4 3
4#92 ADN 4 1
4#NL ... MOVE 3 ATTMAX-1 [ZEROISE GPROPNOS BLOCK
4*8= HUNTW 3,APERI,APROPS
4*MW BNG 3 XSACT [NO MORE TO DO-GO TO SEARCH FOR ACTLF
4B7G LDX 7 A1+1(3)
4BM6 LDN 6 A1+2
4C6Q LDN 5 0
4CLB ... SBN 7 ATTMAX
4D62 BPZ 7 TOMNY [TOO MANY PROPERTIES
4DKL ... ADN 7 ATTMAX
4F5= SETNCORE 5,3,CPB,CUNI
4FJW STOZ JPARNUM(3)
4G4G OPENSYS XBRK,PROPERTY,READ
4GJ6 ...[
4H3Q ...[ LOOP TO CONVERT PROPERTY NAMES TO NUMBERS
4HHB ...[
4J32 XLOOP MHUNTW 2,APERI,APROPS
4JGL MHUNTW 3,CPB,CUNI
4K2= ADX 2 6
4KFW ADN 3 ANUM
4K^G MOVE 2 4 [MOVE IN PROPERTY NAME
4LF6 ADN 6 4
4LYQ ...[
4MDB CHEKLFN2 (GEOERR),XFORM
4MY2 ... PROPNO 3,0,XNFND,4
4NCL BNG 3 XCONS [CONSOLE PROPERTY
4NX= ... ANDX 4 GSIGN
4QB6 ORX 4 3 [GET PROP NO IN FORMAT FOR GOUT/GPROP
4QTQ MHUNTW 3,GOUT,GPROPNOS
4R*B SMO 5
4RT2 STO 4 GPROPNUM+1(3)
4S#L ADN 5 1
4SS= BCT 7 XLOOP [GO TO GET NEXT PROPERTY NAME
4T?W ...[
4TRG CLOSE
4W?6 MFREEW CPB,CUNI
4WQQ MFREEW APERI,APROPS
4X=B ...[
4XQ2 ...[ GO TO SEARCH FOR ACTLF/ALPS14
4Y9L ...[
4YP= XSACT CALL 7 SCHKBREAK
4^8W BRN XCRET [GO TO CREATE ALPS14
4^NG BRN XBRKIN [BROKEN IN ON
5286 ...[
52BS ... LFBBUS S,3,XNREP [NOT BETWEEN LISTINGS
52KG ... LFBBUS G,3,XLPOK
52S8 ...[ REMOVE OLD GOUT,GPROPNOS BLOCK
532W ... HUNT2J 2,GOUT,GPROPNOS,3,XLPOK
539J ... FREECORE 2
53D= ... BRN XLPOK
53M2 ...[
546L ...[
54L= ...[ CREATE AN ACTLF/ALPS14
555W ...[
55KG XCRET GETACT ACTLF,ALPS14 [WILL NOT BE LONG LOCKED
5656 LDX 2 BPTR(2)
56JQ ADN 2 JOBRING
574B POINTACT OUT,3
57J2 ADN 3 JOBRING
583L ENRING 2,3 [RING ACTLF ON JOBRING
58H= LDX 3 BPTR(2)
592W LDX 0 JOBNO(2)
59GG STO 0 JOBNO(3)
5=26 LDX 0 AWORK1(2)
5=FQ STO 0 JSOURCE1(3)
5=LY ... LDN 0 1
5=S6 ... STO 0 JSOURCE2(3)
5=^B LFBITSET S,3 [BETWEEN LISTINGS
5?F2 LDN 0 #72
5?YL DCH 0 JSOURCE3(3) [PUT Z IN DEBATCHING CHAR
5#D= ...[
5#XW ...[
5*CG XLPOK LFBITSET G,3 [ACTIVITY HAS GOUT/GPROPNOS
5*X6 MHUNTW 2,GOUT,GPROPNOS
5BBQ CHAIN 2,3
5BLJ ... LFBITCLR F,3
5BWB STARTACT OUT
5CB2 CALL 7 SWAITACT [WAIT FOR ACTLF TO FINISH
5F#G XFIN2 UPPLUS 1
5FS6 ...[
5G?Q ...[
5GRB ...[ THIS IS THE ENTRY POINT FOR THE NIPRPERT MACRO
5H?2 ...[ EXPECTS THE TYPE/UNIT NUMBER OF THE PROGRAM CHANNEL IN
5HQL ...[ ACOMMUNE1
5J== ...[ THERE MUST BE AN APERI/ARPERT BLOCK IN THE ACTIVITY CHAIN
5JPW ...[
5K9G ...[ THE INFORMATION IN THE BLOCK IS VALIDATED AND NON-ZERO
5KP6 ...[ ITEMS MOVED TO THE ACTLF
5L8Q ...[ EXPECTS ACTLF TO BE BEFORE FIRST LINE OF LISTING
5LNB ...[ LEAVES ACTLF THE SAME
5M82 ...[
5MML ...[
5N7= POINT2
5NLW LDX 0 ACOMMUNE1(2)
5P6G STO 0 AWORK1(2) [KEEP FOR FUTURE USE
5PB# ... STOZ AWORK2(2)
5PL6 MHUNTW 3,APERI,ARPERT
5Q5Q LDX 0 A1(3) [PAGE WIDTH
5QKB BZE 0 XNWDT [NONE SPECIFIED
5R52 ... SBN 0 512
5RJL BPZ 0 XTBIG [TOO MANY PRINT POSITIONS
5S4= ... ADN 0 512
5SHW XNWDT STO 0 AWORK3(2) [STORE IN ACTLF
5T3G ...[
5TH6 ... LDCH 0 A1+1(3) [DEBATCHING CHARACTER
5W2Q BZE 0 XNDBC [NONE SPECIFIED
5WGB TXL 0 XA(1)
5X22 BCS XNALF [NOT ALPHA
5XFL TXL 0 XZPLUS(1)
5X^= BCC XNALF [NOT ALPHA
5YDW SBN 0 1 [UPDATE DEBATCHING CHAR BEFORE LISTIN
5YYG TXL 0 XA(1)
5^D6 BCC XDBC
5^XQ LDN 0 #72 [IF WAS A SET TO Z
62CB XDBC DCH 0 AWORK3(2)
62HL ...[
62MW ...XNDBC LDX 0 A1+1(3) [PAGE LENGTH
62S6 ... SLL 0 6
62YB ... SRL 0 6
634L ... BZE 0 XNPGL [NONE SPECIFIED
638W ... TXL 0 XHALF(1)
63*6 ... BCC XERPL [TOO HIGH PAGE LENGTH
63FB ... STO 0 AWORK4(2)
63KL ...[
63PW ...XNPGL LDX 0 A1+2(3) [CHARACTER SET
643W ... BZE 0 XCHSX [NONE SPECIFIED
64*W LDN 4 #4000
64TG ... TXU 0 X48(1)
65*6 BCC XCHS [48 CHAR SET
65SQ SRC 4 1
66#B ... TXU 0 X96(1)
66S2 ... BCC XCHS [96 CHAR SET
67?L ... LDN 4 0
67R= ... TXU 0 X64(1)
68=W BCS XERCH [CHAR SET NOT 48,64 OR 96
68QG ...XCHS ORS 4 AWORK3(2)
692# ...XCHSX MFREEW APERI,ARPERT
69=6 ...[
69PQ CALL 7 SCHKBREAK [FIND THE ACTLF
6=9B BRN SNFND [ACTLF NOT FOUND-GEOERR
6=P2 ... BRN XBRK2 [BROKEN IN ON
6?8L ...[
6?N= LFBBUS Q,3,XNREP [EXTRACODE ISSUED IN THE WRONG ORDER
6#7W LDCH 0 AWORK3(2) [MOVE DATA INTO ACTLF
6#MG BZE 0 XNDEP
6*76 DCH 0 JSOURCE3(3)
6*LQ XNDEP LDEX 0 AWORK3(2)
6B6B BZE 0 XNDEX
6BL2 DEX 0 JSOURCE3(3)
6B^P ...XNDEX LDX 0 AWORK3(2)
6C*D ... ANDN 0 #7000
6CP7 ... BZE 0 XNPL
6D4W LDN 4 #7000
6DJG ANDX 4 JSOURCE3(3)
6F46 ERS 4 JSOURCE3(3)
6FHQ ORS 0 JSOURCE3(3)
6FXW ...XNPL LDX 0 AWORK4(2)
6G#2 ... BZE 0 XFIN
6GN6 ... STO 0 JSOURCE2(3)
6H4= ...[
6HDB ...XFIN SETREP OK
6HSG ... BRN XFIN2
6J8L ...[
6JJQ ...[ THIS IS THE ENTRY POINT FOR THE NIPLINES MACRO
6JYW ...[ EXPECTS THE TYPE/UNIT NUMBER OF THE PROGRAM CHANNEL IN
6K*2 ...[ ACOMMUNE1
6KP6 ...[ EXPECTS ACTLF TO BE BEFORE FIRST LINE OF A LISTING OR
6L5= ...[ IN THE MIDDLE OF A LISTING(NO BITS SET IN FLAG WORD)
6LFB ...[ LEAVES ACTLF IN THE MIDDLE OF A LISTING OR AT END OF
6LTG ...[ LISTING
6M9L ...[
6MKQ ...[ WILL GIVE AN ERROR REPLY IF REPERTOIRE INFO NOT COMPLETE
6M^W ...[
6NBG POINT3
6NW6 LDX 0 ACOMMUNE1(2)
6P*Q STO 0 AWORK1(2) [KEEP FOR FUTURE USE
6PKJ ... STOZ AWORK2(2)
6PTB CALL 7 SCHKBREAK
6Q*2 BRN SNFND [ACTLF NOT FOUND-GEOERR
6QSL BRN XBRK2 [BROKEN IN ON
6R#= ...[
6RRW ... LFBBS R,3,XNREP [MODES IN
6S?G ... LFBBS S,3,XNREP [WRONG ORDER
6SR6 ...[
6T=Q ...[ CHECK REPERTOIRE INFO COMPLETE
6TQB LDEX 0 JSOURCE3(3)
6W=2 BZE 0 XNORP [INFO INCOMPLETE
6WPL ... LDN 0 #6000
6X9= ANDX 0 JSOURCE3(3)
6X#K ... BZE 0 XCHOK
6XCY ... LDN 4 #1000
6XH? ... BXE 4 0,XCHOK
6XLL ... SLL 4 1
6XP^ ... BXU 4 0,XNORP [INFO INCOMPLETE
6XT# ...XCHOK
6XYN ... LDX 0 JSOURCE2(3)
6Y8G ... BZE 0 XNORP
6YD# ...[
6YN6 LFBBUS Q,3,XFPUT [J IF IN MIDDLE OF LISTING
6^7Q LINKSET 3,XINIT(1)
6^MB XFPUT LDX 2 3
7272 FPUT [FPUT ACTLF
72LL CALL 7 SWAITACT [WAIT FOR ACTLF TO FINISH
736= ... BRN XFIN2 [GO TO SET OK REPLY AND UPPLUS1
73KW ...[
745G ...[ THIS IS THE ENTRY POINT FOR THE NIPENDLF MACRO
74K6 ...[ EXPECTS THE TYPE/UNIT NUMBER OF THE PROGRAM CHANNEL IN
754Q ...[ ACOMMUNE1
75JB ...[
7642 ...[ EXPECTS ACTLF TO BE AT END OF LISTING OR BETWEEN LISTINGS
76HL ...[ LEAVES ACTLF BETWEEN LISTINGS
773= ...[
77GW ...[
782G ...[
78G6 POINT4
78^Q LDX 0 ACOMMUNE1(2)
79FB STO 0 AWORK1(2) [KEEP FOR FUTURE USE
79P8 ... STOZ AWORK2(2)
79^2 CALL 7 SCHKBREAK
7=DL BRN SNFND [ACTLF NOT FOUND-GEOERR
7=Y= BRN XBRK2 [BROKEN IN ON
7?CW ...[
7?XG LFBBS S,3,XFIN [BETWEEN LISTINGS-OK REPLY
7#C6 ... LFBBUS R,3,XNREP [NOT END OF LISTING
7*BB LDX 2 3
7*W2 FPUT
7B*L CALL 7 SWAITACT
7BT= BRN XFIN
7C#W ...[
7CSG ...[
7D#6 ...[ THIS IS THE ENTRY POINT FOR THE NIPREL MACRO
7DRQ ...[ EXPECTS THE TYPE/UNIT NUMBER OF THE PROGRAM CHANNEL IN
7F?B ...[ ACOMMUNE1
7FR2 ...[
7G=L ...[ ACTLF MAY BE IN ANY STATE(EVEN NON EXISTENT)
7GQ= ...[ CLOSES DOWN ACTLF AND MURDERS IT
7H9W ...[
7HC4 ...[ THIS MACRO CANNOT BE BROKEN IN ON
7HJ= ...[ - SEE USE OF AWORK2 IN SUBROUTINES
7HPG ...[
7J96 ...[
7JNQ POINT5
7K8B LDX 0 ACOMMUNE1(2)
7KN2 STO 0 AWORK1(2) [KEEP FOR FUTURE USE
7KXS ... NGS 2 AWORK2(2)
7L7L CALL 7 SCHKBREAK
7LM= BRN XFIN2 [ACTLF DOES NOT EXIST END
7M6W BRN XBRK2 [BROKEN IN ON
7MLG ...[
7N66 LFBBS S,3,XBETL [BETWEEN LISTINGS-GO TO MURDER ACTLF
7NCG ... LFBBS R,3,XREND
7NNW ... LFBBUS Q,3,XNFST
7P2= ... LINKSET 3,XNXT2(1)
7P?L ...XENDL LDX 2 3
7PK2 FPUT [GO TO CANTDO LISTING
7Q4L CALL 7 SWAITACT [WAIT FOR ACTLF TO CLOSE DOWN LISTING
7QJ= CALL 6 SFINDACT [FIND ACTIVITY AGAIN
7R3W BRN SNFND [ACTLF SHOULD STILL BE THERE
7RHG ...[
7S36 XBETL LOCK 3
7SGQ MURDER 3 [MURDER ACTLF
7T2B BRN XFIN2
7T3S ...[
7T5= ...[ IF FLAG R SET FORCE CANTDO BY CLEARING FLAG R
7T6N ...[
7T86 ...XREND LFBITCLR R,3
7T9J ... BRN XENDL
7T?2 ...[
7T#D ...[ IF FLAG R CLEAR FORCE CANTDO BY SETTING FLAG R
7TB5 ...[
7TPS ...XNFST LFBITSET R,3
7W5H ... BRN XENDL
7WF= ...[
7WS^ ...[
7X8N ...[ BREAKIN AND ALL THAT
7XJC ...[
7XY6 XBRK MFREEW CPB,CUNI [OPENING :SYSTEM.PROPERTY IN NIPSTART
7YCQ MFREEW APERI,APROPS
7YXB XBRKIN [DURING LW FOR BREAKIN BIT IN NIPSTAR
7^C2 MFREEW GOUT,GPROPNOS
7^WL XBRK2 UP
84#Q ...[
84SB ...[ ERRORS
85#2 ...[
85RL TOMNY SETREP MAXATT [TOO MANY PROPERTIES
86?= ...[
86QW TOMN2 MFREEW APERI,APROPS
87=G MFREEW GOUT,GPROPNOS
87Q6 TOMN3 UPPLUS 1
889Q ...[
88PB XNFND SETREP XPROP [NO SUCH PROPERTY
8992 XNF2 CLOSE
89NL BRN TOMN2
8=8= ...[
8=MW XCONS SETREP XCPROP [CONSOLE PROPERTY
8?7G BRN XNF2
8?M6 ...[
8#6Q XFORM SETREP FORMAT [FORMAT ERROR
8#LB BRN XNF2
8BJW ...[
8C4G ...XNREP GEOERR 0,ILLMODE [ILLEGAL MODE
8CJ6 XNR2 MFREEW APERI,ARPERT
8D3Q ... BRN TOMN3
8DHB ...[
8F32 XTBIG SETREP LONG [PAGE WIDTH TOO BIG
8FGL BRN XNR2
8G2= ...[
8GFW XNALF SETREP FORMAT [DEBATCHING CHAR NOT ALPHA
8G^G BRN XNR2
8HF6 ...[
8HYQ XERCH SETREP WRONG [CHAR SET NOT 48,64 OR 96
8JDB BRN XNR2
8JY2 ...[
8KCL ...XERPL SETREP TOOHIGH
8KX= ... BRN XNR2
8LBW ...[
8LWG XNORP SETREP NOPROP [REPERTOIRE INFO INCOMPLETE-NIPLINES
8MB6 ... BRN TOMN3
8MTQ ...[
8N*B ...[
8NT2 ...[
8P#L #END
^^^^ ...242123540001