{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LOADERBU867)}}
====== LOADERBU867 ======
(George Source)
22FL ...#SEG LOADERBU86 [M.C.D. MANN
22J9 ...# ########################################################
22LS ...#
22PC ...# (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22S2 ...#
22WK ...# #########################################################
22^= #LIS K0LOADER>K0LOADERMT>K0ALLGEO
23DW #
23YG # THIS SEGMENT CONTAINS THE
24D6 # ALTERS TO GEORGE & MEND AREA FOR MT ALLOCATOR/LOADER.
24XQ # IT NEED NOT IMMEDIATELY PRECEDE THE SEGMENT LENDMT.
25CB #
25X2 # FSDESC TABLES & JLREST/JLBUFF BUFFERS NOW IN FIXED CORE
26BL # VIA LOADERMT.
26W= #
27*W #
27TG #
2QC= # MT LOADER COMES HERE ON RECEIPT OF ME(ND) COMMAND
2QWW # VALID COMMAND CAUSES TWO WDS TO BE ADDED TO JLRAT
2RBG # WD0 DRUM ADDRESS
2RW6 # WD1 WORD
2S8H ...JLME LDX 3 AJLRAT(2)
2SGY ... LDX 0 0(3)
2STB SBN 0 50
2T*2 BPZ 0 JLWRC [TOO MANY ALTERS
2TSL CALL 0 JLPOINT
2W8* ... LDX 6 0(3)
2WD7 ... ADX 6 AJLRAT(2) [CURRENT ADDRESS IN ALTER TABLE
2WM^ ... ADN 6 1
2WXR ... LDX 3 6
2X?G CALL 0 MECONV [CONVERT & STORE D-ADDR
2XR6 LDCH 0 0(1)
2Y=Q SBN 0 #34
2YQB BNZ 0 JLWRC [NOT COMMA TERMINATING
2^=2 BCHX 1 £
2^PL CALL 0 MECONV [CONVERT & STORE WD
329= LDCH 0 0(1)
32NW SBN 0 #20
338G BNZ 0 JLWRC [NOT SPACE TERMINATING
33N6 LDN 0 2
342H ... LDX 3 AJLRAT(2)
34#Y ... ADS 0 0(3) [UPDATE POINTER
34MB BRN JLXOK
3572 #
35LL #
366= MECONV
36KW LDCH 4 0(1)
375G SBN 4 #32 [* ?
37K6 BNZ 4 ME1 [DECIMAL
384Q BCHX 1 £ [OCTAL CONVERSION
38JB LDN 7 0
3942 LDN 5 9
39HL ME3 LDCH 4 0(1)
3=3= TXL 4 OCT8(2)
3=GW BCC ME2
3?2G BCHX 1 £
3?G6 SLL 7 3
3?^Q ORX 7 4
3#FB BCT 5 ME3
3#^2 BRN JLWRC
3*DL #
3*Y= ME1 LDN 5 8 [DECIMAL CONVERSION
3BCW LDN 6 0
3BXG LDN 7 0
3CC6 ME6 CDB 6 0(1)
3CWQ BCS ME2
3DBB BCHX 1 £
3DW2 BCT 5 ME6
3F*L BRN JLWRC
3FT= #
3G#W ME2 STO 7 0(3) [STORE RESULT IN TABLE
3GSG ADN 3 1
3H#6 EXIT 0 0
3HRQ #
3J?B #
3MNQ #SKI K6LOADERMT
3N8B (
3NN2 # ALSO CONTAINED HEREIN ARE ANY TESTING ROUTINES.
3P7L #
3PM= # THE AL COMMAND ALLOWS THE LOADER/COMMAND TO BE MENDED AT RUN TIME.
3Q6W # COMMAND FORMAT IS ...
3QLG ...# 'AL ADDRESS,WORD' BOTH IN PLAIN UNDATUMISED OCTAL
3R66 ...# E.G. AL 7241,3 (*77241 _ LDX 0 3)
3RKQ #
3S5B JLAL CALL 0 JLPOINT
3SK2 LDN 3 0
3T4L TAL2 LDCH 4 0(1)
3TJ= TXL 4 OCT8(2)
3W3W BCC TAL1
3WHG SLL 3 3
3X36 ADX 3 4
3XGQ BCHX 1 £
3Y2B BRN TAL2
3YG2 TAL1 SBN 4 #34
3Y^L BNZ 4 JLWRC
3^F= LDN 5 0
3^YW TAL4 BCHX 1 £
42DG LDCH 4 0(1)
42Y6 TXL 4 OCT8(2)
43CQ BCC TAL3
43XB SLL 5 3
44C2 ADX 5 4
44WL BRN TAL4
45B= TAL3 SBN 4 #20
45TW BNZ 4 JLWRC
46*G SMO 2
46T6 TAL5 STO 5 0(3)
47#Q BRN JLXOK
47SB #
48#2 # THIS ROUTINE PRINTS A WORD OF LOADER/ALLOCATOR AT RUN TIME
48RL # COMMAND FORMAT IS ...
497* ...# 'PR ADDRESS' IN PLAIN UNDATUMISED OCTAL
49H4 ...# E.G. PR 3241
49WR ...#
4==G JLPR CALL 0 JLPOINT
4=Q6 LDN 3 0
4?9Q PR2 LDCH 4 0(1)
4?PB TXL 4 OCT8(2)
4#92 BCC PR1
4#NL SLL 3 3
4*8= ADX 3 4
4*MW BCHX 1 £
4B7G BRN PR2
4BM6 PR1 SBN 4 #20
4C6Q BNZ 4 JLWRC
4CLB SMO 2
4D62 PR3 LDX 4 0(3)
4DKL ... LDN 1 OPRINT+2(2)
4F5= LDN 5 8
4FJW PR4 LDN 3 0
4G4G SLL 34 3
4GJ6 DCH 3 0(1)
4H3Q BCHX 1 £
4HHB BCT 5 PR4
4J32 ... LDN 1 OPRINT(2)
4JGL BRN JLTURN
4K2= #
4KFW #SKI 77?<515$515 [SKIP LABEL IF GIN515 OR LATER
4K^G OCT8
4LF6 +8
4MDB #
4MY2 )
4SS= #
4T6L ...#
4T?W # *** MEND AREA ***
4TRG #
4W?6 ...K7LOADERMT
4WQQ ...#GAP 383-0? [MEND AREA FOR OVERLAY
4X=B # [LEAVE SPACE FOR METAFORM & LENDMT
4^NG #
5286 #END
^^^^ ...170173670001