{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LISTSTAR867)}}
====== LISTSTAR867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:APPEND|APPEND]], [[george:macro:CLOSE|CLOSE]], [[george:macro:CREATEB|CREATEB]], [[george:macro:CREATEWF|CREATEWF]], [[george:macro:DATECON|DATECON]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:GEOERR|GEOERR]], [[george:macro:IDFOPEN|IDFOPEN]], [[george:macro:ISSUCOMB|ISSUCOMB]], [[george:macro:LOBSFILE|LOBSFILE]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:ON|ON]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OPENWORK|OPENWORK]], [[george:macro:P|P]], [[george:macro:PICKREP|PICKREP]], [[george:macro:REPALLER|REPALLER]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREPX|TESTREPX]], [[george:macro:TIMECON|TIMECON]], [[george:macro:V|V]], [[george:macro:VFREE|VFREE]]
22FL ...#SEG LISTSTAR [LEN WAGSTAFF
22PD ...# COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22^= #OPT K0LISTSTAR=0
23DW #LIS K0LISTSTAR>K0ALLGEO>K0GREATGEO>K0COMMAND>K0IDF
23YG 8HLISTSTAR
24D6 # ENTRY POINTS
24XQ SEGENTRY K1LISTSTAR,Z1LISTSTAR
25CB SEGENTRY K2LISTSTAR,Z2LISTSTAR
25X2 SEGENTRY K30LISTSTAR,Z30LISTSTAR
26BL MENDAREA 30,K99LISTSTAR
26W= [ THIS SEGMENT BEGINS &ENDSLISTING OF THE IDF.
27*W # FIRST THE BEGINNING- JUST ONE ENTRY POINT,
27TG # WHICH CREATES & OPENS THE FILES NEEDED AND
28*6 # PRINTS THE MAIN HEADING.
2DLQ WHEAD 44H CONTENTS OF THE INSTALLATION DESCRIPTION
2F6B 28HFILE ON AT
2GK= Z1LISTSTAR [ENTRY FROM LI COMMAND
2H4W CREATEWF [CREATE A WORKFILE
2HJG CREATEB
2J46 MHUNTW 1,FILE,CREATE
2JBH ... LDN 0 #12
2JNY ... ORX 0 GSIGN [ GRAPHIC FILE
2K3B STO 0 CETM(1)
2KH2 OPENWORK X,APPEND,EMPTY [OPEN A WORKFILE
2L2L TESTREP OK,OKL
2LG= X GEOERR 1,IDFERR
2L^W OKL LOBSFILE
2PD2 P IDFANDPROP,XABORT1
2PXL ... OPENSYS XABORT1,PROPERTY,READ
2QC= SETNCORE 26,1,FILE,FAPB
2QWW ... LDX 4 ACES
2RW6 STO 4 A1+2(1)
2S*Q LDN 4 A1+2(1)
2STB LDN 5 A1+3(1)
2T*2 MOVE 4 24
2TSL LDN 4 26
2W#= STO 4 A1(1)
2WRW SMO FX1
2X?G LDN 4 WHEAD
2XR6 LDN 5 #51
2Y=Q STO 5 A1+1(1) [ST.PFCC.
2YQB LDN 5 A1+5(1)
2^=2 MOVE 4 18 [MOVE IN HEADING
2^PL DATECON EDATE [CAL. TO-DAYS DATE.
329= MHUNTW 2,FILE,FAPB [HUNT FOR APPEND BLOCK
32NW SMO FX2
338G LDX 0 ACOMMUNE1 [LOAD FIRST PART.
33N6 STO 0 A1+18(2) [STO. DATE
347Q SMO FX2
34MB LDX 0 ACOMMUNE2 [LOAD 2ND HALF.
3572 STO 0 A1+19(2) [STO. 2ND DATE
35LL TIMECON CLEANCT [CAL. TIME
366= MHUNTW 2,FILE,FAPB
36KW SMO FX2
375G LDX 0 ACOMMUNE1
37K6 STO 0 A1+22(2) [ST. TIME
384Q SMO FX2
38JB LDX 0 ACOMMUNE2
3942 STO 0 A1+23(2) [ST. 2ND PART OF TIME.
39HL APPEND 1,XABORT2
3=3= TESTREP REFUSED,XABORT2
3=GW VFREE FILE,FAPB
3?2G #
3?G6 # MAIN ROUNTINE
3?^Q #
3J7F ... IDFOPEN XABORT2
3J#* ...SIDFOPEN
3JF9 ... ACROSS LISTIDF,1
3JR2 # THE REST OF THIS SEGMENT TIDIES UP AFTER
3K=L # LISTIDF ETC. IT CLOSES FILES AND ISSUES
3KQ= # THE LISTFILE COMMAND.
3L9W # IT USED TO BE THE SEGMENT "LISTFIN".
3LPG ...QLF 12HLF !,*LP,
3M96 #
3MNQ # SUBROUTINE TO CLOSE A FILE.
3N8B #
3NN2 XCL SBX 4 FX1
3P7L PICKREP 6
3PM= XC CLOSE [ISSUE CLOSE.
3Q6W BCT 5 XC [CLOSED ENOUGH FILES?
3QLG ... V IDFANDPROP
3R66 ADX 4 FX1 [Y
3RKQ EXIT 4 0
3S5B Z2LISTSTAR
3SK2 LDN 5 3
3T4L CALL 4 XCL [CALL CLOSE SUBROUTINE.
3T6N ...XPHX
3T^G ... SETNCORE CPDATA+6-A1,3,ADATA,CREADL
3W3W LDN 0 8
3WHG STO 0 A1(3)
3X36 LDN 2 QLF(1)
3XGQ ADN 3 CPDATA
3Y2B MOVE 2 2
3Y2H ...Z2FROMA
3Y3M ... SPARAPAS [TRY FOR 'PR' PARAMETER
3Y4Y ... MHUNT 2,CPB,CUNI
3Y69 ... LDX 6 ANUM(2)
3Y7G ... BZE 6 NOPR [NOPE
3Y8R ... BNG 6 NOPR [NOPE
3Y=4 ... MHUNTW 3,ADATA,CREADL
3Y?* ... LDX 5 3 [SPARE COPY
3Y#L ... ADN 5 CPDATA+2 [FOR MVCH
3Y*X ... ADN 2 APARA
3YC8 ... LDN 4 QLF+2(1)
3YDF ... MVCH 4 1 [MOVE COMMA
3YFQ ... LDN 7 1 [UPDATE CHAR CT
3YH3 ... ADS 7 A1(3)
3YJ# ... ANDN 6 #7777
3YKK ... LDN 0 16 [TRUNCATE 'PR' PARAMETER..
3YLW ... TXL 6 0 [..IF TOO LONG
3YN7 ... BCS NOTR
3YPD ... LDN 6 15
3YQP ...NOTR ADS 6 A1(3) [UPDATE COUNT
3YS2 ... LDX 4 2
3YT? ... SMO 6
3YWJ ... MVCH 4 0 [MOVE 'PR' PARAMETER
3YXT ...NOPR ISSUCOMB XPHZ,XPHZ
3Y^L XPHZ
3^F= ENDCOM
3^YW XABORT2 [BRK-IN,2 FILES TO CLOSE
42DG LDXC 0 GSIGN
42Y6 XABORT1 [BRK-IN,1 TO CLOSE
43CQ LDN 5 1
43XB BRN XZ
44C2 Z30LISTSTAR
44WL LDN 5 3
45B= XZ CALL 4 XCL
45TW TESTREPX 6,OK,XPHZ
46*G REPALLER
46T6 TESTREPX 6,REFUSED,XPHX
47#Q BRN XPHZ
47SB #END
^^^^ ...32265006000100000000