{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: MTDUMP860)}}
====== MTDUMP860 ======
(George Source)
**Macros used:** [[george:macro:BS|BS]], [[george:macro:BXU|BXU]], [[george:macro:CHANGEACT|CHANGEACT]], [[george:macro:COOR1|COOR1]], [[george:macro:DCA|DCA]], [[george:macro:FINDACTFB|FINDACTFB]], [[george:macro:FPUT|FPUT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GPERI|GPERI]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2OPT|HUNT2OPT]], [[george:macro:JBC|JBC]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCK|LOCK]], [[george:macro:LONGON|LONGON]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:PAIR|PAIR]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SLEEP|SLEEP]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UP|UP]]
227P ... SEG MTDUMP,860,FILESTORE,INCDUMP
22*D ...#
22H7 ... SEGENTRY K1MTDUMP,X1
22NW ... SEGENTRY K2MTDUMP,X2
22WK ... SEGENTRY K3MTDUMP,X3
234# ... SEGENTRY K4MTDUMP,X4
23=3 ...#
23CQ ...# THIS VERSION OF MTDUMP IS INTENDED FOR USE WITH THE PARALLEL
23KF ...# VERSION OF DUMPER.
23R8 ...#
23YX ...# ENTRY 1 IS USED WHEN A DUMP TAPE ACTIVITY FINISHES POSITIONING
246L ...# ITS TAPE IN RESPONSE TO A DUMPER REQUEST. IT INITIALISES THE DTA.
24#* ...#
24G4 ...# ENTRY 2 IS ENTERED BY THE DUMPER CPAT WHEN A NONAUTONOMOUS TRANSFER
24MR ...# IS TO BE CARRIED OUT. ON ENTRY ACOMMUNE1=MODE, 2=COUNT, 3=CTSA.
24TG ...#
2539 ...# ENTRY 3 IS AS FOR ENTRY 2 EXCEPT THAT THE TRANSFER IS TO BE AUTONOMOU
258Y ...#
25BM ...# ENTRY 4 IS WHAT THE K2+3 ENTRIES LEAVE THE DTAS LINKSET TO. IT
25JB ...# INFORMS THE CPAT OF THE END OF TRANSFER, AND SETS BITS 0-1 OF THE
25Q5 ...# INCACT WORD IN THE SELECTED FINC TO INDICATE THE OCCURRENCE OF FAILS
25XS ...# AND EOT OR TM RESPECTIVELY
265H ...#
26?= ...X4ENT
26D^ ... PAIR MTDUMP,4
26LN ...#
26SC ...# THE FOLLOWING SUBROUTINE SETS X3-> CURRENTLY SELECTED FINC BLOCK.
2726 ...# ON ENTRY X3->BLOCK FROM WHICH TO SEARCH.
277T ...XLOCFINC
27*J ... SMO FX2
27H? ... STO 0 ACOMMUNE4
27P2 ... HUNT2 3,FILE,FINC
27WP ... JBC NPLL,,BFILEINC
284D ... HUNT2 3,FILE,FINC
28=7 ...NPLL
28CW ... SMO FX2
28KK ... LDX 0 ACOMMUNE4
28R# ... EXIT 0 0
28^3 ...#
296Q ...#
29#F ...X1
29G8 ... STOZ AWORK1(2) [MARKER WORD TO REMEMBER FAILS
29K3 ... LONGON FGOTWAIT [ WAKE UP DUMPER
29MX ...SCOOR COOR1
29TL ... GEOERR BRIEFPM,DTA FPUT [DONT EXPECT TO BE WOKEN FROM THIS
2=3* ... [COOR.
2=94 ...#
2=BR ...#
2=JG ...X4
2=Q9 ...#SKI K6MTDUMP>499-499
2=XY ...(
2?5M ...#
2??B ...# THIS CODE IS USEFUL FOR TESTING. IT SIMULATES EOT IF THE FIRST
2?F5 ...# ENT BLOCK ENCOUNTERED IN THE ACT CHAIN AFTER THIS ACT IS FOR A FILE
2?LS ...# 'ZZZZ22220000' (NOTE THAT THIS ALWAYS COMES LAST IN ANY DIRECTORY.
2?SH ...#
2#2= ... LDX 3 2
2#7^ ... FINDACTFB 3,,CPAT,,,FPTR
2#*N ... HUNT2OPT 3,FILE,ENT
2#HC ... BNG 3 NOPE
2#P6 ... LDX 0 XEOT(1)
2#WT ... BXU 0 ELOC1(3),NOPE
2*4J ... LDX 0 XEOT+1(1)
2*=? ... BXU 0 ELOC2(3),NOPE
2*D2 ... LDX 0 XEOT+2(1)
2*KP ... BXU 0 ELOC3(3),NOPE
2*RD ... BS 2,BRWEOT
2*^7 ... BRN NOPE
2B6W ...XEOT 12HZZZZ22220000
2B#K ...NOPE
2BG# ...)
2BN= LDCT 6 #060
2C7W ANDX 6 CPRW1(2)
2CMG SLL 6 3 [GET FAIL AND EOT BITS FOR THIS WRITE
2C^* ... STO 6 AWORK1(2) [KEEP REPLY
2F6B FINDACTFB 3,2,CPAT,,,FPTR [FIND DUMPER'S ACT. (1ST CPAT ALONG C
2FL2 LDX 4 3 [X4-> DUMPER'S ACT.
2G5L ... CALL 0 XLOCFINC [X3-> DUMPER'S FINC BLOCK
2GK= ORS 6 INCACT(3) [TRANSFER BITS 3-4 OF REPLY TO BITS
2H4W [B 0-1 OF INCACT
2HJG LDEX 0 INCACT(3) [ COUNT OF CURRENTLY ACTIVE
2J46 [DUMPER PROCESSES (DUMPER+DTA'S)
2JHQ SBN 0 1 [REDUCE COUNT
2K3B DEX 0 INCACT(3) [PUT IT BACK
2KH2 ... BNZ 0 SLEEP [J IF NOT LAST DTA
2L2L [OR DUMPER STILL GOING
2LG= LDX 2 4
2L^W FPUT [WAKE UP DUMPER
2MFG ...SLEEP
2M^6 UNLOCK 2 [UNLOCK THIS DTA
2NDQ BRN SCOOR
2NYB ...#
2PD2 ...#
2PXL ...X2
2QC= ... STOZ AWORK1(2) [SHOW NONAUT ENTRY
2QWW ...PERIS
2RBG ... LDX 3 FX2
2RW6 ... CALL 0 XLOCFINC [X3->FINC
2S*Q ... LDN 0 1
2STB ... ADS 0 INCPERIS(3) [UPDATE COUNT OF ISSUED PERIS
2T*2 ... LDX 5 ACOMMUNE1(2)
2TSL ... LDX 6 ACOMMUNE2(2)
2W#= ... LDX 7 ACOMMUNE3(2)
2WRW ... LDX 4 INCCOPIES(3) [NO OF TAPES
2X?G ... SLL 4 1 [LENGTH OF WORDS IN TAPELIST
2XR6 ... LDN 0 1
2Y=Q ... DEX 0 INCACT(3) [SET 1 IN COUNT OF RUNNING ACTS
2YQB ... [FOR DUMPER CPAT, IN CASE DTAS
2^=2 ... [FINISH BEFORE WE GO TO SLEEP
2^PL ...NEXTACT
329= ... FINDACTFB 2,,ACTDOC,ADUMPT,,BPTR
32NW ... LDX 0 ADTSN(2) [PICK UP TSN OF NEXT BLOCK ALONG
338G ... SMO 4 [J IF NOT DTA ON OUR LIST
33N6 ... BXU 0 FGETSER-FGETLEN(3),NEXTACT
347Q ... LDX 0 AWORK1(2) [IGNORE IT IF ITS A FAILED TAPE
34MB ... BNG 0 YFAILED
3572 ... LDN 0 1
35LL ... ADS 0 INCACT(3) [INCREMENT RUNNING ACT COUNT
366= ... CHANGEACT 2 [CHANGE TO DTA TO ISSUE PERI
36B4 ... LOCK 2 [LOCK DOWN THIS DTA. CANT USE LOCKC
36KW ... [IN THESE CIRCS UNTIL CENT BUG
36TN ... [2231 FIXED
375G ... LDX 1 CPPTR(2) [X1-> DEVLIST ENTRY
37K6 ... DCA 1,STO,5,MODE
384Q ... DCA 1,STO,6,COUNT
38JB ... DCA 1,STO,7,CTSA [DETAILS SET UP
3942 ... GPERI ,2 [ISSUE PERI
39HL ... LDX 1 FX1
3=3= ... LINKSET 2,X4ENT(1) [ENSURE ACT WAKES UP ON X4 ENTRY
3=GW ... FINDACTFB 2,,CPAT,,,FPTR [LOCATE DUMPER CPAT
3?2G ... CHANGEACT 2 [CHANGE BACK TO IT
3?G6 ...YFAILED
3?^Q ... LDX 2 FX2
3#FB ... LDX 3 2
3#^2 ... CALL 0 XLOCFINC [X3->FINC
3*DL ... SBN 4 FGETLEN [DECR NO OF WORDS IN TSN LIST TO
3*Y= ... [LOOK AT
3BCW ... BNZ 4 NEXTACT [CARRY ON WITH LOOP IF MORE
3BXG ... LDX 0 AWORK1(2)
3CC6 ... BNZ 0 UP [GO UP IN NONAUT TRANS
3CWQ ... LDEX 0 INCACT(3) [DECR COUNT OF RUNNING ACTS
3DBB ... SBN 0 1
3DW2 ... DEX 0 INCACT(3)
3F*L ... BZE 0 UP
3FT= ... COOR1 [SLEEP TILL DTAS WAKE US
3G#W ...UP UP
3GSG ...#
3H#6 ...#
3HRQ ...#
3J?B ...X3
3JR2 ... LDN 0 1
3K=L ... STO 0 AWORK1(2)
3KQ= ... BRN PERIS
3L9W ...#
3LPG ...#
3M96 ... MENDAREA 20,K99MTDUMP
3MNQ ...#
3N8B ...#END
^^^^ ...01532407000300000000