{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MOVCART867)}}
====== MOVCART867 ======
(George Source)
**Macros used:** [[george:macro:BS|BS]], [[george:macro:BUTTONUP|BUTTONUP]], [[george:macro:COMERRX|COMERRX]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR3|COOR3]], [[george:macro:DCA|DCA]], [[george:macro:DEMAND|DEMAND]], [[george:macro:DISENGPER|DISENGPER]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FON|FON]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHACCWK|FSHACCWK]], [[george:macro:FSHACTPR|FSHACTPR]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:FSHKILL|FSHKILL]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:FSHTEST|FSHTEST]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GPERI|GPERI]], [[george:macro:GSCAN|GSCAN]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INFORM|INFORM]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JBUSY|JBUSY]], [[george:macro:JDED|JDED]], [[george:macro:JDISENG|JDISENG]], [[george:macro:JENG|JENG]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JPROP|JPROP]], [[george:macro:JUNDE|JUNDE]], [[george:macro:LADDP|LADDP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINT|LINT]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LPROP|LPROP]], [[george:macro:MBSXD|MBSXD]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PAIR|PAIR]], [[george:macro:PARSORT|PARSORT]], [[george:macro:REPEAT|REPEAT]], [[george:macro:RESET|RESET]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:TESTUNPR|TESTUNPR]], [[george:macro:TRANSBEG|TRANSBEG]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:VFREEW|VFREEW]]
22FL ... SEG MOVCART,865,FRANK BLUNDELL,MOVCART
23YG # THIS IS THE SEGMENT WHICH CONTROLS THE MOVING OF
24D6 # FILESTORE/SWAP CARTRIDGES
24XQ #
25CB # XA1=CPPTR,+1=TYPE/GEOG,+2=CSN OR BSA ADDR
25X2 # +3=BSUN,+4=APIA ADDR
26BL #DEF XBSA=BSFAIL
26W= #DEF XREC=5
27*W #DEF XA1=A1
27TG #DEF XBUFSTART=2*XREC+XA1+1
28*6 #DEF XLENCART=XBUFSTART-XA1+128
28SQ #
29#B SEGENTRY K1MOVCART,QK1MOVCART
29D? ... FSHENTRY K2MOVCART,QK2MOVCART,QK2MOVCART,QK2MOVCART
29J8 ... FSHENTRY K3MOVCART,QK3MOVCART,QK3MOVCART,QK3MOVCART
29N5 ... FSHENTRY K4MOVCART,QK4MOVCART,QK4MOVCART,QK4MOVCART
29Q3 ... FSHENTRY K5MOVCART,XBGONE,,XBGONE
29S2 #
2=?L XMASK #17770000
2=R= XMASK1 #777777
2?=W #DEF XSER=2*XREC+XA1
2?*5 ...# THESE FIRST TWO MESSAGES MUST BE AT THE SAME OFFSET AS
2?C# ...# IN MOVCASH
2?FH ...#
2?HQ ...XBMCG +BMVCG
2?K^ ...XBMG3 +BMVG3
2?N8 ...#
2?QG XBMV +BMVINV
2#=6 XBMVC +BMVINC
2#PQ XBMCOM +BMVINCOM
2*9B XBMSAME +BMVSAME
2*P2 XBMFILE +BMVFILE
2B8L XBMFIL1 +BMVFILE1
2CG= ...XBMFD +BMVFD
2CSN ...XWAITSWIT +EWAITSWIT [UNIT IS WAITING TO BE SW OUT
2D76 XBMENT +ENTIN30
2D7* ... FSHCODE AORB
2D7J ...(
2D7K ...# LINK FOR UNANTICIPATED CLOSEDOWN
2D7L ...#
2D7M ...SCDLINK
2D7N ... PAIR MOVCART,5
2D7P ...#
2D7R ...XBMSH +FSHBMSH [SPINDLES MUST BE SHARED
2D82 ...XBMUN +FSHBMUN [SPINDLES MUST BE DEDICATED OR SHARED
2D89 ...XBMIX +FSHBMIX [CANT HAVE RESIDENCES ON BOTH
2D8D ...XMASK2 #77770000
2D8M ...#
2D** ...)
2DG3 ...#
2DLQ QK1MOVCART
2F6B ... PARSORT XBRKIN,ALL,GROPE [CONVERT OPERATORS UNIT NOS.
2FL2 SETNCORE XLENCART,3,BSTB,CART,1 [CREATE BUFFER BLOCK
2G5L LDN 4 2
2GK= LDN 5 0
2H4W X1 HUNTW 1,CPAR,JSCE [HUNT FOR PARAMETER BLOCK
2HJG ... BNG 1 TIDYUP [FINISH IF NO PARAM-MESSAGE O/P BY PARS
2JHQ LDN 6 JSCEP(1)
2K3B SMO 5 [MOVE DEVICE LIST POINTER AND
2KH2 LDN 7 XA1(3) [DEVICE TYPE/GEOGRAPHICAL NUMBER
2L2L MOVE 6 2 [TO BUFFER BLOCK
2LG= SMO 5
2L^W STOZ XA1+2(3) [CLEAR SERIAL NUMBER WORD
2MFG FREECORE 1 [FREE PARAMETER BLOCK
2M^6 ADN 5 XREC
2NDQ BCT 4 X1 [LOOK FOR SECOND PARAMETER
2NYB HUNTW 1,CPAR,JSCE [IF ANY MORE PARAMETERS THE
2PD2 LDN 6 XBMV [....COMMAND IS INCORRECT
2PXL BPZ 1 XINV [COMMAND IS INVALID
2QC= LDX 4 XA1+1(3)
2QWW SRL 4 18 [GET DEVICE TYPES
2RBG LDX 5 XA1+6(3)
2RW6 SRL 5 18
2S*Q LDN 6 XBMCOM [....DIFFERENT CHARACTERISTICS
2STB TXU 4 5 [MAKE SURE DEVICES OF SAME TYPE
2T*2 BCS XINCOM
2TSL SBN 4 6
2W#= ... BZE 4 X2 [DEVICE TYPE MUST EITHER BE 6 OR 26
2WRW SBN 4 20
2X7K ... LDN 6 XBMVC
2XH# ... BNZ 4 XWRTYP
2XX3 ...X2 LPROP XA1(3),4 [LOAD PROPERTIES AND CHECK DEVICES
2Y=Q ... LPROP XA1+5(3),5 [ARE SAME TYPE
32F4 ... LDN 6 XBMCOM
32SR ... TXU 4 5 [COMMAND INVALID IF
338G BCS XINCOM [DIFFERENT
33?3 ... LDN 6 XBMFD [CHECK DEVICES ARE
33?W ... JPROP XA1(3),XINCOM,XINCOM [NOT FIXED
33#Q ...XCHEKST
33#R ... LADDP XA1(3),2 [PTR TO APIA
33#S ... LDX 4 BSUNIT3(2)
33#T ... LDX 5 4
33#W ... ANDN 5 BSWOUT
33#X ... BNZ 5 XBSW [ERROR IF WAITING TO BE SW OUT
33#Y ... ANDN 4 #10 [CHECK IF STATUS CHANGE IN PROGRES
33#^ ... BZE 4 XNOS1 [ON FIRST, ^ IF NOT
33*2 ... COOR3 KTSCTF
33*3 ... BRN XNOS2
33*4 ...XNOS1 LADDP XA1+5(3),2
33*5 ... LDX 4 BSUNIT3(2) [CHECK IF STATUS CHANGE IN PROGRES
33*6 ... LDX 5 4
33*7 ... ANDN 5 BSWOUT
33*8 ... BZE 5 XNOS4
33*9 ... ADN 3 5 [ERROR IF WAITING TO BE SW OUT
33*= ... BRN XBSW
33*? ...XNOS4
33*# ... ANDN 4 #10 [ON SECOND
33** ... BZE 4 XNOS3 [^ IF NOT
33*B ... COOR3 KTSCTF
33*C ...XNOS2 MHUNTW 3,BSTB,CART
33*D ... BRN XCHEKST
33*F ...XNOS3
33*N ... FSHSKIP
347Q LDN 6 XBMENT [SPINDLES MUST BE DEDICATED
34MB LDN 7 0
3572
35LL LADDP XA1(3),2 [GET POINTER TO APIA AND
366= STO 2 XA1+4(3) [REMEMBER IN BUFFER BLOCK
36KW LDX 4 BSUNIT(2)
375G ANDN 4 #7777
37K6 STO 4 XA1+3(3) [REMEMBER BSUN
384Q ORX 7 BSUNIT3(2) [B22 SET IF CG IN PROGRESS
38JB
38PJ ... FSHSKIP
38WQ ...(
3=3= JDED 2,X25 [JUMP IF DEDICATED
3=GW BRN XCG
3?2G X25
3?PY ...)
3?^Q LADDP XA1+5(3),2 [GET POINTER TO APIA FOR OTHER
3#FB STO 2 XA1+9(3) [DEVICE AND STORE IN BUFFER BLOCK
3#^2 LDX 5 BSUNIT(2)
3*DL ANDN 5 #7777
3*Y= STO 5 XA1+8(3) [REMEMBER BSUN
3BCW ORX 7 BSUNIT3(2) [B22 SET IF CG IN PROGRESS
3BXG
3C4N ... FSHSKIP
3C9W ...(
3DBB JDED 2,X26 [JUMP IF DEDICATED
3DW2 BRN XCG
3F*L X26
3G54 ...)
3G#W ANDN 7 BCGCOM [CG IN PROGRESS BIT
3GSG LDN 6 XBMCG
3H#6 BNZ 7 XCG [J IF CG ALREADY IN PRORESS
3HRQ LDN 6 XBMSAME [....REFER TO THE SAME DEVICE
3J?B TXU 5 4 [IF THE BSUNS ARE THE SAME THE
3JR2 BCC XSAME [COMMAND MUST BE INVALID
3K=L LDN 6 XBMG3 [....CARTRIDGE CONTAINS GEORGE FILE
3K*9 ... LDX 7 BRADSPLTBSU [BSUN OF SCF ; =0 IF NOT PRESENT
3KCS ... TXU 4 7
3KGC ... BCC XG3 [J IF EQUAL TO
3KK2 ... TXU 5 7
3KMK ... BCC XG3 [EITHER DEVICE
3KQ= LDN 7 1 [BSUN OF GEORGE DEVICE
3L9W TXU 4 7
3LPG BCC XG3 [INVALID IF CG ON GEORGE FILE
3M96 TXU 5 7
3MNQ BCC XG3
3N8B LDN 7 0 [ZEROISE MARKERS
3NN2 LDN 5 0
3P7L X6 SLL 4 12 [MOVE BSUN TO BITS0-11
3PM= LDX 2 ALFTP [POINTER TO LOGICAL FILE TABLE
3Q6W LDX 6 ALOGLEN(2)
3QLG X3 BZE 6 X5 [BRANCH IF NO MORE ENTRIES
3R66 LDX 0 A1(2)
3RKQ BNG 0 X4 [BRANCH IF NO RESIDENCES
3S5B SMO FX1
3SK2 ANDX 0 XMASK
3T4L TXU 0 4 [SEE IF ENTRY FOR SAME BSUN
3TJ= BCC X7
3W3W X4 SBN 6 2
3WHG BDX 2 X3 [LOOK AT NEXT ENTRY
3X36 X5 BNZ 5 X8 [BRANCH IF WE HAVE LOOKED FOR BOTH
3XGQ X9 LDX 4 XA1+8(3) [BSUN'S - IF NOT LOOK AGAIN
3Y2B ADN 5 XREC
3YG2 BRN X6
3YJ9 ... FSHCODE AORB
3YLD ...(
3YNM ...X7 LDX 1 2
3YQW ... LDEX 2 A1(2) [GET MODIFIER TO FDTABLE AND
3YT5 ...)
3YX# ... FSHSKIP
3Y^L X7 LDEX 2 A1(2) [GET MODIFIER TO FDTABLE AND
3^F= ADX 2 AFDTP [ADD ADDRESS OF FDTABLE
3^YW LDX 0 A1+5(2) [LOAD SERIAL NUMBER FROM FDTABLE...
42DG SMO 5
42Y6 STO 0 XA1+2(3) [...AND STORE IN BUFFER BLOCK
43CQ ADN 7 1
43D= ... FSHCODE AORB
43DQ ...(
43F= ... ADX 3 5 [UPDATE POINTER FOR BORING BS MACRO
43FQ ...X7A
43G= ... LDCT 0 #200
43GQ ... ANDX 0 A1(1)
43H= ... BZE 0 NOTSWAP [J IF FILESTORE RESIDENCE
43J= ... BS 3,BCGHOMESWAP [SET SWAP BIT IN DEVICE ENTRY
43JQ ... BRN NOTFS
43LQ ...NOTSWAP
43M= ... BS 3,BCGFILESTOR [SET F/S BIT IN DEVICE ENTRY
43MQ ...NOTFS
43N= ... SBN 6 2 [PROCESS REST OF ALFTABLE IN
43NQ ... BDX 1 £ [CASE F/S+SWAP ON SAME DRIVE
43P= ... BZE 6 XALFIN
43PQ ... LDX 0 A1(1)
43Q= ... BNG 0 NOTFS
43QQ ... SMO FX1
43R= ... ANDX 0 XMASK
43RQ ... TXU 0 4
43S= ... BCC X7A
43SQ ... BRN NOTFS
43T= ...XALFIN
43TQ ... SBX 3 5 [RESET X3
43W= ...)
43XB BZE 5 X9 [LOOK FOR OTHER BSUN?
44C2 X8 LDN 6 XBMFILE [....MUST CONTAIN A RESIDENCE
44WL BZE 7 XFILE [BRANCH IF RESIDENCES ON NONE
45B= LDN 6 XBMFIL1
45TW SBN 7 2
46*G BPZ 7 XFILE [BRANCH IF RESIDENCES ON BOTH
46GN ... FSHCODE AORB
46MW ...RESET
46T6 LDX 2 XA1+4(3)
47#Q LDX 1 XA1+9(3)
47SB LDN 5 BCGCOM
48#2 ORS 5 BSUNIT3(2) [REMEMBER CG NOW IN PROGRESS ON
48RL ORS 5 BSUNIT3(1) [THE TWO DEVICES.
48RR ... FSHCODE AORB
48RY ...(
48S= ... SMO FX2
48SC ... STOZ AWORK1 [ZEROISE TRANSBEG MARKER
48SJ ... LDX 5 3 [SET UP SECOND POINTER
48SP ... ADN 5 XREC [TO POINT TO SECOND ENTRY
48SW ... LDN 6 XBMUN
48T3 ... JUNDE 2,XXCG [DRIVES MUST NOT BE UNDEDICATED
48T8 ... JUNDE 1,XXCG
48T* ... JBS XFS,3,BCGFILESTOR [J IF 1ST DRIVE HAS F/S
48TG ... JBC XSWAP,5,BCGFILESTOR [J IF NOT F/S
48TM ...XFS LDN 6 XBMSH
48TS ... JDED 2,XXCG [ERROR - DRIVE NOT SHARED
48T^ ... BS 3,BCGSHARED [SET SHARED BIT
48W6 ... JDED 1,XXCG [ERROR AGAIN - DRIVE MUST BE SHARED
48W? ... BS 5,BCGSHARED [SET SHARED BIT
48WD ... BRN XCHKD
48WK ...XSWAP
48WQ ... JDED 2,XSETDD [ALLOWABLE FOR SWAP
48WX ... BS 3,BCGSHARED [SET SHARED BIT
48X4 ... BRN XNXTSW
48X9 ...XSETDD
48XB ... BS 3,BCGDEDIC [SET DEDICATED BIT
48XH ...XNXTSW
48XN ... JDED 1,XSETDE [AGAIN ALLOWABLE
48XT ... BS 5,BCGSHARED [SET SHARED BIT
48Y2 ... BRN XCHKD
48Y7 ...XSETDE
48Y# ... BS 5,BCGDEDIC [SET DEDICATED BIT
48YF ... JDED 2,NOWAY [BOTH DEDICATED! NO TRANSBEG
48YL ...XCHKD
48YR ... JBC NOWAY,,FSHRUNNING [J IF B M/C DOWN
48YY ... LDX 0 GSIGN
48^5 ... SMO FX2
48^= ... ORS 0 AWORK1 [SET MARKER -VE TRANSBEG REQD
48^C ... FSHCODE A,XIAMB
48^D ...(
48^F ... SETNCORE 1,3,FSH,FSHAMBLES
48^G ... LDX 0 SCDLINK(1)
48^H ... STO 0 FSHCDLINK(3)
48^J ... FSHACTPR XBDOWN [SET UP PAIRED ACT IN OTHER M/C
48^K ...)
48^P ...XIAMB
48^W ... SETNCORE 2*XREC+1,3,BSTB,HORSE [SET UP /HORSE AFORE THE /CART
4923 ... MHUNTW 2,BSTB,CART [REFIND THE /CART BLOCK
4928 ... ADN 2 XA1
492* ... ADN 3 XA1
492G ... MOVE 2 2*XREC+1 [COPY DETAILS OF THE DRIVES
492M ... [HEEEEEERE WEEEEEEE GOOOOO!!!
492S ... TRANSBEG FSHCGID,MOVCASH,2,BSTB,HORSE,ACOMMUNE1,XBDOWN
492^ ... BRN XBERR [ERROR JUMP
4936 ... MHUNTW 3,BSTB,CART
493? ... MHUNTW 2,BSTB,HORSE
493D ... LDN 6 XBMIX [MESSAGE - NO MIXTURE ALLOWED
493K ... LDX 4 XA1+3(3) [GET SHFS BITS
493Q ... ORX 4 XA1+3(2) [FROM ALIEN M/C ALSO
493X ... LDX 5 XA1+3+XREC(3) [ALSO FOR OTHER DRIVE
4944 ... ORX 5 XA1+3+XREC(2)
4949 ... MBSXD 7,BCGHOMESWAP,BCGAWAYSWAP,BCGFILESTOR [SET UP MASK
494B ... LDX 0 4 [FIRST DRIVE!
494H ... ANDX 0 7
494N ... BNZ 0 RECHK1 [J IF RES ON 1ST DRIVE
494T ... LDX 0 5 [NONE ON 1ST
4952 ... ANDX 0 7
4957 ... BNZ 0 RECHK2 [SO J IF ANY ON 2ND
495# ... GEOERR 1,NORES [NO RESIDENCES - IMPOSSIBLE
495F ...RECHK1
495L ... LDX 0 5
495R ... ANDX 0 7
495Y ... BNZ 0 XAPIA [ILL RES ON BOTH FROM EITHER M/C
4965 ...RECHK2
496= ... ORX 4 5
496C ... MBSXD 7,BCGHOMESWAP,BCGAWAYSWAP [SET UP ANOTHER MASK
496J ... LDX 0 4
496P ... ANDX 0 7 [CHECK IF SWAP RESIDENCES
496W ... ERX 0 7 [ON SAME FOR MORE CHECKS
4973 ... BNZ 0 RECHK4
4978 ...RECHK3
497* ... LDN 6 XBMSH
497G ... MBSXD 7,BCGDEDIC [SET UP YET ANOTHER MASK
497M ... LDX 0 4
497S ... ANDX 0 7
497^ ... BNZ 0 XAPIA [ILLEGAL TO HAVE SWAP ON DEDIC
4986 ...RECHK4
498? ... LDX 1 FX1
498D ... LDX 0 XA1+3(3)
498K ... ANDX 0 XMASK2(1) [ISOLATE SHFS BITS
498Q ... ORS 0 XA1+3(2) [TO /HORSE BLOCK
498X ... LDX 0 XA1+3+XREC(3)
4994 ... ANDX 0 XMASK2(1) [ISOLATE SHFS BITS
4999 ... ORS 0 XA1+3+XREC(2) [TO /HORSE BLOCK
499B ... TRANSBEG FSHCGID,MOVCASH,3,BSTB,HORSE,ACOMMUNE1,XBDOWN
499H ... BRN XBERR
499N ... MHUNTW 3,BSTB,CART
499T ... LDX 2 XA1+4(3)
49=2 ... LDX 1 XA1+4+XREC(3)
49=7 ...NOWAY
49=# ...)
49?= X12 LDX 5 BSUNIT(2)
49QW BNG 5 X10 [CO-ORDINATE IF GRUESOME IN TRANSIT
4==G LDX 5 BSUNIT(1)
4=Q6 BPZ 5 X11 [ON EITHER DEVICE
4?9Q ...X10 COOR3 ENDGRU
4?PB MHUNTW 3,BSTB,CART [REFIND BUFFER BLOCK
4#92 LDX 2 XA1+4(3)
4#NL LDX 1 XA1+9(3) [LOAD POINTERS TO APIAS
4*8= BRN X12
4*MW X11 LDN 5 BNOENG
4B7G ORS 5 BSUNIT3(2) [TELL GRUESOME TO IGNORE ANY ENGAGE..
4BM6 ORS 5 BSUNIT3(1) [..BUTTONS FOR THE TIME BEING
4C6Q LDX 1 3
4CLB LDN 4 CGINPROG
4D62 LDN 5 2
4DKL X13 LDX 7 XA1+3(3) [LOAD BACKING STORE UNIT NUMBER
4DQS ... FSHCODE AORB
4DY2 ... ANDN 7 #7777 [MASK OUT SHFS BITS
4F5= MPY 7 ASBSAB
4FJW NGX 2 0
4G4G ADX 2 BBAC [FIND RELEVANT BSA
4GJ6 ADX 2 ASBSAB
4H3Q ORS 4 XBSA(2) [TELL BSA TO HOLD UP ALL FILESTORE
4HHB JDISENG XA1(3),XDIS [TRANSFERS
4J32 X22 JBUSY XA1(3),X22 [WAIT UNTIL NON BUSY
4JGL DISENGPER XA1(3) [DISENGAGE DEVICE IF ENGAGED
4K2= X23 JENG XA1(3),X23
4KFW LINT XA1(3),0 [GET INTERNAL NUMBER
4K^G LDN 4 24
4LF6 DVS 7 4 [CONVERT INTERNAL NUMBER...
4LYQ LDCT 4 256 [...TO A BUTTON
4MDB SMO 7
4MY2 SRL 4 0
4NCL LDX 7 0
4NX= BUTTONUP 4,7 [SET INTERRUPT BIT IN EBA
4PBW LDN 4 CGINPROG
4PWG XDIS LDX 0 XA1+2(3)
4Q25 ... BNZ 0 X14 [BRANCH IF CARTRIDGE CONTAINING RESID
4Q5N ... LDX 6 XA1(3)
4Q9? ... FSHCODE AORB
4Q#W ...(
4QDF ... SMO FX2
4QJ4 ... STO 6 AWORK3
4QMM ...)
4QR= ... STO 2 XA1+2(3) [POINTER TO BSA
4QWT ...X15 ADN 3 XREC
4R2D ... BCT 5 X13 [LOOK AT OTHER DEVICE
4R63 ... BRN X16
4R9L ...X14 STO 0 XSER(1) [REMEMBER SERIAL NO
4R*B LDCT 0 256
4RC^ ...#UNS FSHTEST
4RGJ ...(
4RK7 ... SMO XA1+4(3) [*** TESTING AID ON ONE M/C ***
4RMQ ... ORS 0 BSUNIT2
4RQ* ...)
4RT2 SMO XA1+4(3) [CLEAR IN USE BY SYSTEM BIT
4S#L ERS 0 BSUNIT2
4SS= ... STO 2 XA1+2(3) [POINTER TO BSA
4T?W ... ORS 0 XA1+2(3) [MKR FOR BSA ORIGINALLY REFERRING
53M2 BRN X15
53NY ...# NOW OUTPUT MESSAGE REQUESTING RESIDENCE TO BE
53QW ...# LOADED ON ALTERNATIVE DRIVE
53SS ...#
53WQ ...X16 GSCAN XSER(1),CGCOM
53YN ...XWAIT LONGSET CGENG,XSET
542L ... CALL 7 XOUTB [CREATE PARAM BLOCK
544J ... CALL 7 XOUTCSN
546G ... LGEOG 6,4 [OPS UNIT NO TO X4
548D ... CALL 7 XOUTOPNO
54=B ... DEMAND 1,BMVLOAD,XCANTDO,XBRKIN,XRENT,2
54## ... JENG 6,XENG
54B= ... LONGSET CGENG,XSET
54D8 ... BRN XRENT [RE-ENTER IF STILL NOT ENGAGED
54G6 ...XENG CALL 7 XDQUIT [FREE DEMAND BLOCKS
54GQ ... MHUNTW 3,BSTB,CART
54HB ... LOCKC 3,XFIND [LOCK BLOCK
54J4 ... MHUNTW 3,BSTB,CART [REFIND BUFFER BLOCK
54L= LDN 4 128
555W DCA 6,STO,4,COUNT [COUNT TO DEVICE LIST
55KG LDN 4 1
55PC ... JENVNOT XADDR,MEEP [J IF 1900 OR DME ENVIRONMENT
55T# ... ORX 4 GSIGN [SET BO OF ADDR FOR EDEM
55^9 ...XADDR
5656 DCA 6,STO,4,DTSA [HARDWARE ADDRESS TO DEVICE LIST
56JQ LDN 4 XBUFSTART(3)
574B DCA 6,STO,4,CTSA [BUFFER ADDRESS TO DEVICE LIST
57J2 LDN 4 0
583L DCA 6,DLA,4,MODE [MODE TO DEVICE LIST
592W LOCKC 2,£ [LOCK ACTIVITY
59GG GPERI 6,2 [DO PERI
5=26 COOR1 [WAIT FOR E0T
5=FQ UNLOCK 2
5=^B UNLOCK 3 [UNLOCK BUFFER BLOCK
5?F2 LDCH 4 CPRW1(2)
5?YL BZE 4 X17 [BRANCH IF TRANSFER OK
5#D= BPZ 4 X18
5#XW GEOERR 1,CARTBUSY [DEVICE STILL BUSY!
5*CG X18 LGEOG 6,4 [GET GEOGRAPHICAL NUMBER
5*X6 ... CALL 7 XOUTOPNO
5CTL INFORM 1,EWFAIL,1 [UNIT NN FAILED
5D*= BRN X20F
5DSW X17 LDN 0 1
5F#G SBX 0 XBUFSTART(3)
5FS6 BNZ 0 X18 [BLOCK ADDRESS OK?
5G?Q LDX 0 XBUFSTART+1(3)
5GRB BZE 0 X19 [BRANCH IF NO CHECKSUM
5H?2 LDN 1 XBUFSTART(3)
5HQL SUM 0 128
5J== BNZ 0 X18 [BRANCH IF CHECKSUM FAIL
5JPW X19 LDX 7 XBUFSTART+5(3)
5K9G SMO FX1
5KP6 ANDX 7 XMASK1
5L8Q TXU 7 XSER(3) [CORRECT CARTRIDGE?
5LNB BCS X20
5LPF ... FSHCODE AORB
5LQJ ...(
5LRM ... LDX 0 AWORK1(2)
5LSQ ... BPZ 0 RUNIN [NO CHECKS REQUIRED
5LTT ... STO 6 AWORK2(2) [PRESERVE D.L. POINTER
5LXF ... TRANSBEG FSHCGID,MOVCASH,4,BSTB,HORSE,ACOMMUNE1,UNIMP,AUT,SUP
5L^6 ... LDX 6 AWORK2(2) [REINSTATE D.L. POINTER
5M29 ...UNIMP
5M3# ... MHUNTW 3,BSTB,CART
5M4C ... LDX 7 XSER(3) [RESET CSN
5M5G ...RUNIN
5M6K ...)
5M82 LDN 5 CGINPROG [CG IN PROGRESS BIT
5MML LDX 1 XA1+2(3)
5N7= LDX 4 XA1+5(3) [NOW TO SWOP OVER BORING CPPTRS
5NLW STO 4 CPPTR(1)
5NQ2 ... LDX 4 AWORK4(1) [AND SWAP TRANSFER COUNTS TOO
5NT6 ... SMO XA1+7(3)
5NY= ... LDX 0 AWORK4
5P3B ... STO 0 AWORK4(1)
5P4C ...#UNS FSHTEST
5P5D ... ORS 5 XBSA(1) [*** TESTING AID ON ONE M/C ***
5P5H ... LDX 0 BA2(1)
5P5L ... LDX 2 XA1+7(3)
5P5P ... LDX 4 BA2(2)
5P5S ... STO 0 BA2(2)
5P5X ... STO 4 BA2(1)
5P62 ... LDX 0 BA3(1)
5P65 ... LDX 4 BA3(2)
5P68 ... STO 0 BA3(2)
5P6? ... STO 0 BA3(1)
5P6G #SKI K6MOVCART>199-199
5PL6 (
5Q5Q LDX 0 XBSA(1) [CHECK IN PROGRESS BIT SET
5QKB ANDX 0 5
5R52 BNZ 0 X20A
5RJL X20B GEOERR 1,CARTBIT
5S4= X20A
5SHW )
5SQ6 ... LDN 0 BKARTWT
5SYB ... ANDX 0 XBSA(1) [CLEAR WT FOR KARTCONT BIT IF SET
5T6L ... ORS 5 0
5T#W ... ERS 0 XBSA(1) [AND CG IN PROG BIT IN BSA
5TH6 LDX 1 XA1+7(3)
5TQY ... STO 4 AWORK4(1)
5W2Q LDX 4 XA1(3)
5WGB STO 4 CPPTR(1)
5WMJ ...#UNS FSHTEST
5WSQ ... ORS 5 XBSA(1) [*** TESTING AID ON ONE M/C ***
5X22 #SKI K6MOVCART>199-199
5XFL (
5X^= LDX 0 XBSA(1)
5YDW ANDX 0 5
5YYG BZE 0 X20B
5^D6 )
5^LB ... LDN 0 BKARTWT
5^SL ... ANDX 0 XBSA(1) [CLEAR WT FOR KARTCONT BIT IF SET
622W ... ORS 5 0
6296 ... ERS 0 XBSA(1) [AND CG IN PROG BIT IN BSA
62CB #SKI CRAB
62X2 (
63BL LDX 0 XA1+5(3) [FOR PM PURPOSES JSWAPDR POINTS TO
63W= TXU 4 JSWAPDR [ THE DEVICE RECORD FOR THE LEVICE
64*W BCS X30A [ ON WHICH THE LARGEST SWAP FILE
64TG STO 0 JSWAPDR [ IS KEPT, SO BOTH CPPTRS ARE
65*6 BRN X31A [ CHECKED TO ENSURE THAT JSWAPDR
65SQ X30A TXU 0 JSWAPDR [ STILL POINTS TO THE
66#B BCS X31A [ CORRECT DEVICE
66S2 STO 4 JSWAPDR [ RECORD
67?L X31A
67R= )
68=W
68QG LADDP 6,1 [GET POINTER TO APIA
69=6 LDCT 4 256
69PQ ORS 4 BSUNIT2(1) [SET IN USE BY SYSTEM BIT
6=9B STO 7 BSUNIT5(1) [REMEMBER CSN
6=P2 LDN 4 BCGCOM+BNOENG
6?8L LDX 1 XA1+4(3)
6?N= LDX 5 XA1+8(3) [SWOP OVER BSUNS IN APIAS...
6?TD ... FSHCODE AORB
6#2L ... ANDN 5 #7777 [MASK OUT SHFS BITS
6#7W DEX 5 BSUNIT(1) [AND CLEAR MOVCART MARKERS
6#*4 ...#UNS FSHTEST
6#G= ... ORS 4 BSUNIT3(1) [*** TESTING AID ON ONE M/C ***
6#MG #SKI K6MOVCART>199-199
6*76 (
6*LQ LDX 0 BSUNIT3(1)
6B6B ANDN 0 BCGCOM+BNOENG [CHECK MOVCART MARKERS SET
6BL2 SBN 0 BCGCOM+BNOENG
6C5L BZE 0 X20C
6CK= X20D GEOERR 1,CGAPIABT
6D4W X20C
6DJG )
6F46 ERS 4 BSUNIT3(1)
6FHQ LINT XA1(3),2
6G3B LDN 7 24
6GH2 CALL 6 XBUTT [LET GRUESOME INTERROGATE
6H2L LDX 1 XA1+9(3)
6HG= LDX 5 XA1+3(3)
6HMD ... FSHCODE AORB
6HSL ... ANDN 5 #7777 [MASK OUT SHFS BITS
6H^W DEX 5 BSUNIT(1)
6J74 ...#UNS FSHTEST
6J#= ... ORS 4 BSUNIT3(1) [*** TESTING AID ON ONE M/C ***
6JFG #SKI K6MOVCART>199-199
6J^6 (
6KDQ LDX 0 BSUNIT3(1) [CHECK MOVCART MARKERS SET
6KYB ANDN 0 BCGCOM+BNOENG
6LD2 SBN 0 BCGCOM+BNOENG
6LXL BNZ 0 X20D
6MC= )
6MWW ERS 4 BSUNIT3(1)
6NBG LINT XA1+5(3),2
6NW6 CALL 6 XBUTT [LET GRUESOME INTERROGATE
6P5Y ...TIDYUP
6P*Q FON CARTWAIT [WAKE UP BSAS
6PTB MHUNTW 3,BSTB,CART
6Q*2 FREECORE 3 [FREE CART BLOCK
6QB5 ... FSHCODE AORB
6QC8 ...(
6QD? ... HUNTW 3,BSTB,HORSE
6QFB ... BNG 3 XNOGG
6QGF ... FREECORE 3
6QHJ ...XNOGG
6QR9 ...)
6QRC ... FSHCODE A,XNOPRINB
6QRK ...(
6QRR ... TESTUNPR XNOPRINB [CHECK IF THERE'S A PAIR IN M/C 'B'
6QR^ ... FSHKILL [MURDER IT IF THERE IS !
6QS7 ...XNOPRINB
6QS* ...)
6QSL ENDCOM [COMMIT SUICIDE
6R#= XBUTT DVS 1 7 [CONVERT INTERNAL NUMBER...
6RRW LDCT 5 256 [...FOR BUTTONUP
6S?G SRL 5 0(1)
6SR6 BUTTONUP 5,2
6T=Q EXIT 6 0
6TQB X20 LGEOG 6,4 [GEOGRAPHICAL NO.TO X4
6W=2 X20F DISENGPER 6 [DISENGAGE DEVICE
6WPL X24 JENG 6,X24
6X9= ... CALL 7 XOUTB
6XNW ... CALL 7 XOUTOPNO
6Y8G ... CALL 7 XOUTCSN
7=DL INFORM 1,BMVRONG,1
7=DT ... BRN XWAIT
7=F4 ...# SET UP PARAMETER BLOCK
7=F? ...XOUTB
7=FG ... LDN 0 4
7=FK ... SBX 7 FX1
7=FP ... OUTBLOCK 0
7=FS ... ADX 7 FX1
7=FY ... EXIT 7 0
7=G7 ...# OUTPACK CSN PARAMETER
7=GB ...XOUTCSN
7=GF ... SBX 7 FX1
7=GK ... MHUNTW 3,BSTB,CART
7=GS ... OUTPACK XSER(3),1,CSN
7=GX ... ADX 7 FX1
7=H3 ... EXIT 7 0
7=H= ...# OUTPACK GEOG UNIT NO PARAMETER
7=HF ...XOUTOPNO
7=HJ ... SBX 7 FX1
7=HN ... OUTPACK 4,1,GEOPER
7=HR ... ADX 7 FX1
7=HX ... EXIT 7 0
7=J6 ...#
7=J* ...XDQUIT
7=JJ ... DEMANDQUIT
7=JR ... LONGOFF
7=K2 ... EXIT 7 0
7=K9 ...#
7=KD ...# HERE IF OPERATORS RESPOND TO DEMAND WITH CANTDO.
7=KM ...# I.E. CARTRIDGE COMMAND MUST BE CANCELLED.
7=KW ...#
7=L5 ...XCANTDO
7=L# ... CALL 7 XDQUIT [FREE DEMAND BLOCKS
7=LH ... FSHCODE AORB
7=LQ ...(
7=L^ ... TRANSBEG FSHCGID,MOVCASH,1,BSTB,HORSE,ACOMMUNE1,XUNIMP
7=M8 ... BRN XBERR [ERROR JUMP
7=MC ...XUNIMP
7=ML ...)
7=MT ... MHUNTW 3,BSTB,CART
7=N4 ... LDN 4 2
7=N? ...REPEAT
7=NG ... LDN 6 CGINPROG
7=NP ... LDN 7 BNOENG+BCGCOM
7=NY ... LDX 1 XA1+4(3) [PTR TO APIA
7=P7 ...#UNS FSHTEST
7=PB ... ORS 7 BSUNIT3(1) [*** TESTING IN ONE MACHINE ***
7=PK ... ERS 7 BSUNIT3(1) [UNSET IGNORE ENGAGE EVENTS BIT AN
7=PS ...# [CG IN PROGRESS BIT
7=Q3 ... LDX 2 XA1+2(3) [POINTER TO BSA
7=Q= ... BPZ 2 NOTRES [^ IF NOT UNIT CONTAINING RES
7=QF ... LDCT 7 #400
7=QN ... ORS 7 BSUNIT2(1) [RESET IN USE BY SYSTEM BIT
7=QX ... LDX 1 XA1(3)
7=R6 ... LGEOG 1,7 [PRESERVE GEOG UNIT NO FOR MESSAG
7=R* ... SMO FX2
7=RJ ... STO 7 ACOMMUNE1
7=RR ...NOTRES
7=S2 ...#UNS FSHTEST
7=S9 ... ORS 6 XBSA(2) [*** TESTING IN ONE MACHINE ***
7=SD ... ERS 6 XBSA(2) [UNSET CG IN PROGRESS BIT
7=SM ... LINT XA1(3),2
7=SW ... LDN 7 24
7=T5 ... CALL 6 XBUTT
7=T# ... ADN 3 XREC
7=TH ... BCT 4 REPEAT
7=TQ ... CALL 7 XOUTB
7=T^ ... CALL 7 XOUTCSN
7=W8 ... SMO FX2
7=WC ... LDX 4 ACOMMUNE1
7=WL ... CALL 7 XOUTOPNO
7=WT ... INFORM 1,BMVCANC,1
7=X4 ... BRN TIDYUP
7=^5 ... FSHCODE AORB
7=^Y ...(
7?29 ...XBGONE
7?2G ... FSHACCWK [ RESTORE ACCS AND AWORKS
7?2R ...XBDOWN
7?2W ... LDX 0 GSIGN [
7?2^ ... SMO FX2 [ CLEAR 'NEED TO T/BEG' MARKER
7?34 ... ERS 0 AWORK1 [
7?37 ... VFREEW BSTB,HORSE [ FREE M/C 'B' BLOCK
7?3= ... MFREEW FSH,FSHAMBLES [ AND CLOSEDWN BLOCK
7?3* ... BRN NOWAY [ CARRY ON REGARDLESS !!!
7?3L ...XBERR
7?4F ... MHUNTW 3,BSTB,CART
7?4Q ... LDX 0 GSIGN [SET MKR -VE TO INDICATE X6
7?53 ... ORS 0 6 [ALREADY CONTAINS MESSAGE ADDRESS
7?5# ...XAPIA
7?67 ... HUNTW 2,BSTB,HORSE
7?72 ... BNG 2 XNOH
7?7T ... FREECORE 2
7?8N ...XNOH
7?9H ... LDX 2 XA1+4(3)
7?=B ... LDX 1 XA1+4+XREC(3)
7??9 ...XXCG
7?#4 ... LDN 5 BCGCOM
7?#X ... ERS 5 BSUNIT3(1) [CLEAR CG IN PROGRESS BIT
7?*Q ... ERS 5 BSUNIT3(2) [ " " " " "
7?BK ...)
7?CW XG3
7?XG XINV
7#C6 XINCOM
7#WQ XWRTYP
7*BB XSAME
7*W2 XFILE
7B*L XCG FREECORE 3 [FREE CART BLOCK
7BGS ... LDXC 6 6
7BN2 ... BCS XCG1 [^ IF ALREADY CONTAINS MESSAGE ADDRESS
7BT= ADX 6 FX1
7C#W SMO 6
7CSG LDX 6 0 [ADDRESS OF MESSAGE
7CTK ...XCG1
7CWP ... FSHCODE A,XNOBPR
7CYY ...(
7D37 ... TESTUNPR XNOBPR
7D5B ... FSHKILL
7D7K ...XNOBPR
7D9S ...)
7D#6 COMERRX 6
7DRQ XFIND MHUNTW 2,BSTB,CART [REFIND CART
7F?B EXIT 1 0
7F?N ...XBSW LDEX 4 XA1+1(3)
7F#2 ... CALL 7 XOUTOPNO
7F## ... LDX 6 XWAITSWIT(1) [UNIT WAITING TO BE SW OUT
7F#L ... MHUNTW 3,BSTB,CART
7F#Y ... LDX 0 GSIGN
7F*= ... ORS 0 6
7F*J ... BRN XCG
7F*^ ...QK2MOVCART
7FDJ ...QK3MOVCART
7FH7 ...QK4MOVCART
7FKQ ... GEOERR 1,MOVCASH [CODE NOW IN MOVCASH
7FN* ...XSET GEOERR 1,LONGSET [LONG WAIT FIELDS ALREADY SET
7FR2 XBRKIN GEOERR 1,BRKINOPS
7G=L #
7GQ= MENDAREA 50,K99MOVCART
7H9W #END
^^^^ ...413023650002