{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: PLUGIN867)}}
====== PLUGIN867 ======
(George Source)
**Macros used:** [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:BSOFF|BSOFF]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:COBJUNUSE|COBJUNUSE]], [[george:macro:COBJUSE|COBJUSE]], [[george:macro:COBJUSRT|COBJUSRT]], [[george:macro:COMPROLINK|COMPROLINK]], [[george:macro:COOR1X|COOR1X]], [[george:macro:ENDPAXES|ENDPAXES]], [[george:macro:EVENTFIN|EVENTFIN]], [[george:macro:FCAPCA|FCAPCA]], [[george:macro:FINDPUC|FINDPUC]], [[george:macro:FINDTP|FINDTP]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FPUT|FPUT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JBSS|JBSS]], [[george:macro:JCAFSBSY|JCAFSBSY]], [[george:macro:JMBAC|JMBAC]], [[george:macro:LDBIT|LDBIT]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCKC|LOCKC]], [[george:macro:MACCS|MACCS]], [[george:macro:MBC|MBC]], [[george:macro:MBI|MBI]], [[george:macro:MBS|MBS]], [[george:macro:MELRING|MELRING]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PCATEST|PCATEST]], [[george:macro:RINGTP|RINGTP]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETBIT|SETBIT]], [[george:macro:TRACE|TRACE]], [[george:macro:UPLINK|UPLINK]]
22FL #LIS K0PLUGIN>K0LLS
22^= ...#SEG PLUGIN [OWEN N. JOHN (:CENT)
2357 ...[
2394 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
23#^ ...[
23DW 8HPLUGIN
23YG #
24D6 # THIS SEGMENT'S ONLY FUNCTION IS TO PLUG IN A PROGRAM
24XQ #
25CB # THE ENTRY POINTS ARE :
25X2 #
26BL #
26W= SEGENTRY K1PLUGIN,XX1P [FROM RUNPROG - PROGRAM S/I
27*W SEGENTRY K2PLUGIN,XX2P [PCAPLUG ENTRY
27TG SEGENTRY K3PLUGIN,XX3P [FROM CORESHED - PROGRAM WAS S/O
28*6 P12 COMPROLINK ['PROGBRKIN' TYPE LINK
28SQ ZAYT +8
29#B SMASK #40777000 [MASK FOR CLEARING SOME BITS IN ASTOP
29S2 # S/R TO SET TIME SLOT: LINK X7,EXPECTS X3 -> JOBBLOCK
2=?L #
2=R= TIMESLOT
2?=W LDX 5 JCSIZE(3)
2?QG ADN 5 1023
2#=6 SRL 5 10 [SIZE IN K
2#PQ BSOFF CPIBIT,USESIZE [J IF USING SIZE FOR TIMESLOT
2*9B LDN 5 100
2*P2 MPY 5 JCPI(3) [OTHERWISE USE CPI
2B8L BNZ 5 NONZ
2BN= LDN 5 1
2C7W NONZ
2CMG USESIZE
2D76 MPY 5 ASLOTTIME
2DLQ STO 6 ATIMES(3) [SET IN JOB BLOCK
2F6B STOZ HTIMES(3)
2FL2 STOZ HMSLOT(3)
2G5L EXIT 7 0
2GK= [
2H4W [
2HJG [ SUBROUTINE TO RING MEL ON PROGRAM RING
2J46 [
2JHQ [
2JM^ ...PGEO2
2JPB ... LDX 0 GSIGN [SET B0 OF ATU1
2JQR ... SMO 6 [TO INDICATE PROGRAM HAS BEEN
2JS8 ... ORS 0 ATU1 [PLUGGED IN.USED BY CHARGESC
2JTK ... MELRING 6
2KH2 TRACE JOBNO(2),PLUGGDIN
2L2L EXIT 4 0
2LG= XFCA FCAPCA 2
2L^W EXIT 6 0
2MFG [ S/R TO FIND J VIA JOB RING
2M^6 [
2NDQ TJOB FJOPCA 3,FX2
2NYB EXIT 6 0
2PD2 [
2PXL [
2QC= [ SUBROUTINE TO CLEAR TOO BIG MARKERS I.E. RETURN SUCH JOBS
2QWW [ TO CORE SCHEDULER CONSIDERATION
2RBG [
2RW6 #
2S*Q TCLEAR
2SGD ... LDX 0 BIGPROGCP
2SJ2 ... BZE 0 (6) [EXIT IF NO BIG PROG'S
2SKJ ... STOZ BIGPROGCP
2TSL LDN 3 BJOBQ
2W#= NN LDX 3 FPTR(3)
2WRW BXE 3 CXJO,(6)
2X?G BC 3,JBBIG [CLEAR ANY TOO BIG MARKERS
2XR6 BRN NN
2Y=Q #
2YQB # PUT ALL MELS OF JOB ON TIMESHARER'S LIST USING MELRING.
2^=2 # ON ENTRY, X3 CONTAINS THE ADDRESS OF THE RELEVANT JOB BLOCK. LINK
2^PL # ON EXIT, X1=FX1,X2=FX2,X3 IS UNCHANGED,X0 AND X4,X5,X6 ARE DESTROY
329= # NO COORDINATION.
32NW #
338G SPLUGIN1
33N6 LDX 5 1
347Q PCATEST 1,NORM,TP,PUC
34MB TP FINDPUC 1,6
3572 CALL 4 RCTP [SORT OUT WORD 31 PROBLEMS
35LL BRN PUC1
366= PUC LDX 6 1 [X6 ALWAYS -> PUC
36KW FINDTP 1,5 [X5 ALWAYS -> TP
375G CALL 4 RCTP1
37K6 PUC1 CALL 4 PGEO2 [RING PUC ON TIMESHARER RING
384Q LDBIT 14,0
38JB SMO 6
3942 STO 0 ASTOP [SET PUCS STOP WORD
39HL NORM LDX 6 5 [X6 -> NORMAL/TP PCA
3=3= CALL 4 PGEO2
3?G6 JBCC (7),3,JBREON [J UNLESS REALTIME REQUESTED
3?^Q LDX 5 1
3#FB BS 3,JBREEF [MARK REALTIME EFFECTED
3#^2 SMO 6
3*DL LDX 2 ADATUM
3*HQ ...#UNS CA1D
3*LW ... SBX 2 CA1D [X2 -> AOBJPROG BLOCK
3*Q2 ...#UNS CA1D
3*T6 ...#SKI
3*Y= SBN 2 A1D [X2 -> AOBJPROG BLOCK
3BCW LDX 0 ALOGLEN(2)
3BXG ADS 0 COBJUSRT [UPDATE CORE FOR REALTIME PROGS
3CC6 LDX 0 GSIGN
3CWQ ORS 0 JRETI(2)
3DBB LDX 1 FX1
3F*L EXIT 7 0
3FT= #
3G#W # S/R FOR RCTP PROBLEMS
3GGP ...# TP ENTERS AT RCTP, PUC AT RCTP1,X5-> TP,X6 ->PUC,LINK X4
3GNJ ...[
3GWC ...[ THE FOLLOWING CORRECTS B3068 - WHICH RESULTED INTHE
3H4= ...[ PUC BEING INCORRECTLY RINGED RE JOBBLOCK
3H=5 ...[ DONE 19TH JUNE 1975 :CENT
3HCY ...[
3HKR ...RCTP1 RINGTP 6 [ENRING TP.PCA
3HRQ RCTP LDX 1 5
3J?B LINKSET 1,GVFN
3JR2 LINKSET 6,GVFN [SET LINKS
3K=L MACCS ,1,2 [X2 -> TP DATUM
3KQ= SMO 6
3L9W LDX 0 ANM
3LPG ANDN 0 3 [PUC MEMB NO
3M96 SLL 0 6
3MNQ ORS 0 31(2)
3N8B MACCS ,6,2 [X2 -> PUC DATUM
3NN2 ... BXE 5 FX2,(4) [J IF TP CUURENT
3PSD ... LDX 0 GMSK1
3P^L ... ANDS 0 9(2) [CLEAR MODE BITS
3Q6W SMO 6
3QLG LDCH 0 ALMT [X0 HAS PUC MODES
3R66 SRC 0 8
3RKQ ORS 0 9(2) [SET MODE BITS IN PUC
3T4L EXIT 4 0
3TJ= #
3W3W #
3WHG # SUBROUTINE TO FIND BLOCK OF TYPE IN X4 SEARCHING FROM X5,RESULT
3X36 # IN X2,LINK X1
3XGQ #
3Y2B RFIND LDX 2 5
3YG2 RFIN1 LDX 2 FPTR(2)
3Y^L LDX 0 ATYPE(2)
3^F= SRL 0 12
3^YW BXU 0 4,RFIN1
42DG EXIT 1 0
42Y6 #
43CQ # SUBROUTINE TO LOCK BLOCK POINTED TO BY X2,LINK X6
43XB #
44C2 XLOCK SBX 6 FX1
44WL LOCKC 2,RFIND
45B= XLOCK1
45TW CALL 1 RFIND [GET POINTERS AGAIN
46*G LDX 1 5
46T6 LDCH 0 ATYPE(1)
47#Q SBN 0 APET/64
47SB BZE 0 XIT [J IF X1 -> APET
48#2 LDX 1 APETADDR(1) [X1 ->APET
48RL XIT ADX 6 FX1
49?= EXIT 6 0
49QW # SUBROUTINE TO LOCK BLOCKS FOR PLUGIN
4==G #
4=Q6 #
4?9Q SPLUGIN2
4?PB SBX 7 FX1
4#92 LDX 5 1
4#NL LDN 4 APERI+APERIRES
4*8= CALL 1 RFIND [X2 -> PRB
4*MW CALL 6 XLOCK [LOCK PRB,X2 ->PRB,X5=X1 ->APET
4B7G LDN 4 A1(2)
4BM6 PCATEST 1,NORMAL,TP1
4C6Q FINDTP 1,1 [X1 -1TP/PCA FOR X5 -> PUC
4CLB BRN PUC3
4D62 TP1 FINDPUC 1,5 [X5 -> PUC,X1 ->TP
4DKL PUC3 SMO 5
4F5= ADS 4 APRB [MAKE PUCS PRB PTR ABSOLUTE
4FJW NORMAL
4G4G LDX 5 1 [X5 -> NORMAL/TP PCA
4GJ6 STO 4 APRB(1)
4H3Q LDX 3 4 [X3 -> DOWN PRB
4HHB LDN 4 AOLPT
4J32 XLOOP LDXC 0 0(3)
4JGL BCS PEND [J IF END OF PRB
4K2= LDXC 0 1(3)
4KFW BCC XLOOP1 [J IF ONLINE
4K^G CALL 1 RFIND [X2 -> NEXT OLPA
4L6N ...#UNS CAFSINT
4L?W ... JCAFSBSY 2,XNOLOCK [DON'T LOCK OLPA IF CAFS ORDERS O/S
4LF6 CALL 6 XLOCK
4LL# ...#UNS CAFSINT
4LMK ...(
4LNW ... BRN XLOCKED
4LQ7 ...#
4LRG ...XNOLOCK
4LS4 ... LDX 1 5 [WHEN WE DON'T LOCK THE OLPA, WE HAVE
4LSL ... LDCH 0 ATYPE(1) [TO RECONSTRUCT THE POINTER TO THE
4LT8 ... SBN 0 APET/64 [APET WHICH IS CORRUPTED BY CALLING
4LTQ ... BZE 0 XLOCKED ['RFIND' & NORMALLY RESET BY 'XLOCK'
4LW# ... LDX 1 APETADDR(1)
4LWW ...#
4LXD ...XLOCKED
4LY2 ...)
4LYQ LDN 0 CHAINADD(2)
4MDB ORX 0 GSIGN
4MY2 STO 0 1(3) [CHAINING ADDRESS TO PRB
4NCL STO 1 APETADDR(2)
4NX= LDX 5 2 [X5 -> LAST OLPA
4PBW XLOOP1
4PWG BDX 3 XLOOP [BACK FOR NEXT
4QB6 PEND
4QTQ ADX 7 FX1
4R*B LDX 1 FX1
4RT2 LDX 2 FX2
4S#L CALL 6 TJOB [X3 -> JOBBLOCK
4SS= BC 3,JBPLUGGING [ALL SAFE NOW
4T?W MBC 3,JBBEING,JBSUSP
4TRG MBS 3,JBSI,JBPLUG,JBRUN [SET JOBBLOCK MARKERS
4W?6 JBC (7),3,JBRCTP [EXIT IF NOT RCTP
4WQQ JBC (7),3,JBREEF [EXIT IF NOT REALTIME EFFECTED
4X=B FPCAJO 1,3
4XQ2 BXU 2 1,PUCCURRENT [J IF PUC CURRENT
4Y9L FINDPUC 1,6
4YP= LDX 5 1 [X5-> TP,X6->PUC
4^8W CALL 4 RCTP
4^NG BRN PUCC1
5286 PUCCURRENT
52MQ LDX 5 1 [X5 -> TP
537B LDX 6 2 [X6 -> PUC
53M2 CALL 4 RCTP1
546L PUCC1
54L= LDN 0 #1000
555W SMO 6
558N ... STO 0 ASTOP [SET B14 OF PUC STOP WORD
55?G ...[
55B# ...[ THIS CURES B2925 - GEOERR TWOTRANS WHEREBY PROGRAMS
55F6 ...[ WITH A HIGHER PRIORITY THAN GEORGE HAVE THERE ASTOP CLEARED
55HY ...[ BECAUSE ON LEAVING THIS ROUTINE X1 .NE. FX1
55LQ ...[ DONE 3RD JUNE 75 :CENT
55PJ ...[
55SB ... LDX 1 FX1
55X8 ... LDX 2 FX2
5622 ...[
5656 EXIT 7 0
56JQ #
574B XX3P
57J2 LDN 0 0
583L BRN XJOYN
58H= XX1P
592W LDN 0 1
59GG ...XJOYN STO 0 AWORK2(2) [CLEARS B0170 - ACOMMUNE1 OVERWRITT
5=26 # ENTRY IN PCA : TO PLUGIN AFTER SWAPIN
5=FQ # FIRST WE OUTPUT MESSAGES IF APPROPRIATE
5=^B
5?F2 CALL 6 TCLEAR
5?YL CALL 6 TJOB
5#D= COBJUSE 5
5#SH ... JBC NOTRE,,ASWREALBAD [J IF RE FRAG MESS.NOT BEEN OUTPUT
5#YL ... BXL 5 COBJQUOTA,NOCAN [IF WE ARE MEETING OQ,THEN J TO
5*4P ... BC ,ASWREALBAD [ QUOTAMET TO OUTPUT CLEAR MESSAGE
5*8S ... BRN QUOTAMET
5*#X ...NOTRE
5*K5 ...[
5*P8 ...[ NOW ADD TO TOTAL IN USE FOR O/P THE AMOUNT OF FREE/FREEABLE CORE
5*T? ...[
5*^B ... LDX 0 ACHAP
5B5F ... SBX 0 CHAPQUOTA
5B9J ... BNG 0 NOCHAP
5B*M ... ADX 5 0 [ADD IN CHAPTERS OVER CHAPQUOTA
5BFQ ...NOCHAP
5BKT ... COBJUNUSE
5BPY ... ADX 5 0 [ +FREE PROGRAM BLOCKS/PAGES
5BW3 ... ADX 5 CFREE [ + FREE CORE
5C26 ... SBX 5 FREZTOT [ - FROZEN BLOCKS APART FROM
5C69 ... ADX 5 FREZFREE [ FREE
5C=# ... ADX 5 FREZCHAP [ & CHAP
5CBC ... BXL 5 COBJQUOTA,NOCAN [J IF WE CANNOT MEET OQ
5CGG ... JBCC NODEL,,ASWOQMISS [J IF MESS.NOT OUTPUT TO CLEAR DELAY
5CLK ...QUOTAMET
5CQN ... MONOUT CANQUOT [OUTPUT THAT QUOTA CAN NOW BE MET
5CWR ... CALL 6 TJOB
5D2W ... BRN NOCAN [CAN'T STOZ DELAY IN CASE RE FRAG.
5D6^ ...NODEL
5D?4 ... STOZ CLLSUNOQ [MAKE SURE NO DELAY IN PROGRESS
5DC7 ...[
5DH= ...[ NOW SEE IF CLEARANCE MESSAGES ARE NECESSARY FOR TOO BIG MESSAGES
5DM* ...[ WHICH HAVE BEEN/ARE WAITING FOR OUTPUT
5DRD ...[
5DXH ...NOCAN
5F3L ... BC 3,JBSIFAIL [CLEAR BIT IF SET
5F7P ... JBCC NOOK,3,JBBIGMESS [J IF NO MESS OUTSTANDING 4 CLEAR
5F#G [OTHERWISE
5FS6 OUTPACK JOBNUM(3),1,NUMA
5G?Q MONOUT APROGOK
5GRB CALL 6 TJOB
5H?2 NOOK BC 3,JBBEING
5HQL #
5J== # NOW CHECK IF THIS IS SWAPIN AFTER SPECIAL SWAPOUT
5JPW # IF SO WE MUST FIND WHICH ACTIVITY WAS WAITING FOR CORE AND
5K9G # FPUT IT TO TRY AGAIN
5KP6 # AS WE ARE IN PCA,WE MOVE CJACCLINK OVER OURSELVES
5L8Q #
5LNB BS 3,JBSI [MARK S/I
5M82 JMBAC NSPEC,3,JBPISO,JBSTSO [J IF NOT SPEC S/O & CLEAR IF WAS
5MML JBCC STOPPED,3,JBPISO [J IF WAS STOPPED
5N7= LDX 1 2 [LEAVING PI BIT CLEAR
5NLW SMO FX2
5P6G STO 1 AWORK1
5PL6 CALL 7 SPLUGIN2 [LOCK BLOCKS
5Q5Q SMO FX2
5QKB LDX 1 AWORK1 [X1 -> PCA
5R52 PCATEST 1,NORMAL1,TPS,PUCS
5RJL TPS FINDPUC 1,1
5S4= PUCS LDX 6 1
5SHW CALL 4 PGEO2 [ENRING PUC
5T3G FINDTP 1,1
5TH6 NORMAL1
5W2Q LDX 6 1
5WGB CALL 4 PGEO2 [ENRING NORMAL/TP
5X22 LDX 2 6
5XFL BRN MEET
5X^= STOPPED
5YDW LDX 6 2
5YYG MBI 3,JBSUSP,JBSTSO,JBSTOP [MARK STOPPED
5^D6 MEET [NOW FIND WHICH ACTIVITY WAS WAITING
5^XQ ... PCATEST 2,NORMAL2,NORMAL2 [FOR CORD
63BL FINDTP 2,2
63W= NORMAL2
64*W LDN 4 CJACCLINK
64TG LDN 5 ACC3(2)
65*6 MOVE 4 ALINK
65SQ ADN 4 ALINK
66#B LDN 5 ACOMMUNE1(2)
66S2 MOVE 4 9
67?L ADN 4 9
67R= LDN 5 CLONG1(2)
68=W MOVE 4 1 [RESTORE PCA INFO FROM FIXED
68QG STOZ CJACCLINK+ALINK1-ACC3 [MARK CLEAR FOR ANOTHER SPEC SWAP
68T5 ... PCATEST 2,NORMAL3,TP3,PUC3A
68XN ...TP3 FINDPUC 2,2
692? ...PUC3A CALL 4 TESTW
694W ... FINDTP 2,2
697F ...NORMAL3
69=6 CALL 4 TESTW [OR NORMAL/TP
69PQ NACT LDX 2 ACTRING(2)
6=9B SBN 2 ACTRING
6=P2 LDCH 0 ATYPE(2)
6?8L SBN 0 AOLPT/64
6?N= BNZ 0 XCPA
6#7W CALL 4 TESTW [OR OLPA
6#MG BRN NACT
6*76 XCPA FCAPCA 2,6 [X2 -> CPA
6*LQ CALL 4 TESTW
6B6B GEOERR 1,WAITMISS [ERROR IF NOTHING MISSING
6BL2 [ S/R TO CHECK IF X2-7 ACT WAITING FOR CORE,LINK X4
6C5L TESTW LDX 0 CLONG1(2)
6CK= BPZ 0 XOBJCNT
6D4W LDN 0 1 [INCREMENT WAITING FOR
6DJG ADS 0 CFAIL [ CORE FAIL COUNT
6F46 BRN XAGIN
6FHQ XOBJCNT
6KYB EXIT 4 0
6LD2 XAGIN
6LXL FPUT [LET IT HAVE ANOTHER GO
6MC= COOR1X [LET IT RUN
6MWW NSPEC
6NBG #
6NW6 # NORMAL CASE: PLUGIN AFTER SWAPIN : 1ST CHECK FOR PCACA AND BREAKIN
6P*Q # IF PCACA,KICK CPA IF B-IN,PROGBRKIN VIA CPA,
6PTB # OTHERWISE PLUGIN AND EVENTFIN.
6Q*2
6QSL JBCC NPCACA,3,JBPCACA [J IF CPA NOT WAITING IN PCACA 4 CLEA
6R#= BS 3,JBSTOP [IF IT IS
6RRW MBC 3,JBSUSP,JBPLUGGING [SUSP -> STOPPED
6S?G CALL 6 XFCA
6SR6 FPUT
6T=Q COOR1X [LET CPA RUN
6TQB NPCACA
6W=2 JBC R10,3,JBBIN
6WBD ...[
6WGW ...[ THIS CURES B3092 - BREAK IN PLUGIN BECAUSE WE DO A FCAPCA
6WM# ...[ WITHOUT X2 POINTING AT PCA (ONLY IF BREAK-IN)
6WRQ ...[ DONE 23RD JUNE 75 :CENT
6WY8 ...[
6X4L ... LDX 2 FX2
6X9= RBREAKIN
6XBD ... MBC 3,JBSUSP,JBPLUGGING [SUSPENDED -> DORMANT
6XHL ...[
6XNS ...[ CURES B3288 - CONCERNING FACT THAT IF PLUGIN DETECTED
6XW2 ...[ B-IN IT DID NOT FIRST CHECK THAT CPA WAS ALREADY ACTIVE
6Y38 ...[ THIS WOULD BE IMPLIED IF PROG WAS MARKED DORMANT
6Y8B ...[
6Y*J ... JBSS RBIN,3,JBDORM [IF DORMANT=>B-IN ALREADY NOTICED
6YGQ ... [ELSE SET JBDORM AND CONTINUE
6YN6 CALL 6 XFCA
6^7Q LINKSET 2,P12(1) [PROGBRKIN LINK
6^MB FPUT [PUT COMMAND ACTIVITY ON LIST
6^X8 ...RBIN
7272 COOR1X [LET CPA DO PROGBRKIN
72LL # PCAPLUG ENTRY IN PCA
736= # WE PLUG IN,SETTING TIMESLOT IF NEC,AND UPPLUS 1
73KW #
745G #
74K6 XX2P
754Q BS 2,ASTOPEXEC [ENSURE STOPPED
75JB LDX 1 2
7642 CALL 7 SPLUGIN2 [LOCK PRB AND OPLAS
76HL JBS REALTIME,3,JBREEF [NO NEED TO RING IF REALTIMR
773= LDX 1 FX2 [YES I MEAN FX2
77GW CALL 7 SPLUGIN1 [PLUG IN(MELRING) THE PROGRAM
782G REALTIME
78G6 LDX 2 FX2
78^Q LDX 0 SMASK(1)
79FB ANDS 0 ASTOP(2)
79^2 LDX 0 ATIMES(3)
7=DL BNZ 0 XK55
7=Y=
7?CW CALL 7 TIMESLOT [SET TIMESLOT
7?XG XK55
7#C6 ENDPAXES 3 [CLEAR 'BEING ACCESSED' MARKER
7#WQ BS 3,JBRUN [MRAK RUNNABLE
7D#6 FCAPCA 3,2
7DRQ UPLINK 3,1
7F?B #
7FR2 # NOW REST OF PLUGIN AFTER SWAPIN
7G=L #
7GQ= #
7H9W R10
7HPG LDCT 0 #400
7J96 STO 0 ASTOP(2) [READY FOR EVENTFIN
7JNQ LDX 1 2 [PCA ADDR TO X1
7K8B CALL 7 SPLUGIN2 [LOCK DOWN PRB AND ANY OLPAS
7KN2 LDX 0 ATIMES(3) [ HAS TIMESLOT EVER BEEN SET?
7L7L BZE 0 R10CA [ IF NOT THEN SET (FOR 1ST ENTER ONLY
7LM= SMO FX2
7M6W ... LDX 0 AWORK2
7MLG BNZ 0 R10C [J IF TIME SLOT UNEXPIRED
7N66 R10CA CALL 7 TIMESLOT [SET TIMESLOT
7NKQ BS 3,JBINSLOT [MARK INSLOT
7P5B R10C
7PK2 JBC T21,3,JBRCTP [J UNLESS RCTP
7PMS ...RCTP15
7PQL ...[ THIS CURES B2896 WHEREBY PLUGIN WAS SETTING B16 OF WD150
7PTD ...[ AND CLEARING B3 OF WD 149 OF THE PUC OBJECT PROGRAN !!
7PY= ...[ DONE 30 . 5 . 75 :CENT
7Q34 ...[
7Q5W ... LDX 2 FX2 [REFIND CURRENT PCA
7Q8N ... PCATEST 2,(GEOERR),TPEX [J IF TP IS CURRENT
7Q?G ... FINDTP 2,2 [PUC IS CURRENT SO FIND TP
7QB# ...TPEX
7QF6 ...[
7QJ= LDX 0 ASU1(2) [TICKLE TP MEMBER 0
7R3W BZE 0 SETP
7RHG LDCT 0 #40
7S36 ANDX 0 ASU1(2)
7SGQ BZE 0 SETP
7ST7 ... LDX 0 HSMPBIT
7T7J ... ANDS 0 ASU1(2)
7TG2 BRN T21
7T^L SETP
7W5H ... SETBIT 16,ARM1(2)
7W9D ...[
7W** ...[ THE FOLLOWING CURES B3241 - MUST ENSURE SMP CLEAR ONCE P SET
7WF= ...[
7WK7 ... LDX 0 HSMPBIT
7WP4 ... ANDS 0 ASU1(2) [CLEAR SMP BIT
7WS^ ...[
7WYW T21
82TW NOTRT JBS REALT,3,JBREEF [J IF REALTIME EFFECTED : NO RINGING
83*G REALR
83T6 LDX 1 FX2 [NECESSARY
84#Q CALL 7 SPLUGIN1 [PLUG IN PROGRAM IF NOT YET REALTIME
84SB
84YS ...REALT JBC NOTRCTP,3,JBRCTP [J UNLESS RCTP
855= ... FPCAJO 2,3 [X2 -> TP PCA
859N ... STOZ ASTOP(2) [DONT WANT TO USE EVENTFIN
85B6 ... COOR1X [AS COULD MESS UP STOP WORD
85GJ ...NOTRCTP
85M2 ... EVENTFIN [LET PROG RUN
85RL #
86?=
86QW #
87=G MENDAREA 50,K100PLUGIN
87Q6 #END
^^^^ ...115227140002