{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: LPOBJ6)}}
====== LPOBJ6 ======
(George Source)

**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:CHECKA|CHECKA]], [[george:macro:COMPQU|COMPQU]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FDRMTEST|FDRMTEST]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:LOCKCA|LOCKCA]], [[george:macro:LOOPD|LOOPD]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:NEXTD|NEXTD]], [[george:macro:OLPEND|OLPEND]], [[george:macro:OUTMOP|OUTMOP]], [[george:macro:PAIR|PAIR]], [[george:macro:PMODES|PMODES]], [[george:macro:REM|REM]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SPACECT|SPACECT]], [[george:macro:STEP|STEP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TOPCA|TOPCA]], [[george:macro:TOPCA1|TOPCA1]], [[george:macro:TRACE|TRACE]], [[george:macro:TREP2|TREP2]], [[george:macro:WHICHMOP|WHICHMOP]]

<code - LPOBJ6.txt>22FL    #OPT  K0LPOBJ=K0OLP 
22^=    #OPT  K6LPOBJ=K6OLP 
23DW    #LIS  K0LPOBJ   
23YG    #SEG  LPOBJ6                       [LADISLAV KUTILEK
24D6    # THIS SEGMENT PROCESSES OFFLINE MODE 0 *LP PERIS   
24XQ                   8HLPOBJ  
25CB          SEGENTRY K1LPOBJ,Z1LPOBJ  
25X2          SEGENTRY K2LPOBJ,Z2LPOBJ  
25YC ...#   
25^S ...#     AWORK1   BITS 0 AND 1 - NO OF USED CHARS IN LAST WORD OF DATA 
2639 ...#              BITS 18 TO 23- CONTAIN PFCC  
264L ...#     AWORK2   BIT 9 SET - EXTENDED QUALIFIER GIVEN 
2663 ...#              BITS 15 TO 23 - CONTAIN VALUE OF AUTO QUALIFIER IF GIVEN 
267D ...#     AWORK3 - MUST NOT BE USED BECAUSE OF INTERACTIONWITH  
268T ...#              TPOBJ WHEN IMPLEMENTING MODE 4 *LP PERIS.
26== ...#     AWORK4   BIT 0 SET - END OF MULTIFILE REACHED 
26?M ...#              BIT 1 SET - FILE IS NEARLY FULL  
26*4 ...#   
26BL    MAX            +2002
26W=    PLINK1  
27*W          PAIR     LPOBJ,1  
27TG    NEWCPT  
28*6          LDCT  0  #200 
28SQ          ANDX  0  AWORK4(2)
29#B          ERS   0  AWORK4(2)           [UNSET MARKERS WHEN NEW MULTIFILE CPT
29S2    Z1LPOBJ 
2=?L          LDX   0  ALIMEY(2)
2=R=    #SKI
2?=W          BNG   0  Q1                  [J IF NOTLIMIT   
2?QG          BXL   0  ACOUNT(2),OUTL      [J IF OUTPUT LIMIT EXCEEDED  
2#=6    Q1  
2#PQ          LDX   3  APETADDR(2)  
2*9B          LOCKCA   3,ACAP(2),1  
2*P2          LDX   4  0(1)                [PERI TYPE/MODE  
2B8L          LDX   1  FX1  
2BN=          ANDN  4  #7777
2C7W    Z2LPOBJ 
2CMG          BZE   4  MOK                 [J IF NORMAL PRINT   
2D76          SBN   4  2
2D?S ...      BZE   4  XAUTO               [J IF MODE 2 
2DDG ...      SBN   4  2
2DK8 ...      BNZ   4  MOLE                [ILLEGAL IF NOT MODE 4.  
2DPW ...      LDX   0  BIT9 
2DWJ ...      ANDX  0  AWORK2(2)           [TEST FOR EXTENDED QUALIFIER GIVEN.  
2F3= ...      BZE   0  MOLE                [MODE 4 NOT ALLOWED IF MISSING.  
2F7Y ...      ACROSS   TPOBJ,2  
2F#L ...XAUTO   
2F*R ...      LDX   0  BIT9 
2FBY ...      ANDX  0  AWORK2(2)
2FD5 ...      BNZ   0  MOLE                [MODE 2 NOT ALLOWED IF EXTENDED QUAL 
2FF# ...      LDEX  0  AWORK2(2)
2FL2          BZE   0  MOLE                [MODE 2 NOT ALLOWED - NO QUALIFIER GI
2G5L          ACROSS   LPTWO,2  
2GK=    MOK 
2H4W          LDN   4  4
2HJG          LDX   6  ACAP(2)  
2J46          LDN   7  ACA1(2)  
2JHQ          LDX   3  APETADDR(2)  
2K3B          FOUTMOVE 3,6,7,4,HLOCK1      [MOVE CA TO AOLPT
2KH2          LDX   0  AWORK4(2)
2L2L          BNG   0  OUTF2               [ALREADY READ EOF
2LG=          LDX   6  ACA3(2)  
2L^W          BZE   6  WC   
2MFG          BXGE  6  MAX(1),WC           [J IF ILLEGAL COUNT  
2M^6          ADN   6  6                   [ROUND UP
2NDQ          SRL   6  2                   [CONVERT TO WORDS
2NYB          LDCT  4  #600 
2PD2          LDX   5  ACA4(2)  
2PXL          BCHX  5  £                   [SHOULD BE CHAR 0 NOW
2QC=          ANDX  4  5
2QWW          BNZ   4  WA                  [J IF NOT
2RBG          PMODES   1,3  
2RW6          SBN   5  1                   [GET RIGHT WORD ADDRESS  
2S*Q          ANDN  1  #10  
2STB          BNZ   1  MOKA                [J IF 22AM   
2T*2          ANDX  5  BSP16               [ELSE TAKE 15 BITS   
2TSL    MOKA
2W#=    #SKI  G4
2WRW          LDN   4  CHREAD              [CHECK READ ACCESS ONLY IN G4
2X?G          CHECKA   5,6,RV1,3,4,MOKB,HLOCK2  
2XR6    MOKB
2Y=Q          LDX   1  5
2YQB          FADDRESS 3,1,HLOCK2          [X1-<PFCC WORD   
2^=2          LDN   0  #17  
2^PL          ANDX  0  0(1) 
329=          ERN   0  #11  
32NW          BNZ   0  NOTHRO              [J IF NOT THROW TO CHANNEL 1(HEAD OF 
338G          LDCT  0  #200 
33N6          ANDX  0  AWORK4(2)
347Q          BNZ   0  OUTF                [J IF FILE FNEARLY FULL  
34MB    NOTHRO  
3572          LDX   0  0(1) 
35LL          ANDN  0  #77  
366= ...      STO   0  AWORK1(2)           [STORE PFCC  
36KW          ANDN  0  #40  
375G          STOZ     4                   [X4=0 IF J TO NOPRINT
37K6          BZE   0  NOPRINT             [ASSUME B18 NOT SET IS 'NO-PRINT' COD
384Q          LDX   4  ACA3(2)  
38JB          SBN   4  1                   [PFCC
3942          ANDN  4  3
39HL          LDX   3  5                   [ACA4
3=3=          LOOPD    APETADDR(2),3,6,HLOCK2   
3=GW          NGX   4  4
3?2G          ANDN  4  3                   [N/UNUSED CHARS  
3?G6          BZE   4  TESTW               [J IF ALL CHARS ARE USED 
3?^Q          LDN   2  0
3#FB    NXT   ADN   2  6
3#^2          BCT   4  NXT  
3*DL          LDX   7  0(3)                [LAST WORD   
3*Y=          LDX   0  ACES                [SPACES  
3BCW          SRL   7  0(2) 
3BXG          SLL   70 0(2)                [SPACEFILL UNUSED CHARS  
3CC6          LDX   1  7
3CWQ          BRN      TESTWL   
3DBB    SPACES  
3DW2          NEXTD    3,6,TESTW
3F*L          LDN   4  0                   [NO USED CHARS   
3FT=          BRN      REM  
3G#W    TESTW LDX   1  0(3)                [LAST WORD   
3GSG          LDX   7  1
3H#6    TESTWL  
3HRQ          SPACECT  1,2,SPACES          [COUNT SPACES
3J?B          LDN   4  4
3JR2          SBX   4  2                   [N/USED CHARS
3K=L          ANDN  4  3
3KQ=    REM   REM      6                   [N/WORDS 
3L9W          BRN      STEP 
3LPG    NOPRINT 
3M96          LDN   6  1
3MNQ    STEP
3N8B          ADN   6  1                   [ADD RED TAPE
3NN2          WHICHMOP NOMOP               [J IF NO MOP/MF  
3P7L          SETUPCORE 6,3,FILE,FRB       [OUTPUT BUFFER   
3PM=          ADN   3  A1   
3Q6W          BRN      STEPH
3QLG    NOMOP   
3R66          LDX   2  6
3RKQ          STEP     ,FRH(2),ANSWER   
3S5B          TESTREP2 APPWAIT,WAIT,FILEFULL,WAIT,FNEARLY,NEARLYF,             -
3SCR ...               GLUTTON,TOOMUCH  
3SQ8 ...      TREP2    FNEARLY2,NEARLYF 
3T4L    STEPH   
3TJ=          STO   6  FRH(3)   
3TS4 ...      LDX   0  4
3W3W ...      SRC   0  2
3W?N ...      ORS   0  AWORK1(2)           [REMEMBER NO OF USED CHARS.  
3WHG    #SKI  K6LPOBJ>599-599   
3X36          TRACE    6,REDTAPE1   
3XGQ          SBN   6  2
3Y2B          LDX   1  APETADDR(2)  
3YG2          ADN   3  FRH+1
3Y^L          BZE   6  NEND                [J IF NO DATA
3^F=          BZE   4  NEVEN               [J IF NO ODD CHARS   
3^YW          SMO      6
42DG          STO   7  0(3)                [STORE ODD CHARS 
42Y6          SBN   6  1
43CQ          BZE   6  NEND 
43XB    NEVEN   
44C2          ADN   6  1
44WL          LDX   4  5
45B=          LDX   5  3
45TW          FOUTMOVE 1,4,5,6,HLOCK2   
46*G    NEND
46T6          LDX   0  AWORK1(2)
48#2          STO   0  0(3)                [STORE 2ND RED TAPE WORD 
48RL          WHICHMOP RAPET               [J IF NOT MOP/MF 
49?=          LDN   5  0
49QW          OUTMOP   RAPET,K1LPOBJ       [OUTPUT TO MOP/MF
4==G    RAPET LDX   1  APETADDR(2)  
4=Q6          LDN   5  0
4?9Q    REP 
4?PB          LDX   3  ACAP(2)  
4#92          ADN   3  1
4#NL          FADDRESS 1,3,HLOCK1   
4*8=          STO   5  0(3) 
4*MW          OLPEND
4B7G          BRN      K1LPOBJ  
4BM6    NEARLYF 
4C6Q          LDCT  0  #200 
4CLB          ORS   0  AWORK4(2)
4D62          BRN      STEPH
4DKL    MOLE
4F5=          LDN   3  FYMODE   
4FJW    XILL  CALL  5  TOPCA
4G4G          ACROSS   OLPODD,4            [FOR ILLEGAL 
4GJ6    WC  
4H3Q          LDN   3  FYCOUNT  
4HHB          BRN      XILL 
4J32    WA  
4JGL          LDN   3  FYCHAR   
4K2=          BRN      XILL 
4KFW    RV1 
4K^G          LDN   3  FYNOBUF  
4LF6          BRN      XILL 
4LYQ    OUTF
4MDB          COMPQU   OUTF2               [J IF END OF NON-MULT
4MY2          BRN      NEWCPT   
4NCL    OUTF1   
4NX=          LDCT  0  #400 
4PBW          ORS   0  AWORK4(2)           [SET EOF MARK
4PWG    OUTF2   
4QB6          LDX   0  ACA1(2)  
4QTQ          SRL   0  3
4R*B          ANDN  0  #7777
4RT2          SBN   0  #3000
4S#L          BNZ   0  NMON                [J UNLESS ADDITIVE MODE #30000   
4SS=          LDCT  5  #50  
4T?W          LDX   1  APETADDR(2)  
4TRG          BRN      REP  
4W?6    NMON
4WQQ          LDN   3  FYOUTFULL
4X=B          BRN      OUTP 
4XQ2    OUTL
4Y9L          LDN   3  FYOUTPUT 
4YP=    OUTP
4^8W          LDX   4  FTYPNO(2)
4^NG          BRN      XILL 
5286    WAIT
52MQ          FDRMTEST APPWAIT,NSM         [J IF NOT IN DRM 
537B          LDCT  5  #420 
53M2          TESTREP2 APPWAIT,WAIT1
546L          LDCT  5  #410                [REJECTED INOPERABLE 
54L=    WAIT1   
555W          LDX   1  APETADDR(2)  
55KG          BRN      REP                 [SET REPLY 'REJECTED,OPERABLE'   
5656    NSM 
56JQ          TESTREP2 FILEFULL,OUTF       [J IF FULL FILE  
574B          CALL  5  TOPCA
57J2          ACROSS   OLPODD,1 
583L    TOOMUCH 
58H=          CALL  5  TOPCA
592W          ACROSS   OLPODD,2 
59GG    #   
5=26    TOPCA   
5=FQ          LDX   1  FX1  
5=^B          TOPCA1   PLINK1(1)
5?F2          EXIT  5  0
5?YL          MENDAREA   AOLPGAP,K99LPOBJ   
5#D=    #END
^^^^ ...13773440000700000000
</code>