{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LOGOUT867)}}
====== LOGOUT867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ANAMONST|ANAMONST]], [[george:macro:BC|BC]], [[george:macro:BNSJ|BNSJ]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BSJ|BSJ]], [[george:macro:BXE|BXE]], [[george:macro:CHANASAT|CHANASAT]], [[george:macro:CJOBLOCK|CJOBLOCK]], [[george:macro:CLEANEND|CLEANEND]], [[george:macro:CLOSE|CLOSE]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERR|COMERR]], [[george:macro:DICTJOB|DICTJOB]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FILECOUNT|FILECOUNT]], [[george:macro:FILELOG|FILELOG]], [[george:macro:FINDCORE|FINDCORE]], [[george:macro:FJOBLOCK|FJOBLOCK]], [[george:macro:FON|FON]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETCOREN|GETCOREN]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HUNT|HUNT]], [[george:macro:INHIBITBRK|INHIBITBRK]], [[george:macro:ISSUCOM|ISSUCOM]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JLADJUST|JLADJUST]], [[george:macro:LFEJCNT|LFEJCNT]], [[george:macro:LIMBO|LIMBO]], [[george:macro:LOGANAL|LOGANAL]], [[george:macro:MBC|MBC]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MOPCLOSE|MOPCLOSE]], [[george:macro:NAME|NAME]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTMILL|OUTMILL]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PARABEG|PARABEG]], [[george:macro:PERMITBRK|PERMITBRK]], [[george:macro:QUITLT|QUITLT]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETCMXSK|SETCMXSK]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SKIP|SKIP]], [[george:macro:SUBJOB|SUBJOB]], [[george:macro:SUBJOBJ|SUBJOBJ]], [[george:macro:TESTRACE|TESTRACE]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]], [[george:macro:USERJOB|USERJOB]], [[george:macro:VFREE|VFREE]]
22FL #LIS K0LOGOUT>K0ALLGEO>K0GREATGEO>K0COMMAND
22LS ... SEG LOGOUT,867,SECTION CENT,,G266,G400
22S2 ...[
22^8 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
236B ...[ THIS EXCLUDES CODE UNDER #SKI G266
23?J ...[
23*? ...#UNS G400
23C2 ...# THIS CHAPTER IS MODIFIED FOR G3PLUS-IH MK2
23DQ ...#OPT G266 = 0
23KY ...#SKI G266&1
23R6 ...# WITH UGUG EDIT M266 (SUPPRESS UNWANTED MONITORING FILE LISTINGS)
23YG #
24D6 # THIS SEGMENT IMPLEMENTS THE LOGOUT AND ENDJOB COMMANDS,
24XQ # ENTRY POINTS KILOGOUT AND K2LOGOUT RESPECTIVELY .IT IS
25CB # ALSO ENTERED AT K3 LOGOUT BY OFFLINE ABANDON AND BY THE C
25X2 # PROCESSOR TO CARRY OUT A SIMULATED ENDJOB . K4 LOGOUT IS
26BL # ENTRY FOR ONLINE ABANDON . K7 LOGOUT IS USED WHEN AN ONLI
26W= # ACTIVITY IS 'TIMED OUT' AT NO USER CONTEXT,WHEN THE INPUT
27*W # PERIPHERAL BECOMES DISENGAGED IN A CARD- OR TAPE-READING
27TG # ACTIVITY,WHEN AN OPERATORS' CONSOLE JOB IS TERMINATED,AND
28*6 # A SYSTEM ISSUED JOB RETURNS TO COMMAND PROCESSOR LEVEL 0
28SQ #
29#B SEGENTRY K1LOGOUT,XK1
29S2 SEGENTRY K2LOGOUT,XK2
2=?L SEGENTRY K3LOGOUT,XK3
2=R= SEGENTRY K4LOGOUT,XK4
2?=W SEGENTRY K5LOGOUT,XK5
2?QG SEGENTRY K7LOGOUT,XK7
2#=6 SEGENTRY K8LOGOUT,XK8
2#FY ... FSHENTRY K9LOGOUT,XK9,,XK9
2#PQ #
2#QF [ THERE ARE ALSO THE FOLLOWING SEGENTRY POINTS FOR MENDS:
2#R8 [ SEGENTRY K20LOGOUT FOR RESTORE TIME MACRO LOGOUTBI
2#RH [ SEGENTRY K25LOGOUT FOR RESTORE TIME MACRO PRESETRP
2#RX [ SEGENTRY K50LOGOUT FOR BILA MACRO
2#S= [ SEGENTRY K70LOGOUT FOR RESTORE TIME MACRO REPORTNEST
2#SD [ SEGENTRY K73LOGOUT " " " "
2#SL [ SEGENTRY K80LOGOUT
2#T* [
2#W4 [
2#^Q ...#SKI G266&1
2*5D ...(
2*96 ...#
2*#S ...# MEND EXCHANGE SCHEME CODE
2*DG ...# ASTON CONSTANTS
2*J8 ...#
2*MW ...UAC1
2*RJ ... +JABANDMOF [ JOB ABANDONED - MOP SWITCHED OFF
2*X= ... +JABANDFIN [ JOB ABANDONED - FINISH ISSUED
2B2Y ... +JABANDTIME [ JOB ABANDONED - JOBTIME EXCEEDED
2B6L ... +JABANDWAIT [ JOB ABANDONED - WAITTIME EXCEEDED
2B=# ... +INOPLIMBO [ JOB IN LIMBO - MOP TERMINAL INOPERABLE
2BB2 ... +JMFLIMBO [ JOB IN LIMBO - MOP SWITCHED OFF
2BFN ... +JMOPWTLI [ MOPWAITTIME EXCEEDED - JOB IN LIMBO
2BKB ... +JMOPWTJO [ MOPWAITTIME EXCEEDED - JOB ABANDONED
2BP4 ... +0 [ END OF MESSAGE IDENTIFIERS
2BSQ ...#
2BYD ...)
2C46 ...#
2C7W #
2CMG ZERO +0
2CX# SEGENTRY K25LOGOUT
2D76 PRAMXMSK +AMXMSKPR
2DLQ XCONT #20012 [CONTEXT CONSTANT
2F6B XMASK #77767777
2FL2 #
2G5L XBITS +EJBITS [ALL REPORT STYLES
2GK= NONE +2
2H4W 4HNONE
2HC= XPTEXT 7HPT ,ALL
2HJG #
2HLD [ SWITCH FOR QUILT:
2HNB [ X6=0 - LT ISN'T ALLOWED IN BREAK-IN CONTEXT
2HQ# [ X6=1 - LT IS " " " "
2HS= SEGENTRY K20LOGOUT
2HW8 QUSW LDN 6 0
2HY6 [
2J24 [
2J46 # LOGOUT
2JHQ XK1
2L2L LDN 7 1
2L^W ANAMONST XEND [ANALYSE MON. STYLE PARAMS
2M2G ... INHIBITBRK XBROKE
2M37 OBEY QUSW(1) [SET SWITCH FOR QUITLT
2M4D BNZ 6 XK1A [J IF LT ALLOWED IN B-IN
2M5P LDX 4 CPLEV(2)
2M72 BNZ 4 XNOUGHT [ERROR NOT ISSUED AT LEVEL 0
2M8? BRN XK1B
2M9J [
2M=T XK1A
2M#6 QUITLT [SORT OUT IF ISSUED IN B-IN CONTEXT
2M*C [
2MBN XK1B
2MFG BRN START
2M^6 #
2NDQ #
2NYB # ENTRY FOR SIMULATED LOGOUT(FROM ABANDON COMMAND)
2PD2 #
2PXL XK4
2QC= LDX 7 GSIGN [SET SWITCH FOR K4 ENTRY
2QWW LDN 3 0
2RBG BRN NOSTYLES [J TO SET LOGNAL MASK
2RW6 #
2S*Q # ENTRY FOR ATTACH
2STB #
2T*2 XK5
2TSL LDX 7 GSIGN
2W#= BRN START
2WRW #
2X?G #
2XR6 # END JOB
2Y=Q XK2
2^=2 LDN 7 0 [SET SWITCH FOR NO CONSOOLE
33N6 ANAMONST XEND [END IF MONITORING STYLE ERROR
33YJ INHIBITBRK XBROKE [DISALLOW BREAK-IN
33^^ #
343B # THIS SECTION TAKES CARE OF THE CASE WHERE RETAIN/RT IS SPEC
344R # WITHOUT ANY MONITORING STYLE PARAMETERS
3468 #
347Q PARABEG 1,NONE(1)
34MB HUNT 3,CPB,CUNI
3572 LDX 4 ANUM(3)
35BS LDX 6 APARA(3)
35LL FREECORE 3
366= BZE 4 START [BRN IF "NONE" SPECIFIED
368F SBN 4 2
36=N BNZ 4 STY
36#X SRL 6 12
36C6 ERN 6 #5645
36F* BZE 6 START
36HJ STY
36KW MHUNTW 3,ADATA,AREPORT
375G LDX 4 A1(3)
37K6 BZE 4 NURET
384Q BRN START
38JB #
3942 # ENTRY FOR SIMULATING END JOB
39HL XK3
3=3= LDN 7 0 [SET SWITCH FOR NO CONSOLE
3=3S [
3=4B [ THE FOLLOWING SECTION IS TO ENSURE THAT EXABTEMP
3=4Y [ IS NOT SET FOR A JOB WHICH WAS ORIGINALLY MOP
3=5G [ AND WHICH WAS DISCONNECTED. THIS CAN HAPPEN IN
3=64 [ THE CASE OF FN NOW, SINCE COMPROB ONLY CHECKS
3=6L [ THE CPAT WHERE A DC'D JOB WILL BE MARKED AS BACK
3=78 [ THIS CORRECTS BUG 1196, WHERE A TEMP
3=7Q [ AB MOP JOB CAN BE LEFT IN:SYSTEM.JOBLIST.
3=8# [
3=8W [
3=9D OPENSYS XBROKE,JOBLIST,READ [OPEN SYSTEM JOBLIST
3==2 GETJOB JOBNO(2),SYSTEM [FIND JOBS ENTRY
3==J TESTRPN2 OK,NOJOB [BREAK IF NOT FOUND
3=?6 READAGAIN [READ JOBS ENTRY
3=?N MHUNT 3,FILE,FRB
3=#= JLADJUST 3
3=#S LDX 4 JLSTAT(3) [PICK UP STATUS WORD
3=*B ANDN 4 #14
3=*Y BZE 4 NEVERMOP [J UNLESS JOB STARTED BY LN OR DC
3=BG [
3=C4 [ JOB WAS ORIGINALLY MOP, SO MUST CLEAR EXABTEMP
3=CL BC 2,EXABTEMP
3=D8 [
3=DQ NEVERMOP
3=F# CLOSETOP [CLOSE SYSTEM JOBLIST
3=FW [
3=GW NOSTYLES
3?2G GETCOREN 2,1
3?G6 FINDCORE 3
3?^Q NAME 3,ADATA,AREPORT
3#FB STOZ A1+1(3) [INDICATE NO RETAIN
3#LJ ...[
3#RQ ...[
3#^2 NURET
3#^H ...#SKI G266&1
3*24 ...(
3*2K ...# MEND EXCHANGE SCHEME CODE
3*36 ...#
3*3M ...# IF MOP JOB ABANDONED OR TERMINATED
3*48 ...# WITH ONE OF THE ABOVE SPECIFIED MESSAGES
3*4P ...# DO NOT LIST ITS MONITORING FILE
3*5= ...#
3*5R ... STOZ A1(3) [ CLEAR REPORTING STYLES
3*6# ... LDX 1 FX1
3*6T ... LDX 2 FX2
3*7B ... LDX 0 CONTEXT(2)
3*7X ... ANDN 0 4
3*8D ... BNZ 0 UAL1
3*8^ ...UAL2
3*9G ... LDX 0 UAC1(1)
3*=3 ... BZE 0 UAL3 [ J IF NO MORE MESSAGE IDENTIFIERS
3*=J ... BXE 5 0,START [ J IF REPORTING STYLES NOT TO BE SET
3*?5 ... ADN 1 1
3*?L ... BRN UAL2
3*#7 ...UAL3
3*#N ... LDX 1 FX1
3**9 ...UAL1 [ SET REPORTING STYLES AS NORMAL
3**Q ...#
3*B? ...)
3*BS ...[
3*C* ...[
3*DL LDX 4 XBITS(1) [SET REPORT STYLES=ALL FOR LOGANAL
3*Y= STO 4 A1(3)
3BCW #
3BXG START
3BYX #UNS CMXMSK
3C2# (
3C3P SEGENTRY K73LOGOUT
3C56 BRN XK74 [MENDED NULL IF REPORTNEST ON
3C6H LDX 3 CPLEV(2)
3C7Y BZE 3 XK74
3C9* SETCMXSK 2 [ENSURE AMXMSK DOES NOT CHANGE WHEN C
3C=Q XK74
3C#7 SEGENTRY K74LOGOUT
3C*J )
3CC6 LDX 3 FX1
3CWQ CLEANEND
3DBB FILECOUNT 3
3DL7 SBN 3 1
3DNQ BZE 3 TEMP
3DW2 BRN W1
3F*L W2 CLOSE
3FT= W1 BCT 3 W2
3G2C W6 JBC NTEM,2,EXABTEMP
3G46 FREEZESA
3G5T BRN TEMP
3G7J NTEM CLOSE [LEAVE IT TO FILELOG TO ERASE ANY WJDF
3G9? TEMP
3G#W LDX 6 CONTEXT(2)
3GSG ANDN 6 #1000
3HB8 SEGENTRY K80LOGOUT
3HBW LDN 0 0
3HCJ BZE 0 NOPRINT
3HD= SBX 0 JOBNO(2)
3HDY BNZ 0 NOPRINT
3HFL STOZ 0
3HG# BZE 6 NOCORE
3HH2 LDN 4 #200
3HHN TESTRACE 4,NOPRINT
3HJB SETNCORE CPDATA+2,3,ADATA,CREADL
3HK4 LDN 0 7
3HKQ STO 0 A1(3)
3HLD LDN 4 XPTEXT(1)
3HM6 LDN 5 CPDATA(3)
3HMS MOVE 4 2
3HNG ISSUCOM NOPRINT
3HP8 NOPRINT
3HPW BZE 6 NOCORE
3HRQ LDX 0 XMASK(1)
3J?B ANDS 0 CONTEXT(2)
3JR2 DOWN PROSTART,11 [DELETE OBJECT PROGRAM
3K=L NOCORE
3KK2 BC 2,EXQUIET
3KQ= LDX 5 ACTCHCH(2) [LOAD CHAPTER CHANGE COUNT
3L9W STOZ ACTCHCH(2) [CLEAR IT
3LPG MPY 5 CHAPTIME [CONVERT TO 'BEATS'
3M96 DVR 5 BEATTIME [CONVERT TO MILLISECS
3MNQ LDN 5 0
3N8B CJOBLOCK 3
3NN2 ADSC 6 HTIMEJ+1(3)
3P7L ADS 5 HTIMEJ(3) [STEP JOBTIME USED
3PM= LDN 4 1 [OUTPUT MAX. ONLINE BACKSTORE USED
3Q6W CJOBLOCK 3
3QLG LDX 6 GUBS(3) [GET GUBS/2
3R66 SRA 6 1
3RKQ STO 6 AWORK1(2)
3S5B LDN 3 AWORK1(2)
3SK2 LDN 5 JPDNUMA
3T4L CALL 6 XOUTPACK
3TJ= MONOUT GUBSOUT
3W3W OUTPAR USERNAME,JOBNAME,TIMENOW
3WHG OUTMILL
3X36 LFEJCNT AWORK1(2),AWORK2(2),AWORK3(2)
3XGQ LDN 4 1
3Y2B MHUNT 3,ADATA,AREPORT
3YG2 LDX 0 A1(3)
3Y^L BZE 0 NOMFLF [J IF EJ/LT NONE
3^F= ADS 4 AWORK1(2) [ALLOW FOR MONITORING FILE
3^YW NOMFLF
42DG LDN 3 AWORK1(2)
42Y6 LDN 5 JPDNUMA
43CQ CALL 6 XOUTPACK
43XB LDX 0 AWORK2(2)
44C2 BZE 0 XNONEA
44WL LDN 3 AWORK2(2)
45B= LDN 5 JPDNUMB
45TW CALL 6 XOUTPACK
46*G BRN XAON
46T6 XNONEA
47#Q OUTPAR SKIP
47SB XAON LDX 0 AWORK3(2)
48#2 BZE 0 XBON
48RL LDN 3 AWORK3(2)
49?= LDN 5 JPDNUMC
49QW CALL 6 XOUTPACK
4==G XBON
4=Q6 MONOUT JOBT,,NONAUT
4?9Q #
4?=T ...#UNS G400
4??Y ...(
4?*3 ... SEGENTRY K60LOGOUT [USED TO SWITCH ON LOGOUT HOOK
4?B6 ... BRN XLOG
4?C9 ... DOWN DOMONOP,4
4?D# ... LDX 0 CONTEXT(2)
4?FC ... ANDN 0 #1000
4?GG ... BZE 0 XLOG [J IF NO PROG LOADED
4?HK ... LDX 0 XMASK(1)
4?JN ... ANDS 0 CONTEXT(2)
4?KR ... DOWN PROSTART,11 [DELETE CORE IMAGE
4?LW ...XLOG
4?M^ ...)
4?PB # PROCESS MONITORING FILE
4#92 SEGENTRY K50LOGOUT [USED BY BILA MACRO (TO MEND IN/OUT BILA)
4#NL LOGANAL
4*8= # DELETE TEMPORARY FILES AND TEMPORARY DIRECTORY
4**D #
4*GL XK9
4*MW FILELOG
4B7G [
4BM6 UPJL
4C6Q [ UPDATE SYSTEM JOBLIST & USER JOBLIST
4NX= DOWN JOBLIST,2
4P74 MFREE JWELL,COPYSYS
4P7? [
4P7G UPJL10
4P7Y JBS NDJ1,2,EXABTEMP
4P87 BSJ NDJOB
4P8B USERJOB
4P8K DICTJOB 2
4P9= BRN NDJOB
4P9F NDJ1 BNSJ NDJOB
4P9N USERJOB
4P9X DICTJOB 4
4P=6 CLOSETOP
4P=* MFREE FILE,ADICTENT
4P=R NDJOB
4P?9 CHANASAT 6
4P?D CJOBLOCK 3
4P?M LDX 6 CUBS(3) [GET CUBS/2
4P?W SRA 6 1
4P#5 BZE 6 XCUBSOK [CUBS SHOULD HAVE RETURNED TO ZERO
4P## OUTPAR USERNAME,JOBNAME [OUTPUT USERNAME & JOBNAME PARAMETERS
4P#H STO 6 AWORK1(2)
4P#Q LDN 3 AWORK1(2) [STORE PTR TO RESULT
4P#^ LDN 4 1
4P*8 LDN 5 JPDNUMA
4P*C CALL 6 XOUTPACK
4P*L MONOUT CUBSWRONG
4P*T XCUBSOK
4PBW LDX 3 CONTEXT(2)
4QB6 BNG 3 SYSIS
53FQ JBS SYSIS,2,EXABTEMP
53M2 LDX 0 CONTEXT(2)
546L ANDN 0 #10
54L= BNZ 0 SUBJ
5656 SUBJOBJ
56JQ BRN SYSIS
57J2 SUBJ SUBJOB
583L SYSIS
58B2 MBC 2,EXABTEMP,EXUSAB
58FG MBC 2,EXBEINGAB,EXJTEX
58H= BZE 7 XDJQE [BRANCH IF NOT A CONSOLE
592W # RETURN JOB TO NO USER LEVEL
594K ...#UNS G400
596# ...(
5983 ...XDSK1 HUNT 3,IUSER,G400BLK
599Q ... BNG 3 XDSK2
59?F ... FREECORE 3
59*8 ... BRN XDSK1
59BX ...XDSK2
59DL ...)
59GG CJOBLOCK 3
5KP6 STOZ JOBNO(2)
5L8Q STOZ ALFCNT(2)
5LNB FREECORE 3
5MML LDX 6 XCONT(1)
5N7= STO 6 CONTEXT(2)
5NLW LDX 6 PRAMXMSK(1)
5P6G STO 6 AMXMSK(2) [SET REPORT STYLES TO ALLBUT,COMMANDS
5P7F [
5P8D #UNS CMXMSK
5P9C (
5P=B MHUNTW 3,CPB,CALAS
5P?* [
5P## SEGENTRY K70LOGOUT
5P*? BRN XK71 [MENDED IF REPORTNEST ON
5PB= STO 6 CMXMSK(3) [SET REPORTING MASK
5PC9 BRN XK72
5PD8 XK71
5PJ4 SEGENTRY K71LOGOUT
5PJ? STOZ CMXMSK(3)
5PJG [
5PJP XK72
5PK3 )
5PL6 STOZ EXT+11(2)
5Q5Q STOZ AWFNAME(2)
5QKB LDCT 0 #40
5R52 ORS 0 CLONG1(2)
5RJL ERS 0 CLONG1(2)
5S4= #SKIP K6LOGOUT>99-99
5SHW TRACE FX2,LOGGEDOU
5T3G XEND PERMITBRK
5TH6 BNG 7 XEND2
5W2Q VFREE APED,ADISPLAY
5WGB ENDCOM [ORDINARY LOGOUT
5X22 XEND2 UP [RETURN TO CP TO CONTINUE PROCESS
5XFL #
5X^= # ENTRY FOR DISCONNECT MACRO
5YDW #
5YYG XK8
5^D6 CALL 4 XMOPCLOSE
5^XQ STOZ JSOURCE1(2)
62CB STOZ JSOURCE2(2)
62X2 UP
63BL #
63W= # DELETE JOB QUEUE ENTRY
64*W #
64TG XDJQE
65*6 XK7 [DELETE JOB QUEUE ENTRY
65SQ LDX 4 CONTEXT(2)
6677 ANDN 4 #210
66FJ [ J IF NEITHER MOP NOR REMOTE
66S2 BZE 4 XNOTMOP
67?L LIMBO
67R= BNZ 0 XNOTMOP
68=W CALL 4 XMOPCLOSE
68QG XNOTMOP
69PQ BRUSEN XFIN
6=9B CJOBLOCK 1
6=P2 FJOBLOCK 1
6?8L XFIN
6?N= LDX 4 CONTEXT(2)
6#7W BPZ 4 XCLOSE
6#MG FON ASIFIN
6*76 # CHECK ALL FILES CLOSED
6*LQ XCLOSE
6B6B FILECOUNT 3
6BL2 BZE 3 XEND1
6C5L XCLOSE1
6CK= CLOSE
6D4W BCT 3 XCLOSE1
6DJG XEND1
6F46 #SKIP K6LOGOUT>99-99
6FHQ TRACE FX2,JOBENDED
6G3B ACROSS SUICIDE,1
6GH2 XOUTPACK
6H2L SBX 6 FX1
6HG= OUTPACKX 3,4,5
6H^W ADX 6 FX1
6JFG EXIT 6 0
6J^6 XMOPCLOSE
6KDQ SBX 4 FX1
6KYB MOPCLOSE
6LD2 ADX 4 FX1
6LXL EXIT 4 0
6MC= #
6MWW XBROKE
6NBG COMBRKIN [BROKEN IN BEFORE ENDJOB
6NW6 XNOUGHT [COMMAND NOT ISSUED AT CORRECT LEVEL
6P*Q COMERR JXCONSOLE
6PD* [
6PGY NOJOB
6PKH [ JOB NOT FOUND IN SYSTEM JOBLIST
6PN6 GEOERR 1,NO JOB
6PQP [
6PTB MENDAREA 30,K99LOGOUT
6Q*2 #END
^^^^ ...21245142000500000000