{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: OPILLSA206)}}
====== OPILLSA206 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:CHARS|CHARS]], [[george:macro:CHERRMESS|CHERRMESS]], [[george:macro:DOWN|DOWN]], [[george:macro:FPCACA|FPCACA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INPRINTX|INPRINTX]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:NAME|NAME]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPACKC|OUTPACKC]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OUTPARAX|OUTPARAX]], [[george:macro:OUTPARC|OUTPARC]], [[george:macro:PROGEND|PROGEND]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TRACE|TRACE]]
22FL #LIS K0OPILLSA
22^= #SEG OPILLSA206 [EMRYS WILLIAMS
23DW # THIS SEGMENT IS ENTERED FROM OPILLS TO PRINT THE DIAGNOSTICS CONCE
23YG # WITH AN OBJ PROG.ILLEGAL & TO GENERATE A PROG.EVENT.
24D6 8HOPILLSA6
24XQ SEGENTRY K1OPILLSA,XENT1
25CB #DEF VEXT=EXT
25X2 #DEF VCOUNT=A1 [POSN OF RECORD IN GMON,AOUT
26BL #DEF VSPROG=A1
26W= #DEF VSCOND=A1+2
27*W #DEF VSTATE=A1+3
27TG #DEF VMASK=A1+5
28*6 #DEF VMEMS=A1+6
28SQ #DEF VSMO=A1+20
29#B #DEF VINSTR=A1+24
29S2 #DEF VCAREA=A1+27
2=?L # VARIOUS CONSTANTS
2=R= QH60S #60000000
2?=W QPOINT #36002020
2?QG QIN #51562000
2#=6 NERR GEOERR 0(3),OPILLSA
2#PQ XENT1
2*9B #SKIP K6OPILLSA>199-199
2*P2 TRACE 1,OPILLSA
2B8L #SKIP G4 [PUT OUT ADDITIONAL MESSAGE STORED
2BN= CHERRMESS [BY THE CHECKB MACRO - IF ANY
2C7W LDN 3 XPRINT [ENTER'MACRO CODE'
2CMG BRN XFOP
2D76 # THIS IS THE CENTRAL LOOP WHICH PICKS UP THE CONTROL CHAR LOCATED
2DLQ # BY X3 & SWITCHES ON IT
2F6B XNOP ANDX 3 BITS22LS [ENTRY TO STEP X3 & DO NEXT OPERATION
2FL2 ADN 3 1
2G5L XFOP SMO FX1 [INITIAL ENTRY
2GK= LDCH 0 0(3) [PICK UP CHAR
2H4W BCHX 3 £ [SET X3 READY TO PICK UP PARAM
2HJG SMO FX1
2J46 LDCH 1 0(3) [PICK UP FIRST PARAM
2JHQ SMO 0
2K3B BRN M [SWITCH
2KH2 #SKIP G4
2L2L (
2LG= # THIS SECTION OUTPUTS THE PROGS QUOTA & PAGE TURN COUNT AS PARAMS
2L^W NG4FRIG
2MFG FPCACA 2,FX2
2M^6 HUNT2 2,BSTB,BSCB
2NDQ LDX 6 AQUOTA(2)
2NYB ANDN 6 #7777
2PD2 LDX 7 ATSWAPS(2)
2PXL OUTPACKC 6,1,QUOTA
2QC= OUTPACKC 7,1,PAGETURN
2QWW BRN XNOP
2RBG )
2RW6 NOUTPACK
2S*Q HUNT2 2,APED,ANOMESS
2STB LDX 5 VCAREA+1(2)
2T*2 OUTPACKC 5,1,PERINAME
2TSL BRN XNOP
2W#= # THIS SECTION DOES AN'OUTBLOCK' TO SET UP A BLOCK FOR PARAMS.SIZE=%
2WRW NOUTBLOCK
2X?G #SKIP K6OPILLSA>999-999
2XR6 TRACE 1,OUTBLOCK
2Y=Q OUTBLOCK 1
2YQB BRN XNOP
2^=2 # OUTPUT A CHAR STRING FROM'APED,ANOMESS'AS A PARAM.NO.OF CHARS=%A.P
2^PL NOUTPARAM
329= #SKIP K6OPILLSA>999-999
32NW TRACE 1,OUTPARAM
338G BCHX 3 £ [PICK UP %B
33N6 SMO FX1
347Q LDCH 2 0(3)
34MB OUTPARAX 1,2,APED,ANOMESS
3572 BRN XNOP
35LL # OUTPUT THE CONTENTS OF A WORD(%A-AN ACC)IN OCTAL
366= NOCTAL
36KW LDX 0 0(1)
375G #SKIP K6OPILLSA>999-999
37K6 TRACE 0,OCTAL
384Q OUTNUM 0,OCTAL
38JB BRN XNOP
3942 # OUTPUT THE CONTENTS OF A WORD(%A)IN DECIMAL WITH ZERO SUPRESSION
39HL NDECIMAL
3=3= LDX 0 0(1)
3=GW #SKIP K6OPILLSA>999-999
3?2G TRACE 0,DECIMAL
3?G6 Z10
3?^Q OUTNUM 0,0
3#FB BRN XNOP
3#^2 # OUTPUT THE CONTENTS OF A WORD IN ADDRESS FORMAT.(TWO PARAMS)
3*DL NCADDR
3*Y= LDX 0 0(1) [PICK UP CONTENTS OF WORD
3BCW #SKIP K6OPILLSA>999-999
3BXG TRACE 0,CADDR.
3CC6 ANDX 0 BITS22LS [PUT OUT WORD ADDR
3CWQ OUTNUM 0,0
3DBB SMO FX1
3DW2 LDCH 1 0(3) [PICK UP PARAM AGAIN
3F*L LDCT 0 #600 [GET CHAR ADDR
3FT= ANDX 0 0(1)
3G#W BZE 0 Z12 [JUMP IF ZERO
3GSG SRL 0 10
3H#6 SMO FX1 [OUTPUT '. '
3HRQ ORX 0 QPOINT
3J?B Z11 LDN 2 2
3JR2 Z11A SMO FX2
3K=L STO 0 VEXT
3KQ= Z11B OUTPARAM 2,VEXT
3L9W BRN XNOP
3LPG Z12 LDX 0 ACES [OUTPUT' '
3M96 BRN Z11
3MNQ # OUTPUT THE CONTENTS OF A WORD AS A WORD ADDR.
3N8B NWADDR
3NN2 LDX 0 0(1)
3P7L #SKIP K6OPILLSA>999-999
3PM= TRACE 0,WADDR
3Q6W Z13 ANDX 0 BITS22LS
3QLG BRN Z10
3R66 #SKIP K6OPILLSA>999-999
3RKQ # OUTPUT THE CONTENTS OF A WORD AS A WORD ADDR IF +VE.ELSE OUTPUT NU
3S5B NPOSADDR
3SK2 LDX 0 0(1)
3T4L #SKIP K6OPILLSA>999-999
3TJ= TRACE 0,POSADDR
3W3W BPZ 0 Z13
3WHG Z13A OUTNULL
3X36 BRN XNOP
3XGQ # OUTPUT MESSAGE FROM TABLE.%A GIVES POSN IN TABLE
3Y2B NTABMESS
3YG2 SMO FX1
3Y^L LDX 0 W(1)
3^F= Z14
3^YW #SKIP K6OPILLSA>999-999
42DG TRACE 0,MESSAGE
42Y6 MONOUTX 0
43CQ BRN XNOP
43XB # OUTPUT MESSAGE WHOSE ADDRESS IS IN %A
44C2 NACCMESS
44WL LDX 0 0(1) [PICK UP ADDR OF MESSAGE
45B= ANDX 0 BITS22LS
45TW BRN Z14
46*G Z15 BCHX 3 £ [ENTRY FROM CONDITIONAL BRANCHES
46T6 SMO FX1
47#Q LDCH 1 0(3)
47SB # UNCONDITIONAL BRANCH.RESET X3 FROM TABLE
48#2 NBRN SMO FX1
48RL LDX 3 S(1)
49?= #SKIP K6OPILLSA>999-999
49QW TRACE 3,BRN
4==G BRN XFOP
4=Q6 # BRANCH IF CONTENTS OF %A ARE -VE TO %B
4?9Q NBNG LDX 0 0(1)
4?PB BNG 0 Z15
4#92 BRN XNOP
4#NL # BRANCH IF CONTENTS OF %A ARE ZERO TO %B
4*8= NBZE LDX 0 0(1)
4*MW BZE 0 Z15
4B7G BRN XNOP
4BM6 # BRANCH IF STORE PARITY FAIL
4C6Q NCOMPARE
4CLB LDX 0 0(1)
4D62 SMO FX1
4DKL TXU 0 1(3)
4F5= BCC Z15
4FJW ADN 3 1
4G4G BRN XNOP
4GJ6 # SWITCH TO TABLE ENTRY(%B)+CONTENTS OF %A
4H3Q NSWITCH
4HHB LDX 1 0(1) [PICK UP CONTENTS OF %A
4J32 BCHX 3 £ [PICK UP SECOND PARAM
4JGL SMO FX1
4K2= LDCH 0 0(3)
4KFW ADX 1 0
4K^G BRN NBRN
4LF6 # BRANCH IF B1 OF %A IS SET
4LYQ NBB1
4MDB LDX 0 0(1) [CONTENTS OF %A
4MY2 SLL 0 1
4NCL BNG 0 Z15 [JUMP IF B1 SET
4NX= BRN XNOP
4PBW # PICK UP %B WORDS FROM POSN %A IN APED,ANOMESS BLOCK
4PWG NPICKUP
4QB6 CALL 0 XFANOMESS [X2->APED,ANOMESS
4QTQ ADX 1 2
4R*B BCHX 3 £
4RT2 SMO FX1
4S#L LDCH 0 0(3)
4SS= LDN 2 4
4T?W SMO 0
4TRG MOVE 1 0
4W?6 #SKIP K6OPILLSA>999-999
4WQQ TRACE 4,PICKUP
4X=B BRN XNOP
4XQ2 # OUTPUT MILLTIME AS A PARAM FOR A MESSAGE
4Y9L NOUTMILL
4YP= OUTPARC JOBMILL
4^8W BRN XNOP
4^NG # OUTPUT MEMBER NO AS PARAM OF MESSAGE:EITHER'IN N'OR OUTNULL
5286 NMEMNO
52MQ LDX 0 0(1)
537B #SKIP K6OPILLSA>999-999
53M2 TRACE 0,MEMNO
546L BZE 0 Z13A [JUMP IF MEMBER NO.=0
54L= SMO FX1
555W ORX 0 QIN
55KG LDN 2 4
5656 BRN Z11A
56JQ # OUTPUT THE CONTENTS OF %A IN INSTRUCTION FORMAT.
574B # THE BRANCHING MODE IS FOUND FROM'VSTATE'OF APED,ANOMESS
57J2 NINSTR
583L LDX 2 FX2 [CLEAR BUFFER
58H= LDX 0 ACES
592W STO 0 VEXT(2)
59GG STO 0 VEXT+1(2)
5=26 STO 0 VEXT+2(2)
5=FQ STO 0 VEXT+3(2)
5=^B CALL 0 XFANOMESS [X2->APED;ANOMESS
5?F2 LDX 0 VSTATE(2)
5?YL ANDN 0 #40
5#D= LDN 2 VEXT
5#XW SMO FX1 [PICK UP PARAMETER DESTROYED BY LOCK
5*CG LDCH 1 0(3)
5*X6 INPRINTX 0(1),2,0
5BBQ LDN 2 16
5BWB BRN Z11B
5CB2 # SET UP THE APED,ANEVENT BLOCK WITH MESSAGE FROM THE GMON,AOUT BLOC
5CTL NCODE1
5D*= HUNTW 3,GMON,AOUT
5DSW LDX 4 VCOUNT(3)
5F#G ANDN 4 #7777
5FS6 SBN 4 40
5G?Q BNG 4 ZA6
5GRB LDN 4 0
5H?2 ZA6 ADN 4 40
5HQL CALL 0 XFANOMESS [X2->APED,ANOMESS
5J== STO 4 APEDSP1+2(2)
5JPW ADN 4 3
5K9G SRL 4 2
5KP6 BZE 4 ZA7
5L8Q LDN 5 VCOUNT+2(3)
5LNB LDN 6 APEDSP1+3(2)
5M82 SMO 4
5MML MOVE 5 0
5N7= ZA7 FREECORE 3
5NLW ADN 4 3
5P6G CALL 0 XFANOMESS [X2 POINTS TO APED,ANOMESS
5PL6 NAME 2,APED,ANEVENT
5Q5Q LDX 3 2
5QKB ALTLEN 3,4
5R52
5RJL #SKI IPT
5S4= (
5SHW FPCACA 2,,N
5T3G LDX 0 HPTTRACE(2) [TEST WHETHER PTTRACE PACKAGE IS
5TH6 ANDX 0 BIT11
5W2Q BZE 0 ZA8 [SWITCHED ON AND WHETHER PRINTING IS
5WGB DOWN PTTRACE,3 [REQUIRED AND IF SO GO DOWN TO IT
5X22 ZA8
5XFL )
5X^= PROGEND
5YDW # THIS SUBR SETS X2 APED,ANOMESS(ONLY ALTERS X2).
5YYG XFANOMESS
5^D6 SMO FX2
5^XQ STO 0 AWORK4
62CB HUNT2 2,APED,ANOMESS,FX2
62X2 SMO FX2
63BL LDX 0 AWORK4
63W= EXIT 0 0
64*W # TABLE OF MONITORING FILE MESSAGES
64TG W
65*6 #DEF WJZFAILED=0?-W
65SQ #SKIP G3
66#B +JZFAILED
66S2 #SKIP G4
67?L +JZFAILEDG4
67R= #DEF WJZPROG=0?-W
68=W #SKIP G3
68QG +JZPROG
69=6 #SKIP G4
69PQ +JZPROGG4
6=9B #DEF WHUSHSMO=0?-W
6=P2 +HUSHSMO
6?8L #DEF WHUSHINST=0?-W
6?N= +HUSHINST
6#7W #DEF WHUSHINS1=0?-W
6#MG +HUSHINS1
6*76 #DEF WJZEXIT=0?-W
6*LQ +JZEXIT
6B6B #DEF WJZSUM=0?-W
6BL2 +JZSUM
6C5L #DEF WJZMOVE=0?-W
6CK= +JZMOVE
6D4W #DEF WJZPERI=0?-W
6DJG +JZPERI
6F46 #DEF WJZCA2=0?-W
6FHQ +JZCA2
6G3B #DEF WJZCA3=0?-W
6GH2 +JZCA3
6H2L #DEF WJZCA4=0?-W
6HG= +JZCA4
6H^W #DEF WJZCA5=0?-W
6JFG +JZCA5
6J^6 #DEF WJZCA6=0?-W
6KDQ +JZCA6
6KYB #DEF WJZCA7=0?-W
6LD2 +JZCA7
6LXL #DEF WJZCA9=0?-W
6MC= +JZCA9
6MWW #SKIP 0?-W>63-63
6NBG ! TABLE OF MESSAGES TOO LONG
6NW6 # TABLE OF RESET VALUES FOR X3
6P*Q S
6PTB #DEF S1=0?-S
6Q*2 +T1
6QSL #DEF S2=0?-S
6R#= +T2
6RRW #DEF S3=0?-S
6S?G +T3
6SR6 #DEF S4=0?-S
6T=Q +T4
6TQB #DEF S20=0?-S [SWITCH ON TYPE OF CONTROL AREA
6W=2 +T20
6WPL +T21
6X9= +T22
6XNW +T23
6Y8G +T24
6YN6 #DEF S40=0?-S [SWITCH FOR LENGTH OF PERI AREA
6^7Q +T40
6^MB +T41
7272 +T42
72LL +T43
736= +T44
73KW +T45
745G +T46
74K6 +T47
754Q +T48
75JB +T49
7642 #SKIP 0?-S>63-63
76HL ! TABLE OF RESETS TOO LONG
773= # TABLE OF OPERATIONS.THIS IS THE TABLE THE MAIN LOOP SWITCHES ON
77GW M
782G #DEF MBRN=0?-M
78G6 BRN NBRN [UNCONDITIONAL BRANCH(I.E.RESETTING O
78^Q #DEF MBNG=0?-M
79FB BRN NBNG [BRANCH IF CONTENTS OF %A -VE TO %B
79^2 #DEF MBZE=0?-M
7=DL BRN NBZE [BRANCH IF CONTENTS OF %A ZERO TO %B
7=Y= #DEF MCOMPARE=0?-M
7?CW BRN NCOMPARE [TEST IF STORE PARITY FAIL
7?XG #DEF MSWITCH=0?-M
7#C6 BRN NSWITCH [SWITCH ON CONTENTS OF %A
7#WQ #DEF MBB1=0?-M
7*BB BRN NBB1 [BRANCH IF B1 OF CONTENTS OF %A IS SE
7*W2 #DEF MPICKUP=0?-M
7B*L BRN NPICKUP [PICK UP %B WORDS FROM %A IN APED,ANO
7BT= #DEF MOUTMILL=0?-M
7C#W BRN NOUTMILL [OUTPUT MILL TIME
7CSG #DEF MMEMNO=0?-M
7D#6 BRN NMEMNO [OUTPUT MEMBER NO IN THE FORM'IN N'OR
7DRQ #DEF MINSTR=0?-M
7F?B BRN NINSTR [OUTPUT CONTENTS OF A AS INSTR
7FR2 #DEF MOUTBLOCK=0?-M
7G=L BRN NOUTBLOCK [SET UP BLOCK READY FOR MESSAGE PARAM
7GQ= #DEF MOUTPARAM=0?-M
7H9W BRN NOUTPARAM [OUTPUT CHAR STRING AS PARAM OF MESSA
7HPG #DEF MOCTAL=0?-M
7J96 BRN NOCTAL [OUTPUT CONTENTS OF WORD IN OCTAL
7JNQ #DEF MDECIMAL=0?-M
7K8B BRN NDECIMAL [OUTPUT CONTENTS OF A WORD IN DECIMAL
7KN2 #DEF MCADDR=0?-M
7L7L BRN NCADDR [OUTPUT CONTENTS OF A WORD AS CHAR AD
7LM= #DEF MWADDR=0?-M
7M6W BRN NWADDR [OUTPUT CONTENTS OF A WORD AS WORD AD
7MLG #DEF MTABMESS=0?-M
7N66 BRN NTABMESS [OUTPUT MESSAGE FROM TABLE
7NKQ #DEF MACCMESS=0?-M
7P5B BRN NACCMESS [OUTPUT MESSAGE WHOSE ADDR IS IN %A
7PK2 #DEF MPOSADDR=0?-M
7Q4L BRN NPOSADDR
7QJ= #DEF MCODE1=0?-M
7R3W BRN NCODE1
7RHG #DEF MERR=0?-M
7S36 BRN NERR
7SGQ #SKIP G4
7T2B (
7TG2 #DEF MG4FRIG=0?-M
7T^L BRN NG4FRIG
7WF= )
7WYW #DEF MOUTPACK=0?-M
7XDG BRN NOUTPACK
7XY6 #SKIP 0?-M>63-63
7YCQ ! TABLE OF OPERATIONS TOO LONG
7YXB # THIS SECTION CONTAINS THE OPERATION CALLS FOR PRINTING ILLEGAL MES
7^C2 XPRINT
7^WL CHARS MPICKUP,VSPROG,3 [PICK UP MEMBER NO(X4)& TYPE OO ILLEG
82B= CHARS MACCMESS,6 [OUT PUT MESSAGE WHOSE ADDR IS IN X6
82TW #SKIP G3
83*G CHARS MOUTBLOCK,17 [MAKE BLOCK FOR PARAMS
83T6 #SKIP G4
84#Q CHARS MOUTBLOCK,23
84SB CHARS MOUTMILL [OUTPUT MILL TIME AS PARAM
85#2 #SKIP G4
85RL CHARS MG4FRIG [DESTROYS X6,7
86?= CHARS MMEMNO,4 [OUTPUT MEMBER NO.FROM X4
86QW CHARS MPICKUP,VMEMS,4 [PICK UP POSN OF PROGRAM MEMBERS
87=G CHARS MPOSADDR,4 [OUTPUT POSN OF PROGRAM MEMBERS
87Q6 CHARS MPOSADDR,5
889Q CHARS MPOSADDR,6
88PB CHARS MPOSADDR,7
8992 CHARS MTABMESS,WJZPROG [OUTPUT '%A:FAILED %B.PROG AT %C,%D,%
89NL CHARS MPICKUP,VSCOND,1
8=8= CHARS MCOMPARE,4,S20
8=MW +JYPARFAIL
8?7G CHARS MPICKUP,VSMO,4 [PICK UP'SMO'INSTR
8?M6 CHARS MBNG,4,S1 [ JUMP IF NO SMO I.E.X4 -VE (TO LA
8#6Q CHARS MOUTBLOCK,14
8#LB CHARS MWADDR,4 [OUTPUT ADDR OF SMO INSTR AS PARAM
8*62 CHARS MINSTR,5 [OUTPUT SMO AS PARAM
8*KL CHARS MBB1,4,S3 [JUMP IF SHORT VERSION
8B5= CHARS MWADDR,6 [OUTPUT ADDR OF MODIFIER
8BJW CHARS MWADDR,7 [OUTPUT CONTENTS OF MODIFIER
8C4G CHARS MTABMESS,WHUSHSMO [PRINT'SMO'
8CJ6 T1 CHARS MPICKUP,VINSTR,4 [PICK UP INSTR
8D3Q CHARS MBNG,4,S2 [JUMP(TO T2)IF NO INSTR
8DHB CHARS MOUTBLOCK,14
8F32 CHARS MWADDR,4 [OUTPUT ADDR OF INSTRUCTION
8FGL CHARS MINSTR,5 [OUTPUT INSTRUCTION
8G2= CHARS MBB1,4,S4 [JUMP IF SHORT VERION
8GFW CHARS MCADDR,6 [OUTPUT ADDR
8G^G CHARS MTABMESS,WHUSHINST [PRINT INSTRUCTION
8HF6 T2 CHARS MPICKUP,VCAREA,4 [EXAMINE TYPE OF CONTROL AREA ASSOC
8HYQ CHARS MSWITCH,4,S20 [WITH INSTR & SWITCH ON IT.
8JDB T3 CHARS MTABMESS,WHUSHINS1 [PRINT SHORT VERSION
8JY2 CHARS MBRN,S1
8KCL T4 CHARS MTABMESS,WHUSHINS1
8KX= CHARS MBRN,S2
8LBW # THESE SECTIONS PRINT THE VARIOUS CONTROL AREAS.
8LWG T20 CHARS MCODE1 [NO CONTROL AREA:EXIT FROM MACROS TO
8MB6 # CONTROL AREA ASSOCIATED WITH'EXIT'(TYPE=1)
8MTQ T21 CHARS MWADDR,5 [OUTPUT'EXIT TO %A'WHERE %A=DESTINATI
8N*B CHARS MTABMESS,WJZEXIT [
8NT2 CHARS MCODE1
8P#L # CONTROL AREA ASSOCIATED WITH 'SUM'(TYPE=2)
8PS= T22 CHARS MOUTBLOCK,8
8Q?W CHARS MDECIMAL,5 [NO OF WORDS TO BE SUMMED
8QRG CHARS MWADDR,6 [ADDR AT WHICH SUMMING WAS TO START
8R?6 CHARS MTABMESS,WJZSUM [OUTPUT'SUM %A WORDS FROM %B'
8RQQ CHARS MCODE1
8S=B # CONTROL AREA ASSOC WITH'MOVE'&'MVCH'(TYPE=3)
8SQ2 T23 CHARS MOUTBLOCK,13
8T9L CHARS MDECIMAL,5
8TP= CHARS MCADDR,6
8W8W CHARS MCADDR,7
8WNG CHARS MTABMESS,WJZMOVE [OUTPUT'MOVE %A FROM %B%C TO %D%E
8X86 CHARS MCODE1
8XMQ # CONTROL AREAS ASSOCIATED WITH'PERI'(TYPE=4)
8Y7B T24 CHARS MOUTBLOCK,5
8YM2 CHARS MOUTPACK
8^6L CHARS MDECIMAL,6
8^L= CHARS MTABMESS,WJZPERI
925W CHARS MSWITCH,6,S40 [SWITCH ON LENGTH OF CONTROL AREA
92KG # FORBIDDEN CONTROL AREAS
9356 T40
93JQ T41
944B T48 CHARS MERR [ERROR
94J2 # TWO WORD CONTROL AREAS.PRINT IN OCTAL
953L T42 CHARS MPICKUP,VCAREA+3,2
95H= CHARS MOUTBLOCK,6
962W CHARS MOCTAL,4
96GG CHARS MOCTAL,5
9726 CHARS MTABMESS,WJZCA2
97FQ CHARS MCODE1
97^B # THREE WORD CONTROL AREA.
98F2 T43 CHARS MPICKUP,VCAREA+3,3
98YL CHARS MOUTBLOCK,9
99D= CHARS MOCTAL,4
99XW CHARS MOCTAL,5
9=CG CHARS MDECIMAL,6
9=X6 CHARS MTABMESS,WJZCA3
9?BQ CHARS MCODE1
9?WB # FOUR WORD CONTROL AREA
9#B2 T44 CHARS MPICKUP,VCAREA+3,4
9#TL CHARS MOUTBLOCK,14
9**= CHARS MOCTAL,4
9*SW CHARS MOCTAL,5
9B#G CHARS MDECIMAL,6
9BS6 CHARS MCADDR,7
9C?Q CHARS MTABMESS,WJZCA4
9CRB CHARS MCODE1
9D?2 # FIVE WORD CONTROL AREA
9DQL T45 CHARS MOUTBLOCK,17
9F== CHARS MOCTAL,7
9FPW CHARS MPICKUP,VCAREA+4,4
9G9G CHARS MOCTAL,4
9GP6 CHARS MDECIMAL,5
9H8Q CHARS MCADDR,6
9HNB CHARS MDECIMAL,7
9J82 CHARS MTABMESS,WJZCA5
9JML CHARS MCODE1
9K7= # SIX WORD CONTROL AREA
9KLW T46 CHARS MPICKUP,VCAREA+3,4
9L6G CHARS MOUTBLOCK,22
9LL6 CHARS MOCTAL,4
9M5Q CHARS MOCTAL,5
9MKB CHARS MOCTAL,6
9N52 CHARS MOCTAL,7
9NJL CHARS MPICKUP,VCAREA+7,2
9P4= CHARS MOCTAL,4
9PHW CHARS MOCTAL,5
9Q3G CHARS MOUTPARAM,12,VCAREA+5
9QH6 CHARS MTABMESS,WJZCA6
9R2Q CHARS MCODE1
9RGB # SEVEN WORD CONTROL AREA
9S22 T47 CHARS MOUTBLOCK,25
9SFL CHARS MPICKUP,VCAREA+3,4
9S^= CHARS MOCTAL,4
9TDW CHARS MOCTAL,5
9TYG CHARS MOCTAL,6
9WD6 CHARS MOCTAL,7
9WXQ CHARS MPICKUP,VCAREA+7,3
9XCB CHARS MOCTAL,4
9XX2 CHARS MOCTAL,5
9YBL CHARS MOCTAL,6
9YW= CHARS MOUTPARAM,12,VCAREA+5
9^*W CHARS MTABMESS,WJZCA7
9^TG CHARS MCODE1
=2*6 # NINE WORD CONTROL AREA
=2SQ T49 CHARS MOUTBLOCK,31
=3#B CHARS MOCTAL,7
=3S2 CHARS MPICKUP,VCAREA+4,4
=4?L CHARS MOCTAL,4
=4R= CHARS MOCTAL,5
=5=W CHARS MOCTAL,6
=5QG CHARS MOCTAL,7
=6=6 CHARS MPICKUP,VCAREA+8,4
=6PQ CHARS MOCTAL,4
=79B CHARS MOCTAL,5
=7P2 CHARS MOCTAL,6
=88L CHARS MOCTAL,7
=8N= CHARS MOUTPARAM,12,VCAREA+5
=97W CHARS MTABMESS,WJZCA9
=9MG CHARS MCODE1
==76 #REP 20
==LQ +0
=?6B #END
^^^^ ...15610544000300000000