{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MODE866)}}
====== MODE866 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:CHNUMCON|CHNUMCON]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERR|COMERR]], [[george:macro:COMERRX|COMERRX]], [[george:macro:COOR3|COOR3]], [[george:macro:DCA|DCA]], [[george:macro:DELETE|DELETE]], [[george:macro:DFCLEAR|DFCLEAR]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DFSET|DFSET]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FREEPER|FREEPER]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:GPERI|GPERI]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JBC|JBC]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JNOTMT21S|JNOTMT21S]], [[george:macro:JUNBUSY|JUNBUSY]], [[george:macro:JWRONG|JWRONG]], [[george:macro:LCAP|LCAP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LMODEQ|LMODEQ]], [[george:macro:LPROP|LPROP]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MTINFORM|MTINFORM]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PAIR|PAIR]], [[george:macro:PARSORTX|PARSORTX]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP|PUTREP]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:SDSEARCH|SDSEARCH]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETMODEQ|SETMODEQ]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SMODE|SMODE]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:SPARANOX|SPARANOX]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:UP|UP]]
22FL #LIS K0MODE>K0LIBRARY>K0ALLGEO
22^= ... SEG MODE,865,P.SMITH,LIBRARY
23YG # THIS SEGMENT DEALS WITH THE MODE COMMAND AND VARIOUS
24D6 # UTILITY FUNCTIONS FOR THE LIBRARIAN CHAPTERS INTERESTED
24XQ # IN "MODES"
25CB #
25X2 SEGENTRY K1MODE,QK1MODE
26BL SEGENTRY K2MODE,QK2MODE
26W= SEGENTRY K3MODE,QK3MODE
27*W SEGENTRY K4MODE,QK4MODE
27TG SEGENTRY K5MODE,QK5MODE
28*6 #
28SQ # CONSTANTS
29#B #
29S2 SNM +1
2=?L 4HM
2=R= SNT +1
2?=W 4HT
2??* ...[
2??G ...[ SOME ERROR MESSAGE IDENTIFIERS
2??M ...[
2??S ...SHMODUN +HMODUN
2??^ ...SHNVM +HNVM
2?#6 ...SHMODEAL +HMODEAL
2?#? ...SHNVMOD +HNVMOD
2?#D ...SHNSWBS +HNSWBS
2?#K ...SHNVM7 +HNVM7
2?#M ...SHMODREJ +HMODREJ
2?#Q ...[ SUBMESSAGES
2?#X ...SHUSEC +HUSEC
2?*4 ...SHALLD +HALLD
2?*9 ...[
2?*B ...[ MODES FOR 9TRACK DECKS
2?*H ...[
2?*N ...SMODES +3
2?*T ... 4HNRZI
2?B2 ... 4HPE
2?B7 ... 4HGCR
2?B# ...[
2?BF ...[ TABLE OF MODES FOR #12 PERI
2?BL ...[
2?BR ...SM12 +1
2?BY ... +0
2?C5 ... +2
2?C= ...[
2?NX ...SMON +12
2#=6 SMODE +0
2#PQ +4
2*9B +8
2*P2 +12
2B8L +16
2BN= +20
2C7W +24
2CMG +28
2D76 +32
2DLQ +36
2DWH ... +40
2D^6 ... +44
2F6B SMCHC 4H#0
2FL2 4H#4
2G5L 4H#10
2GK= 4H#14
2H4W 4H#20
2HJG 4H#24
2J46 4H#30
2JHQ 4H#34
2K3B 4H#40
2KH2 4H#44
2KQR ... 4H#50
2KTB ... 4H#54
2L2L SMCHN +2
2LG= +2
2L^W +3
2MFG +3
2M^6 +3
2NDQ +3
2NYB +3
2PD2 +3
2PXL +3
2QC= +3
2QM3 ... +3
2QPL ... +3
2QWW UNMAX +#1000
2RBG TLINK
2RW6 PAIR LIBLOAD,1
2S*Q #
2STB # SUBROUTINES
2T*2 #
2TSL # SCVM
2W#= # THIS SR CHECKS THAT THE NUMBER GIVEN IN X4
2WRW # IS A VALID MT MODE
2WXR ...# FOR THE NRZI/PE ENHANCEMENT THE ENTRY CONDITIONS
2X3N ...# HAVE BEEN CHANGED SO THAT THE MODE IS TO BE
2X7K ...# FOUND IN A CPAR/GNUMCON BLOCK
2X?G # EXIT IF NOT,OTHERWISE EXIT+1
2XR6 # SETS X1=FX1,X2=FX2;LINK X7.
2Y=Q SCVM
2YCX ... MHUNT 3,CPAR,GNUMCON
2YFL ... LDX 0 A1(3)
2YH* ... SBN 0 1
2YK4 ... BNZ 0 SCVM4 [J IF MORE THAN 1 NO.
2YLR ... LDX 4 A1+1(3)
2YQB LDX 1 FX1 [SET X1
2^=2 LDX 2 SMON(1) [NUMBER OF POSSIBLE MODES
2^PL SCVM2 SMO 2
329= TXU 4 SMODE-1(1)
32NW BCC SCVM1 [FOUND
338G BCT 2 SCVM2 [TRY AGAIN
33N6 LDX 2 FX2
33XY ...SCVM4
347Q EXIT 7 0 [NOT FOUND
34MB SCVM1 LDX 2 FX2
3572 STO 4 AWORK3(2)
35LL EXIT 7 1 [VALID
366= #
3689 ...[
368W ...[ SUBROUTINE TO CHECK LEGALITY OF 9-TRACK MODE
369H ...[
36=8 ...SCVM9 LDX 0 ANUM(2)
36=T ... ANDN 0 #7777
36?G ... SBN 0 5
36#7 ... BPZ 0 (7)
36#S ... LDX 0 SMODES(1)
36*F ... LDX 4 APARA(2)
36B6 ...SCV91 SMO 0
36BR ... TXU 4 SMODES(1)
36CD ... BCS SCV92
36D5 ... EXIT 7 1
36DQ ...SCV92 BCT 0 SCV91
36FC ... EXIT 7 0
36G4 ...[
36HB ...[
36J3 ...[ SUBROUTINE TO SWITCH 7-TRACK MODES
36JN ...[
36KW SWITCHQA
375G LPROP 3,0
37K6 #SKI K6MODE>199-199
384Q SWITRACE 0,MOPROPS
38JB ANDN 0 #200 [9 TRACK TAPE?
3942 BZE 0 SWQ1
39HL LDX 0 GSIGN
3=3= EXIT 7 0
3=GW SWQ1 LCAP 3,0 [CAPABILITIES
3?2G #SKI K6MODE>199-199
3?G6 SWITRACE 0,MOCAPS
3?^Q STO 0 AWORK2(2) [SAVE THEM
3#FB ANDN 0 #10 [DENSITY SWITCHABLE BY PROCESSOR ?
3#^2 BNZ 0 SWQ5 [J. IF NOT 1974
3*DL LDN 0 #14
3*Y= ANDS 0 AWORK3(2) [ADJUST DENSITY TO PRESENT SETTING
3BCW #SKI K6MODE>299-299
3BXG SWITRACE 0,MODENSWD
3CC6 LMODEQ 3,0
3CWQ ANDN 0 #60 [CURRENT DENSITY
3DBB ORS 0 AWORK3(2)
3DW2 BRN SWQ3
3F*L SWQ5 LDN 0 #40
3FT= ANDX 0 AWORK3(2) [HIGH DENSITY REQUIRED?
3G#W BZE 0 SWQ3 [J. IF NOT
3GSG #SKI K6MODE>299-299
3H#6 SWITRACE 0,MODEHDEN
3HRQ LDN 0 4
3J?B ANDX 0 AWORK2(2) [J. IF NOT AVAILABLE
3JR2 BZE 0 SWQ2
3JY7 ... LDN 0 8 [SHORT GAP REQUIRED
3J^W ... ANDX 0 AWORK3(2) [ WITH HIGH DENSITY ?
3K3K ... BZE 0 SWQ6 [J IF NOT
3K5# ... JNOTMT21S 3,SWQ2 [ONLY ALLOWED ON MT21S
3K73 ... BRN SWQ4
3K=L SWQ3 LDN 0 8
3KQ= ANDX 0 AWORK3(2) [SHORT GAP REQUIRED
3KYG ... BZE 0 SWQ6
3LPG #SKI K6MODE>299-299
3M96 SWITRACE 0,MODESGAP
3MNQ LDN 0 2
3N8B ANDX 0 AWORK2(2)
3NN2 BNZ 0 SWQ4 [J. IF AVAILABLE
3P7L SWQ2 NGN 0 1
3PM= EXIT 7 0
3PSN ...SWQ6
3PWG ... JNOTMT21S 3,SWQ4
3PY# ... HUNT 1,CPAR,GPERCON [MT21S AND LONG GAP REQUESTED
3Q26 ... BNG 1 SWQ7
3Q3Y ... LDN 0 1 [READ OR WRITE SPEC
3Q5Q ... ANDX 0 A1+3(1)
3Q7J ... BZE 0 SWQ7 [J IF NOT
3Q9B ... ANDX 0 A1+2(1)
3Q?8 ... BNZ 0 SWQ2 [J IF WRITE
3Q*2 ...SWQ7
3QBS ... LDN 0 8 [SET SHORT GAP FOR MT21S
3QDL ... ORS 0 AWORK3(2)
3QJ= ...SWQ4 LDX 0 AWORK2(2)
3QLG SRL 0 3 [SWITCHABLE BIT
3R66 LDX 1 FX1
3RKQ EXIT 7 0
3S5B #
3SK2 # ENTRY POINT 1
3T4L # MODE COMMAND
3TJ= QK1MODE
3W3W SPARABEG 1,SNM(1) [MODE PARAMETER
3WHG MHUNT 3,CPB,CUNI
3X36 LDX 0 ANUM(3)
3XGQ BPZ 0 P1
3Y2B P2 COMERR JPARMIS,HMODE2
3YG2 P1 BZE 0 P2 [PARAMETER IS NULL
3Y^L LDX 5 JPARNUM(3)
4847 ... CHNUMCON 1,P20
486Q ... PICKREP 4 [SAVE REPLY TO CHNUMCON IN X4
487R ... LDX 0 CONTEXT(2)
4886 ... ANDN 0 1
488S ... BZE 0 XNUSE
4897 ...[ USER CONTEXT - CHECK MODE PARAMETER OK AND GO TO MODEA
489G ... TESTREPN OK,NVMUS
489T ... CALL 7 SCVM
48=8 ... BRN NVM
48=H ... ACROSS MODEA,1
48=W ...[
48?9 ...XNUSE
48#2 STOZ AWORK1(2) ["PERMANENT"
48RL SPARABEG 1,SNT(1)
49?= MHUNT 3,CPB,CUNI
49QW LDX 0 ANUM(3)
4==G BNG 0 P6 [NOT TEMPORARY
4=Q6 LDX 6 JPARNUM(3)
4?9Q LDN 0 1
4?PB STO 0 AWORK1(2) [TEMPORARY
4#92 BRN P7
4#NL P6 NGN 6 1 [NO PARAMETER
4#WW ...P7
4*?B ... MFREE CPB,CUNI
4*FL ... SPARAPASS
4*MW MHUNT 3,CPB,CUNI
4B7G LDX 0 ANUM(3)
4B=C ... BPZ 0 XNALL
4B?B ...[ NO UNIT PARAMETER - SO CHANGING MODE ON ALL DECKS
4B#* ... FREECORE 3
4B*# ... PUTREP2 4
4BB? ... TESTREPN OK,NVMAL
4BC= ... CALL 7 SCVM
4BD9 ... BRN NVM
4BF8 ... ACROSS MODEA,2
4BG7 ...[
4BH6 ...XNALL
4BS# ... BZE 0 P7
4DKL P8 LDX 0 JPARNUM(3)
4F5= TXU 0 5
4F?G ... BCC P7
4G4G SBX 0 6
4G=Q ... BZE 0 P7
4GQB ... LDX 6 JPARNUM(3)
4H=2 ...[ KEEP THE MODE CUNI BLOCK ABOUT
4HPL ... HUNT2 3,CPB,CUNI
4J9= ... NAMETOP 3,FILE,FNAME
4JNW ... PARSORTX XBRK,6,GROPE
4K8G ...[ RENAME THE MODE CUNI BLOCK
4KN6 ... MHUNT 3,FILE,FNAME
4L7Q ... NAMETOP 3,CPB,CUNI
4LMB ... SPARANOX 6
4M72 ... HUNT 3,CPAR,JSCE
4MLL ... BPZ 3 PONE
4N6= ... ENDCOM
4NKW ...PONE LDEX 5 JSCEA(3) [DECK NUMBER
4P5G ... LDCH 7 JSCEA(3) [DEVICE TYPE
4PK6 ... LDX 6 JSCEP(3) [DEVICE LIST ADDRESS
4Q4Q ... FREECORE 3
4QJB ... LDX 3 6
4R42 ... SBN 7 5
4RHL ... BZE 7 P11 [MT DECK
4S#L P12 COMERR HNSW [NOT SWITCHABLE
4SJD ...XBRK COMBRKIN
4SS= P11
4T2S ... PUTREP 4
4T3= ... TESTREPN OK,TR9
4T52 ... LDX 6 3 [SAVE DEVICE LIST ADDRESS
4T65 ... CALL 7 SCVM [VALIDATE MODE
4T78 ... BRN NVMF [J IF INVALID
4T8? ... LDX 3 6 [RESTORE DEVICE LIST ADDRESS
4T8M ...[ CHECK FOR 9-TRACK DECK - ILLEGAL MODE SPECIFIED IF SO
4T8R ... LPROP 3,0
4T8X ... ANDN 0 #200
4T93 ... BNZ 0 NVMFU
4T9B ...P11A
4T?W CALL 7 SWITCHQA
4TRG #SKI K6MODE>99-99
4W?6 SWITRACE 0,MOCHREP
4XQ2 BPZ 0 P13 [AVAILABLE
4Y9L OUTNUM 4,OCTAL
4YP= COMERR HMNAV [MODE NOT AVAILABLE
4^8W WRNG OUTNUM 5,0
4^NG COMERR ERWRONGED [WRONG
5286 XALOC COMERR JALOC [ALLOCATED
52MQ P13 JWRONG 3,WRNG
537B JALLOC 3,XALOC
53M2 SETALLOC 3 [MARK ALLOCATED
546L STO 3 CPPTR(2)
54L= SETMODEQ 3,AWORK3(2) [RESET CURRENT MODE
555W #SKI K6MODE>199-199
55KG SWITRACE AWORK3(2),MODEQ
5656 LDX 0 AWORK1(2)
56JQ BNZ 0 P17 [J. IF TEMPORARY SWITCH
574B LDX 0 AWORK3(2)
57J2 #SKI K6MODE>199-199
583L SWITRACE 0,SMODE
58H= DFSET 3,SMODE,0
592W P17 DFJUMPS 3,LOAD,PLOAD
59GG CLALLOC 3 [DE-ALLOCATED DECK
5=26 STOZ CPPTR(2)
5=FQ #SKI K6MODE>199-199
5=^B SWITRACE 3,MODEND
5?F2 ENDCOM
5?YL PLOAD
5#D= DFCLEAR 3,TSN [CLEAR VARIOUS BITS IN APIA
5#XW DFCLEAR 3,TBITS
5*CG OPENSYS XBRKIN,DOCUMENT,GENERAL
5*X6 P19 SDSEARCH P18,GEOG,5
5BBQ DELETE
5BWB CLOSETOP [DOCUMENT
5CB2 GETACT ACTDOC
5CTL LDX 6 CPPTR(2)
5D*= LDX 2 BPTR(2)
5DSW STO 6 CPPTR(2)
5F#G LINKSET 2,TLINK(1)
5FS6 FPUT [START LIBLOAD
5G3Y ...NDCOM
5G?Q ENDCOM [FINISH
5GRB P18 GEOERR 1,NOSYSDOC
5H?2 P20 COMBRKIN
5H?4 ...[
5H?6 ...[ 9-TRACK DECK CODE
5H?8 ...[ ******************
5H?= ...[ EXAMINES MODE PARAMETER TO SEE IF IT IS PE,NRZI OR GCR
5H?# ...[ IF NOT MODE ILLEGAL
5H?B ...[ THEN CHECKS PROPERTIES OF TAPE DECKS AND ENVIRONMENT
5H?D ...[ TO SEE IF CAN SPECIFY MODES FOR SPECIFIED DECK
5H?G ...[ 9-TRACK DECKS ARE ONLY SOFTWARE SWITCHABLE WITH DME
5H?J ...[
5H?Q ...TR9
5H*2 ... MHUNT 2,CPB,CUNI
5H*= ... HUNT2 2,CPB,CUNI [FIND MODE CPB-CUNI
5H** ... CALL 7 SCVM9
5H*B ... BRN NVMF
5HF2 ...STMODE
5HF= ... LDX 2 FX2
5HFG ... STO 0 AWORK4(2)
5HFK ...[ IF 7-TRACK DECK THEN THE MODE IS ILLEGAL
5HFL ... LPROP 3,0
5HFM ... ANDN 0 #200
5HFN ... BZE 0 NVMFU
5HFP ...[ CHECK IF THE DECK IS HARDWARE OR SOFTWARE SWITCHABLE
5HFQ ... LPROP 3,0
5HFR ... ANDN 0 4
5HFS ... BZE 0 P12
5HFW ... LPROP 3,0
5HFY ... ANDN 0 3
5HG= ... BXE 0 AWORK4(2),NALR [J IF DECK ALREADY IN THIS MODE
5HG* ... LDN 0 3
5HGB ... TXU 0 AWORK4(2)
5HGC ... BCS XNGCR [GCR MODE NOT REQUIRED
5HGD ... JBC NMODA,3,CAPMODGCR
5HGF ...XNGCR
5HGH ... JWRONG 3,WRNG
5HGQ ... JALLOC 3,XALOC
5HH2 ... SETALLOC 3
5HH= ... STO 3 CPPTR(2)
5HH# ...[ NOT SOFTWARE SWITCHABLE IF DME
5HHD ... JENVNOT P14A,DME
5HHG ... LDN 0 #12 [SET UP DEVICE LIST FOR PERI
5HHQ ... DCA 3,DLA,0,MODE
5HJ2 ... LDN 0 1
5HJ= ... DCA 3,STO,0,COUNT
5HJ* ... SMO AWORK4(2)
5HJB ... LDX 0 SM12-1(1)
5HJC ... STO 0 AWORK4(2)
5HJG ... LDN 0 AWORK4(2)
5HJQ ... DCA 3,STO,0,CTSA
5HK2 ... GPERI ,2
5HK8 ... LDX 4 CPRW1(2)
5HKB ... BZE 4 SWOK
5HKC ... CLALLOC
5HKD ... STOZ CPPTR(2)
5HKF ...[ UNABLE TO SWITCH UNIT %A TO MODE %B
5HKG ... LDX 4 SHMODREJ(1)
5HKH ... BRN XERRA
5HKJ ...P14A
5HKQ ... CLALLOC
5HL2 ... STOZ CPPTR(2)
5HL5 ...[ NOT SWITCHABLE BY SOFTWARE
5HL6 ... BRN P14
5HLG ...SWOK
5HLQ ... LDX 0 AWORK1(2)
5HM2 ... BZE 0 NOTEMP [J IF NO TEMP PARAM GIVEN
5HM= ... MTINFORM HMODET
5HMG ...NOTEMP
5HMQ ... LDX 3 CPPTR(2)
5HN2 ... DFJUMPS 3,LOAD,PLOAD
5HN= ... CLALLOC
5HNG ... STOZ CPPTR(2)
5HNQ ... ENDCOM
5HQL #
5J== # ENTRY POINT 2
5JPW # THIS IS FOR THE MOCH AND MOCHAS MACROS
5K9G QK2MODE
5KP6 LDX 3 ACOMMUNE1(2) [DLIST POINTER
5L8Q #SKI K6MODE>299-299
5LNB SWITRACE 3,K2MODE
5M82 LTYPE 3,0
5MML SBN 0 5 [MT TYPE
5N7= BZE 0 Q1
5NLW GEOERR 1,DLISTPTR
5P6G Q1 MHUNT 1,CPAR,GPERCON
5PL6 LDX 0 A1+2(1)
5Q5Q ANDN 0 #74 [MODE SPECIFIED ?
5QKB BNZ 0 Q2
5R52 Q3 SETREP OK
5RJL UP
5S4= Q2 LMODEQ 3,0 [CURRENT MODE
5SHW LDX 6 A1+1(1)
5T3G ANDN 6 #74
5TH6 TXU 6 0
5W2Q BCC Q3 [AGREE
5WGB STO 6 AWORK3(2)
5X22 #SKI K6MODE>99-99
5XFL SWITRACE 6,MOCHAS
5X^= CALL 7 SWITCHQA
5YDW BPZ 0 Q4
5YYG SETREP NOTAV
5^D6 UP
5^XQ Q4 LDX 4 ACOMMUNE2(2)
62CB BZE 4 Q3 [J. IF MOCH
62X2 SETMODEQ 3,AWORK3(2) [SWITCH CURRENT MODE
63BL SETREP SWITCHED
63W= UP
64*W #
64TG # ENTRY POINT 3
65*6 # FOR MONICA MACRO
65SQ QK3MODE
66#B SETNCORE 2,3,AONBS,GROT [FOR REPLY
66S2 MHUNT 2,CPAR,GPERCON
67?L LDX 4 A1+1(2)
67R= ANDN 4 #74
68=W LDX 5 SMON(1)
68QG R2 SMO 5
69=6 TXU 4 SMODE-1(1)
69PQ BCC R1 [FOUND
6=9B BCT 5 R2
6=P2 GEOERR 1,MODE3
6?8L R1 SMO 5
6?N= LDX 0 SMCHN-1(1)
6#7W STO 0 A1(3) [NR OF CHARS
6#MG SMO 5
6*76 LDX 0 SMCHC-1(1)
6*LQ STO 0 A1+1(3)
6B6B UP
6CJQ ...[
6CK3 ...[ SOME ERROR ROUTINES
6CK# ...[ *********************
6CKK ...[
6CLD ...[ OUTPUT THE UNIT NUMBER FIRST - THE COMERR WILL OUTPUT THE MODE
6CLP ...[ IN THE SECOND CUNI BLOCK
6CM2 ...[
6CM? ...XERRA OUTNUM 5,0
6CMJ ...[
6CMT ...XFREE MFREE CPB,CUNI
6CN6 ...[
6CNC ...XCOMM COMERRX 4
6CNN ...[
6CN^ ...[ NOT A NUMBER - SEE IF 9-TRACK MODE SPECIFIED
6CP= ...NVM7 MHUNT 2,CPB,CUNI
6CPH ... CALL 7 SCVM9
6CPS ... BRN NVM
6CQ5 ...[ 9-TRACK MODE ILLEGAL HERE - OUTPUT IT
6CQB ... LDX 4 ANUM(2)
6CQM ... ANDN 4 #7777
6CQY ... OUTPARAM 4,APARA,CPB,CUNI
6CR9 ... LDX 4 SHNVM7(1)
6CRG ... COMERRX 4,5
6CRR ...[
6CS4 ...[ NOT A VALID MODE
6CS* ...NVM LDX 4 SHNVM(1)
6CSL ... BRN XCOMM
6CSX ...[
6CT8 ...NVMF LDX 4 SHNVM(1)
6CTF ... BRN XFREE
6CTQ ...[ DECK ALREADY IN GIVEN MODE
6CW3 ...NALR LDX 4 SHMODEAL(1)
6CW# ... BRN XERRA
6CWK ...[ NOT A VALID MODE FOR SPECIFIED TAPE DECK
6CWW ...NVMFU LDX 4 SHNVMOD(1)
6CX7 ... BRN XERRA
6CXD ...[ MODE UNAVAILABLE
6CXP ...NMODA LDX 4 SHMODUN(1)
6CY2 ... BRN XERRA
6CY? ...[ NOT SWITCHABLE BY SOFTWARE
6CYJ ...P14 LDX 4 SHNSWBS(1)
6CYT ... BRN XCOMM
6C^6 ...[ ALL DECKS SPECIFIED-SO 9-TRACK MODE INVALID
6C^C ...NVMAL LDX 5 SHALLD(1)
6C^N ... BRN NVM7
6C^^ ...[ USER CONTEXT - SO 9-TRACK MODE INVALID
6D2= ...NVMUS LDX 5 SHUSEC(1)
6D2H ... BRN NVM7
6D2S ...[
6D3B ...[
6D3M ...[
6D3Y ...[**********************************************************************
6D49 ...[
6D4G ...XBRKIN GEOERR 1,XBRKIN
6D4W #
6DJG # ENTRY POINT 4
6F46 # FOR FREEMT MACRO
6FHQ #
6G3B QK4MODE
6GH2 LDX 3 CPPTR(2)
6H2L LPROP 3,0
6HG= ANDN 0 #200 [9 TRACK?
6H^W BNZ 0 U2
6JFG LMODEQ 3,7 [CURRENT MODE
6J^6 DFLOAD 3,SMODE,6 [STANDARD MODE
6KDQ TXU 6 7
6KYB BCC U2 [ALREADY IN STANDARD MODE
6LD2 #SKI K6MODE>99-99
6LXL SWITRACE 6,K4MODE
6MC= LCAP 3,0
6MWW ANDN 0 #10 [DENSITY SWITCHABLE ?
6NBG BNZ 0 U7
6NW6 LDN 0 #60
6P*Q ANDX 0 7 [CURRENT DENSITY
6PTB LDN 1 #60
6Q*2 ANDX 1 6 [STANDARD DENSITY
6QSL TXU 0 1
6R#= BCS U3 [J. IF SWITCH REQUIRED
6RRW #SKI K6MODE>199-199
6S?G SWITRACE 0,MOSWREQ
6SR6 U7 JUNBUSY 3,U4
6T=Q COOR3 #41 [CO-ORDINATE IF BUSY
6TQB BRN U7
6W=2 U4 SETMODEQ 3,6
6WPL U2 FREEPER
6X9= UP
6XNW U3
6Y8G GETACT ACTDOC [MESSAGE ACTIVITY
6YN6 LDX 2 BPTR(2)
6^7Q STO 3 CPPTR(2) [DLIST POINTER
6^MB LINKSET 2,TLM(1)
7272 #SKI K6MODE>299-299
72LL SWITRACE 3,MOMESS
736= FPUT [START ACTIVITY
73KW BRN U2
745G #
74K6 # ENTRY POINT 5
754Q # FOR OUTPUT OF MESSAGE WHEN DECK
75JB # CANNOT BE SWITCHED TO STANDARD MODE ON UNLOADING
7642 QK5MODE
76HL LGEOG ,5
773= #SKI K6MODE>99-99
77GW SWITRACE 5,K5MODE
782G OUTNUM 5,0 [DECK NR
78G6 SETNCORE 2,3,AONBS,GROT [BUFFER
78^Q LMODEQ ,6 [MODE
79FB LDX 4 SMON(1)
79^2 V2 SMO 4
7=DL TXU 6 SMODE-1(1)
7=Y= BCC V1
7?CW BCT 4 V2
7?XG GEOERR 1,MODE5
7#C6 V1 SMO 4
7#WQ LDX 0 SMCHN-1(1)
7*BB STO 0 A1(3)
7*W2 SMO 4
7B*L LDX 0 SMCHC-1(1)
7BT= STO 0 A1+1(3)
7C#W OUTPARAM A1(3),A1+1,AONBS,GROT
7CSG MTINFORM HMODE
7D#6 SUICIDE
7DRQ TLM PAIR MODE,5
7F?B MENDAREA 50,K99MODE
7FR2 #END
^^^^ ...57671526000300000000