{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MESOUT)}}
====== MESOUT ======
(George Source)
**Macros used:** [[george:macro:GEOERR|GEOERR]], [[george:macro:LABFIX|LABFIX]], [[george:macro:MHUNTW|MHUNTW]]
22FL #SEG MESOUT70 [ R TERRY
22^= #OPT K0MESOUT=0
23DW #LIS K0MESOUT
23YG #
24D6 # ENTRY FROM OUTPACK WITHOUT %D SPECIFIED
24XQ #
25CB LABFIX AAOUT2
25X2 XENA
26BL NGN 0 1 [MARK ENTRY POINT
26W= STO 0 GEN6
27*W BRN XJOINA [JOIN MAIN PATH
27TG #
28*6 # ENTRY FROM OUTPAR MACRO
28SQ LABFIX AAOUT3
29#B XENB
29S2 STOZ GEN6 [MARK ENTRY POINT
2=?L BRN XJOINB [JOIN MAIN PATH
2=R= #
2?=W # ENTRY FROM OUTPACK WITH %D SPECIFIED
2?QG #
2#=6 LABFIX AAOUT1
2#PQ XENC
2*9B LDN 0 1
2*P2 STO 0 GEN6 [MARK ENTRY POINT
2B8L XJOINA
2BN= OBEY HLINK+4(1)
2C7W STO 0 GEN2 [STORE START ADDRESS OF DATA
2CMG LDX 0 HLINK+5(1) [STORE JPD
2D76 STO 0 GEN4
2DLQ XJOINB
2F6B OBEY HLINK+3(1) [STORE SPACE REQUIRED
2FL2 LABFIX AAOUT4
2G5L XJOINC
2GK= STO 0 GEN1
2H4W STO 1 GEN0 [STORE LINK
2HJG STO 2 GEN3 [STORE X2
2J46 STO 3 GEN5 [STORE X3
2JHQ LDCT 0 #100 [ASET MARKER
2K3B LDX 2 GEN6
2KH2 SMO FX2
2L2L ANDX 0 CLONG1
2LG= BZE 0 XNOROOM [NO ROOM SINCE NO ASET
2L^W MHUNTW 3,GMON,ASET
2MFG LDX 0 ALOGLEN(3)
2M^6 ADN 0 A1
2NDQ SBX 0 A1+1(3)
2NYB TXL 0 GEN1
2PD2 BCS XNOROOM [NOT SUFFICIENT ROOM?
2PXL LDN 0 HLINK+2
2QC= ADS 0 GEN0 [ADJUST THE LINK
2QWW LDX 0 GEN1
2RBG LDX 1 A1+1(3) [STORE CURRENT PTR NXT FREE WORD
2RW6 ADX 1 3
2S*Q ADS 0 A1+1(3) [AND UPDATE IT
2STB BZE 2 XENOUTPR [ENTRY FROM OUTPAR?
2T*2 LDN 2 1
2TSL ADS 2 A1(3) [ADJUST COUNT OF PARAMETERS
2W#= XFINALA
2WRW SBN 0 1
2X?G STO 0 GEN1 [STORE ADJUSTED COUNT
2XR6 SLC 0 6
2Y=Q ORX 0 GEN4
2YQB STO 0 0(1) [FORM & STORE HEADER WORD
2^=2 ADN 1 1
2^PL LDX 0 GEN2 [LOAD START OF DATA
329= XFINALB
32NW LDX 2 GEN1
338G BZE 2 XIT [COUNT ZERO?
33N6 LDX 2 GEN3 [RESTORE X2
347Q LDX 3 GEN5 [RESTORE X3
34MB SMO GEN1
3572 MOVE 0 0
35LL XIT
366= LDX 3 GEN5 [RESTORE X3
36KW LDX 1 FX1 [RESTORE ACC'S
375G LDX 2 FX2
37K6 BRN (GEN0) [EXIT
384Q XENOUTPR
38JB ADS 0 A1(3) [ADJUST COUNT OF PARAMETERS
3942 LDX 0 GEN0
39HL ADN 0 2 [LOAD START ADRESS
3=3= BRN XFINALB
3=GW XNOROOM
3?2G LDX 3 FX2
3?G6 LDX 0 GEN1
3?^Q STO 0 ACOMMUNE1(3) [STORE COUNT OF SPACE REQD
3#FB BPZ 2 XIT [NOT ENTRY FROM OUTPACK WITHOUT %D
3#^2 LDN 1 ACOMMUNE2(3)
3*DL TXL 0 EIGHT
3*Y= BCS XFINALA [SUFFICIENT ROOM IN ACOMMUNE WORDS?
3BCW GEOERR 1,OUTWRONG
3BXG #END
^^^^ ...53021711000100000000