{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: PMENDNOS84)}}
====== PMENDNOS84 ======
(George Source)

**Macros used:** [[george:macro:ERROR|ERROR]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:PMESSAGE|PMESSAGE]], [[george:macro:SEGENTRY|SEGENTRY]]

<code - PMENDNOS84.txt>22^=    #OPT  K0PMENDNOS=0  
23DW    #LIS  K0PMENDNOS>K0POST>K0ALLGEO
24D6    #   
24XQ ...#SEG  PMENDNOS84                   [KAREL KOSKUBA - DIAG
25CB    [              THIS SEGMENT CONTAINS A ROUTINE FOR THE OUTPUT OF THE
25X2    [              NUMBERS OF ALL MENDS USED IN THE CURRENT RUN OF GEORGE   
26BL    #REP           +417 
26W=                   +0   
27*W          FIXTRA   JMENDTAB 
27TG                8HPMENDNOS  
28*6    #   
28SQ    #     ENTRY POINT TABLE 
29#B    #   
29S2 ... SEGENTRY K1PMENDNOS,XK1PMENDNOS
2=R=    #   
2?=W    #              MEND CHECKSUM ERROR ACTION MESSAGE   
2?QG    XSUMMESS       30HMEND CHECKSUM ERROR IN RESTORE
2#=6    MENDNO         +G3MARK*10000
2#PQ    XCOUNT         +417 
2*9B    XWORD          +0   
2*BJ ...MENDSFOUND     +0                  [ SET +VE IF ANY FOUND   
2*HQ ...NONE           8H    NONE   
2*P2    XHEADL         36HMENDS INCLUDED IN THIS RUN OF GEORGE  
2B8L    XK1PMENDNOS 
2BDD ...      LDX   1  FXPM1
2BN= ...      ADS   1  XCOUNT(1)           [ DATUMIZE   
2BY4 ...      LDX   2  XBADMEND(1)         [TEST FOR MEND CHECKSUM ERROR
2C7W          BPZ   2  NOBADMEND           [J IF CHECKSUM ERROR DETECTED
2CMG ...      PMESSAGE XSUMMESS(1),8          [PRINT ERROR MESSAGE  
2D76 ...      PMESSAGE XSUMMESS(1),8          [REPEAT ERROR MESSAGE 
2DLQ ...      CALL  7  (JPRINT2)
2F6B    NOBADMEND   
2FL2 ...      CALL  7  (JPRINT2)
2G5L ...      CALL  7  (JPRINT2)
2GK= ...      PMESSAGE XHEADL(1),9  
2H4W ...      LDX   2  FXPM1               [WORD COUNT FOR #GAP AREA
2HJG ...      LDN   0  15                  [INITIALISE PRINT BUFFER COUNTER 
2J46 ...XL6   LDX   3  0(2)                [FIRST/NEXT WORD OF #GAP AREA
2K3B          LDN   4  24   
2KH2          BZE   3  XL1  
2L2L    XL4   BPZ   3  XL3  
2L*3 ...      LDN   5  1
2LMD ...      ADS   5  MENDSFOUND(1)
2L^T ...      STO   3  XWORD(1)            [PRESERVE CHECK WORD 
2M#= ...      LDX   5  MENDNO(1)
2MLM ...      CALL  7  (JDECN)               [CONVERT BIN TO DEC
2M^6    #SKI  G3MARK<10-10        [UPDATE MODIFIER BY 3 CHARS IF <MARK10
2NDQ    (   
2NYB ...      CALL  7  (JUP)
2PD2                   +1   
2PXL    )   
2QC= ...      BCT   0  XL2  
2QWW ...      CALL  7  (JPRINT1)             [PRINT IF BUFFER CONTAINS 15 WORDS 
2RBG ...      LDN   0  15                  [RESET COUNT FO R PRI NT  B UFFER
2RW6 ...XL2   LDX   3  XWORD(1) 
2S*Q    XL3   LDN   6  1
2STB ...      ADS   6  MENDNO(1)           [UPDATE MENDNO BY 1  
2T*2          SLC   3  1
2TSL          BCT   4  XL4  
2W#=          BRN      XL5  
2WRW ...XL1   ADS   4  MENDNO(1)           [UPDATE MENDNO BY 24 
2X?G    XL5   ADN   2  1                   [UPDATE WORD COUNT   
2XR6 ...      TXU   2  XCOUNT(1)
2Y=Q          BCS      XL6                 [LOAD NEXT WORD IF ANY   
2YK7 ...      CALL  7  (JPRINT1)
2YXJ ...      LDX   7  MENDSFOUND(1)
2^9^ ...      BNZ   7  (JPMSEG) 
2^JB ...      PMESSAGE  NONE(1),2   
2^WR ...      BRN      (JPMSEG) 
329=    #   
32NW    #   
338G    XBADMEND       +0                  [ GIN SETS B0 FOR A MEND ERROR   
33N6    #   
347Q    #   
34MB    #END
^^^^ ...33054712000200000000
</code>