{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: OLPMACROS)}}
====== OLPMACROS ======
(George Source)
22FL [
22^= [ TONY HAMILTON
23DW [
23YG [ MACROS AS FOLLOWS
24D6 [
24XQ [ SPACECT
25CB [ ORELP
25X2 [ CHECKSTATE
26BL [ FDRMON
26W= [ FDRMOFF
27*W [ FDRMTEST
27TG [ FDRMCHECK
28*6 [ FDRMAUTO
28SQ [ FDRMAUTX
29#B [ FDRMQUERY
29S2 [ JNOTFDRM
2=?L [ OLPEND
2=R= [ AUTSTART
2?=W [ AUTFIN
2?QG [ AUTFAIL
2#=6 [ JAUTON
2#PQ [ JAUTOFF
2*9B [ JAUTFAIL
2*P2 [ CLAUTFAIL
2*YS ...[ TRTYPE1
2B8L [ ASTABLES
2BN= [ ASTYPE
2BS7 ...[ INCHECK
2BY4 ...[ INMOP
2C3^ ...[ OUTMOP
2C5X ...[ FHONLINE
2C7W [
2CCN ...[??? SPACECT SECT FILE FGN 7 DOC
2CMG [ J TO %C IF X%A ALL SPACES;ELSE COUNT TRAILING SPACES IN X%B
2D76 #MAC SPACECT
2DLQ BXE %A ACES,%C [J IF ALL SPACES
2F6B LDX 0 ACES
2FL2 LDN %B 3
2G5L M1SPACECT
2GK= SLL 0 6
2H4W SLL %A 6
2HJG BXE 0 %A,M2SPACECT [J IF REST ARE SPACES
2J46 BCT %B M1SPACECT
2JHQ M2SPACECT
2K3B #NOR
2K?8 ...[??? ORELP SECT FILE FGN 7 DOC
2KH2 [
2L2L #MAC ORELP
2LG= #ACC %A
2L^W LDX 0 %A
2MFG SMO FX2
2M^6 #ACC %A
2NDQ #SKI
2NYB STO %A ACOMMUNE8
2PD2 #ACC %A
2PXL STO 0 ACOMMUNE8
2QC= DOWN OFFREL,3
2QWW #NOR
2R6N ...[??? CHECKSTA SECT FILE FGN 7 DOC
2RBG # THIS MACRO CHECKS THE STATE OF AN OFF-LINE PERI CHANNEL FOR ALLOT
2RW6 #MAC CHECKSTATE
2S*Q SMO 1(%A)
2STB LDX %B ALTMARK-CHAINADD
2T*2 ANDX %B GSIGN
2TSL #NOR
2W4D ...[??? FDRMON SECT FILE FGN 7 DOC
2W#= [ MACROS USED IN IMPLEMENTATION OF DRM ON COMMUNICATION FILES
2WRW [ FIRST 2 USED IN PCA WHEN PLUGGED IN - FOR ALLOT EXTRACODE
2X?G [ FDRMON %A->PRB RECORD
2XR6 #MAC FDRMON
2Y=Q LDCT 0 #200
2YQB SMO 1(%A)
2^=2 ORS 0 BFSTATE-CHAINADD
2^PL #NOR
2^^D ...[??? FDRMOFF SECT FILE FGN 7 DOC
329= [
32NW [ FDRMOFF %A->PRB RECORD
338G #MAC FDRMOFF
33N6 LDCT 0 #200
347Q SMO 1(%A)
34MB ANDX 0 BFSTATE-CHAINADD
3572 SMO 1(%A)
35LL ERS 0 BFSTATE-CHAINADD
366= #NOR
36B4 ...[??? FDRMTEST SECT FILE FGN 7 DOC
36KW [
375G [ FDRMTEST IS USED BY OFFLINE PERI SEGMENTS TO TEST IF DRM IS APPLICABLE
37K6 [ %A=APPWAIT OR STEPWAIT
384Q [ %B-LABEL TO JUMP TO IF NOT DRM OR NOT OPEN COMUNALLY
38JB #MAC FDRMTEST
3942 LDX 2 FX2
39HL JNOTFDRM %B
3=3= TOPFCA2 1
3=GW JBC %B,1,BACOMM
3?2G LDN 0 FCA%A
3?G6 ORS 0 FGENERAL1(1)
3?^Q ADX 1 FBACKPOINT(1)
3#FB LDX 1 BPTR(1)
3#^2 LDN 0 FCB%A
3*DL ORS 0 FINFC(1)
3*Y= #NOR
3B84 ...[??? FDRMCHEC SECT FILE FGN 7 DOC
3BCW [
3BXG [ FDRMCHECK IS USED IN STEP(APPEND) TO CHECK IF THERE ARE ANY DRM WAITER
3CC6 [ %A(MODIFIER)->FCB
3CWQ [ %B-LABEL IF WAITERS
3DBB #MAC FDRMCHECK
3DW2 LDN 0 FCBSTEPWAIT
3F*L ANDX 0 FINFC(%A)
3FT= BNZ 0 %B
3G#W #NOR
3GJN ...[??? FDRMAUTO SECT FILE FGN 7 DOC
3GSG [
3H#6 [ FDRMAUTO IS USED BY ACCESS SYSTEM TO TICKLE SUSINED PROGRAMS
3HRQ [ %A=APPWAIT OR STEPWAIT
3J?B #MAC FDRMAUTO
3JR2 SMO FX2
3K=L LDX 1 FILERING
3KQ= ADX 1 FBACKPOINT(1)
3L9W LDX 2 BPTR(1)
3LPG LDN 0 FCB%A
3M96 ANDX 0 FINFC(2)
3MNQ BZE 0 %B
3N8B ERS 0 FINFC(2)
3NN2 M1FDRMAUTO
3P7L LDEX 2 ARINGNO(1)
3PM= M2FDRMAUTO
3Q6W LDN 0 FCA%A
3QLG ANDX 0 A1+FGENERAL1(1)
3R66 BZE 0 M3FDRMAUTO
3RKQ ERS 0 A1+FGENERAL1(1)
3S5B LDX 1 A1+FPTRF(1)
3SK2 LDX 0 JOBNO-FILERING(1)
3T4L TICKLER 0
3TJ= LDX 1 FILERING(2)
3W3W ADX 1 FBACKPOINT(1)
3WHG BRN M1FDRMAUTO
3X36 M3FDRMAUTO
3XGQ ADN 1 FELLEN
3Y2B BCT 2 M2FDRMAUTO
3YG2 LDX 2 FX2
3Y^L LDX 1 FX1
3^F= #NOR
3^P4 ...[??? FDRMAUTX SECT FILE FGN 7 DOC
3^YW [
42DG [ USED BY OPEN & CLOSE TO TICKLE WHEN LAST OPENER CLOSES FILE
42Y6 [ OR FIRST OPENER OPENS FILE
43CQ [ %A IS X3->X7 & CONTAINS FCBAPPWAIT OR FCBSTEPWAIT AS APPROPRIATE
43XB #MAC FDRMAUTX
44C2 SMO FX2
44WL LDX 1 FILERING
45B= ADX 1 FBACKPOINT(1)
45TW LDX 2 BPTR(1)
46*G LDX 0 %A
46T6 ANDX 0 FINFC(2)
47#Q BZE 0 M5FDRMAUTX
47SB ERS 0 FINFC(2)
48#2 SRL %A 7
48RL M1FDRMAUTX
49?= LDEX 2 ARINGNO(1)
49QW BZE 2 M3FDRMAUTX
4==G M2FDRMAUTX
4=Q6 LDX 0 %A
4?9Q ANDX 0 A1+FGENERAL1(1)
4?PB BZE 0 M4FDRMAUTX
4#92 ERS 0 A1+FGENERAL1(1)
4#NL LDX 1 A1+BPTRF(1)
4*8= LDX 0 JOBNO-FILERING(1)
4*MW BZE 0 M3FDRMAUTX
4B7G TICKLER 0
4BM6 LDX 1 FILERING(2)
4C6Q ADX 1 FBACKPOINT(1)
4CLB BRN M1FDRMAUTX
4D62 M3FDRMAUTX
4DKL GEOERR 1,FDRMAUTX
4F5= M4FDRMAUTX
4FJW ADN 1 FELLEN
4G4G BCT 2 M2FDRMAUTX
4GJ6 M5FDRMAUTX
4H3Q LDX 1 FX1
4HHB LDX 2 FX2
4J32 #NOR
4J=S ...[??? FDRMQUER SECT FILE FGN 7 DOC
4JGL [
4K2= [ USE BY SERIAL ACCESS SYSTEM TO AVOID COOR & LONGSET IF DRM CASE
4KFW #MAC FDRMQUERY
4K^G LDCT 0 #200
4LF6 SMO FX2
4LYQ ANDX 0 BFSTATE
4MDB BNZ 0 %A
4MY2 #NOR
4N7S ...[??? JNOTFDRM SECT FILE FGN 7 DOC
4NCL [
4NX= [ JUMPS IF CHANNEL NOT DRM
4PBW #MAC JNOTFDRM
4PWG LDCT 0 #200
4QB6 ANDX 0 BFSTATE(2)
4QTQ BZE 0 %A
4R*B #NOR
4RK8 ...[??? OLPEND SECT FILE FGN 7 DOC
4RT2 [
4S#L ...[ DOES TICKLE IF DRM & NOT COMMUNE : THEN OLPFIN1
4SS= #MAC OLPEND
4T?W LDX 2 FX2
4TF4 ... TOPFCA2 3
4TL= ... JBS M1OLPEND,3,BACOMM
4TRG JNOTFDRM M1OLPEND
4W?6 TICKLES 2,3
4WQQ M1OLPEND
4X=B OLPFIN1
4XQ2 #NOR
4X^S ...[??? AUTSTART SECT FILE FGN 7 DOC
4Y9L [
4YP= # PUTS OLPA INTO AUTONOMOUS MODE OF OPERATION
4^8W #
4^NG #MAC AUTSTART
5286 LDX 2 FX2
52MQ LDX 1 EVENT2(2) [GET PNTR TO CONTROL AREA
537B ADN 1 1 [GET PNTR TO REPLY WORD
53M2 FADDRESS APETADDR(2),1,HLOCK1,2 [CONVERT TO GEORGE ADDRESS
546L LDCT 0 256
54L= STO 0 0(1) [SET REPLY WORD NEGATIVE
555W ORS 0 BFSTATE(2) [SET PERIPHERAL CHANNEL BUSY MARKER
55KG SMO APETADDR(2)
5656 ERS 0 ASTOP [UNSET PROGRAM STOP BIT
56JQ LDX 1 FX1
574B #NOR
57#8 ...[??? AUTFIN SECT FILE FGN 7 DOC
57J2 #
583L # TERMINATES AN OLPA WHICH MAY BE RUNNING IN AUTONOMOUS MODE
58H= #
592W #MAC AUTFIN
59GG ... LDX 5 %A [LOAD REPLY
5=26 #STR %B
5=^B LDX 6 %B [GET SPECIFIED LINK PAIR
5#XW LDX 2 FX2
5*CG LDX 1 APETADDR(2) [GET PCA ADDR
5*X6 LDX 3 EVENT2(2) [GET PNTR TO CONTROL AREA
5BBQ ... LDX 7 BFSTATE(2)
5BWB ... BPZ 7 MAUTFIN8 [J IF NOT IN AUTONOMOUS MODE
5DSW LDN 4 1
5F#G ... ADS 4 ASTOP(1) [SET STOP WORD NON-ZERO
5FS6 ... STOPIT 1
5J== LDCT 0 256
5JPW ERS 0 BFSTATE(2) [CLEAR PERIPHERAL CHANNEL BUSY MARKER
5K?P ...MAUTFIN8
5K*Y ... ADN 3 1 [GET PNTR TO REPLY WORD
5KD7 ... FADDRESS 1,3,HLOCK1,2 [GEORGE ADDRESS
5KGB ... STO 5 0(3) [STORE REPLY
5KJK ... CLEAR 1,0 [CLEAR LOCKS & MARK ENTRIES EMPTY
5KLS ... BPZ 7 MAUTFIN7 [J IF NOT IN AUTONOMOUS MODE
5KP6 JNOTFDRM MAUTFIN6
5L8Q TICKLES 2,3
5LDJ ...MAUTFIN6
5LNB ... SBS 4 ASTOP(1) [ REMOVE STOP BIT
5LY8 ... LDX 4 AVENT1(2)
5M82 BZE 4 MAUTFIN1 [JIF SPOUT EMPTY
5MML STOZ AVENT1(2) [CLEAR SPOUT
5N7= BPZ 4 MAUTFIN2 [JIF NOT SUSBY SPOUTED
5NLW MAUTFIN7 LDX 2 APETADDR(2)
5P6G MONEND [CLEAR STOP BIT - THIS IS ALL THAT
5PL6 [IS LEFT OF OLPFIN1 AFTER REMOVING
5Q5Q [CLEAR & COOR1Y
5Q7F ...MAUTFIN1
5Q98 ...[ FOLLOWING CODE ADDED FOR BUG 0218 TO ENSURE EXEC TIMESHARER IS
5Q=X ...[ ENTERED IF PROGRAM IS REALTIME WITH PRIORITY
5Q#L ... FJOPCA 1,2,N
5QB* ... JBC MAUTFIN9,1,JBREPRI
5QD4 ... PROGRING LOCKOFF
5QFR ...MAUTFIN9
5QHG ...[ END OF CODE INSERTED
5QKB #STR %B
5R52 (
5RJL ... LDX 2 FX2
5S4= STO 6 ALINK1(2) [SET SPECIFIED LINK
5TH6 COOR1X [SWITCH OFF - LINK NOT PROCESSED
5W2Q )
5WGB #STR %B
5X22 #SKI
5XFL (
5X^= ... COOR1Y [SWITCH OFF - ACCUMULATORS NOT SAVED
5YDW BRN MAUTFIN3 [J TO DEAL WITH NEXT PERI
5YYG )
5^D6 MAUTFIN2 STO 4 EVENT1(2)
5^XQ LDN 4 AVENT2(2) [TRANSFER DETAILS OF PERI FROM SPOUT
62CB LDN 5 EVENT2(2) [TO CURRENT AREA
62X2 MOVE 4 G4<1*2+3 [4WD AREA IN G3 - 6WD AREA IN G4
63BL #STR %B
63W= ACROSSVA 6 [TO DEAL WITH SPOUTED PERI
64*W #STR %B
64TG #SKI
65*6 (
65JY ...MAUTFIN3 [PROCESS NEXT PERI
65SQ LDX 1 FX1
66S2 )
67?L #NOR
67HD ...[??? AUTFAIL SECT FILE FGN 7 DOC
67R= #
68=W # TERMINATES AN OLPA AFTER A FAIL HAS OCCURRED WHILST (POSSIBLY)
68QG # RUNNING IN AUTONOUOUS MODE
69=6 #
69PQ #MAC AUTFAIL
6=9B ... LDX 5 %A [LOAD REPLY
6=P2 LDX 2 FX2
6?8L LDX 1 APETADDR(2) [GET PCA ADDR
6?N= LDX 3 EVENT2(2) [GET PNTR TO CONTROL AREA
6#7W ... LDX 7 BFSTATE(2)
6#MG ... BPZ 7 MAUTFAIL8 [J IF NOT IN AUTONOMOUS MODE
6B6B LDN 4 1
6BL2 ADS 4 ASTOP(1) [INCREMENT STOP WORD FOR FAIL
6C5L ... STOPIT 1
6HG= LDCT 0 256
6H^W ERS 0 BFSTATE(2) [CLEAR CHANNEL BUSY MARKER
6JFG ORS 4 BFSTATE(2) [SET CHANNEL FAILED MARKER
6JHP ...MAUTFAIL8
6JKY ... ADN 3 1 [GET PNTR TO REPLY WORD
6JN7 ... FADDRESS 1,3,HLOCK1,2 [GEORGE ADDRESS
6JQB ... STO 5 0(3) [STORE (FAILED) REPLY
6JSK ... CLEAR 1,0 [CLEAR LOCKS & MARK ENTRIES EMPTY
6JWS ... BPZ 7 MAUTFAIL7 [J IF NOT IN AUTONOMOUS MODE
6J^6 JNOTFDRM MAUTFAIL7
6KDQ TICKLES 2,3
6KYB MAUTFAIL7
6LD2 LDX 0 AVENT1(2)
6LXL BZE 0 MAUTFAIL4 [J IF SPOUT EMPTY
6MC= STOZ AVENT1(2) [CLEAR SPOUT
6MWW BNG 0 MAUTFAIL3 [J IF SUSBY SPOUTED
6NBG SBS 4 ACOUNT(2) [DECREMENT PERI COUNT
6NW6 MAUTFAIL3
6P*Q STEPBAC1 ,1 [STEP BACK PROGRAMS ONR
6PTB MAUTFAIL5
6Q*2 LDX 2 APETADDR(2)
6QSL MONEND [CLEAR STOP BIT - THIS IS ALL THAT
6R#= [IS LEFT OF OLPFIN1 AFTER REMOVING
6RRW [CLEAR & COOR1Y
6S?G MAUTFAIL4
6SR6 COOR1Y [SWITCH OFF - ACCUMULATORS NOT SAVED
6T=Q #NOR
6TGJ ...[??? JAUTON SECT FILE FGN 7 DOC
6TQB #
6W=2 # BRANCH TO %B IF OLPA IS PROCESSING AUTONOMOUSLY
6WPL #
6X9= #MAC JAUTON
6XNW #STR %A
6Y8G (
6YN6 #MOD %A
6^7Q (
6^MB SMO %A
7272 LDX 0 BFSTATE
72LL )
736= #MOD %A
73KW #SKI
745G LDX 0 BFSTATE(%A)
74K6 )
754Q #STR %A
75JB #SKI
7642 (
76HL SMO FX2
773= LDX 0 BFSTATE
77GW )
782G BNG 0 %B
78G6 #NOR
78PY ...[??? JAUTOFF SECT FILE FGN 7 DOC
78^Q #
79FB # BRANCH TO %B IF OLPA IS NOT PROCESSING AUTONOMOUSLY
79^2 #
7=DL #MAC JAUTOFF
7=Y= #STR %A
7?CW (
7?XG #MOD %A
7#C6 (
7#WQ SMO %A
7*BB LDX 0 BFSTATE
7*W2 )
7B*L #MOD %A
7BT= #SKI
7C#W LDX 0 BFSTATE(%A)
7CSG )
7D#6 #STR %A
7DRQ #SKI
7F?B (
7FR2 SMO FX2
7G=L LDX 0 BFSTATE
7GQ= )
7H9W BPZ 0 %B
7HPG #NOR
7H^# ...[??? JAUTFAIL SECT FILE FGN 7 DOC
7J96 #
7JNQ # BRANCH TO %B IF OLPA IS MARKED 'PERIPHERAL CHANNEL FAILED'
7K8B #
7KN2 #MAC JAUTFAIL
7L7L #STR %A
7LM= (
7M6W #MOD %A
7MLG (
7N66 SMO %A
7NKQ LDX 0 BFSTATE
7P5B )
7PK2 #MOD %A
7Q4L #SKI
7QJ= LDX 0 BFSTATE(%A)
7R3W )
7RHG #STR %A
7S36 #SKI
7SGQ (
7T2B SMO FX2
7TG2 LDX 0 BFSTATE
7T^L )
7WF= ANDN 0 1
7WYW BNZ 0 %B
7XDG #NOR
7XN# ...[??? CLAUTFAI SECT FILE FGN 7 DOC
7XY6 #
7YCQ # CLEAR PERIPHERAL CHANNEL FAILED MARKER IN OLPA
7YXB #
7^C2 #MAC CLAUTFAIL
7^WL NGN 0 2
82B= #STR %A
82TW (
83*G #MOD
83T6 (
84#Q SMO %A
84SB ANDS 0 BFSTATE
85#2 )
85RL #MOD %A
86?= #SKI
86QW ANDS 0 BFSTATE(%A)
87=G )
87Q6 #STR %A
889Q #SKI
88PB (
8992 SMO FX2
89NL ANDS 0 BFSTATE
8=8= )
8=MW #NOR
8=XN ...[??? TRTYPE1 SECT FILE FGN 7 DOC
8?7G #
8?M6 # THE NEXT 2 MACROS ARE FOR SETTING UP TABLES IN ASSIGN
8#6Q #
8#8# ...#MAC TRTYPE1
8#9W #MEN TROBJ
8#?D #TRA K91TROBJ
8#*2 ... NULL
8#BJ #TRA K92TROBJ
8#D6 ... BZE 6 K92TROBJ+4
8#FN ... NULL
8#H= #END
8#JS #NOR
8#KK ...[??? ASTABLES SECT FILE FGN 7 DOC
8#LB # ASTABLES - SET UP (EMPTY) COMPACT TABLE OF ALLOWABLE PERIPHERAL TYPES
8*62 #
8*KL #MAC ASTABLES
8B5= #DEF M1ASTABLES=0?
8BJW #REP 16
8C4G +0
8CJ6 #NOR
8CRY ...[??? ASTYPE SECT FILE FGN 7 DOC
8D3Q #
8DHB # ASTYPE - FILL IN ABOVE TABLE & APPEND 4 WD ENTRY TO PERIPHERAL DATA
8F32 # TABLE
8FGL #MAC ASTYPE
8G2= #OPT M1ASTYPE=0?
8GFW #DEF 19?+0=0?
8G^G #TRA %A/4+M1ASTABLES+1
8HF6 #FID %A&3*6,%A&3+1*6-1,19?+0]-M1ASTYPE+1
8HYQ #TRA 19?+0]
8JDB +%C
8JY2 +%B
8KCL #FID 7,13,AOLPTLEN+%D
8KX= #STR %G
8LBW #FID %G,%G,1
8LWG #STR %H
8MB6 #FID %H,%H,1
8MTQ #STR %I
8N*B #FID %I,%I,1
8NT2 #STR %J
8P#L #FID %J,%J,1
8PS= LINK %E,%F
8Q?W #NOR
8QRG ...[??? INCHECK SECT COMM FGN 40 DOC
8R?6 ...#SKI
8RQQ ...(
8S=B ...[
8SQ2 ...
8T9L ...)
8TP= ...#MAC INCHECK
8W8W ...#SKI G4
8WNG ...(
8X86 ... SMO FX2 [%A:ADDRESS OF LOCKDOWN ENTRY IN BLK
8XMQ ... LDX 7 %A [%B:LABEL TO JUMP TO IF OUTSIDE
8Y7B ... LDX 6 7 [OBJECT PROGRAM'S RESERVATIONS
8YM2 ... ANDN 6 #1777 [%A+1:WORD CONTAINING ADDR OF START
8^6L ... ANDX 7 B2T13 [OF AREA TO BE CHECKED WRT O.P. DATUM
8^L= ... SMO FX2 [%C:ADDRESS OF BLK CONTAINING
925W ... LDX 5 %A+1 [LOCKDOWN ENTRIES
92KG ...MAX CHECKB 5,7,%B,,6,MAX,%A,%C
9356 ...)
93JQ ...#NOR
944B ...[??? INMOP SECT COMM FGN 40 DOC
94J2 ...#SKI
953L ...(
95H= ...[
962W ...[ MACRO TO DEAL WITH INPUT FROM MOP CONSOLE OR JDF
96GG ...[
9726 ...)
97FQ ...#MAC INMOP
97^B ... SMO FX2
98F2 ... LDX 0 IDENTINFO
98YL ... BZE 0 MNOTMOP [J. NOT MOP OR JDF
99D= ... LDX 2 FX2
99XW ... LDN 0 3
9=CG ... LDN 1 ACC3(2)
9=X6 ... MOVE 0 5
9?BQ ... LDX 1 FX1 [RESET X1.
9?WB ... LDX 0 APETADDR(2)
9#B2 ... SBS 0 EVENT1(2)
9#TL ... LDX 5 IDENTINFO(2) [LD. PERI TYPE & UNIT NO.
9**= ... LDX 7 ACNUM(2) [LD. ACT.NO. OF AOLPT.
9*SW ... LDCT 6 #100
9B#G ... ANDX 6 ALTMARK(2) [LD. NEWLINE SUPPRESSION INDICATOR.
9BS6 ... ERS 6 ALTMARK(2)
9C?Q ... ORX 6 IDENTIND(2) [ORX IN IDENT.OR NOT INDICATOR.
9CRB ... TOPCA MPAIR(1) [CHANGE ACT AND GO AWAY
9D?2 ... COOR1Y [PUT THIS TO SLEEP
9DQL ... BRN %A [
9F== ... LDX 0 APETADDR(2)
9FPW ... ADS 0 EVENT1(2)
9G9G ... BRN %B
9GP6 ...MPAIR PAIR INMOP,1
9H8Q ...MNOTMOP [CONTINUE
9HNB ... LDX 1 FX1 [LD. VALUES OF FX1 & FX2
9J82 ... LDX 2 FX2
9JML ...#NOR
9K7= ...[??? OUTMOP SECT FILE FGN 40 DOC
9KLW ...#SKI
9L6G ...(
9LL6 ...[
9M5Q ...[ MACRO TO DEAL WITH OUTPUT TO MOP CONSOLE OR THE JDF
9MKB ...[
9N52 ...)
9NJL ...#MAC OUTMOP
9P4= ... DOWN INMOP,2 [DOWN TO DEAL WITH OUTMOP
9PHW ... BRN %A [EXIT TO OLPFIN
9Q3G ... MHUNTW 1,FILE,FRB [HUNT FOR UNIVERSAL
9QH6 ... CHAIN 1,APETADDR(2) [RE-CHAIN BLK 1FTER PCA
9R2Q ... LDCT 7 #100
9RGB ... ANDX 7 ALTMARK(2) [LD. NEWLINE SUPPRESSION WORD.
9S22 ... ERS 7 ALTMARK(2)
9S78 ...#SKI G505&1
9S#B ... ORX 7 IDENTIND(2)
9SFL ... LDX 1 FX1
9S^= ... TOPCA MOPAIR(1) [CHANGE ACT
9TDW ... COOR1
9TYG ... BRN %B
9WD6 ...MOPAIR
9WXQ ... PAIR INMOP,3
9XCB ...#NOR
9XX2 ...[
9YBL ...[??? FHONLINE SECT FILE
9YW= ...[ SWITCHES ON AND OFF THE SETTING OF BIT 1 IN ONLINE FH MODE #12
9^*W ...#MAC FHONLINE
9^TG ...#MEN FHOBJIND
=2*6 ...#TRA K80FHOBJIND
=2SQ ...#STR %A,ON
=3#B ...#SKI
=3S2 ...(
=4?L ... NULL
=4R= ...#END
=5=W ...#EXI
=5QG ...)
=6=6 ...#STR %A,OFF
=6PQ ...#SKI
=79B ...(
=7P2 ... BRN K81FHOBJIND
=88L ...#END
=8N= ...#EXI
=97W ...)
=9MG ...#STR %A
==76 ...#SKI
==LQ ...(
=?6B ...#END
=?L2 ...#EXI
=#5L ...)
=#K= ...! PARAMETER MUST BE ON OF OFF
=*4W ...#NOR
^^^^ ...567416750018