{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: NEWINST867)}}
====== NEWINST867 ======
(George Source)
**Macros used:** [[george:macro:APPEND|APPEND]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:CREATEB|CREATEB]], [[george:macro:CURTAIL|CURTAIL]], [[george:macro:DELETE|DELETE]], [[george:macro:FASTREWIND|FASTREWIND]], [[george:macro:FSHTEST|FSHTEST]], [[george:macro:GEOERR|GEOERR]], [[george:macro:INST|INST]], [[george:macro:MBS|MBS]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:MOVLONG|MOVLONG]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]]
22FL #LIS K0NEWINST>K0ALLGEO
22^= #SEG NEWINST82 [OWEN N. JOHN
23DW 8HNEWINST
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23YG [
24D6 SEGENTRY K1NEWINST,START
24XQ [
25CB [ THIS SEGMENT CHECKS FOR THE EXISTENCE OF :SYSTEM.PARAMINDEX(G4)
25X2 [ IF IT EXISTS AND THE FOLLOWING CONDITIONS ARE NOT TRUE THEN
26BL [ NO ACTION IS TAKEN.
26W= [ A)RESTORE FROM INCREMENT 1 (WORD JINCLAST IN FIXED
27*W [ B)WE HAVE WRONG VERSION NO. (WORD IPVERNO
27TG [ C)FILE DOES NOT EXIST
28*6 [ D)FILE EXISTS BUT CANNOT BE ACCESSED
28JY ...[ E)FILE EXISTS BUT IS EMPTY
28SQ [
29#B [ IF ANY OF THE ABOVE ARE TRUE THE FILE IS RECREATED
29S2 [ IF B) WE TRY TO PRESERVE CHANGES IN THE CURRENT VAL.
2=?L [
2=DS ...#DEF XCONTEXT =+JCONTEXTA+JCONTEXTB+JCONTEXTC [MAX CONTEXT
2=L2 ...[
2=R8 ...[ THE MAX TRACE VALUE MUST INCLUDE FORCEPRINT (EXCEPT OPTRACE)
2=YB ...[ BUG 2533
2?5J ...[ DONE 15TH APRIL 75 :CENT
2?=Q ...[
2?CY ...#DEF TRACEMAX=+ALLBITS^(1@L(23-CBFORCEPRI)) [TRACE ALL FOR JOB/MOP
2?K6 ...#DEF OPTRAMAX = +ALLBITS [NO FORCEPRINT FOR OPTRACE
2?QG #DEF NOCHECK=AWORK1 [THIS IS PURE CODE !!
2#=6 #DEF TRACEMIN=1@L(23-CBLOGGING) [LOGGING FOR JOB/MIN TRACE-OTHERS NON
2#PQ #DEF TERMPARA=AWORK2
2*9B XMESS +IPDEFAULT [ALL IP S SET TO DEFAULT:PLSE RUN IPE
2*P2 #PAGE
2B8L [
2BN= [ *** TABLE OF INSTALLATION PARAMETERS
2C7W [
2CMG [
2D76 [ IPNAME IPMAX IPMIN FIXED-CORE
2DLQ [ (PARAMETER * (MAX * (MIN * NAME/
2F6B [ NAME) VALUE) VALUE) ADDRESS
2FL2 [
2G5L [
2GK= SEGENTRY IPTABLE
2H4W NEWREC +RECLEN
2HJG +IPVERNO
2HPN ...#UNS ECS
2HWW ... INST BACKCP , 60, 1, BACKCP
2J46 INST BACKGROUND , 1, 0, BACKGROUND
2JHQ INST BACKJAM , 99, 50, BSJAM
2K3B INST BACKJOBS , 1, 0, BACKJOBS
2KH2 INST BACKTHRESH , 50, 0, BACKTHRESH
2L2L INST BSINTERVAL , 8388607, 0, IDEALJAM
2LG= INST CHAPTERQUOTA, 0, 0, CHAPQUOTA
2LJT ...#UNS ECS
2LMD ...(
2LQ3 ... INST CLUSBACKCP , 60, 1, CLUSBACKCP
2LSL ... INST CLUSMOPCP , 60, 1, CLUSMOPCP
2LX9 ...)
2L^W INST CLUSTERBACK , 0, 0, CLUSTERBACK
2MFG INST CLUSTERMOP , 0, 0, CLUSTERMOP
2M^6 INST CONTEXT , XCONTEXT, 0, ICONTEXT
2NDQ INST COREOBJECT , 5120, 0, AOBJCORES
2NYB INST CPIRATIO , 500, 100, CPIRATIO
2PD2 INST DATE , 1440, 1, ADINT
2PXL INST DATINTERVAL , 8388607, 1, CDATINT
2QC= INST DEFAULTBS , 10000, 10, IDEFBS
2QWW INST DUMPTAPES , 3, 1, AINCCOPIES
2RBG INST DUMPTIME , 2000, 0, ADUMPTIME
2RW6 INST FORMULA , 1000000, 0, FORMULA
2S*Q INST HLSREVIEW , 20, 1, HLSREVIEW
2STB INST HOLDUP , 10000, 1, HOLDUP
2T*2 INST IDIV , 100, 1, IDIV
2TSL INST IMULT , 100, 0, IMULT
2W#= INST IPAGE , 50, 1, IPAGE
2WRW #SKI IPL
2X?G INST IPLIMIT ,IPLMAXDEF, 0, IPLIMIT
2XR6 INST JOBLIMIT , 2, 0, JOBLIMIT
2Y=Q INST JOBTIME , 3600, 50, JOBTIME
2YQB INST JOBTRACE , TRACEMAX, TRACEMIN, JOBTRACE
2^=2 INST L , 8388607, 0, IMIN
2^C8 ... INST LPSTIME , 2000, 0, INIPTIME
2^JB ... INST LPSVALUE ,#37777777, 0, INIPCONTROL
2^PL INST MANAGER0 , 8388607, 0, 0+INSTPARAM
329= INST MANAGER1 , 8388607, 0, 1+INSTPARAM
32NW INST MANAGER2 , 8388607, 0, 2+INSTPARAM
338G INST MANAGER3 , 8388607, 0, 3+INSTPARAM
33N6 INST MANAGER4 , 8388607, 0, 4+INSTPARAM
347Q INST MANAGER5 , 8388607, 0, 5+INSTPARAM
34MB INST MANAGER6 , 8388607, 0, 6+INSTPARAM
3572 INST MANAGER7 , 8388607, 0, 7+INSTPARAM
35LL #SKI G4
366= INST MAXQUOTA , 5120, 0, AMAXQUOTA
36KW INST MESSAGETIME , 400, 1, ASYSTEMMESS
375G INST MINTRACE , TRACEMAX, TRACEMIN, IMINTRACE
37=N ...#UNS ECS
37CW ... INST MOPCP , 60, 1, IMOPCP
37K6 INST MOPCPI , 100, 0, IMOPCPI
384Q INST MOPJOBS , 1, 0, IMOPJOBS
38JB INST MOPLIMIT , 1, 0, IMOPLIMIT
38PJ ...#SKI JWPHASE3
38WQ ... INST MOPTOTAL , 8388607, 0, IMOPTOTAL
393Y ... INST MOPTRACE , TRACEMAX, 0, IMOPTRACE
3996 ...#SKI JSKI37
39B# ... INST MOPWAITTIME ,#37777777, 0, IPMOPWAIT
39HL INST OBJECTQUOTA , 0, 0, COBJQUOTA
3=3= ... INST OPTRACE , OPTRAMAX, 0, IOPTRACE
3=8D ...#UNS ENHOPER
3=*L ... INST PAGEWAIT , IPWMAX, IPWMIN, IPAGEWAIT
3=GW INST PERFWAIT , 8388607, 10, APERFWAIT
3?2G INST PROGTIME , 600, 1, IPROGTIME
3?G6 INST RELOAD , 1, 0, ARELOAD
3?^Q INST REPORTTIME , 8388607, 1, IPROGREP
3#FB INST SIZEDEFAULT , 5120, 0, COREDEFAULT
3#^2 INST SLOTTIME , 32767, 10, ASLOTTIME
3*DL INST TIME , 1440, 1, ATINT
3*Y= INST VOLUME , 8388607, 1, AZVOLUME
3BCW INST WAITTIME , 90, 0, AWAITEND
3BXG INST WAITWEIGHT , 500, 100, IK
3BY2 ...#UNS FSHTEST
3BYG ...#SKI
3CC6 #DEF RECLEN=0?-NEWREC
3CWQ #PAGE
3DBB [
3DW2 [
3F*L XBRK GEOERR 1,EMSBRKIN [BREAK-IN ON OPENING PARAMINDEX(G4).
3FH= ...START
3G9Q ... STOZ TERMPARA(2)
3G#W LDN 5 1
3GSG STO 5 NOCHECK(2) [SETTING INITIAL VALUES
3H#6 OPENSYS XBRK,PARAMINDEX,GENERAL,QUERY,NOWAIT
3HRQ [
3J?B [ FIRST ACTION IS TO ATTEMPT TO OPEN PARAMINDEX(G4)
3JR2 [
3K=L [ WE NOW TEST REPLIES **
3KQ= TESTREP OK,OKAY [SUCCESS? IF YES GO TO OKAY
3L9W TESTREP NOFILE,XFAIL [DOESNOT EXIST? IF YES GO TO XFAIL
3LPG TESTREP MAG,OFFLN [OFFLINE? IF YES GO TO OFFLN
3M96 [
3MNQ [ OH-OH!! SOMETHINGS WRONG! WE ARE UNABLE TO CONTINUE SO GEOERR
3N8B [
3NN2 SFAIL GEOERR 1,IPOPFAIL
3P7L [
3PM= [ OKAY THE FILE IS OFFLINE - SO WE EMPTY IT AND RECREATE USING
3Q6W [ TABLE IN NEWINST
3QLG [
3R66 OFFLN OPENSYS XBRK,PARAMINDEX,GENERAL,EMPTY
3RKQ BRN XCONT [OFF WE GO TO TEST REPLY
3S5B #SKI K6NEWINST>200-200
3SK2 ... TRACE EXEC3(2),OFFLINE
3T4L [
3TJ= [ THE FILE DOESNOT EXIST SO WE CREATE A DIRECTORY ENTRY
3W3W [
3WHG XFAIL CREATEB 3 [CREATE A FILE/CREATE BLOCK-ADD IN X3
3X36 MBS 3,CESERIAL,CECARE [SET -- THIS IS A SERIAL FILE
3XGQ [ -- UPDATE CAREFULLY
3Y2B MBS 3,CEONLINE,CEALLINCS[SET -- KEEP ONLINE
3YG2 [ -- DUMP ON ALL INCREMENTS
3Y^L #SKI K6NEWINST>200-200
3^F= ... TRACE EXEC3,NOTEXIST
3^YW OPENSYS XBRK,PARAMINDEX,GENERAL,CREATE
42DG XCONT TESTREPN OK,SFAIL [IF IT IS NOT OKAY -- WE GEOERR
42Y6 XINC MONOUTX XMESS(1) [O?P DEFAULT MESSAGE
43CQ BRN XAPPD [NOCHECK SET FOR NO CHECK
43XB [OFF NOW TO APPEND RECORD
44C2 [
44WL [ SO WE HAVE MANAGED TO OPEN PARAMINDEX WITH NO PROBLEMS
45B= [
45L4 ...OKAY STEP [READ THE ONE + ONLY RECORD
45TW ... BZE 3 XINC [FTLE IS EMPTY SO APPEND
465N ... LDX 5 JINCLAST [INC NO. OF LAST RESTORE
46*G #SKI K6NEWINST>200-200
46T6 ... TRACE JINCLAST,ALLOKAY
47#Q NGS 5 NOCHECK(2) [NEGATE TO INDICATE A DELETE-NOCHECK
47SB SBN 5 1 [IF IT WAS INC 1 : X5=0
48RL BZE 5 XINC [JUMP IF INC 1 & WE JUST APPEND
49?= LDX 5 IPVERSION-A1(3) [LOAD VALUE OF IPVERNO HELD IN FILE
49DD ...#SKI K6NEWINST>200-200
49KL ... TRACE 5,IPVERNO
49QW STOZ NOCHECK(2) [WE MUST CHECK IF VERSION NO.S WRONG
4==G SBN 5 IPVERNO [SUBTRACT FIXED CORE VERSION NO
4=CN ...#UNS IPEXTENSION+1*IPEXTENSION
4=JW ... SBX 5 GSIGN [FORCE JUMP IF DIFFERENT FORMATS
4=Q6 BNZ 5 XAPPD [JUMP IF VERSION NO. NOT EQUAL
4?9Q #SKI K6NEWINST>200-200
4?PB ... TRACE 5,FINISHED
4#92 CLOSETOP [HOME+DRY WITH NO EFFORT
4#NL UP [UP UP AND AWAY
4*8= [
4*MW [ SOMETHING IS WRONG SO WE MUST RECREATE BY APPENDING
4B7G [
4BM6 XAPPD SETNCORE RECLEN,4,FILE,FAPB [SET UP A FILE APPEND BLOCK:ADD IN X3
4C6Q [RECLEN = LENGTH OF PARAMINDEX
4CLB LDN 3 NEWREC(1) [START ADDR. OF TABLE IN NEWINST
4D62 ADN 4 A1 [START ADDR. OF FILE/FAPB +A1
4D89 ...#UNS IPEXTENSION+1*IPEXTENSION
4D=D ...(
4D#M ... LDN 0 RECLEN [NUMBER OF WORDS IN IP TABLE (>512?)
4DBW ... MOVLONG 3,4,0 [MOVE TABLE INTO FILE/FAPB
4DF5 ...)
4DH# ...#UNS IPEXTENSION-1
4DKL MOVE 3 RECLEN [MOVE TABLE INTO FILE/FAPB
4F5= LDX 5 NOCHECK(2) [SEE IF WE MUST COMPARE WITH PREVIOUS
4FJW BNG 5 XEOB [DELETE IS REQUIRED
4G4G BNZ 5 XSKIP [ PARAMINDEX - ONLY IF NOCHECK=0
4GJ6 #PAGE
4H3Q [
4HHB [ IF WE GET HERE WE MUST COMPARE NEW AND OLD VERSIONS OF PARAMINDEX
4J32 [
4JGL #SKI K6NEWINST>200-200
4K2= ... TRACE NOCHECK(2),COMPARE
4KFW STEPAGAIN [BACK TO START OF PARAMINDEX
4K^G MHUNTW 2,FILE,FAPB [LOOK FOR FILE/FAPB IN CASE WE COORD
4LF6 LDX 1 FX2 [PUT FX2 IN X1 -- SORRY I AM PUSHED
4LYQ [
4MDB [ WE ARE NOW GOING TO SET UP THE ACCUMULATORS IN A SPECIAL WAY
4MY2 [ WHERE TO CONTENTS ARE AS FOLLOWS
4NCL [
4NX= [ OLD FILE/FAPB
4PBW [ PARAMINDEX BLOCK
4PWG [
4QB6 [ START ADDRESS : X3 X6
4QTQ [
4R*B [ MAX ADDRESS : TERMPARA X4
4RT2 [
4S#L [ RUNNING POSIT : X3 X2 (WE DO NOT HAVE TO
4SS= [ (KEEP START OF POS
4T?W [ VALUE OF BLOCK IPVAL : X7 (IN OLD PARAMINDEX
4TRG [
4W?6 [ WORDS OF BLOCK IPNAME : X5 (1ST WORD OTHER 2 IN X0
4WQQ [
4X=B [ VALUE OF FX2 IS KEPT IN: X1
4XQ2 [
4Y9L [
4YP= [ NOTE:
4^8W [ IN WRITING THE FOLLOWING IT IS REQUIRED THAT THE OLD
4^NG [ AND NEW ARE COMPARED BY USING IPNAME AND NOT
5286 [ BY USING IPNUM (WHY?? JE NE SAIS PAS !!
52MQ LDX 6 2 [PUT START ADDR OF FILE/FAPB IN X6
537B SBN 6 IPLINE
53?? ...#UNS IPEXTENSION+1*IPEXTENSION
53C8 ... LDX 4 IPHEAD(2) [PUT RECORD LENGTH IN X4
53H5 ...#UNS IPEXTENSION-1
53M2 LDEX 4 IPHEAD(2) [PUT RECORD LENGTH IN X4
546L ADX 4 6 [SO OBTAINING ADDR OF END OF BLOCK
5499 ...#UNS IPEXTENSION
54?S ...(
54BC ... LDX 0 IPVERSION-A1(3)
54F2 ... BNG 0 XAGNNEW [J IF PARAMINDEX IN EXTENSION FORMAT
54HK ...)
54L= LDEX 5 IPHEAD-A1(3) [PUT RECORD LTN OF OLD PARA IN X5
5656 SBN 3 IPLINE [TO AVOID JUMPS WE SUBTRACT IPLINE
56=# ADX 5 3 [SO OBTAIN END ADDR. OF OLD PARA
56CG STO 5 TERMPARA(1) [STORE END ADDR OF OLD PARAMINDEX
56G^ ...XAGN
56LD ...#UNS IPEXTENSION
56PX ... BNG 3 XAGNNEW [J IF IP IN EXTENSION TABLE
56TB ... ADN 3 IPLINE [UPDATE POINTER OF OLD PARA
56YT ...#UNS IPEXTENSION<1$1
574B BXGE 3 TERMPARA(1),XEOB [WHEN WE REACH END OF OLD PARA JUMP
575C ...#UNS IPEXTENSION
576D ...(
577F ... SMO FX2
578G ... TXL 3 TERMPARA
579H ... BCC XEOB [J IF REACHED END OF OLD PARAMINDEX
57=J ... BRN VALUE
57?K ...XAGNNEW
57#L ... STEP [READ NEXT RECORD
57*M ... BZE 3 XEOB [J IF REACHED END OF FILE
57BN ... SBN 3 IPNAME-IPHEAD-1 [PTR TO IPHEAD-1
57CP ... LDCT 0 #400
57DQ ... ORX 3 0 [SET 'EXTENSION TABLE FORMAT' BIT
57FR ...VALUE
57GS ...)
57J2 LDX 7 IPVAL-A1(3) [LOAD VALUE OF IP
57NN ...[
57TB ...[ THE FOLLOWING LINES HAVE BEEN ALTERED DUE TO G5456(B O878)
5824 ...[ THIS IS TO ENABLE NEWINST TO CARRY OVER ANY CHANGES
586Q ...[ TO IP NAMES(E.G. BY IPEDIT)ON RE-CREATING PARAMINDEX(G4)
58?D ...[ THIS IS DONE BY COMPARING IPNUM INSTEAD OF IPNAME(3 WORDS)
58D6 ...[
58JS ...[ DONE 3.SEPT.74 (:CENT)
58PG ...[
58W8 ... LDX 5 IPNUM-A1(3) [LOAD LOCATION OF IP IN FIXED
58YH ...#UNS IPEXTENSION<1$1
592W LDX 2 6 [RESET X2 TO START OF FAPB
595F ...#UNS IPEXTENSION
5984 ...(
59=M ... MHUNT 2,FILE,FAPB [PTR TO FILE/FAPB BLOCK
59*= ... SBN 2 IPLINE
59CT ...)
59GG XFBL ADN 2 IPLINE [UPDATE POINTER
5=26 BXGE 2 4,XAGN [JUMP WHEN END OF FAPB IS REACHED
5=6J ... BXU 5 IPNUM(2),XFBL [JUMP IF TWO NUMBERS NOT EQUAL
5=?2 ...[
5=CD ...[ WE NOW HAVE A MATCH SO WE MERELY HAVE COPY ACROSS THE NAME
5=HW ...[
5=N# ... LDX 0 IPNAME-A1(3) [FIST WORD
5=SQ ... STO 0 IPNAME(2) [STORE IN NEW PARAMINDEX
5=^B LDX 0 IPNAME-A1+1(3) [REPEAT FOR 2ND WORD OF IPNAME
5?F2 ... STO 0 IPNAME+1(2) [STORE THE SECOND
5?YL LDX 0 IPNAME-A1+2(3) [AND FOR THE THIRD
5#D= ... STO 0 IPNAME+2(2) [STORE THE LAST
5#XW [
5*CG [ IF WE GET HERE WE HAVE A MATCH
5*X6 [
5*^8 STO 7 IPVAL(2) [PUT OLD VALUE INTO FAPB
5B3= [
5B5# [ THE FOLLOWING 4 LINES WHERE INSERTED TO CORRECT
5B7B [ BUG 0585 (G 5395).
5B9D [ THIS RESULTS IN NEWINST82 PASSING OVER THE MAX & MIN
5B?G [ VALUES AS WELL AS THE CURRENT VALUE WHEN IT
5B*J [ RE CREATES PARAMINDEX(G4).
5BCL [ DONE 17.JULY.74 :CENT
5BFN [
5BHQ LDX 0 IPMAX-A1(3)
5BKS STO 0 IPMAX(2) [FIRST THE MAX VALUE
5BMW LDX 0 IPMIN-A1(3)
5BPY STO 0 IPMIN(2) [THEN THE MIN VALUE
5BS2 [
5BWB #SKI K6NEWINST>200-200
5CB2 ... TRACE 7,MATCH
5CTL BRN XAGN [BACK TO DO NEXT IP
5D*= #PAGE
5DB9 ...XEOB
5DC8 ...#UNS IPEXTENSION
5DD7 ...(
5DF6 ... FASTREWIND 3 [REWIND TO START OF FILE
5DG5 ... LDN 3 0
5DH4 ... CURTAIL 3
5DJ3 ...)
5DK2 ...#UNS IPEXTENSION
5DK^ ...#SKI
5DLY ... DELETE [REMOVE RECORD IN OLD PARAMINDEX
5DMX ...XSKIP
5DNW ...#UNS IPEXTENSION+1*IPEXTENSION
5DPT ...(
5DQS ... STEP ,2 [RENAME /FURB TO /FUWB
5DRR ... LDN 0 2 [2 WORDS IN FIRST RECORD
5DSQ ... STO 0 0(3) [HEADER OF FIRST RECORD
5DTP ... MHUNTW 2,FILE,FAPB [PTR TO FILE/FAPB BLOCK
5DWN ... LDX 0 IPVERSION(2) [VERSION NUMBER OF PARAMINDEX
5DXM ... ORX 0 GSIGN [SET 'EXTENSION TABLE FORMAT' BIT
5DYL ... STO 0 1(3) [STORE AS FIRST RECORD
5D^K ... LDN 7 2
5F2J ...XLOOP
5F3H ... STEP ,IPLINE+1 [RENAME NEXT FILE/FURB TO FILE/FUWB
5F4G ... MHUNTW 1,FILE,FAPB [PTR TO FILE/FAPB BLOCK
5F5F ... LDN 0 IPLINE+1
5F6D ... STO 0 0(3) [SETUP RECORD HEADER
5F7C ... ADN 3 1 [PTR TO START OF RECORD ENTRY
5F8B ... SMO 7
5F9* ... LDN 2 IPNAME-2(1)
5F=# ...#SKI K6NEWINST>300-300
5F?? ... TRACE 2,EXTIPWRI
5F#= ... MOVE 2 IPLINE [MOVE IP DETAILS
5F*9 ... ADN 7 IPLINE [UPDATE POINTER
5FB8 ... BXL 7 ALOGLEN(1),XLOOP [J IF STILL MORE TO WRITE
5FC7 ...)
5FD6 ...#UNS IPEXTENSION-1*IPEXTENSION
5FF5 ...(
5FG4 ... MHUNT 3,FILE,FAPB [PTR TO FILE/FAPB BLOCK
5FH3 ... LDX 0 GSIGN
5FJ2 ... ORS 0 A1+1(3)
5FJ^ ... ERS 0 A1+1(3) [ENSURE 'EXTENSION TABLE' BIT UNSET
5FKY ... APPEND [APPEND OUR FAPB BLOCK.
5FLX ...)
5FMW ...#UNS IPEXTENSION
5FNT ...#SKI
5FPS ... APPEND [APPEND OUR FAPB BLOCK
5FS6 CLOSETOP [CLOSE PARAMINDEX
5G?Q MFREE FILE,FAPB [RELEASE FILE/FAPB BLOCK
5GRB #SKI K6NEWINST>200-200
5H?2 ... TRACE NOCHECK(2),ENDOFSEG
5HQL UP [UP UP AND AWAY !!
5J== #END
^^^^ ...36530721000300000000