{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MACS PCT)}}
====== MACS PCT ======
(George Source)
22*7 ...#SKI
22N# ...(
233F ...[
23BL ...[ PLEASE RETURN THIS LISTING TO ROOM F11 (G. CONSTANTINIDES
23PR ...[
244Y ...[ THIS SUBFILE CONTAINS MACROS USED BY THE 7020 ROUNTINES
24D6 [
24XQ [CONTENTS LIST:-
25CB [
25X2 [ ATT7020
266S ...[ DEF7502ID
26BL [ FLIP
26W= [ HUNT2J
27*W [ HUNT7020
27TG [ NUDGE
28*6 [ OFF7020
28SQ [ PAGE7020
29#B [ PCT7020
29S2 [ PCT7020S
2=?L [ PCTFACT
2=R= [ PCTFIND
2?=W [ PCTHUNT
2?QG [ PCTHUNTB
2#=6 [ PCTHUNTS
2*9B [ RDLCHECK
2*P2 [ RENGAGE
2B8L [ RMDIS
2BN= [ SLEEP2
2C7W [ SLEEP
2CMG [ WAKEUP
2D76 [ WIDTH7020
2DLQ [
2F6B [END OF LIST.
2FL2 [
2FYP ...)
2G?D ...[??? ATT7020 SECT COMM FGN 12 DOC
2GL7 ...#SKI
2GYW ...(
2H?K ...[
2HL# ...[
2H^3 ...[
2J?Q ...[ TO SET MOP OFF AND ATTACHED BITS IN INFORM BLOCK,UNSET PCT INACTIVE
2JLF ...[ BITS,FLIP CONSOLE OUTPUT AND WAKE UP AMOP,APCT ACTIVITY
2J^8 ...[ %A IS THE LABEL TO JUMP TO IF SOME PCT STILL ACTIVE,ALREADY CLOSING
2K?X ...[ DOWN,ACTIVITIES STILL RUNNING OR BEING SET UP.
2KLL ...[ %B IS LABEL TO JUMP TO ON EXIT FROM MACRO.
2K^* ...[ USED IN ATTACHA.
2L#4 ...[
2LLR ...)
2L^W #MAC ATT7020
2MFG HUNT2B 2,A7020,INFORM,1 [HUNT BACK FROM THE A7020/ALCB.
2M^6 LDX 1 APCTACT(2) [J. OUT IF SOME PCT IS STILL ACTIVE,
2NDQ BNZ 1 %A
2NYB LDXC 0 ALINESTAT(2) [OR IF ALREADY CLOSING DOWN FOR SOME
2PD2 BCS %A [OTHER REASON,
2PXL LDX 1 FPTPCT(2) [OR IF SOME ACTIVITIES STILL RUNNING,
2QC= LDXC 0 APCTID-FPTPCT(1)
2QWW BCC %A
2RBG HUNTACT AMOP,2 [OR BEING SET UP.
2RW6 LDX 0 JOBRING+BPTR(2)
2S*Q SBN 0 JOBRING(2)
2STB BNZ 0 %A
2T*2 LDCT 0 #500 [SET MOP-OFF : ATTACHED MARKER.
2TSL ORS 0 ALINESTAT-FPTPCT(1)
2W#= LDX 0 APCTNUM-FPTPCT(1) [MAKE ALL OPERABLE PCTS LOOK ACTIVE.
2WRW SBX 0 APCTINOP-FPTPCT(1)
2X?G ANDX 0 BITS22LS
2XR6 BZE 0 MATT3
2Y=Q STO 0 APCTACT-FPTPCT(1)
2YQB MATT1 LDXC 0 APCTSTAT-FPTPCT(1) [J. IF INOP.
2^=2 BCS MATT2
2^PL ANDX 0 BITS22LS [UNSET THE INACTIVE BIT IF SET.
329= STO 0 APCTSTAT-FPTPCT(1)
32NW LDCH 0 APCTX-FPTPCT(1) [FLIP CONSOLE OUTPUT.
338G ORS 0 APCTD-FPTPCT(1)
33N6 MATT2 ADNC 0 1 [APCTSTAT = -1 SHOWS END OF BLOCK.
347Q ADN 1 APCTRLEN
34MB BNZ 0 MATT1
3572 MATT3 LONGCLEA 2,#62,%B [KICK THE PCT ACTIVITY,IF ASLEEP$
35LL BRN %B
366= #NOR
366G ...[??? DEF7502ID SECT COMM FGN 13 DOC
366Q ...[
3672 ...[ DEFINE IDENTIFIER AS 7502 LP
367= ...[
367G ...#MAC DEF7502ID
367Q ...#STR CLEAR,%A
3682 ...(
368= ...#MEN IDFCONF
368G ...#TRA K90IDFCONF
368Q ...#DEF 20? = 34? + 0? ] + 1
3692 ...#SKI IDF7502IDS - 20?
369= ...#SKI
369G ...(
369Q ...!! TOO MANY IDENTIFIERS DEFINED
36=2 ...#EXI
36== ...)
36=G ... +20?
36=Q ...#TRA K90IDFCONF + 20?
36?2 ... +%A
36?= ...#END
36?G ...)
36?Q ...#STR CLEAR,%A
36#2 ...#SKI
36#= ...(
36#G ...#MEN IDFCONF
36#Q ...#TRA K90IDFCONF
36*2 ... +0
36*= ...#END
36*G ...)
36*Q ...#STR %B
36B6 ... DEF7502ID %B,%C,%D,%E,%F,%G,%H,%I,%J,%K,%L,%M,%N,%O,%P,%Q,%R,%S,%T
36BG ...#NOR
36CL ...[??? FLIP SECT COMM FGN 12 DOC
36P2 ...#SKI
372B ...(
37?Q ...[
37K6 ...[ TO SET FLIP BIT FOR INTERFACE WHOSE BLOCK IS POINTED TO IN X3 AND
37WG ...[ WAKE UP AMOP,APCT.
387W ...[ USED IN RMTLF,PCTLISTA,RENGAGE,INPCT,READOPLN.
38F= ...[
38QL ...)
3942 #MAC FLIP
39HL LDCT 0 #2
3=3= ANDX 0 EWAIT(3)
3=GW #STR %A
3?2G BNZ 0 %A
3?G6 #STR %A
3?^Q #SKI
3#FB BNZ 0 MFLIP
3#^2 LDX 2 3
3*DL BCHX 2 £
3*Y= LDCH 1 APCTID(2)
3BCW PCTHUNT 2
3BXG LDEX 0 APCTID(3)
3CC6 SMO 0
3CWQ ORS 1 APCTD(2)
3DBB HUNTACT AMOP,2
3DW2 LONGCLEA 2,#62,MFLIP
3F*L MFLIP
3FT= #NOR
3G7M ...[??? HUNT2J SECT COMM FGN 12 DOC
3GG4 ...#SKI
3GSF ...(
3H6W ...[
3HF? ...[ THIS MACRO SEARCHES FORWARD FOR A DATA BLOCK AS SPECIFIED
3HRN ...[ IN %B,%C. IT SEARCHS FROM THE POINTER IN %D ELSE FROM %A.
3J65 ...[ IT GIVES THE POINTER TO THE BLOCK IN %A WHICH IS X1 TO X3.
3JDG ...[ IF THE BLOCK IS NOT FOUND IT J TO LABEL %E
3JQX ...[ USED IN CONSROOT
3K5# ...[
3KCP ...)
3KQ= #MAC HUNT2J
3L9W #STR %D
3LPG LDX %A %D
3M96 MHUNT2J1
3MNQ LDX %A FPTR(%A)
3N8B LDX 0 ATYPE(%A)
3NN2 TXL 0 CACT
3P7L BCC %E
3PM= SRL 0 12
3Q6W SBN 0 %B+%C
3QLG BNZ 0 MHUNT2J1
3R66 #NOR
3RDY ...[??? HUNT7020 SECT COMM FGN 12 DOC
3RRQ ...#SKI
3S6J ...(
3SFB ...[
3SS8 ...[
3T72 ...[
3TFS ...[ TO SEARCH FORWARD ALONG ACTIVITY CHAIN FOR THE FIRST A7020 BLOCK.
3TSL ...[ %A IS A MODIFIER CONTAINING A POINTER, ON EXIT, TO THE A7020 BLOCK.
3W7D ...[ %B(OPTIONAL) CONTAINS A POINTER TO START SEARCH FROM.
3WG= ...[ USED IN PCTDIS,RENGAGE.
3WT4 ...[
3X7W ...)
3XGQ #MAC HUNT7020
3Y2B HUNTACTF A7020,%A,%B
3YG2 #NOR
3YT7 ...[??? NUDGE SECT COMM FGN 12 DOC
3^8# ...#SKI
3^HF ...(
3^WL ...[
429R ...[
42JY ...[
42Y5 ...[
43?= ...[
43LC ...[
43^J ...[ TO WAKE UP THE CPAT OR ACTLF WHOSE BUFFER BLOCK IS POINTED TO BY X2.
44#P ...[ USED IN PCTCON,PCTINOP.
44MW ...[
4533 ...)
45B= #MAC NUDGE
45TW LDX 1 2
46*G PCTFACT 2
46T6 LDXC 0 EWAIT(1)
47#Q BCC MNUDGEWAIT
47SB STO 0 EWAIT(1)
48#2 FPUT
48RL BRN MNUDGEND
49?= MNUDGEWAIT
49QW LONGCLEA 2,#36,MNUDGEND
4==G MNUDGEND
4=Q6 #NOR
4?4H ...[??? OFF7020 SECT COMM FGN 12 DOC
4?BY ...#SKI
4?P* ...(
4#3Q ...[
4#B7 ...[
4#NJ ...[
4*2^ ...[ TO SET MOP OFF BIT IN INFORM BLOCK,UNSET INACTIVE BITS FOR EACH PCT,
4**B ...[ FLIP CONSOLE OUTPUT AND WAKE UP AMOP,APCT ACTIVITY.
4*MR ...[ USED IN MOPCOM
4B28 ...[
4B#K ...)
4BM6 #MAC OFF7020
4C6Q HUNT2B 1,A7020,INFORM
4CLB LDX 0 GSIGN
4D62 ORS 0 ALINESTAT(1)
4DKL SMO FX2
4F5= STO 2 ACOMMUNE9
4FJW LDX 0 APCTNUM(1) [MAKE ALL OPERABLE PCTS LOOK ACTIVE.
4G4G SBX 0 APCTINOP(1)
4GJ6 ANDX 0 BITS22LS
4H3Q LDX 2 1
4HHB STO 0 APCTACT(1)
4J32 BZE 0 MOFF3
4JGL MOFF1 LDXC 0 APCTSTAT(1) [J. IF INOP.
4K2= BCS MOFF2
4KFW ANDX 0 BITS22LS [UNSET THE INACTIVE BIT, IF SET.
4K^G STO 0 APCTSTAT(1)
4LF6 LDCH 0 APCTX(1) [FLIP CONSOLE OUTPUT.
4LYQ ORS 0 APCTD(1)
4MDB MOFF2 ADNC 0 1 [LAST RECORD APCTSTAT = -1.
4MY2 ADN 1 APCTRLEN
4NCL BNZ 0 MOFF1 [J. IF NOT END.
4NX= MOFF3 HUNTACT AMOP,2 [WAKE UP THE PCT ACTIVITY, IF ASLEEP.
4PBW LONGCLEA 2,#62,MOFF4
4PWG MOFF4 SMO FX2 [RESTORE X2.
4QB6 LDX 2 ACOMMUNE9
4QTQ #NOR
4R5J ...[??? PAGE7020 SECT COMM FGN 12 DOC
4R*B ...#SKI
4RK8 ...(
4RT2 ...[
4S4S ...[ THIS RESTORE TIME MACRO RESETS THE DEFAULT NO. OF LINES PER 7021 PAGE.
4S#L ...[
4SJD ...)
4SS= #MAC PAGE7020
4T?W #DEF 19?+9=1?
4TRG #STR %B
4W?6 #LIS %B
4WQQ #SKI %A�
4X=B #SKI
4XQ2 (
4Y9L #ALT A7021PAGE=%A-1>HEADINGS
4YP=
4^8W #MEN IPBLISTB
4^B4 ...#SKI JSKI17<1$1 [7503
4^H= ...(
4^NG #TRA K55IPBLISTB
5286 LDN 6 A7021PAGE<63
52CY ...)
52FR ...#TRA K55IPBLISTB
52HL ... SBN 0 A7021PAGE-1<62
52KG ...#TRA K56IPBLISTB
52R4 ... SBN 6 A7021PAGE-1<62
52YL ...#TRA K57IPBLISTB
5368 ... SBN 0 A7021PAGE-1<62
53?Q ...#TRA K58IPBLISTB
53F# ... ADN 0 A7021PAGE<63
53H8 ...#TRA K59IPBLISTB
53K4 ... ADN 0 A7021PAGE<63
53M2 #END
546L
54L= #MEN RMTLF
54Q7 ...#UNS JSKI40
54W4 ...#SKI
54^^ ...(
555W #TRA K55RMTLF
55KG LDN 6 A7021PAGE-HEADINGS-1
55T# ...)
5656 #TRA K56RMTLF
56JQ LDN 0 A7021PAGE-1
574B #TRA K57RMTLF
57J2 LDN 0 A7021PAGE-1
583L #TRA K58RMTLF
58H= LDN 0 A7021PAGE-1
592W #END
594S ...#UNS JSKI40
596Q ...(
598N ...#MEN PCTLISTA
59=L ...#TRA K80PCTLISTA
59#J ... LDN 6 A7021PAGE-HEADINGS-1
59BG ...#END
59DD ...)
59GG
5=26 )
5=FQ #LIS 19?+9]
5=^B #NOR
5?#H ...[??? PCT7020 SECT COMM FGN 12 DOC
5?MN ...#SKI
5#2T ...(
5#B2 ...[
5#P7 ...[
5*4# ...[
5*CF ...[ TO SEARCH FOR A A7020 BUFFER BLOCK WITH SPECIFIED IDENTIFIER.
5*QL ...[ %A IS A MODIFIER POINTING TO ANY PCT BUFFER BLOCK ON EXIT %A WILL
5B5R ...[ CONTAIN A POINTER TO THE START OF THE BLOCK.
5BDY ...[ %B CONTAINS THE IDENTIFIER OF THE REQUIRED BLOCK
5BS5 ...[ USED IN PCTINOP,RIGHT
5C7= ...[
5CGC ...)
5CTL #MAC PCT7020
5D*= PCT7020S %A,%B
5DSW SBN %A FPTPCT
5F#G #NOR
5FMM ...[??? PCT7020S SECT COMM FGN 12 DOC
5G2S ...#SKI
5G*^ ...(
5GP6 ...[
5H4? ...[
5HCD ...[
5HQK ...[ TO SEARCH FOR A A7020 BUFFER BLOCK WITH SPECIFIED IDENTIFIER.
5J5Q ...[ %A IS A MODIFIER POINTING TO THE START OF A BUFFER BLOCK. ON EXIT %A
5JDX ...[ WILL CONTAIN A POINTER TO THE RING ELEMENT OF THE REQUIRED BLOCK.
5JS4 ...[ %B CONTAINS THE IDENTIFIER OF THE REQUIRED BLOCK.
5K79 ...[ USED IN THE MACRO PCT7020.
5KGB ...[
5KTH ...)
5L8Q #MAC PCT7020S
5LNB ADN %A FPTPCT
5M82 PCTFIND %A,%B
5MML #NOR
5N2D ...[??? PCTFACT SECT COMM FGN 12 DOC
5N*= ...#SKI
5NN4 ...(
5P2W ...[
5P*N ...[
5PNG ...[
5Q3# ...[ TO SEARCH BACKWARDS ALONG ACTIVITY CHAIN FOR THE FIRST ACTIVITY BLOCK.
5QB6 ...[ %A IS A MODIFIER CONTAINING A POINTER TO THE START OF THE SEARCH.
5QNY ...[ ON EXIT %A CONTAINS A POINTER TO THE ACTIVITY BLOCK.
5R3Q ...[ USED IN PCTCON AND MACRO NUDGE.
5RBJ ...[
5RPB ...)
5S4= #MAC PCTFACT
5SHW MPCTF LDX %A BPTR(%A)
5T3G LDX 0 ATYPE(%A)
5TH6 BXL 0 CACT,MPCTF
5W2Q #NOR
5W*X ...[??? PCTFIND SECT COMM FGN 12 DOC
5WP4 ...#SKI
5X49 ...(
5XCB ...[
5XQH ...[
5Y5N ...[
5YDT ...[ TO SEARCH FOR A PCT RING ELEMENT WITH SPECIFIED IDENTIFIER.
5YS2 ...[ %A IS A MODIFIER POINTING TO THE START OF A PCT RING ELEMENT. ON EXIT
5^77 ...[ %A WILL CONTAIN A POINTER TO THE RING ELEMENT OF THE REQUIRED BLOCK.
5^G# ...[ %B CONTAINS THE IDENTIFIER OF THE REQUIRED BLOCK.
5^TF ...[ USED IN PCTCON AND MACROS PCT7020 AND PCT7020S.
628L ...[
62HR ...)
62X2 #MAC PCTFIND
63BL MPCTFIND
63W= LDX %A FPCT(%A)
64*W BXU %B APCTID-FPTPCT(%A),MPCTFIND
64TG #NOR
658# ...[??? PCTHUNT SECT COMM FGN 12 DOC
65H6 ...#SKI
65TY ...(
668Q ...[
66HJ ...[
66WB ...[
6798 ...[ TO SEARCH FOR AN A7020,INFORM BLOCK IN A PCT RING.
67J2 ...[ %A IS A MODIFIER POINTING TO THE START OF AN A7020 BUFFER BLOCK. ON
67WS ...[ EXIT %A CONTAINS A POINTER TO THE INFORM BLOCK.
689L ...[ USED IN PCTDIS.
68JD ...[
68X= ...)
69=6 #MAC PCTHUNT
69PQ ADN %A FPTPCT
6=9B MPCT LDX %A FPCT(%A)
6=P2 LDXC 0 APCTID-FPTPCT(%A)
6?8L BCC MPCT
6?N= SBN %A FPTPCT
6#7W #NOR
6#GN ...[??? PCTHUNTB SECT COMM FGN 12 DOC
6#TG ...#SKI
6*8# ...(
6*H6 ...[
6*TY ...[
6B8Q ...[
6BHJ ...[ TO SEARCH BACKWARDS IN A PCT RING FOR AN A7020,INFORM BLOCK.
6BWB ...[ %A IS A MODIFIER POINTING TO THE START OF AN A7020 BUFFER BLOCK. ON
6C98 ...[ EXIT %A CONTAINS A POINTER TO THE START OF AN A7020,INFORM BLOCK.
6CJ2 ...[ USED IN RENGAGE.
6CWS ...[
6D9L ...)
6DJG #MAC PCTHUNTB
6F46 PCTHUNTS %A
6FHQ SBN %A FPTPCT
6G3B #NOR
6GBH ...[??? PCTHUNTS SECT COMM FGN 12 DOC
6GPN ...#SKI
6H4T ...(
6HD2 ...[
6HR7 ...[
6J6# ...[
6JFF ...[ TO SEARCH BACKWARDS IN A PCT RING FOR THE RING ELEMENT OF THE A7020,
6JSL ...[ INFORM BLOCK.
6K7R ...[ %A CONTAINS A POINTER TO AN A7020 BUFFER BLOCK. ON EXIT %A CONTAINS A
6KGY ...[ POINTER TO THE RING ELEMENT OF THE A7020,INFORM BLOCK.
6KW5 ...[ USED IN THE MACRO PCTHUNTB.
6L9= ...[
6LJC ...)
6LXL #MAC PCTHUNTS
6MC= ADN %A FPTPCT
6MWW MHPCT LDX %A BPCT(%A)
6NBG LDXC 0 APCTID-FPTPCT(%A)
6NW6 BCC MHPCT
6P*Q #NOR
6YH# ...[??? RDLCHECK SECT COMM FGN 12 DOC
6YW6 ...#SKI
6^8Y ...(
6^HQ ...[
6^WJ ...[
729B ...[
72J8 ...[
72X2 ...[ TO GO DOWN TO INPCT OR READBULK OR READLINE TO READ THE FIRST LINE OF
739S ...[ BULK INPUT FROM THE PCT,IPB OR LOCAL ROUTINES RESP.
73JL ...[ USED IN COMPROB.
73XD ...[
74== ...)
74K6 #MAC RDLCHECK
754Q LDX 2 FX2
75JB SAWCEJ MRDLOC,MRDLCC
7642 DOWN INPCT,1
76HL BRN MRDLFIN
773= MRDLCC
77GW DOWN READBULK,1
782G BRN MRDLFIN
78G6 MRDLOC
78^Q DOWN READLINE,1
79FB MRDLFIN
79^2 #NOR
7==Y ...[??? RENGAGE SECT COMM FGN 12 DOC
7=JW ...#SKI
7=WS ...(
7?8Q ...[
7?GN ...[
7?SL ...[
7#6J ...[ TO GO DOWN TO RENGAGE,%A AND COME UP TO LABEL %B OR UPPLUS TO %C.
7#DG ...[ USED IN MACROS SLEEP,SLEEP2.
7#QD ...[
7*4B ...)
7*BB #MAC RENGAGE
7*W2 DOWN RENGAGE,%A
7B*L BRN %B
7BT= BRN %C
7C#W #NOR
7CM? ...[??? RMDIS SECT COMM FGN 12 DOC
7C^N ...#SKI
7D#5 ...(
7DLG ...[
7DYX ...[
7F?# ...[
7FKP ...[ TO SET THE 'WAITING TO BE WRONGED' BIT IN THE APPROPRIATE REMOTE
7FY6 ...[ BUFFER AND TO FALL THROUGH IF LOCAL.
7G=H ...[ USED IN ENGAGE.
7GJY ...[
7GX* ...)
7H9W #MAC RMDIS
7HPG SAWCEJ MLOC,MIPB
7J96 HUNT7020 1,FX2
7JNQ LDCT 0 4
7K8B ORS 0 EWAIT(1)
7KN2 BRN MLOC
7L7L MIPB MHUNTW 1,AMXOR,ADCB
7LM= LDN 0 #1000
7M6W ORS 0 IWAIT(1)
7MLG MLOC LDX 1 FX1
7N66 LDX 2 FX2
7NKQ #NOR
7NXG ...[??? SLEEP2 SECT COMM FGN 12 DOC
7P9= ...#SKI
7PH2 ...(
7PSQ ...[
7Q6G ...[
7QD= ...[
7QQ2 ...[
7R3Q ...[
7R*G ...[ TO PUT CURREN0 ACTIVITY(ACTLF) TO SLEEP OR OUTPUT 'PLEASE ENGAGE'
7RM= ...[ REQUEST ON REMOTE CONSOLE.
7R^2 ...[ %A IS LABEL TO JUMP TO IF'TERMINATE'IS TYPED.
7S=Q ...[ %B IS LABEL TO JUMP TO IF'CANTDO' IS TYPED.
7SJG ...[ USED IN RMTLF.
7SW= ...[
7T82 ...)
7TG2 #MAC SLEEP2
7T^L LDCT 0 #43
7WF= ANDX 0 EWAIT(3)
7WYW BZE 0 MNOT
7XDG RENGAGE 2,%A,%B
7XY6 BRN SLEEPFIN
7YCQ MNOT LDX 0 GSIGN
7YXB ORS 0 EWAIT(3)
7^C2 COOR1
7^WL SLEEPFIN
82B= #NOR
82Q8 ...[??? SLEEP SECT COMM FGN 12 DOC
8366 ...#SKI
83G4 ...(
83W2 ...[
849Y ...[
84KW ...[
84^S ...[ TO PUT CURRENT ACTIVITY TO SLEEP OR TO OUTPUT 'PLEASE ENGAGE' REQUEST
85*Q ...[ ON REMOTE CONSOLE.
85PN ...[ %A IS CONSOLE,LF,LP,TP IN WHICH CASE THERE IS NO CHECK ON WHETHER DC4
865L ...[ HAS BEEN RECEIVED.
86FJ ...[ %B IS LABEL TO JUMP TO IF OPERATOR TYPES'TERMINATE'.
86TG ...[ %C IS LABEL TO JUMP TO IF OPERATOR TYPES 'CANTDO'.
879D ...[ %D IS LABEL IF DC4 HAS BEEN RECEIVED.
87KB ...[ USED IN INPCT,PCTLISTA,READOPLN.
87^# ...[
88*= ...)
88PB #MAC SLEEP
8992 #STR %A,CONSOLE
89NL (
8=8= #STR %A,LF
8=MW (
8?7G #STR %A,LP
8?M6 (
8#6Q #STR %A,TP
8#LB (
8*62 LDCT 0 #020
8*KL ANDX 0 EWAIT(3)
8B5= BZE 0 MNODC4
8BJW ERS 0 EWAIT(3)
8C4G BRN %D
8CJ6 MNODC4
8D3Q )
8DHB )
8F32 )
8FGL LDCT 0 #003
8G2= ANDX 0 EWAIT(3)
8GFW BNZ 0 %C
8G^G LDCT 0 #040
8HF6 ANDX 0 EWAIT(3)
8HYQ BZE 0 MNOT
8JDB RENGAGE 1,%B,%C
8JY2 BRN SLEEPFIN
8KCL )
8KX= MNOT LDX 0 GSIGN
8LBW ORS 0 EWAIT(3)
8LWG COOR1
8MB6 SLEEPFIN
8MTQ #NOR
8N8X ...[??? WAKEUP SECT COMM FGN 12 DOC
8NJ4 ...#SKI
8NX9 ...(
8P=B ...[
8PKH ...[
8PYN ...[
8Q?T ...[ TO WAKE UP AMOP,APCT IF NECESSARY.
8QM2 ...[ %A IS CONSOLE IN WHICH CASE THE AMOP,APCT IS WOKEN UP.
8R27 ...[ LF IN WHICH CASE THE WAIT BIT IS CHECKED FIRST.
8R*# ...[ NONEXISTENT IN CASE THE NUMBER OF FREE BUFFERS IS CHECKED FIRST.
8RNF ...[ USED IN INPCT,PCTLISTA,RMTLF.
8S3L ...[
8SBR ...)
8SQ2 #MAC WAKEUP
8T9L #STR %A,CONSOLE
8TP= (
8W8W #STR %A,LF
8WNG (
8X86 LDN 0 1
8XMQ ADS 0 FREBUFF(3)
8Y7B LDX 0 FREBUFF(3)
8YM2 SBN 0 2
8^6L BNG 0 MWAKEFIN
8^L= )
925W LDXC 0 EWAIT(3)
92KG BCC MWAKEFIN
9356 STO 0 EWAIT(3)
93JQ )
944B LDX 2 BPTPCT(3)
94J2 SBN 2 FPTPCT
953L HUNT2B 2,AMOP,APCT
95H= FPUT
962W MWAKEFIN
96GG #NOR
96SD ...[??? WIDTH702 SECT COMM FGN 12 DOC
976B ...#SKI
97D# ...(
97Q= ...[
9848 ...[
98B6 ...[
98N4 ...[
9922 ...[ THIS RESTORE TIME MACRO RESETS THE DEFAULT NO. OF CHARS. PER 7021 LINE
99?Y ...[
99KW ...)
99XW #MAC WIDTH7020
9=7N ...#OPT AOEW7020=0
9=CG #DEF 19?+9=1?
9=X6 #STR %B
9?BQ #LIS %B
9?WB #DEF 19?+0=33?
9#B2 #SKI %A
9#TL (
9**= #SKI 19?+0]-33?<1$1
9*SW (
9B#G #ALT A7021WIDTH=%A>80
9BFN ...#SKI AOEW7020$1
9BLW ...(
9BS6 #SKI %A>132$132
9C?Q #ALT A7021WIDTH=132
9C*^ ...)
9CD8 ...#SKI AOEW7020
9CGC ...(
9CJL ...#SKI %A>511$511
9CLT ...#ALT A7021WIDTH=511
9CP4 ...)
9CRB
9D?2 #MEN IPBLISTA
9D?L ...#UNS FL7502
9D#= ...(
9D#W ...#TRA K50IPBLISTA
9D*G ... LDN 4 A7021WIDTH+4
9DB6 ...#TRA K51IPBLISTA
9DBQ ... SBN 4 A7021WIDTH+4
9DCB ...#TRA K52IPBLISTA
9DD2 ... LDN 4 A7021WIDTH+4
9DDL ...#TRA K53IPBLISTA
9DF= ... MVCH 4 A7021WIDTH-8
9DFW ...#TRA K54IPBLISTA
9DGG ... LDN 0 A7021WIDTH
9DGK ...)
9DGN ...#UNS FL7502
9DGR ...#SKI
9DGW ...(
9DG^ ...#TRA K50IPBLISTA
9DH4 ... LDN 3 A7021WIDTH
9DH7 ...)
9DH= ...#END
9DH* ...#UNS FL7502
9DHD ...(
9DHH ...#MEN IPBLISTD
9DHL ...#TRA K55IPBLISTD
9DHQ ... LDN 4 A7021WIDTH+6
9DJB ...#TRA K56IPBLISTD
9DK2 ... MVCH 4 A7021WIDTH-8
9DKL ...#TRA K57IPBLISTD
9DL= ... LDN 4 A7021WIDTH+8
9DLW ...#TRA K58IPBLISTD
9DMG ... MVCH 4 A7021WIDTH-10
9FPW #END
9F^N ...)
9G9G
9GP6 #MEN IPBLISTB
9H8Q #TRA K50IPBLISTB
9HNB SBN 5 A7021WIDTH+1
9J82 #TRA K51IPBLISTB
9JML ADN 5 A7021WIDTH+1
9K7= #TRA K52IPBLISTB
9KLW ... LDN 5 A7021WIDTH-4
9L6G #END
9LL6
9M5Q #MEN PCTLISTA
9MKB #TRA K50PCTLISTA
9MNC ... MVCH 4 A7021WIDTH-66
9MRD ...#TRA K54PCTLISTA
9MWF ... LDN 6 A7021WIDTH
9M^G ...#TRA K55PCTLISTA
9N4H ... LDN 6 A7021WIDTH
9N7K ...#UNS JSKI40
9N=8 ...(
9N#R ...#TRA K85PCTLISTA
9NCB ... LDN 5 A7021WIDTH+1
9NF^ ...)
9NJL #END
9NK= ...
9NKW ...#MEN PCTLISTB
9NLG ...#TRA K50PCTLISTB
9NM6 ... LDN 7 A7021WIDTH-66
9NMQ ...#END
9NNH ...#UNS JSKI40
9NSD ...#SKI
9NY* ...(
9P4=
9PHW #MEN RMTLF
9Q3G #TRA K50RMTLF
9QH6 LDN 5 A7021WIDTH+1
9R2Q #END
9R=J ...)
9RGB
9S22 )
9SFL )
9S^= #LIS 19?+9]
9TYG #NOR
^^^^ ...23752725002400000000