{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LOGACC863)}}
====== LOGACC863 ======
(George Source)
**Macros used:** [[george:macro:BRUSEN|BRUSEN]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FCAPCA|FCAPCA]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FJOCA|FJOCA]], [[george:macro:HUNT|HUNT]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JMBS|JMBS]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:ORIGIN|ORIGIN]], [[george:macro:OUTBLOCN|OUTBLOCN]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:SBADN|SBADN]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TOPFCB|TOPFCB]], [[george:macro:UP|UP]]
229S ...#OPT K0LOGACC=K0ALLGEO
22FL ...#LIS K0LOGACC>K0ALLGEO>K0GREATGEO>K0COMMAND
22^= ...#SEG LOGACC863 [JOY THOMPSON-CENT
23DW ... 6HLOGACC
23YG ... SEGENTRY K1LOGACC,QENTRY1
24D6 ...#
24XQ ...#
25CB ...# K1LOGACC(ENTRY POINT)
25X2 ...# -------------------- THIS SEGMENT IMPLEMENTS THE LOGACCESS MACRO,
26BL ...# AND SERVES TO LOG ANY ACCESSES TO NOMINATED ENTRANTS,BY SENDING A
26W= ...# MESSAGE TO SYSTEM JOURNAL.
27*W ...#
27TG ...#
28*6 ...# THIS SUBROUTINE ASSEMBLES MESSAGES IN THE GMON,ASET BLOCK
28SQ ...MESSOUT
29#B ... SBX 7 FX1
29S2 ... OUTPACKX 6,5,4
2=?L ... ADX 7 FX1
2=R= ... EXIT 7 0
2?=W ...#
2?QG ...#
2#=6 ...#
2#PQ ...# THIS SUBROUTINE CHECKS THAT THE CURRENT ACTIVITY IS THE CPAT
2*9B ...# IF NOT, IT FINDS THE CPAT FROM THE AOLPT
2*P2 ...XHUNTCPAT
2B8L ... SBX 7 FX1
2BN= ... LDX 2 FX2
2C7W ... LDCH 4 ATYPE(2)
2CMG ... SBN 4 CPAT/64
2D76 ... BZE 4 XGOTIT [J IF IS CPAT
2DLQ ... SBADN 4,(AOLPT/64)-(CPAT/64)
2F6B ... BZE 4 XFINDIT [J IF IS AOLPT
2FL2 ... SBADN 4,(AREWIND/64)-(AOLPT/64)
2G5L ... BZE 4 XAREWIND [J IF IT IS AREWIND
2GK= ...XNOCPAT
2H4W ... NGN 2 4095
2HJG ... BRN XGOTIT
2J46 ...XAREWIND
2JHQ ... LDX 4 JOBNO(2)
2K3B ... BZE 4 XNOCPAT
2KH2 ... FINDJOBQ 3,4,(GEOERR) [X3 POINTS TO JOB BLOCK
2L2L ... FCAJO 2,3 [X2 POINTS TO CPAT
2LG= ... BRN XGOTIT
2L^W ...XFINDIT
2MFG ... LDX 1 APETADDR(2)
2M^6 ... FCAPCA 2,1
2NDQ ...XGOTIT
2NYB ... ADX 7 FX1
2PD2 ... EXIT 7 0
2PXL ...#
2QC= ...#
2QWW ...#
2RBG ...# IDENTIFIERS USED FOR OUTPUTTING JOBTYPE,AND ENTRANT TYPE CODE
2RW6 ...ZERO 0 [MOP(CENTRAL),OR FILESTORE FILE
2S*Q ...XONE 1 [BACK(CENTRAL),OR MAG.TAPE
2STB ...TWO 2 [REMOTE MOP(IE CLUSTER),OR EXOFILE
2T*2 ...THREE 3 [RJE(IE CLUSTER +BACKGROUND)
2TSL ...#
2W#= ...XCI #20435120 [CI
2WRW ...#
2X?G ...#
2XR6 ...QENTRY1
2Y=Q ... MHUNTW 3,FILE,ENT
2YQB ... JMBS UP,3,BETEMP,BEWORK [DON'T LOG TEMP FILES
2^=2 ... LDX 0 ACOMMUNE1(2)
2^PL ... STO 0 AWORK1(2)
329= ... LDX 0 ACOMMUNE2(2)
32NW ... STO 0 AWORK2(2)
338G ... OUTBLOCN 55 [SET UP GMON/ASET BLOCK
33N6 ... OUTPAR DATENOW,TIMENOW [PUT IN DATE AND TIME
347Q ... LDN 6 GMTNOW
34MB ... LDN 5 1 [OUTPUT GEORGE MEAN TIME
3572 ... LDN 4 JPDNUMA
35LL ... CALL 7 MESSOUT
366= ... MHUNT 3,FILE,ENT
36KW ... LDN 6 TWO(1)
375G ... LDN 5 1
37K6 ... LDN 4 JPDNUMB
384Q ... JBS XENOTYPE,3,BEEXO [J IF EXOFILE
38JB ... SBN 6 1
3942 ... JBS XENOTYPE,3,BELIB [J IF MT
39HL ... SBN 6 1
3=3= ...XENOTYPE
3=GW ... CALL 7 MESSOUT [OUTPUT ENTRANT TYPE
3?2G ... TOPFCB 3 [FIND FILE/FCB
3?G6 ... LDN 6 FME1(3)
3?^Q ... LDN 5 3 [USERNAME OF ENTRANT
3#FB ... LDN 4 JPDUSERNAME
3#^2 ... CALL 7 MESSOUT
3*DL ... MHUNTW 2,FILE,ENT [FIND FILE/ENT
3*Y= ... LDN 6 ELOC1(2)
3BCW ... LDN 5 3
3BXG ... LDN 4 JPDLOCNAME [LOCAL NAME
3CC6 ... CALL 7 MESSOUT
3CWQ ... MHUNTW 2,FILE,ENT
3DBB ... LDX 4 ESER(2)
3DW2 ... BZE 4 MFILE [J IF NOT MT
3F*L ... LDN 6 EREEL(2)
3FT= ... LDN 5 1 [REEL NUMBER
3G#W ... LDN 4 JPDREELNUM
3GSG ... CALL 7 MESSOUT
3H#6 ... MHUNTW 2,FILE,ENT
3HRQ ... LDN 6 EGEN(2)
3J?B ... LDN 5 1 [GENERATION NO.
3JR2 ... LDN 4 JPDGENNUM
3K=L ... CALL 7 MESSOUT
3KQ= ... OUTNULL [NOT LANG CODE
3L9W ... MHUNTW 2,FILE,ENT
3LPG ... LDN 6 ESER(2)
3M96 ... LDN 5 1 [TSN
3MNQ ... LDN 4 JPDTSN
3N8B ... CALL 7 MESSOUT
3NN2 ... BRN MTAPE
3P7L ...MFILE
3PM= ... OUTNULL
3Q6W ... MHUNTW 2,FILE,ENT
3QLG ... LDN 6 EGEN(2)
3R66 ... LDN 5 1 [GENERATION
3RKQ ... LDN 4 JPDGENNUM
3S5B ... CALL 7 MESSOUT
3SK2 ... MHUNTW 2,FILE,ENT
3SN6 ... JBC XLANG,2,BEEXO [J IF NOT EXOFILE
3SR= ... OUTNULL [NO LANG FOR EXOFILE
3SWB ... BRN NULLTSN
3S^G ...XLANG
3T4L ... LDN 6 ELAN(2)
3TJ= ... LDN 5 1 [LANG
3W3W ... LDN 4 JPDLANGUAGE
3WHG ... CALL 7 MESSOUT
3WR# ...NULLTSN
3X36 ... OUTNULL [NOT TSN FOR FILE
3XGQ ...MTAPE
3Y2B ... CALL 7 XHUNTCPAT
3YG2 ... BNG 2 MNOUS
3Y^L ... BRUSEN MNOUS,2 [BR IF IN NO USER CONTEXT
3^F= ... FJOCA 2
3^YW ... OUTPACK JUSER(2),3,USERNAME [OUTPUT USERNAME OF JOB
42DG ... CALL 7 XHUNTCPAT
42Y6 ... FJOCA 2
43CQ ... OUTPACK JNAME(2),3,JOBNAME [OUTPUT JOB NAME
43XB ... LDN 6 ZERO(1) [CODE FOR JOBTYPE
44C2 ... CALL 7 XHUNTCPAT
44WL ... JBS XMOP,2,CXTMOP [J IF MOP CONTEXT
45B= ... ADN 6 1 [IS NOT MOP CONTEXT
45TW ...XMOP
46*G ... LDX 3 JSOURCE3(2) [IS ZERO IF CENTRAL
46T6 ... BZE 3 XCENTRAL [J IF CENTRAL
47#Q ... ADN 6 2 [IS CLUSTER
47SB ...XCENTRAL
48#2 ... LDN 5 1
48RL ... LDN 4 JPDJOBTYPE [OUTPUT JOBTYPE
49?= ... CALL 7 MESSOUT
49QW ... BRN MUSER
4==G ...MNOUS
4=Q6 ...# [IF NO USER -PUT OUT 3 NULL PARAM'S
4?9Q ... OUTNULL
4?PB ... OUTNULL
4#92 ... OUTNULL
4#NL ...MUSER
4*8= ...# OUTPUT JOB/INPUT SOURCE
4*MW ... CALL 7 XHUNTCPAT
4B7G ... BNG 2 TCENT
4BM6 ... LDX 3 2
4C6Q ... LDX 2 FX2
4CLB ... LDX 0 ACES
4D62 ... STO 0 ACOMMUNE1(2)
4DKL ... STO 0 ACOMMUNE2(2) [SPACEFILL ACOMMUNE WORDS
4F5= ... STO 0 ACOMMUNE3(2)
4FJW ... STO 0 ACOMMUNE4(2)
4G4G ... LDCH 0 JSOURCE1(3)
4GJ6 ... SBN 0 #74 [PERI TYPE 60
4H3Q ... BZE 0 TCI [J IF CI
4HHB ... JBS TMOP1,3,CXTMOP [J IF MOP
4J32 ... LDN 7 0 [X7 IS ZERO IF NOT MOP
4JGL ... LDX 0 JSOURCE3(3) [THEREFORE IS BACK
4K2= ... ANDX 0 BITS22LS [PROPERTY NO B2-23
4KFW ... BZE 0 TCENT [J IF CENTRAL
4K^G ... LDN 0 #6220 [THEREFORE IS REMOTE BACK
4LF6 ... DSA 0 ACOMMUNE1(2) [R
4LYQ ...TMOP1
4MDB ... LDN 0 JSOURCE1(3)
4MY2 ... LDN 1 ACOMMUNE7(2)
4NCL ... MOVE 0 3 [MOVE JSOURCE1,2,3 TO ACOMMUNE7,8,9
4NX= ... ORIGIN
4PBW ... BNZ 7 TMOP2 [X7 NON-ZERO IF MOP;J IF MOP
4PWG ... LDN 0 ACOMMUNE1(2)
4QB6 ... ORX 0 GSIGN
4QTQ ... LDN 1 ACOMMUNE1(2)
4R*B ... MVCH 0 10 [MOVE EVERYTHING UP 2 CHARACTERS
4RT2 ... LDN 5 3 [OUTPUT LENGTH IF REMOTE
4S#L ... BRN TMESS
4SS= ...TMOP2
4T?W ... LDN 5 2 [OUTPUT LENGTH IF MOP
4TRG ... LDN 0 ACOMMUNE2(2)
4W?6 ... LDN 1 ACOMMUNE1(2)
4WQQ ... MOVE 0 2 [MOVE EVERYTHING UP 1 WORD
4X=B ... BRN TMESS
4XQ2 ...TCENT
4Y9L ... OUTNULL [IF CENTRAL
4YP= ... BRN XAREQ
4^8W ...TCI
4^NG ... LDN 5 1 [OUTPUT LENGTH FOR CI
5286 ... SMO FX1
52MQ ... LDX 0 XCI [CI
537B ... STO 0 ACOMMUNE1(2)
53M2 ...TMESS
546L ... LDN 6 ACOMMUNE1(2) [START ADDR OF MESSAGE DATA
54L= ... LDN 4 JPDVARCHAR [PDC
555W ... CALL 7 MESSOUT
55KG ...
5656 ...XAREQ
56JQ ... LDX 7 AWORK2(2)
574B ... SBN 7 2 [ONLY O/P ACCESS BEING
57J2 ... BZE 7 XACC [ATTEMPTED IF REASON
583L ... SBN 7 5 [CODE IS 2,OR 7
58H= ... BZE 7 XACC
592W ... OUTNULL
59GG ... BRN XREA
5=26 ...XACC
5=FQ ... LDN 6 AWORK1(2)
5=^B ... LDN 5 1
5?F2 ... LDN 4 JPDOCTA [ACCESS REQ'D
5?YL ... CALL 7 MESSOUT
5#D= ...XREA
5#XW ... LDN 6 AWORK2(2)
5*CG ... LDN 5 1 [REASON CODE
5*X6 ... LDN 4 JPDNUMC
5BBQ ... CALL 7 MESSOUT
5BWB ... LDX 5 AWORK2(2)
5CB2 ... SBN 5 10
5CTL ... BNZ 5 XNOTRAPS [J IF NOT ACCESS CODE 10
5D*= ... HUNT 3,FILE,FTRAP
5DSW ... BNG 3 XNOTRAPS [J IF TRAPLIST(NO FILE,FTRAP)
5F#G ... LDN 6 ETRUSER1(3)
5FS6 ... LDN 5 3
5G?Q ... LDN 4 JPDUSERNAME
5GRB ... CALL 7 MESSOUT [OUTPUT USER FOR WHOM TRAPS BEING GIVE
5H?2 ... MHUNT 3,FILE,FTRAP
5HQL ... LDN 6 ETRAPMODES(3)
5J== ... LDN 5 1
5JPW ... LDN 4 JPDOCTB
5K9G ... CALL 7 MESSOUT [OUTPUT TRAPS
5KP6 ... BRN XLOCNAM
5L8Q ...XNOTRAPS
5LNB ... OUTNULL [IF NO TRAPS ARE BEING GIVEN
5M82 ... OUTNULL
5MML ...XLOCNAM
5N7= ... LDX 5 AWORK2(2)
5NLW ... SBN 5 6
5P6G ... BNZ 5 XNOTRN [J IF NOT A RENAMED ENTRANT
5PL6 ... MHUNT 3,FILE,ENT
5Q5Q ... LDN 5 3
5QKB ... LDN 4 JPDLOCNAME
5R52 ... JBS XEXO,3,BEEXO [J IF EXOFILE
5RJL ... MHUNT 3,FILE,FLOCNB
5S4= ... LDN 6 A1(3)
5SHW ... CALL 7 MESSOUT [OP NEW LOC NAME OF RENAMED FILST FILE
5T3G ... LDN 6 A1+4(3)
5TH6 ... LDN 5 1
5W2Q ... LDN 4 JPDGENNUM [OP GEN FOR RENAMED FILESTORE FILE
5WGB ... CALL 7 MESSOUT
5X22 ... LDN 6 A1+5(3)
5XFL ... LDN 5 1 [OP LANG FOR RENAMED FILESTORE FILE
5X^= ... LDN 4 JPDLANGUAGE
5YDW ... CALL 7 MESSOUT
5YYG ... BRN XOPMESS
5^D6 ...XEXO
5^XQ ... MHUNT 3,FILE,FABSNB
62CB ... ADX 6 HDREC(3)
62X2 ... ADN 6 A1-6(3) [OP LOCAL NAME FOR RENAMED EXOFILE
63BL ... CALL 7 MESSOUT
63W= ... ADX 6 HDREC(3)
64*W ... ADN 6 A1-2(3)
64TG ... LDN 5 1
65*6 ... LDN 4 JPDGENNUM
65SQ ... CALL 7 MESSOUT [OP GEN FOR RENAMED EXOFILE
66#B ... BRN XOPMESS1
66S2 ...XNOTRN
67?L ... OUTNULL
67R= ... OUTNULL
68=W ...XOPMESS1
68QG ... OUTNULL
69=6 ...XOPMESS
69PQ ... LDCH 5 ATYPE(2)
6=9B ... SBN 5 CPAT/64
6=P2 ... BNZ 5 NOTCPA
6?8L ... LDX 6 AMFMSK(2)
6?N= ... LDX 7 AMXMSK(2)
6#7W ... STOZ AMFMSK(2) [PREVENT MESS BEING SENT
6#MG ... STOZ AMXMSK(2) [ANYWHERE EXCEPT SYSTEM JOURNAL
6*76 ...NOTCPA
6*LQ ... SEGENTRY K50LOGACC
6B6B ...# THIS SECTION, UP TO LABEL X,IS THERE TO BE COMPILED AND
6BL2 ...# THEN OVERWRITTEN,TO ENSURE SUFFICIENT ROOM IS AVAILABLE
6C5L ...# IN CASE THE RESTORE-TIME MACRO,LOGAUT,IS USED,WHICH
6CK= ...# 'MENDS' THIS SEGMENT
6D4W ... MONOUT JLOGACC
6DJG ... BRN £
6F46 ...X
6FHQ ...#TRA K50LOGACC
6G3B ... MONOUT JLOGACC,,NONAUT
6GH2 ... BRN MONDONE
6H2L ...Y
6HG= ...#TRA X>Y
6H^W ...MONDONE
6JFG ... SEGENTRY K51LOGACC
6J^6 ... BNZ 5 UP
6KDQ ... STO 6 AMFMSK(2)
6KYB ... STO 7 AMXMSK(2)
6LD2 ...UP
6LXL ...
6MC= ... UP
6MWW ...#END
^^^^ ...14513620002700000000