{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LOGANAL864)}}
====== LOGANAL864 ======
(George Source)
**Macros used:** [[george:macro:APJOBSET|APJOBSET]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLOSE|CLOSE]], [[george:macro:DICTJL|DICTJL]], [[george:macro:DOWN|DOWN]], [[george:macro:ERASEWORK|ERASEWORK]], [[george:macro:FILECOUNT|FILECOUNT]], [[george:macro:FILEMOVE|FILEMOVE]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FRIGMONF|FRIGMONF]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:FSHMOVE|FSHMOVE]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:ICT|ICT]], [[george:macro:ISSUCOM|ISSUCOM]], [[george:macro:ISSUCOML|ISSUCOML]], [[george:macro:LOBSFILE|LOBSFILE]], [[george:macro:MASKSTOZ|MASKSTOZ]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OUTMON|OUTMON]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SFCB|SFCB]], [[george:macro:SPRIVON|SPRIVON]], [[george:macro:TRANSBEG|TRANSBEG]], [[george:macro:TRANSFIN|TRANSFIN]], [[george:macro:UP|UP]], [[george:macro:XCBINDEX|XCBINDEX]], [[george:macro:XYZ|XYZ]]
22FL #LIS K0LOGANAL>K0ALLGEO
22^= #SEG LOGANAL3 [K.KOSKUBA
23DW XYZ 8HLOGANAL
23YG #
24D6 # THIS SEG. IS ENTERED BY THE MACRO LOGANAL. THE LOGANALYSI
24XQ # PROGRAM IS LOADED(:SYSTEM.LOGPROG). IT CALLS THE SYS. MAC
25CB # LOGANAL. THIS RUNS THE LOGANALYSIS PROGRAM.
25X2 #
26BL # THE ISSUCOM USES THE ADATA/CREADL BLOCK ES ITS DATA,THIS CONTAINS
26W= # THE NO. OF CHARS IN THE DATA, THE MACRO NAME FOLLOWED BY THE PARAM
27*W # WHICH IS THE MONITOR FILE SELECTION MASK, GIVEB_N AS AN OCTAL
27TG # NO.THIS IS FOUND FOM THE ADATA/AREPORT BL. &CONVERTED TO A SUITABL
28*6 #
28SQ SEGENTRY K1LOGANAL,XK1LOG
28^Y ... FSHENTRY K2LOGANAL,XK2LOG,,XK2LOG
2976 ... FSHENTRY K3LOGANAL,XK3LOG,,XK3LOG
29FH ...XZZ 20
29RY ... +0
2=6* ... 20HLOAD :SYSTEM.LOGPROG
2=DQ ...#
2=R7 ...XLIST 30
2?5J ... +0
2?C^ ... 32HLISTFILE :%Z.%Y( 1/B1B0),*LP
2?QB ...#
2#4R ...XISSUE 32
2#C8 ... +0
2#PK ... 32HLOGANAL # ,
2*42 ...#
2*BC ...MONCAT #12002
2*NS ...#
2B39 ...XLFAIL 26H:SYSTEM.LOGPROG IS CORRUPT
2B*L ...#
2BN3 ...#OPT ANAL=#1100
2C2D ...#
2C#T ...XK1LOG
2CM= ...[ FIRST GET FGN OF MONITORING FILE
2C^M ... NGN 6 1
2D#4 ... SFCB 6,3 [SETS X3 POINTING TO FCB OF MON FILE
2DLF ...[
2DYW ...[ CONVERT FGN TO CHARS AND STORE IN AWORK2
2F?? ... LDN 1 AWORK1(2)
2FKN ... XCBINDEX 4,1,FGEN(3)
2FY5 ... LDX 1 FX1
2G=G ...[
2GK= CLOSE -1 [CLOSE MONITORING FILE
2H4W LDX 5 AMFMSK(2) [CLEAR MONITORING FILE
2HJG MASKSTOZ ,2
2J46 STO 5 AWORK1(2)
2JHQ LDX 4 CONTEXT(2)
2K3B ANDN 4 8 [TEST MOP CONSOLE BIT
2KH2 BZE 4 NOTMOP
2L2L LDN 4 2 [MOPOUT REPORT STYLE
2LG= STO 4 AMXMSK(2) [STORE MASK INTO MULTIPLEXOR MASK
2LHS ...#UNS CMXMSK
2LKB ...(
2LLY ... SEGENTRY K70LOGANAL
2LNG ... BRN XK71 [MENDED TO NULL IF REPORTNEST ON
2LQ4 ... MHUNTW 3,CPB,CALAS
2LRL ... STO 4 CMXMSK(3)
2LT8 ...XK71
2LWQ ... SEGENTRY K71LOGANAL
2LY# ...)
2L^W NOTMOP
2MFG # THE PROGRAM IS LOADED
2M^6 SETNCORE 7,2,ADATA,CREADL
2NDQ LDN 4 XZZ(1)
2NYB LDN 5 A1(2)
2PD2 MOVE 4 7
2PXL FJOCA 3,FX2
2QC= NGN 1 1
2QWW STO 1 ATIMEJ(3)
2RBG #
2RW6 # THE LOGANALYSIS PROGRAM IS GIVEN SYSTEM STARTED PRIVILEGE
2S*Q #
2STB SPRIVON JSSTART,3
2SX# ...#UNS ECS
2S^= ...(
2T38 ... LDN 0 62
2T56 ... DEX 0 ACOREP(3) [SET HIGH CORE PRI
2T74 ... LDX 0 ISISSMP
2T92 ... STO 0 AMILLP(3) [...AND MILL PRI
2T=Y ...)
2T?9 ...#UNS ICT
2T?G ...(
2T?R ... LDN 7 0 [GIVE ACT PRI OF ZERO TO ALLOW DEFAU
2T#4 ...
2T#* ... APJOBSET JOBNUM(3),7 [SET ACT PRI
2T#L ...)
2T*2 # AND THEN LOADED
2TSL LDN 7 1
2W#= ISSUCOM XERR
2WRW SETNCORE 10,2,ADATA,CREADL
2X?G LDN 4 XISSUE(1)
2XR6 LDN 5 A1(2)
2Y=Q MOVE 4 10
2YQB MHUNT 3,ADATA,AREPORT
2^=2 LDX 5 A1(3)
2^PL LDN 6 8
329= XL1 LDN 4 0
32NW SLL 45 3
338G BCHX 2 £
33N6 DCH 4 A1+4(2)
347Q BCT 6 XL1
34MB LDX 1 A1+1(3)
3572 BZE 1 XL2 [IF ZERO NO RETAIN
35LL LDN 4 A1+2(3)
366= LDN 5 A1+5(2)
36KW MOVE 4 0(1) [X1= AMOUNT TO MOVE
375G XL2
37K6 MFREE ADATA,AREPORT
37L7 ... FSHCODE B,XNOTA1
37M8 ...(
37N9 ...# WE CAN'T DO A FRIGMONF ON 'B' WITH THE SHARED FILESTORE SYSTEM
37P= ...# SO WE MUST GO TO 'A' TO OPEN THE WORKFILE!!!!
37Q? ...#
37R# ... SETNCORE 0,3,FSH,FSHTERM
37S* ... TRANSBEG FSHLOGNALID,LOGANAL,2,,,ACOMMUNE1
37TB ... FSHMOVE END [RING THE NEW WORKFILE
37WC ... FILEMOVE 0,-1 [& PUT IT TO THE BOTTOM OF THE STACK
37XD ...#
37YF ...XNOTA1
37^G ...)
382H ... FSHSKIP B,XNOTB1
383J ...(
384Q FRIGMONF [OPEN : FOR ERROR MESSAGES
388M ...#
38#J ...XNOTB1
38DF ...)
38JB LOBSFILE [FOR ONLINE BS COUNT
3942 MHUNT 3,FILE,FABSNB [GET WORKFILE'S FABSNB
39HL NAMETOP 3,ANAL,FABSNB
3=3= LDX 5 AWORK1(2) [RESET MONITORING FILE MASK
3=GW STO 5 AMFMSK(2)
3?2G LDN 7 0
3?8Q #SKI JSKI08
3?C2 ISSUCOM XERR [NU 'SPECIAL'-S71320
3?K= ...#SKI JSKI08<1$1
3?RG ISSUCOML XERR
3?^Q XER1 CALL 7 XCLEAN [TIDY UP FILES
3#FB XER2 LDX 4 CONTEXT(2)
3#^2 ANDN 4 #1000
3*68 ...#UNS FTS1
3*?B ... DICTJL
3*DL BZE 4 XER3
3*Y= DOWN PROSTART,11 [DELETE PROGRAM
3BCW XER3 UP
3BPL ...XERR SETNCORE 10,2,ADATA,CREADL
3C3B ... LDN 4 XLIST(1)
3C*6 ... LDN 5 A1(2)
3CLW ... MOVE 4 10
3CYL ... SMO FX2
3D=B ... LDX 4 AWORK2
3DJ6 ... STO 4 CPDATA+4(2) [STORE FGN IN COMMAND
3DW2 ISSUCOM XER4 [LF MONFILE
3F*L XER4 BZE 7 XER1
3FT= SETNCORE 7,2,CPB,CUNI
3G#W LDX 7 MONCAT(1)
3GSG ADN 2 A1
3H#6 ADN 1 XLFAIL
3HRQ MOVE 1 7
3J?B LDN 6 26
3JR2 OUTMON 6,A1,7,CPB,CUNI
3K=L MFREE CPB,CUNI
3KQ= BRN XER2
3L9W XCLEAN [ERASE WORKFILE & CLOSE ALL FILES
3LPG MASKSTOZ ,2
3M96 SBX 7 FX1
3MNQ MHUNT 3,ANAL,FABSNB [FIND THE ABSOLUTE NAME BLOCK
3N8B CHAIN 3,2 [FOR THE WORKFILE,RENAME AND
3NN2 NAMETOP 3,FILE,FABSNB
3NP? ... FSHCODE B,XNOTA2
3NQJ ...(
3NRT ...# AS FOR FRIGMONF ABOVE, WE CANNOT DO AN ERASEWORK ON THE
3NT6 ...# 'B' MACHINE!!!!
3NWC ...#
3NXN ... TRANSBEG FSHLOGNALID,LOGANAL,3,FILE,FABSNB,ACOMMUNE1
3NY^ ...#
3P2= ...XNOTA2
3P3H ...)
3P4S ... FSHSKIP B,XNOTB2
3P65 ...(
3P7L ERASEWORK
3P?H ...#
3PCD ...XNOTB2
3PH* ...)
3PM= FILECOUNT 5 [GET NU MBER OF FILES OPEN
3Q6W XCL1 BZE 5 XCL2 [THEN
3QLG SBN 5 1 [CLOSE
3R66 CLOSE [EACH
3RKQ BRN XCL1 [FILE
3S5B XCL2 ADX 7 FX1
3SK2 EXIT 7 0
3T4L MENDAREA 45
3T5# ... FSHCODE A,XNOTB3
3T62 ...(
3T6N ...#
3T7B ...# THIS IS THE CODE FOR THE OPERATIONS THAT CANNOT BE CARRIED
3T84 ...# OUT ON THE 'B' MACHINE
3T8Q ...#
3T9D ...XK2LOG
3T=6 ...#
3T=S ... FRIGMONF ,1 [CREATE A WORKFILE AT THE TOP LEVEL
3T?G ... FSHMOVE START [AND PREPARE IT FOR MOVING TO 'B'
3T#8 ...#
3T#W ...XFIN
3T*J ... TRANSFIN [GO BACK TO 'B'
3TB= ...#
3TBY ...#
3TCL ...XK3LOG
3TD# ... ERASEWORK [ERASE WORKFILE DESCRIBED IN /FABSNB
3TF2 ... BRN XFIN
3TFN ...#
3TGB ...XNOTB3
3TH4 ...)
3TJ= #END
^^^^ ...20104226000600000000