{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MEXTSJ70)}}
====== MEXTSJ70 ======
(George Source)
**Macros used:** [[george:macro:CATMASK|CATMASK]], [[george:macro:CHECKB|CHECKB]], [[george:macro:CHEKPRIV|CHEKPRIV]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:FREECORE|FREECORE]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MONOUT|MONOUT]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SJCHAIN|SJCHAIN]]
22FL #SEG MEXTSJ70 [K.KOSKUBA
22^= #LIS K0MEXTSJ>K0ALLGEO>0
23DW # THIS SEGMENT SERVICES THE SYSTA_EM JOURNAL SJMESS TYPE EXTRACODES:
23YG # THAT IS PERI TYPE 60 MODES:- #73 J
24D6 # ON ENTRY FROM OPCA THE SEGMENT ENSURES THAT THE USER HAS THE
24XQ # REQUIRED PRIVILEGE, PERFORMS MINIMAL CHECKING ON THE FORMAT OF
25CB # THE MESSAGE WHICH IS THEN PUT ON THE JOURNAL CHAIN
25X2 # AUTONOMOUSLY FOR MODE #73 AND NON-AUTONOMOUSLY FOR MODE #74
26BL # AND THE PROGRAM IS RESTARTED
26W= 8HMEXTSJ
27*W SEGENTRY K1MEXTSJ,XK1MEXT
27TG SJM1 CATMASK JL,OL
28*6 SJMESS 8HSJMESS
28SQ SERB4 +ERB4
29#B XK1MEXT
29S2 CHEKPRIV JOB,SJMESS(1),R10,NOTOPEN [CHECK USER HAS PRIVILEGE
2=?L # TO USE EXTRACODE
2=R= LDX 3 EVENT2(2)
2?=W LDN 5 4
2?QG LDN 4 AWORK1(2)
2#=6 FOUTMOVE 2,3,4,5,HLOCK1 [MOVE 4WD CONTROL AREA TO AWORK WDS
2#PQ LDX 5 AWORK1(2) [PICK UP MODE FROM CONTROL AREA
2*9B LDCT 6 60
2*P2 ADN 6 #74
2B8L LDN 7 1 [SET NON-AUTONOMOUS INDICATOR
2BN= SBX 6 5
2C7W BZE 6 SJMX1 [J IF MODE #73 :- AUTONOMOUS CASE
2CMG SBN 6 1
2D76 BNZ 6 R20 [J IF ILLEGAL MODE
2DLQ LDN 7 0 [ZEROISE AUT/NON-AUT INDICATOR
2F6B SJMX1
2FL2 LDX 4 AWORK4(2) [PICK UP START ADDR OF MESSAGE
2G5L LDX 5 AWORK3(2) [PICK UP NO. OF CHARS IN MESSAGE
2GK= LDN 6 2000
2H4W SBX 6 5
2HJG BNG 6 R40 [J IF COUNT OF CHARS OUT OF RANGE
2HS# ... BZE 5 R40
2J46 ADN 5 1
2JHQ SRA 5 2 [CALCULATE NO. OF WDS MSG REQUIRES
2K3B CHECKB 4,5,R30,,
2KH2 ADN 5 JCATS-A1+1
2L2L SETUPCORE 5,3,GMON,JRNAL
2LG= STOZ JWAITER(3)
2L^W LDX 1 5
2MFG SBN 1 JCATS-A1+1
2M^6 LDN 5 JCATS(3)
2NDQ FOUTMOVE 2,4,5,1,HLOCK2
2NYB LDX 5 JJOBNO(3)
2PD2 ADN 5 1
2PXL BZE 5 SJMX2
2QC= BNG 5 RF10
2QWW BNZ 5 SJMX3
2RBG SJMX2
2RW6 FJOPCA 1,2
2S*Q LDX 5 JOBNUM(1)
2STB STO 5 JJOBNO(3)
2T*2 SJMX3
2TSL SMO FX1
2W#= LDX 4 SJM1
2WRW ORS 4 JCATS(3)
2X?G LDX 5 JCATS(3)
2XR6 SLL 5 3
2Y=Q STOZ JWAITER(3)
2YQB BPZ 5 SJMX4
2^=2 LDX 6 JPACKORG(3)
2^PL BNZ 6 SJMX4
329= SJMX35
32NW MONOUT JINCPM [INCORRECT PACKED MESSAGE
338G BRN R15
33N6 SJMX4
347Q LDX 6 JPACKORG(3)
34MB ANDN 6 #7777
3572 BZE 6 SJMX45
35LL LDCT 5 #40
366= ORS 5 JCATS(3)
36KW SJMX45
375G BZE 7 SJMX5
37K6 LDX 4 ACTNUM(2)
384Q STO 4 JWAITER(3)
38JB SJMX5
3942 LDX 5 AWORK3(2)
39HL SBN 5 12
3=3= TXL 5 6
3=GW BCS SJMX35
3?2G SJCHAIN 3,5
3?G6 STOZ AWORK2(2)
3?^Q LDN 5 0
3#FB SJMX55
3#^2 LDX 3 EVENT2(2)
3*DL ADN 3 1
3*Y= FADDRESS 2,3,HLOCK1
3BCW STO 5 0(3)
3BXG RUNPROG
3CC6 R50
3CWQ LDCT 5 #40
3DBB FREECORE 3
3DW2 STO 5 AWORK2(2)
3F*L BRN SJMX55
3FT= R10
3G#W ILLEGAL MODE
3GSG R15 ILLEGAL
3H#6 R20 ILLEGAL MNOTREC
3HRQ ...R30 ILLEGAL RESVIOL
3J?B R40 ILLEGAL COUNT
3JR2 RF10 MONOUT JINVJNO
3K=L ILLEGAL
3KQ= MENDAREA 75
3L9W #END
^^^^ ...06632537000400000000