{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: NEWPASSW867)}}
====== NEWPASSW867 ======
(George Source)

**Macros used:** [[george:macro:CJOBLOCK|CJOBLOCK]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERR|COMERR]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:HUNT|HUNT]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTPARN|OUTPARN]], [[george:macro:READDICT|READDICT]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SINM551|SINM551]], [[george:macro:SINMAC1|SINMAC1]], [[george:macro:SPARAPAS|SPARAPAS]]

<code - NEWPASSW867.txt>22FL    #LIS           K0NEWPASSW>K0ALLGEO>K0GREATGEO>K0COMMAND 
22J9 ...      SEG      NEWPASSW,867,SECTION CENT,,G3UGSI
22LS ...#OPT  G3UGSI=0  
22PC ...#SKI  G3UGSI
22S2 ...(   
22WK ...# MACRO TO PREVENT M551 AND SECURITY INTERFACE CLASH
22^8 ...      SINM551   
233R ...)   
236B ...[   
238^ ...[ (C)  COPYRIGHT INTERNATIONAL COMPUTERS LIMITED  1982  
23?J ...[      THIS EXCLUDES CODE UNDER #SKI G3UGSI 
23B7 ...[   
23DW    #   
23YG    #           THIS SEGMENT IMPLEMENTS THE NEWPASSWORD COMMAND  RESETTING T
24D6    #           USER'S PASSWORD IN HIS DICTIONARY ENTRY TO THE VALUE SPECIFI
24XQ    #   
25X2    #   
26BL ...      SEGENTRY K1NEWPASSW   
26W=    #   
273D ...[   
278L ...[   
27*W ...#   
27TG ...      SETNCORE 3,3,FILE,ADICT   
2*9B          CJOBLOCK 2
2*P2          LDN   4  JUSER(2) 
2B8L          LDN   5  A1(3)
2BN=          MOVE  4  3                   [STO USERNAME IN FILE, ADICT 
2C7W ...      OPENSYS  XBRK,DICTIONARY,GENERAL  [OPEN DICTIONARY
2H4W          READDICT  
2HJG          SPARAPAS                     [GET NEW PASSWORD
2JHQ          HUNT     2,CPB,CUNI   
2JMM ...      LDX   5  ACES                [SPACEFILL SPACE FOR PASSWORD
2JRJ ...      LDX   6  ACES 
2JXF ...      LDX   7  ACES 
2K3B          LDX   4  ANUM(2)  
2KH2          BNG   4  XNEG                [NO PASSWORD 
2L2L          BZE   4  XNEG                [NULL PASSWORD   
2LG=          ANDN  4  #7777               [NO. OF CHARS IN NEW PASSWORD
2L^W ...      LDN   0  12   
2MFG ...      SBX   0  4                   [X0=12-NO. OF CHARS IN NEW PASSWORD  
2M^6 ...      BPZ   0  PWCPY               [BRN IF NO. OF CHARS NOT >12 
2NDQ          LDN   4  12                  [DON'T WANT >12 CHARS
2NYB    PWCPY LDN   1  APARA(2) 
2PD2 ...      LDN   2  5
2PXL    XLP   LDCH  0  0(1) 
2QC=          SBN   0  #25  
2QWW          BZE   0  THING
2RBG          MVCH  1  1
2RW6          BCT   4  XLP  
2S*Q ...XNEG
2STB ...#SKI  G3UGSI<1$1
2T*2 ...      SINMAC1  5                   [SECURITY INTERFACE MACRO
2TBY ...[   
2TDW ...#SKI  G3UGSI
2TGS ...(   
2TJQ ...[     COMPILED IF USER GROUP SECURITY INTERFACE SWITCHED ON 
2TLN ...      SINMAC1  5,,3 
2TNL ...)   
2TQJ ...[   
2TSL ...      MHUNTW   3,FILE,ADICTENT  
2W#= ...      LDN   2  5                   [MOVE NEW PASSWORD INTO ADICTENT BLOC
2WRW ...      ADN   3  CPASS
2X?G ...      MOVE  2  3
2XR6 ...      SBN   3  CPASS
2Y=Q ...      NAME     3,FILE,FWB   
329=          REWRITE                      [OVERWRITE LAST ENTRY READ   
32HM ...      MFREEW   FILE,FWB 
32W4 ...      CLOSETOP                     [CLOSE DICTIONARY
338G          ENDCOM
33N6    XBRK  COMBRKIN                     [BROKEN IN   
347Q ...THING CLOSETOP                     [CLOSE THE DICTIONARY
34MB          LDN   0  #25                 [% CHAR  
3572          DCH   0  ACOMMUNE1(2) 
35LL          OUTPARN  1,ACOMMUNE1  
366=          COMERR   HNOPC               [ERROR IF % CHAR IN PARAM
36KW          MENDAREA 20,K99NEWPASSW   
375G    #END
^^^^ ...21266735000200000000
</code>