{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LOADERDB867)}}
====== LOADERDB867 ======
(George Source)
**Macros used:** [[george:macro:JTWIN|JTWIN]]
22FL ...#SEG LOADERDB86 [M. DRUKKER
22J9 ...# ########################################################
22LS ...#
22PC ...# (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22S2 ...#
22WK ...# #########################################################
22^= #LIS K0LOADERMT>K0LOADER>K0ALLGEO
23DW #
23YG # THIS SEGMENT CONTAINS TWO BUFFERS
24D6 ...# USED IN LOADERDA86.
24XQ #
257J ...#GAP 120 [CONTINUE MEND AREA
25CB JLSCA
25X2 #GAP 129
26BL JLSCAFAC
26W= #GAP 129
27*W #
27BN ...#
27BP ...# SUBROUTINE CHECKS THAT A DA DEVICE
27BQ ...# IS STANDARD UDAS.
27BR ...# THERE THREE CHECKS.
27BS ...# 1 CHECKSUM OK
27BT ...# 2 ENTRY IN FIP CELL FOR SYFLE OK
27BW ...# 3 CSN IN SCA+5 IS THE SAME AS SYFLENNNNN IN SCA+22
27BX ...# IF ANY OF THESE CHECKS FAIL : UNIT NNN NOT UDAS IS OUTPUT.
27BY ...# THIS SUBROUTINE IS CALLED FROM LOADERDA
27B^ ...# IT WAS ADDED IN MK866 PREDOMINANTLY FOR CME.
27C2 ...#
27C5 ...#
27CG ...CHECKDISC
27CX ... STO 0 OCHECKD(2)
27D7 ... SMO OSCA(2)
27DC ... LDX 0 1
27DP ... BZE 0 SN61
27F6 ... LDX 1 OSCA(2)
27FH ... SUM 0 128
27FY ... BNZ 0 SN63
27G8 ...SN61 SMO OSCA(2)
27GD ... LDX 0 21
27GQ ... TXU 0 OXSYF(2)
27H7 ... BCS SN63
27HJ ... LDN 0 0
27H^ ... LDN 6 6
27JB ... LDCT 1 #400
27JL ... SMO OSCA(2)
27JW ... ORN 1 22
27K8 ...SN62 LDCH 5 0(1)
27KK ... TXL 5 OCT8(2)
27L2 ... BCC SN63
27LC ... SLL 0 3
27LS ... ADX 0 5
27M9 ... BCHX 1 £
27ML ... BCT 6 SN62
27MW ... SMO OSCA(2)
27N6 ... LDX 6 5
27ND ... SLL 6 6
27NT ... SRL 6 6
27P= ... TXU 0 6
27PM ... BCS SN63
27PT ... LDX 0 OCHECKD(2)
27Q4 ... EXIT 0 1
27QF ...SN63 LDN 1 OXEM2(2)
27QW ... STO 3 OXDEVICE(2)
27R? ... CALL 0 JLGEOG
27RN ... CALL 6 JLOUT
27S5 ... LDX 3 OXDEVICE(2)
27S? ... LDX 0 OCHECKD(2)
27SG ... EXIT 0 0
28#6 ...#
28RQ ...#
29?B ...# LOADER/ALLOCATOR COMES HERE ON RECEIPT OF RP COMMAND
29R2 ...# ONE PARAMETER: 'ON' OR 'OFF'.
2==L ...# ON-> LIST INOP UNITS AFTER DISC SEARCHES.
2=Q= ...#
2?9W ...JLRP CALL 0 JLPOINT
2?PG ... LDN 2 0
2#96 ... MVCH 1 4
2#NQ ... LDX 2 G3DOL
2*8B ... TXU 0 OFF(2)
2*N2 ... BCC RP1
2B7L ... TXU 0 ON(2)
2BM= ... BCS JLWRC
2C6W ... STOZ OSTRGMK(2)
2CLG ... BRN JLXOK
2D66 ...RP1 LDCT 0 #400
2DKQ ... STO 0 OSTRGMK(2)
2F5B ... BRN JLXOK
2FK2 ...#
2G4L ...#
2GJ= ...# L/A COMES HERE FOR (UN)DEDICATE COMMANDS. PARAMETER STRI NG OF
2H3W ...# GEOG.NOS. REMEMBERED FOR FILLING IN TABLE A(UN)RES IN
2HHG ...# TWINSET. NO PARAMS -> CLEAR TABLE.
2J36 ...#
2JGQ ...JLDC NGNC 0 1
2K2B ...JLUN LDN 0 0
2KG2 ... SMO 0
2K^L ... LDX 6 JLUNDC [PICK UP RELEVANT D-ADDRESS
2LF= ... LDN 3 OTABUNDC(2)
2LYW ... STO 3 OSMOTAB(2)
2MDG ... CALL 0 JLPOINTN
2MY6 ... BRN UNDC2 [NO PARAMS
2NCQ ...UNDC4 CALL 0 JLGETNUM [GET NEXT GEOGNO
2NXB ... BRN JLWRC [SOME ERROR
2PC2 ... BRN UNDC2 [NO MORE
2PWL ... FINDPERE 3,APGEOG,JLGOTIT(2) [DOES IT EXIST?
2QB= ... BNG 3 JLWRC [NO - ERROR
2QTW ... JTWIN 3,UNDC3 [YES - IS IS TWINNED?
2R*G ... BRN JLWRC [NO
2RT6 ...UNDC3 LDX 3 OSMOTAB(2)
2S#Q ... STO 6 0(3) [STORE D-ADDRESSS
2SSB ... ADN 6 1 [& INCRMENT
2T#2 ... LDX 0 JLGOTIT(2)
2TRL ... STO 0 1(3) [STORE GEOGNO
2W?= ... ADN 3 2
2WQW ... STO 3 OSMOTAB(2) [- INCREMENT TABLE PTR
2X=G ... BRN UNDC4 [& GO FOR NEXT
2XQ6 ...UNDC2 LDX 3 OSMOTAB(2)
2Y9Q ... STO 6 0(3) [STORE D-ADDRESS
2YPB ... NGN 0 1
2^92 ... STO 0 1(3) [ & EOT WD
2^NL ... ADN 3 2
328= ... SBN 3 OUNDCTAB(2) [LENGTH OF TABLE
32MW ... LDX 1 AJLRAT(2)
337G ... LDX 0 0(1)
33M6 ... ADX 0 3
346Q ... SBN 0 51
34LB ... BPZ 0 JLWRC [NO MORE ROMM
3562 ... LDX 6 0(1)
35KL ... ADX 6 AJLRAT(2)
365= ... ADN 6 1
36JW ... LDN 5 OUNDCTAB(2)
374G ... MOVE 5 0(3) [INSERT TABLE
37J6 ... ADS 3 0(1)
383Q ... BRN JLXOK [FINI
38HB ...#
3932 ...#GAP 639-0?
39GL ...#END
^^^^ ...572447270001