{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ONLINCL864)}}
====== ONLINCL864 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:ADDRELT|ADDRELT]], [[george:macro:ALTLENR|ALTLENR]], [[george:macro:CCOUT|CCOUT]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR3|COOR3]], [[george:macro:COOR4|COOR4]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FCJOB|FCJOB]], [[george:macro:FINDACTFB|FINDACTFB]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:FWAIT|FWAIT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:GETACTX|GETACTX]], [[george:macro:HUNTACT|HUNTACT]], [[george:macro:IDFOFF|IDFOFF]], [[george:macro:IPBCOUNT|IPBCOUNT]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGCLEAR|LONGCLEAR]], [[george:macro:MARK|MARK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:PAIR|PAIR]], [[george:macro:PUTPERENT|PUTPERENT]], [[george:macro:RING2CHK|RING2CHK]], [[george:macro:RINGTWO|RINGTWO]], [[george:macro:ROLPA|ROLPA]], [[george:macro:RTTEST|RTTEST]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETIDENT|SETIDENT]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETXCORE|SETXCORE]], [[george:macro:TESTBRKIN|TESTBRKIN]], [[george:macro:ZERRORX|ZERRORX]], [[george:macro:ZERRORY|ZERRORY]]
22FL SEG ONLINCL,,JOHN BAILEY
22PD ...#OPT K0ONLINCL=0
22^= ...#OPT CONTROL=#34
2394 ...#LIS K0ONLINCL>K0ONLINE>K0COMMAND>K0ALLGEO
23DW 8HONLINCL
23YG #
24D6 #SKI G3
24XQ SEGENTRY K1ONLINCL,SK1ONLINCL
25CB SEGENTRY K2ONLINCL,SK2ONLINCL
25X2 #
28*6 #
28SQ # THIS CHAPTER IS ENTERED BY ACROSSES FROM ONLINEB
29#B # K1 ONLINES A CONCEPTUAL MPX OR UPX ; IT SETS UP A NEW OLPA
29S2 # K2 ONLINES A CONCEPTUAL IPB ; IT SETS NEW OLPA AND AMOP/IPBCCA
2=?L #
2=R= NAMCL #43540000
2?=W RECCON +CONRECLEN
2?GN ... FSHSKIP
2?QG TBLIC PAIR IPBCCA,1
2?TL ... FSHCODE AORB
2?YQ ...(
2#3W ...TBLIC PAIR IPBCCC,4
2#72 ...)
2#=6 TBLIP PAIR CONIPB,1
2#PQ #SKI G3
2*9B TBLMX PAIR CONMXA,1
2*P2 XADEVS
2B8L #HAL AMXOR+ADEVS,0
2BN= XALINES
2C7W #HAL AMXOR+ALINES,0
2CMG XCROUTE
2D76 #HAL AMXOR+CROUTE,0
2DBY ...ZADE #77657777 [TO UNSET BITS 8 AND 10
2DLQ #
2F6B # SET UP OLPA WITH CONCEPTUAL NAME , JOB NO. ETC AND MARK IN PRB.
2FL2 #
2G5L PROLP SBX 7 FX1
2GK= LDCT 4 AOLPT/8 [FOR ATYPE WORD
2H4W GETACTX 4,3,1 [OLPA LENGTH IN X3 ; %C FOR LONGLOCK
2HJG LDX 3 BPTR(2)
2J46 LDCT 0 #400
2JHQ LDX 4 JOBNO(2)
2K3B STO 0 GIVE(3) [PERIPHERAL ALLOTABLE
2KH2 STO 0 FRECHADD(3) [EXEC EVENT CHAINING REQUIRED
2L2L STO 4 JOBNO(3) [GIVE IT THE SAME JOB NO.
2LG= STO 5 ATMARK(3) [SWITCH FOR USE BY RELPER
2L^W LDN 2 CNAME(3)
2MFG CALL 6 STON [INSERT CONCEPTUAL NAME
2M^6 SBN 1 APARA
2NDQ FREECORE 1 [CPB/CUNI
2NYB PUTPERENT AWORK1(2),GSIGN
2PD2 LDX 3 BPTR(2)
2PXL ROLPA
2QC= ADX 7 FX1
2QWW EXIT 7 0
2RBG #
2RW6 # SEARCH FOR BLOCK OF TYPE IN X5 FROM AMOP WITH ADDRESS IN X1
2S*Q #
2STB SEEK LDX 1 FPTR(1)
2T*2 LDX 0 ATYPE(1)
2TSL TXU 0 5 [BLOCK TYPE REQUIRED IN X5
2W#= BCC SBLK [HAVE FOUND BLOCK : EXIT
2WRW TXL 0 CACT
2X?G BCS SEEK [NOT NEXT ACTIVITY ; TRY NEXT BLOCK
2XR6 EXIT 7 0 [NO AMXOR/ALINES BLOCK
2Y=Q SBLK EXIT 7 1
2YQB #
2^=2 # INSERT CONCEPTUAL NAME AFTER ADDRESS IN X2 ; SPACE-FILL IF NEEDED
2^PL #
329= STON MHUNT 1,CPB,CUNI
32NW LDEX 0 ANUM(1) [LENGTH OF CONCEPTUAL NAME
338G ADN 1 APARA
33N6 SBN 0 9
347Q MOVE 1 3
34MB BPZ 0 (6) [LENGTH > 8 : NO NEED TO SPACE-FILL
3572 LDX 5 ACES
35LL ADN 0 4
366= STO 5 2(2) [SPACE-FILL NAME TO 12 CHARACTERS
36KW BPZ 0 (6)
375G STO 5 1(2)
37K6 EXIT 6 0
384Q #
38JB # LONGCLEAR MOP ATTACH ACTIVITY WITH ALCB/ADCB ADDRESS IN X2
3942 #
39HL ULON HUNTACT CPAT,2
39W3 ... LONGCLEAR 2,#107,NWT
3=8D ...NWT LDX 2 FX2
3=GW EXIT 7 0
3?2G #SKI G3
3?G6 (
3?^Q #
3#FB # CONCEPTUAL MPX OR UPX : CONSTRUCT AMXOR/CONLCB BLOCK AND NEW OLPA
3#^2 #
3*DL SK1ONLINCL
3*Y= LDX 6 AWORK1(2)
3BCW MHUNTW 3,IDF,CONCEP [GET CONCEPTUAL DESCRIPTION BLOCK
3BXG SRL 6 15 [PERIPHERAL TYPE.
3CC6 LDX 4 ALOGLEN(3) [1 WD. PER CONCEPTUAL LINE.
3CWQ SBN 6 BHUPX
3DBB BNZ 6 YMPX [ZERO IF UNIPLEXOR
3DW2 BCT 4 NUPX [J. TO ERROR IF >1 LINE FOR UPX,
3F*L YMPX STO 4 AWORK2(2) [SAVE HIGHEST LINE NO. (0 IF UPX)
3FT= ADN 4 1 [ADD 1 FOR LINE 0.
3G#W FJOCA 3,2
3GSG MARK 3 [UPDATE COUNT OF REAL-TIME PERIPHS.
3H#6 LDX 3 4
3HRQ MPY 4 RECCON(1) [NO. OF LINES X LENGTH OF EACH RECORD
3J?B SETXCORE 5,2,AMXOR,CONLCB,,3,CONRECLEN [FOR CONCEPTUAL LCB
3JR2 ADN 5 A1 [TOTAL LENGTH OF BLOCK
3K=L MHUNTW 3,IDF,CONCEP [CONCEPTUAL DESCRIPTION BLOCK
3KQ= SMO FX2
3L9W STO 5 AWORK3
3LPG LDX 5 XALINES(1) [FOR SEEK SUBROUTINE
3M96 #
3MNQ # FOR EACH LINE THIS LOOP SETS UP AN AMXOR/CONLCB ENTRY AND MARKS
3N8B # THE AMXOR/ALINES RECORD WHEN IDF FINISHED WITH OTHER COMMANDS
3NN2 #
3P7L REPAS LDN 4 A1 [FOR SETTING BSTARTS AND ENDING LOOP
3PM= NXT3 BNG 6 NOFI [NOT FIRST PASS : CHECK WAITING LINES
3Q6W STOZ A1+FPTR(2)
3QLG STOZ A1+BPTR(2)
3R66 NGS 4 A1+BSTART(2)
3RKQ LDCH 0 6 [NON-ZERO ONLY THE FIRST TIME ; SET
3S5B BZE 0 NNUL [NULL ENTRY FOR MPX LINE ZERO
3SK2 LDN 6 0
3T4L SBN 3 1 [ALLOW FOR NULL MPX LINE ZERO
3TJ= NULL STOZ A1+ADDMOP(2)
3W3W STOZ A1+ACTUAL(2)
3WHG BRN NXT1 [GO ON TO NEXT LINE
3X36 NNUL LDX 7 A1(3) [GEOG NO. IN B0-8 IF LINE ATTACHED.
3XGQ SRL 7 15
3Y2B BZE 7 NULL [LINE POINTED TO BY X3
3YG2 LDN 1 ADMULTACT-ADMP
3Y^L NXT2 LDX 1 ADMP(1) [SEARCH DOWN MOP ACTIVITIES LIST.
3^F= #SKI K6ONLINE>99-99
3^YW BZE 1 VAB [GEOERR IF AMOP NOT FOUND.
42DG LGEOG CPPTR(1),0 [GET PLEXOR GEOG NO.
42Y6 TXU 7 0
43CQ BCS NXT2 [TRY AGAIN : DIFFERENT GEOG NO.
43XB STO 1 A1+ADDMOP(2)
44C2 LDEX 7 A1(3) [ACTUAL LINE NO.
44WL STO 7 A1+ACTUAL(2)
45B= #
45TW #
46*G REEN CALL 7 SEEK [FIND AMXOR/ALINES BLOCK
46T6 BRN NADD [ALINES ABSENT : WAIT A BIT
47#Q LDX 7 A1+ACTUAL(2)
47SB SLL 7 2 [4 WORDS PER LINE IN ALINES BLOCK
48#2 ADX 1 7
48RL LDX 0 A1+FOURTHWD(1)
49?= SLC 0 1
4==G LDCT 7 #10
4=Q6 ORS 7 A1+FOURTHWD(1) [SET B5 : ONLINE
4=T= ... BNG 0 STLAH [J IF STILL ATTACHED
4=YB ... ERS 7 A1+FOURTHWD(1) [ELSE UNSET ONLINE...
4?3G ... BRN NULL [AND TREAT AS NULL
4?6L ...STLAH
4?9Q LDX 7 A1+BPTR(1) [MUST COOR3 IF BUSY
4?PB BNZ 7 YBUS [ALCB PRESENT : BUSY
4#92 SLC 0 3
4#NL BNG 0 NADD [B4 SET : SCAN SETTING UP CPA
4*8= SLC 0 2
4*MW ANDN 0 #73 [UNSET SCAN BIT IF SET
4B7G ORN 0 #41 [B0 INHIBITS PROFLAG ; B5 SETS ONLINE
4BM6 DCH 0 A1+FOURTHWD(1)
4C6Q BRN NXT1
4CLB #
4D62 NOFI LDXC 1 A1+ADDMOP(2) [TEST BIT 0
4DKL BCC NXT1 [NOT MARKED 'FOR ATTENTION'
4F5= STO 1 A1+ADDMOP(2) [UNSET BIT 0
4FJW BRN REEN
4G4G #
4GJ6 YBUS LDX 0 A1+FOURTHWD(1)
4H3Q ANDN 0 #77 [MASK FOR TERMINAL TYPE
4HHB SBN 0 ASENTMACH
4J32 LDX 1 7
4JGL SMO FX2
4K2= STO 2 ACOMMUNE1 [PRESERVE AROUND LONGCLEAR OR FPUT
4KFW SBN 1 A1+FPTR
4K^G BZE 0 YADD
4LF6 LDX 2 1
4LYQ CALL 7 ULON [LONGCLEAR MOP CPA
4MDB BRN NWAIT
4MY2 YADD LDXC 0 GWAIT(1)
4NCL BCC NADD [CPA ALREADY ON LIST
4NX= STO 0 GWAIT(1)
4PBW HUNTACT CPAT,2,1 [FIND SENTINEL CPA
4PWG FPUT [PUT CPA ON LIST
4QB6 NWAIT LDX 2 ACOMMUNE1(2) [POINTER TO CONDCB ENTRY
4QTQ #
4R*B NADD ORN 6 #100 [COOR3 IF COOR2 BIT NOT SET
4RT2 LDCT 0 #400
4S#L ORS 0 A1+ADDMOP(2) [MARK THIS LINE : 'FOR ATTENTION'
4SS= NXT1 ADN 2 CONRECLEN [POINTER TO CONLCB RECORD
4T?W ADN 4 CONRECLEN [FOR SETTING BSTARTS AND ENDING LOOP
4TRG ADN 3 1 [POINTER TO IDF/CONCEP RECORD
4W?6 SMO FX2
4WQQ TXL 4 AWORK3
4X=B BCS NXT3 [NOT END OF BLOCK ; LOOK AT NEXT LINE
4XQ2 BNG 6 NOWF
4Y9L MFREEW IDF,CONCEP [FIRST PASS FINISHED : BLOCK USED
4YP= NOWF ANDN 6 #300
4^8W BZE 6 NOMR2 [COOR3 BIT NOT SET : CONLCB COMPLETE
4^NG COOR3 #62
5286 LDX 6 GSIGN [INDICATE NOT THE FIRST PASS
52MQ MHUNTW 2,AMXOR,CONLCB [RELOCATE AFTER COORDINATION
537B BRN REPAS
53M2 #
546L # END OF LOOP ; OTHER COMMANDS FINISHED AND AMXOR/CONLCB COMPLETE
54L= #
555W NOMR2 LDX 2 FX2
55KG LDX 4 AWORK2(2) [ACTUAL NO. OF LINES ON CONCEPTUAL.
5656 LDN 3 FLAGCT+1-A1 [LENGTH OF OLPA FOR CONCEPTUAL UPX.
56JQ BZE 4 UPX2
574B ADN 3 15 [LENGTH OF OLPA FOR 64 LINE CONCEP
57J2 SBN 4 64
583L BNG 4 UPX2
58H= ADN 3 48 [LENGTH OF OLPA FOR 256 LINE CONCEP
592W UPX2 LDN 5 5
59GG CALL 7 PROLP
59MN ... LDCT 0 #400
59SW ... STO 0 CFLAG(3)
5=26 LDX 4 AWORK2(2) [NO. OF LINES
5=FQ STO 4 CMAXLINE(3)
5=^B LINKSET 3,TBLMX(1) [SET LINK TO K1CONMXA
5?F2 MHUNTW 2,AMXOR,CONLCB [CHAIN LINE CONTROL BLOCK AFTER OLPA.
5?YL CHAIN 2,3
5#D= FON #106
5#XW ENDCOM
5*CG )
5*X6 #
5BBQ # #####################################################
5BWB #
5CB2 # ONLINE CONCEPTUAL IPB : SET UP AMXOR/CSTATE BLOCK , & AMXOR/CROUTE
5CTL # BLOCKS IF NECESSARY ; SET UP AMXOR/CONDCB BLOCK WITH ENTRY FOR
5D*= # EACH IDENTIFIER ; WHEN ALL ATTACHED DEVICES CLOSED , GET NEW OLPA
5DSW # & AMOP/IPBCCA ACTIVITIES AND PUT ENTRY IN PRB.
5F#G #
5FCL ...[
5FGQ ...UNULL
5FKW ... STO 1 IDADIN(3)
5FP2 ... BRN ZNNUA
5FS6 SK2ONLINCL
5G?Q LDX 1 IPBADDR
5GHJ ... BZE 1 NOCC
5GRB LDN 3 1
5H?2 LDN 4 CSTATELEN
5HD8 ...NEAM
5HKB ... SEGENTRY K41ONLINCL
5HQJ ... NULL
5HXQ ... LDX 0 BIT9
5J4Y ... ANDX 0 IPBSW(1)
5J=6 ... BNZ 0 VNOCON [NOT IF V7900
5JC# ... SEGENTRY K42ONLINCL
5JJG ... ADN 4 CSTATELEN
5JPN ... ADN 3 1
5JWW ...VNOCON
5K44 ... LDX 1 IPBL(1)
5K9G BNZ 1 NEAM
5K*C ... LDX 0 3
5KF# ... SBN 0 1
5KK9 ... BZE 0 NOCC
5KP6 LDN 0 A1+CSTATELEN
5L8Q STO 0 ACOMMUNE3(2)
5LNB SETXCORE 4,2,AMXOR,CSTATE,,3,CSTATELEN [CONCEPTUAL STATUS BLOCK
5M82 LDX 1 IPBADDR
5MML #
5N7= # RING CSTATE BLOCK TO AMXOR/CROUTE BLOCK BEHIND EACH AMOP/IPBIN
5NLW #
5P6G NEXPB LDX 4 1
5P8P ... SEGENTRY K43ONLINCL
5P=Y ... NULL
5P*7 ... LDX 0 BIT9
5PCB ... ANDX 0 IPBSW(1)
5PFK ... BNZ 0 NEXPC
5PHS ... SEGENTRY K44ONLINCL
5PL6 YECL LDCT 0 4
5Q5Q ANDX 0 IPBSW(1) [B6 SET IF CROUTE BEING ALTERED
5QKB BZE 0 NOW
5R52 COOR3 #62
5RJL LDX 1 4
5S4= BRN YECL
5SHW NOW LDCT 0 4
5T3G SMO FX1
5TH6 LDX 5 XCROUTE
5W2Q ORS 0 IPBSW(1) [INHIBIT OTHERS ALTLENNING
5WGB CALL 7 SEEK [LOOK FOR AMXOR/CROUTE BLOCK
5X22 BRN VNOR [NONE : SET ONE UP
5XFL LDX 6 1
5X^= ALTLENR 6,7 [LENGTHEN TO ADD NEW ENTRY
5YDW LDX 1 4 [AMOP/IPBIN ADDRESS
5YYG CALL 7 SEEK [POINT TO CROUTE AGAIN
5^D6 NULL [ALLOW FOR EXIT+1 FROM SEEK
5^XQ LDX 6 1
62CB ADDRELT 1,NULL [INITIALISE NEW ENTRY
62X2 BRN VSTAL
63BL VNOR SETNCORE CROUTELEN,1,AMXOR,CROUTE,,1,CROUTELEN
63W= LDN 0 A1
64*W SMO 4
64TG LDX 2 ACTRING
65*6 NGS 0 A1+BSTART(1)
65SQ SBN 2 ACTRING
66#B LDX 6 1
66S2 CHAIN 1,BPTR(2) [AT END OF AMOP/IPBIN ACTIVITY
67?L #
67R= VSTAL MHUNTW 3,AMXOR,CSTATE
68=W LDX 0 ACOMMUNE3(2) [MODIFIER DOWN CSTATE BLOCK
68QG ADX 3 0
69=6 NGS 0 BSTART(3)
69PQ ADN 0 CSTATELEN
6=9B STO 0 ACOMMUNE3(2)
6=P2 LDX 2 6 [ADDRESS OF CROUTE BLOCK
6?8L ADX 2 ALOGLEN(2)
6?N= SBN 2 CROUTELEN
6#7W ... RING2CHK FPTR(3),A1+FPTR(2) [CSTATE AND CROUTE ENTRIES
6#MG ADN 2 A1+CONNM
6*76 CALL 6 STON [INSERT CONCEPTUAL NAME
6*LQ LDX 1 4
6B6B LDCT 0 4
6BL2 ERS 0 IPBSW(1) [UNSET ALTLEN INHIBITER
6C5L LDX 0 IPBSW(1)
6CK= STO 0 IPSTATUS(3) [COPY OVERLOAD AND OPERABILITY
6CT4 ...NEXPC
6D4W LDX 1 IPBL(1)
6DJG BNZ 1 NEXPB [REPEAT FOR NEXT AMOP/IPBIN
6F46 #
6FHQ # SET UP AMXOR/CONDCB BLOCK AND RING FIRST ENTRY TO CSTATE BLOCK
6G3B #
6GH2 MHUNTW 3,IDF,CONCEP1 [PRODUCED BY IDFCLON
6H2L LDX 5 ALOGLEN(3)
6HG= SRL 5 1 [NUMBER OF IDENTIFIERS IN CONCEPTUAL
6H^W LDX 4 5
6JFG LDN 0 CONDCBLEN
6J^6 MPY 5 0
6KDQ SETXCORE 6,2,AMXOR,CONDCB,,4,CONDCBLEN [IDENTIFIER STATUS BLOCK
6KYB MHUNTW 1,AMXOR,CSTATE
6LD2 ... RING2CHK A1+FPTR(1),A1+FPTR(2)
6LXL #
6MC= MHUNTW 3,IDF,CONCEP1
6MWW LDN 5 A1
6NBG STOZ A1+IDADIN(2)
6NW6 LDCT 0 #20
6P*Q NGS 5 A1+BSTART(1)
6PTB STO 0 A1+IDSTATUS(2) [INDICATE CONCEPTUAL CLOSED
6Q*2 LDN 4 3
6QSL NGS 5 A1+BSTART(2)
6R#= LDX 0 A1+1(3)
6RRW STO 4 A1+IDMDNPU(2) [FOR FIRST 'INITIALISE'
6S?G STOZ A1+IPSTATUS(1)
6SR6 STO 0 A1+IDNUM(2) [LOWEST IDENTIFIER ON CONCEPTUAL
6T=Q ADX 5 ALOGLEN(2)
6TQB LDX 2 FX2
6W=2 STOZ ACOMMUNE7(2)
6WPL STOZ ACOMMUNE4(2) [IDF/CONCEP1 POINTER
6X9= LDN 4 A1+CONDCBLEN
6XNW STO 5 ACOMMUNE5(2) [FOR TXU AT END OF LOOP
6Y8G #
6YN6 # START OF MAIN LOOP
6^7Q #
6^?M ... LDN 0 6
6^CJ ... STO 0 AWORK4(2)
6^HF ...[ PRESET COUNT FOR WAITING 20 SECS
6^MB UNXT MHUNTW 3,AMXOR,CONDCB
7272 ADX 3 4 [POINT TO NEXT CONDCB ENTRY
72LL STO 4 ACOMMUNE6(2)
736= BNG 6 UNOF [NOT FIRST PASS
73KW #
745G MHUNTW 1,IDF,CONCEP1
74K6 ADX 1 ACOMMUNE4(2)
754Q LDX 0 A1+3(1)
75JB ANDN 0 #7777
7642 STO 0 IDNUM(3)
76CP ... NGXC 1 A1+2(1)
76RD ... BCS NNUL11 [J IF ATTACHED AND 7900 IS...
7777 ...[ ...ON INSTALLATION
77GW ... LDN 1 0 [ELSE ZEROISE AMOP ADRESS WORD
77WK ...NNUL11
78=# ... NGS 1 IDADIN(3) [AMOP ADDR WITH BIT 0 SET
78L3 ...ZNNUA LDN 0 2
78^Q NGS 4 BSTART(3)
79FB ADS 0 ACOMMUNE4(2) [UPDATE CONCEP1 POINTER
79^2 LDN 0 1
7=DL STO 0 IDSTATUS(3) [SET CLOSED BIT
7=Y= STOZ IDSTATUS+1(3)
7?CW BZE 1 UAGA [NULL IDENTIFIER
7?XG #
7#C6 # END OF FIRST PASS CODE ; COMPLETE CONDCB ENTRIES FOR IDLE DEVICES
7#WQ #
7*BB UNOF LDXC 1 IDADIN(3) [AMOP/IPBIN ADDRESS
7*W2 BCC UAGA [ENTRY COMPLETED ALREADY
7B*L SMO FX1
7BT= LDX 5 XADEVS
7C#W CALL 7 SEEK [FIND AMXOR/ADEVS BLOCK
7CSG BRN UWAIT
7D#6 LDX 0 IDNUM(3)
7DRQ SBX 0 A1+FOURTHWD(1) [LOWEST IDENTNO ON THIS IPB
7F?B SLL 0 2
7FR2 ADX 1 0 [POINT TO ADEVS ENTRY
7G=L #
7GBH ... LDCT 0 #40
7GGD ... ANDX 0 A1+FOURTHWD(1)
7GL* ... BNZ 0 UWAIT [WAIT IF STILL SETTING UP
7GQ= LDX 2 A1+BPTR(1)
7GT4 ... LDCT 0 #200
7GXW ... ANDX 0 A1+FOURTHWD(1)
7H2N ... BZE 0 NLAH [J IF NO LONGER ATTACHED
7H5G ... BZE 2 UZERO [J IF RING ELEMENT ZERO TO CHECK IF C
7H5N ... TXU 2 3
7H5W ... BCC TALRI
7H64 ...[ J IF ALREADY RINGED TO CONDCB BY AHB
7H6= ... LDCT 0 #10
7H6D ... ANDX 0 A1+FOURTHWD(1)
7H6L ... BZE 0 NUNAH [J IF NOT RINGED TO A CONDCB
7H6S ... LDN 0 #400
7H72 ... ANDX 0 IDSTATUS+1(2)
7H78 ... BZE 0 NUNAH [J IF AH NOT CANCELLED
7H7B ... STOZ IDNUM(3)
7H7J ... NGNC 0 1
7H7Q ... ANDS 0 IDADIN(3) [SHOW NO LONGER WAITING TO BE DEALT W
7H7Y ... BRN UAGAA
7H86 ...NUNAH
7H8# ... SMO FX2
7H?6 ... LDXC 0 AWORK4
7H*Y ... BCC NIB1 [J IF NOT BREAK IN
7HDQ ... LDX 0 BIT10
7HHJ ... ORS 0 A1+FOURTHWD(1)
7HLB ...NIB1
7HM2 ... LDCT 0 #30
7HML ... ANDX 0 A1+FOURTHWD(1)
7HN= ... BNZ 0 UWAIT
7HNW ...[ J IF RINGED TO CONDCB OR REINITIALIS
7HPG LDEX 0 A1+FOURTHWD(1)
7J96 SBN 2 A1+FPTR
7JNQ BNZ 0 UNMOP
7K8B ...UVDU CALL 7 ULON [LONGCLEAR MOP CPA
7KN2 BRN UWAIT
7L7L UNMOP LDCT 4 1
7L#S ... SBN 0 10
7LG2 ... BZE 0 UVDU
7LM= #SKI K6IPB>99-99
7M6W (
7MLG ... ADN 0 5
7N66 BNZ 0 UBULK [BULK : ATTACH SHOULD HAVE COMERRED
7NKQ )
7P5B ORS 4 A1+FOURTHWD(1) [7023 : SET B8 TO INDICATE CLOSED
7PK2 LDCT 0 #400
7Q4L ANDX 0 IWAIT(2)
7QJ= BZE 0 UWAIT [ALREADY AWAKE
7R3W ERS 0 IWAIT(2)
7RHG HUNTACT CONSA,2
7S36 FPUT [WAKE CONSA/I7023 ACTIVITY
7SGQ BRN UWAIT
7T2B UZERO LDX 0 A1+FOURTHWD(1)
7TG2 LDCT 4 #10
7T^L SLC 0 9
7WF= ORS 4 A1+FOURTHWD(1) [SET ONLINE BIT
7WYW BPZ 0 UNCLO [B9 NOT SET : STILL OPEN
7XDG SLC 0 1
7XY6 BPZ 0 URING [B10 NOT SET : RING TO CONDCB
7YCQ SRC 0 1 [ATTACH REOPENING : CLOSE AGAIN
7YXB UNCLO SRC 0 1
7^4N ... BNG 0 UWAITA
7^7* ... SLC 0 3
7^=2 ... ANDN 0 3
7^C# ... ERN 0 1
7^JL ... BZE 0 UWAITA [J IF CLOSING
7^Q2 ...UNAIT
7^WL LDCT 0 1
82B= ORS 0 A1+FOURTHWD(1) [SET B8
82TW LDN 0 #127 [B0-11 OF CRASH CLOSE SEGMENT
83*G LDX 2 FX2
83T6 STO 0 ACOMMUNE1(2)
84#Q CCOUT IDNUM(3),IDADIN(3) [CRASH CLOSE THE IDENTIFIER
84SB #
84T8 ... MHUNTW 3,AMXOR,CONDCB
84W2 ... ADX 3 ACOMMUNE6(2) [CONDCB ENTRY
84WS ... LDX 4 ACOMMUNE6(2) [IN CASE GO TO UNULL
84XL ... LDX 5 XADEVS(1)
84YD ... LDXC 1 IDADIN(3)
84^= ... CALL 7 SEEK [FIND ADEVS
8524 ... BRN UNULL
852W ... LDX 0 IDNUM(3)
853N ... SBX 0 A1+FOURTHWD(1)
854G ... SLL 0 2
855# ... ADX 1 0 [ADEVS ENTRY
8566 ...UWAITA
856Y ... SMO FX2
857Q ... LDXC 0 AWORK4
858J ... BCC UWAIT [J IF NOT BROKEN IN
859B ... LDN 0 #2203
85=8 ... ORS 0 IDSTATUS(3) [SET CLOSE IDENT,FREE
85?2 ... BRN URING
85#2 UWAIT LDN 0 1
85RL LDX 2 FX2
86?= ORS 0 ACOMMUNE7(2) [INDICATE NOT FINISHED YET
86QW BRN UAGA [GET NEXT IDENTIFIER
876K ...URING RING2CHK A1+FPTR(1),FPTR(3)
87G# ...TALRI
87Q6 SMO IDADIN(3)
889Q LDX 0 IPBSW [B0 SET IF IPB INOPERABLE
88PB LDCT 4 #400
8992 SLC 0 10
89NL ANDX 4 A1+FOURTHWD(1)
8=8= ... ANDN 0 #1000
8=MW SRL 4 12
8?7G ORS 0 IDSTATUS(3) [SET B14 IF IPB INOPERABLE
8?9P ... SLL 0 1
8??Y ... ORS 0 IDSTATUS(3)
8?B7 ... ERS 0 IDSTATUS(3) [UNSET FREE IF INOP
8?DB ... SMO FX1
8?GK ... LDX 0 ZADE
8?JS ... ANDS 0 A1+FOURTHWD(1) [LEAVE BITS 8,10 UNSET
8?M6 LDX 2 FX2
8#6Q LDX 0 BITS22LS
8#LB ORS 4 IDSTATUS(3) [SET B12 IF INOPERABLE
8*62 ANDS 0 IDADIN(3) [FOR TEST AT UNOF ON NEXT PASS
8*KL IPBCOUNT 4,IDADIN(3),1 [GET AMOP/IPBIN COUNT IN X4
8B5= ORS 4 IDSTATUS(3)
8BJW #
8BSN ...UAGAA LDX 2 FX2
8C4G UAGA LDN 4 CONDCBLEN
8CJ6 LDX 6 ACOMMUNE7(2)
8D3Q ADX 4 ACOMMUNE6(2)
8DHB TXU 4 ACOMMUNE5(2)
8F32 BCS UNXT [NOT YET AT END OF CONDCB BLOCK
8FGL BNG 6 ULAP [NOT END OF FIRST PASS
8G2= MFREEW IDF,CONCEP1
8GFW ULAP ANDN 6 1
8G^G BZE 6 UFIN [CONDCB COMPLETE : CARRY ON
8HF6 LDN 4 A1+CONDCBLEN
8HYQ LDX 6 GSIGN
8JDB STO 6 ACOMMUNE7(2)
8JGP ...UW LDX 1 FX1
8JK4 ... LDX 2 FX2
8JMC ... LDX 0 AWORK4(2)
8JPQ ... BNG 0 UFIN [J IF BROKEN IN
8JS5 ... BZE 0 ZTE [J IF ALREADY SAID WAITING
8JWD ... BCT 0 UW11 [J UNLESS END OF 20SECS
8JYR ... LDX 5 ACOMMUNE5(2) [SAVE AC5 THROUGH MONOUT
8K36 ... MONOUT JCCREPW [SAY WAITING FOR *CC
8K5F ... STO 5 ACOMMUNE5(2)
8K7S ... STO 6 ACOMMUNE7(2) [RESTORE AC WDS AFTER MONOUT
8K=7 ...ZTE TESTBRKIN ZRK [J IF BREAK IN
8K#G ... LDN 0 0
8KBT ...UW11 STO 0 AWORK4(2)
8KF8 ...[ STORE NEW NUMBER OF WAITS FOR 20SECS
8KHH ... COOR4 CCREPWT [WAIT 4 SECS
8KKW ... BRN UNXT
8KN9 ...ZRK LDCT 0 #400
8KQJ ... STO 0 AWORK4(2) [SET BROKEN IN
8KSX ... BRN UNXT [GO TO FINISH OFF
8KX= #
8LBW # END OF LOOP : AMXOR/CONDCB COMPLETE ; SET UP OLPA AND AMOP/IPBCCA
8LWG #
8M6# ... SEGENTRY K65ONLINCL
8MB6 ...UFIN SETNCORE CONCALEN*2,2,AMXOR,CONTROL
8MKY ... GETACT BMOP,IPBCCA
8MTQ LDX 2 BPTR(2)
8N*B LINKSET 2,TBLIC(1) [SET LINK TO K1IPBCCA
8NT2 NGS 2 ICA(2) [INDICATE NO READ IN PROGRESS
8P#L MHUNTW 1,AMXOR,CONDCB
8PS= CHAIN 1,2
8Q?W LDN 3 CNAME+3-A1
8QRG LDN 5 7 [FOR ATMARK
8R?6 CALL 7 PROLP [INITIALISE OLPA
8RQQ LINKSET 3,TBLIP(1) [SET LINK TO K1CONIPB
8RXY ... MHUNTW 1,AMXOR,CONTROL
8S56 ... CHAIN 1,3
8S=B MHUNTW 1,AMXOR,CSTATE
8SQ2 CHAIN 1,3
8T9L FINDACTFB 2,,BMOP,,,BPTR [POINT TO AMOP/IPBCCA AGAIN
8TP= RINGTWO IPBRING(2),IPBRING(3) [RING TO NEW OLPA
8W8W FWAIT #4062 [QUEUE IPBCCA TO BE WOKEN EVERY 4SECS
8W#2 ... LDXC 0 AWORK4(2)
8WC6 ... BCC ZENCO [J UNLESS BROKEN IN
8WG= ... ABANDCOM
8WKB ...ZENCO
8WLC ... RTTEST RTIME,,,CPA [J. IF PROG REALTIME
8WMD ...XENDC
8WNG ENDCOM
8WNP ...RTIME
8WNY ... FCJOB 2,,,CPA [FIND JOB BLOCK
8WP7 ... LDN 0 1
8WPB ... ADS 0 AEXCO(2) [INCREMENT CT OF REALTIME PERIS
8WPK ... BRN XENDC
8WP^ ...NLAH LDX 4 IDNUM(3) [SAVE ID NUMBER
8WRD ... STOZ IDNUM(3)
8WSY ... NGNC 0 1
8WX7 ... ANDS 0 IDADIN(3) [SO AS NOT TO LOOK AT THIS ONE AGAIN
8WX= ... LDN 0 #4000
8WX* ... SLL 0 1
8WXD ... ANDX 0 A1+FOURTHWD(1)
8WXH ... BNZ 0 UAGAA
8WXN ... BZE 2 SETID [J TO REINITIALISE IF RING ELEMENT NU
8WY9 ... LDEX 0 A1+FOURTHWD(1)
8WYQ ... ANDN 0 #17
8W^? ... SBN 0 5
8W^S ... BZE 0 UAGAA [J IF REMOTE OPERATORS CONSOLE
8X2* ... LDCT 0 1
8X2W ... ORS 0 A1+FOURTHWD(1)
8X3C ... ERS 0 A1+FOURTHWD(1) [ELSE UNSET B8 IN FOURTHWD
8X3Y ... BRN UAGAA
8X4F ...SETID
8X52 ... SETIDENT IDADIN(3),4
8X5S ... BRN UAGA
8X86 #
8XMQ # VARIOUS COMMAND ERRORS AND GEORGE ERRORS
8Y7B #
8YM2 ZERRORY
8YQ6 ...#UNS IDFMARK8
8YT= ...NUPX IDFOFF (GEOERR),VAB [NOT UNIPLEXOR
8YYB ...#UNS IDFMARK8
8^3G ...#SKI
8^6L NUPX IDFOFF VAB [NOT UNIPLEXOR
8^L= ZERRORX JNUPX
925W #
92KG #SKI K6IPB>99-99
9356 UBULK GEOERR 1,BULKBUSY
93JQ VAB GEOERR 1,IDFERROR
93NM ...NOCC
93SJ ... IDFOFF (GEOERR),VAB
93YF ... ZERRORX JNOCC
944B MENDAREA 50,K100ONLINCL
94J2 #END
^^^^ ...15270327001600000000