{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: PROCONTX867)}}
====== PROCONTX867 ======
(George Source)
**Macros used:** [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CCBRKIN|CCBRKIN]], [[george:macro:CIBRKIN|CIBRKIN]], [[george:macro:COMPROLINK|COMPROLINK]], [[george:macro:COOR3|COOR3]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JBSS|JBSS]], [[george:macro:JMBAS|JMBAS]], [[george:macro:JMBS|JMBS]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:MBC|MBC]], [[george:macro:MBS|MBS]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SENDPARS|SENDPARS]], [[george:macro:STOPIT|STOPIT]], [[george:macro:TESTAXES|TESTAXES]], [[george:macro:TESTOUT|TESTOUT]], [[george:macro:TRACE|TRACE]], [[george:macro:UNQUEUE|UNQUEUE]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22FL ...#SEG PROCONTX83 [RUTH PORTER
22PD ...# (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22^= #OPT K0PROCONTX=0
23DW #LIS K0PROCONTX>K0ALLGEO
23YG 8HPROCONTX
24D6 #
24XQ #
25CB # THIS SEGMENT INSPECTS THE CURRENT STATE OF A JOB AND TAKES S
25X2 # MEASURES AS ARE NECESSARY TO ENSURE THAT CONTROL OF THE JOB WILL B
26BL # RETURNED AS QUICKLY AS POSSIBLE TO THE COMMAND PROCESSOR, WHERE IT
26W= # BE 'STOPPED' AT A WELL DEFINED CLEAN POINT. THERE ARE ENTRY POINTS
27*W # EACH SEPARATE REASON FOR REQUIRING A JOB TO BE STOPPED, AS FOLLOWS
27TG # K3: USER REQUIRES TO BREAK-IN ON HIS JOB
28*6 # K13: USER REQUIRES TO CONNECT THE JOB TO HIS CONSOLE
28SQ # K14: OPERATOR REQUIRES TO ABANDON THE JOB
29#B # K15: GEORGE REQUIRES TO TERMINATE THE JOB DUE TO ITS MONITORING FI
29S2 # BECOMING FULL
2=?L # K16: GEORGE REQUIRES TO TERMINATE THE JOB DUE TO THE MOP CONSOLE B
2=R= # INOPERABLE
2?=W # K17: BREAK-IN VIA NBREAKIN MACRO
2?BR ...# K18: READ FAIL
2?GN ...# K20: ABANDON TIMED OUT MOP JOB
2?LK ...# K21: 'MOP OFF,LIMBO' COMMAND
2?NH ...# K22: SHARED FILESTORE ENTRY FOR TRANSBICHECK MACRO
2?QG #
2#=6 #
2#PQ ... SEGENTRY K1PROCONTX,XX1P [STOPJOB
2*9B ... SEGENTRY K2PROCONTX,XX2P [FINISH AB
2*P2 ... SEGENTRY K3PROCONTX,XX3P [MX B-IN
2B8L ... SEGENTRY K4PROCONTX,XX4P [CI B-IN
2BN= ... SEGENTRY K5PROCONTX,XX5P [CI RELEASE
2C7W ... SEGENTRY K7PROCONTX,XX7P [FINISH
2CMG ... SEGENTRY K8PROCONTX,XX8P [IPB
2D76 ... SEGENTRY K9PROCONTX,XX9P [S.P. UNLOAD
2DLQ ... SEGENTRY K12PROCONTX,XX12P [MF FILL
2F6B ... SEGENTRY K13PROCONTX,XX13P [CN
2FL2 ... SEGENTRY K14PROCONTX,XX14P [AB
2G5L ... SEGENTRY K15PROCONTX,XX15P [MF FULL
2GK= ... SEGENTRY K16PROCONTX,XX16P [INOP MOP
2H4W SEGENTRY K17PROCONTX,XX17
2H7F ...[ ENTRY POINT 20 TO AB TIMED OUT MOP JOBS
2H=4 ...[ MARK 830 ONLY
2H?R ... SEGENTRY K18PROCONTX,XX18P [READ FAIL
2H*G ... SEGENTRY K20PROCONTX,XX20 [AB
2HC? ...#UNS CRAMP
2HFW ... SEGENTRY K21PROCONTX,XX21P [MOP OFF LIMBO
2HF^ ... FSHENTRY K22PROCONTX,XX22P,XX22P,XX22P [COMPLETE AWAY BREAKIN
2HG4 ... FSHENTRY K23PROCONTX,XX23P,XX23P,XX23P [CONNECT WAIT IN HOME M/C
2HG5 ... FSHENTRY K24PROCONTX,XX24P,,XX24P [UNANTICIPATED CLOSEDOWN
2HH? ... SEGENTRY K25PROCONTX,XX25P [WRITE FAIL
2HJG PJLEN +ASTJOB [SIZE OF SHORT JOB BLOCK
2HLB ...PMASK #27777777
2HM# ...PMASKH #67777777
2HN= ...PBROKALMSK #67773777
2HQ6 ...PBROKADMSK #56377777
2HS2 ...PBROKCIMSK #76777777
2HTW ...PBROKALCB
2HXQ ...#HAL AMXOR+ALCB,0
2H^L ...PBROKADCB
2J3G ...#HAL AMXOR+ADCB,0
2J5B ...PBROKCILCB
2J7= ...#HAL AMXOR+CILCB,0
2J9# ...#SKI JWPHASE4
2JBG ...XABBITS +ABBITS
2JHQ #
2JRJ ... BITDEFS AWORK4,0,SWELL,SMOP,,USER,TEMP,SMESS
2JW7 ...#SKI JWPHASE4
2JYQ ... BITDEFS AWORK4,9,XAUTO
2K3B # STOPJOB
2KH2 #
2L2L # THIS SUBROUTINE IS USED BY ALL THE ENTRIES TO THE SEGMENT IN ORDER
2LG= # INSPECT THE CURRENT STATE OF THE JOB TO BE STOPPED AND TAKE THE NE
2L^W # ACTION TO GET IT STOPPED AS SOON AS POSSIBLE. THE ADDRESS OF THE C
2MFG # THE JOB IS IN X3 ON ENTRY AND THE LINK IS X5. EXITS 0 IF JOB NOT C
2M^6 # STOPPABLE, ELSE EXITS 2. NO COORDINATION. X0,X2,X4,X6,X7 DESTROYED
2NDQ #
2NYB #
2PD2 P10 COMPROLINK ['PROGBRKIN' TYPE LINK
2PXL #
2QC= ...[ THIS SUBROUTINE ISSUES THE TESTOUT MACRO
2QWW ...TESTOUT
2RBG ... SBX 5 FX1
2RW6 ... TESTOUT
2S*Q ... ADX 5 FX1
2STB ... EXIT 5 0
2Y=Q #
2Y#F ...[
2YB8 ...[ NB. ************
2YCX ...[
2YFL ...[ NEG X2 INDICATES NO JOBBLOCK - AS FOR MOP WELL JOBS.
2YH* ...[
2YK4 ...[ THIS IS USED IN THE K14 ENTRY FROM THE (AB) COMMAND
2YLR ...[
2YNG ...[
2YN^ ...STOPJOB1 [CHECK FOR BEING SAVED
2YPD ... BNG 2 STOPJOB
2YPX ... JBS XIT,2,JBSAVING
2YQB STOPJOB
2^=2 ...[CHECK BREAKIN BITS
2^PL ... JMBS XIT,3,BRBRKIN,BRINHIBIT
2^^D ...STOPMOP
329= ... MBS 3,BRBRKIN,BRNOTED [SET CPAT BITS
338G ... ADN 5 1
34CJ ... BNG 2 SKJB
34X8 ... BS 2,JBBIN [JOBBLOCK BIT
35#8 ...SKJB
35P8 ... LDX 4 ATYPE(3)
366= ANDN 4 #2000
36KW BZE 4 NOTLW [J NOT IN LONGWAIT
375G LDX 2 3 [COPY CPA ADDR
37K6 #SKI K6PROCONTX>99-99
384Q TRACE ATYPE(3),LONGWSJ
38JB UNQUEUE [REMOVE CPA FROM WAITING QUEUE
3942 FPUT [AND PUT IT ON THE LIST
39BC ...XIT
39NS ... EXIT 5 0
3=3= NOTLW
3=?4 ... BNG 2 XIT
3=GW LDX 0 JMISC(2)
3?2G #SKI K6PROCONTX>99-99
3?G6 TRACE 0,JMISCSJ
3?^Q ANDN 0 #777 [TEST IF CORE IMAGE
3#FB ... BZE 0 XIT [NO
3#^2 ANDN 0 #62 [TEST IF PROGRAM IS IN SUSPENDED STAT
3*DL BZE 0 NOTSUSP [NO
3*Y= ANDN 0 #60 [TEST IF SWAPPED BY UNJAMMER
3BCW BZE 0 NSPEC [NO
3BXG ANDN 0 #20 [ISOLATE SPECIAL PLUGGED STATE
3CC6 BRN TESTP [J TO SEE WHICH IT IS
3CWQ NSPEC
3D2M ...[ ALTHOUGH PROGRAM SUSPENDED,WE IGNORE BREAK-IN IF PROGRAM BEING
3D6J ...[ PLUGGED IN AS PLUGIN WILL NOTICE IT
3DL8 ... JBS XIT,2,JBPLUGGING
3F5S ... JBS XIT,2,JBBEING [IGNORE IF BEING SWAPPED
3FKD ... TESTAXES 2,XIT
3G54 ... JBC X1,2,JBPCACA [IGNORE LOAD CHECK UNLESS PCACA S37
3GJN ... JBCC XIT,2,JBLOAD [CLEAR LOAD MARKER IF SET
3H4# ... BS 2,JBDORM
3HHY ... BC 2,JBSUSP [CHARGE SUSP -> DORMANT
3LPG BRN X2 [YES,SO FPUT ACTIVITY
3M96 X1
3MHH ... BS 2,JBDORM
3MTY ... BC 2,JBSUSP
3N8B LINKSET 3,P10(1) [PROGBRKIN LINK
3NN2 X2
3Q6W LDX 2 3
3QLG FPUT [PUT COMMAND ACTIVITY ON LIST
3R66 ... BRN XIT
3RKQ NOTSUSP
3S5B LDX 0 JMISC(2)
3SK2 ANDN 0 #4 [SEE IF PROGRAM IS MARKED PLUGGED IN
3T4L TESTP
3TJ= ... BZE 0 XIT [NO
3W3W LDX 7 2
3WHG FPCAJO 2 [FIND PCA
3X36 ... BS 2,ASTOPBIN
3XGQ ... BRN XIT
3Y^L #
3^F= #
3^YW #
42DG # ENTRY FROM OLPA FOR STOPJOB EXTRACODE. X6=JOB NO.
42Y6 #
43CQ XX1P
43XB #SKI K6PROCONTX>99-99
44C2 TRACE 6,STOPJOBX
44WL CALL 5 SFINDCPA
4593 ... BRN UP
45HD ...#SKI JWPHASE4<1$1
45NL ...(
45TW LDX 0 CONTEXT(3)
46*G ANDN 0 #4000
46T6 BZE 0 NOSTOP1 [J IF NOT FULLY STARTED
474Y ...)
47#Q CALL 5 STOPJOB
47SB BRN NOSTOP1
48#2 LDCT 7 #200
48RL ORS 7 JOBEVENTS(3)
49?= ... LDX 7 PMASKH(1)
49QW ANDS 7 JOBEVENTS(3)
49S? ...#SKI
49TN ...(
49X5 ...#SKI JWPHASE4
49YG ...(
49^X ... JBS NSETB19,3,EXNONSTOP
4=3# ... LDN 0 #20
4=4P ... ORS 0 JOBEVENTS(3) [SAME AS B2 BUT ONLY NOTICED IN LONGWA
4=66 ...NSETB19
4=7H ...)
4=8Y ...)
4=FH ... BRN UPPLUSONE
4?9Q NOSTOP1
4?PB #SKI K6PROCONTX>99-99
4#92 TRACE JOBEVENTS(3),NSTOPJBX
4#NL ... BRN UP
4*8= #
4*MW # STOPJOB ENTRY FROM FINISH COMMAND.X6=JOB NO.
4B7G #
4BM6 XX2P
4C6Q #SKI K6PROCONTX>99-99
4CLB TRACE 6,FINISH
4D62 CALL 5 SFINDCPA
4DKL ... BRN UP [NON-EXISTANT
4F5= LDX 7 CONTEXT(3) [SYSTEM ISSUED?
4FJW BPZ 7 NSYSF [NO
4G4G ... BRN UPPLUSONE
4GJ6 ...NSYSF CALL 5 STOPJOB1
4H3Q ... BRN UP [JOB NOT STOPPABLE
4HHB ... BS 3,BRFINISH
4J32 ... CALL 5 TESTOUT
4JGL ... BRN UPPLUSTWO
4LYQ #
4MDB # BREAKIN. ENTRY FROM MULTIPLEXOR ACTIVITY. X6=JOB NO.
4MY2 #
4NCL XX3P
4NX= #SKI K6PROCONTX>99$99
4PBW TRACE 6,BREAKIN
4PWG CALL 5 SFINDCPA1
4QB6 ... BRN UPPLUSONE [NON-EXISTENT
4QTQ ... CALL 5 STOPMOP
4SS= ... BRN UPPLUSONE [JOB NOT STOPPABLE
4T?W ... BRN UP [JOB STOPPED
4XQ2 #
4Y9L # BREAKIN. ENTRY FROM OLPA FOR PERI TYPE 60. X6=JOB NO.
4YP= #
4^8W XX4P
4^NG CALL 5 SFINDCPA1
5286 BRN UPPLUSONE [NON-EXISTENT
52MQ CALL 5 STOPJOB
537B BRN UPPLUSONE [BREAK-IN INHIBITED
53M2 CIBRKIN 3 [SET 'BYI EFFECTED' BIT IN CILCB
546L ... BRN UP [BREAK-IN EFFECTED
55KG #
5656 # STOPJOB ENTRY FROM MOP OFF COMMAND OR WHEN ABANDONING JOBS BEING
56JQ # RUN FROM C.I. CHANNEL WHEN CHANNEL RELEASED. X6=JOB NO.
574B #
57J2 XX5P
583L CALL 5 SFINDCPA1
58H= ... BRN UP [NON-EXISTENT
592W CALL 5 STOPJOB
59GG BRN NOSTOP5 [NOT STOPPABLE
5=26 LDCT 7 #20
5=9Y ...XX5UP
5=FQ ORS 7 JOBEVENTS(3)
5=^B ... CALL 5 TESTOUT
5?F2 ... BRN UPPLUSONE [WILL BE STOPPED
5#D= NOSTOP5
5#XW #SKI K6PROCONTX>99-99
5*CG TRACE JOBEVENTS(3),NSTOPMOP
5*X6 ... BRN UP [NOT STOPPED
5BBQ #
5BWB #
5CB2 XX7P
5CTL CALL 5 SFINDCPA
5D*= ... BRN UP
5DSW ... CALL 5 STOPJOB1
5F#G ... BRN UP
5FS6 ... BS 3,BRSTOPFIN
5G?Q ... BRN UPPLUSONE
5JPW #
5K9G # BREAKIN.ENTRY FROM MULTIPLEXOR ACTIVITY FOR COMMUNICATIONS PROCESS
5KP6 # X6=JOB NO.
5L8Q #
5LNB XX8P
5M82 #SKI K6PROCONTX>99-99
5MML TRACE 6,BREAKIN8
5N7= CALL 5 SFINDCPA1
5NLW ... BRN UPPLUSONE
5P6G CALL 5 STOPJOB
5PL6 ... BRN UPPLUSONE [NOT STOPPABLE
5Q5Q CCBRKIN 3
5QKB ... BRN UP
5SHW #
5T3G # 'SPUNLOAD' ENTRY
5TH6 #
5W2Q XX9P
5WGB CALL 5 SFINDCPA1
5X22 ... BRN UP
5XFL CALL 5 STOPJOB
5X^= ... BRN UP
5YDW ... BS 3,BRUNLOAD
5YYG ... BRN UPPLUSONE
62CB #
62X2 # STOPJOB ENTRY FROM CONNECT COMMAND. X6=JOB NO.
63BL #
63W= XX13P
64*W #SKI K6PROCONTX>99$99
64TG TRACE 6,STOPJOBC
65*6 STO 6 AWORK1(2) [REMEMBER NO. OF JOB TO BE STOPPED
65SQ CALL 5 SFINDCPA
66#B ... BRN UP [NON EXISTENT
66S2 LDX 7 CONTEXT(3)
67?L BPZ 7 XNSYS
67R= ... BRN UPPLUSONE [ERROR IF SYSTEM ISSUED
68=W XNSYS
68QG ... CALL 5 STOPJOB1
69=6 BRN NOSTOP13 [NOT STOPPABLE
69PQ ... BS 3,BRCONNECT
6=P2 WAIT42
6?8L COOR3 #42 [WAIT FOR JOB TO STOP
6?N= LDX 6 AWORK1(2) [LOAD JOB NO.
6#7W CALL 5 SFINDCPA
6#CN ... BRN UP [JOB DISAPPEARED
6*76 LDX 7 JOBEVENTS(3)
6*LQ SLL 7 5
6B6B BNG 7 WAIT42 [J NOT STOPPED YET
6BL2 ... BRN UPPLUSTWO [JOB SUCCESSFULLY STOPPED
6CK= NOSTOP13
6D4W #SKI K6PROCONTX>99$99
6DJG TRACE JOBEVENTS(3),NSTOPCON
6F46 ... BRN UP [NOT STOPPED
6FHQ #
6G3B # STOPJOB ENTRY FROM ABANDON COMMAND. X6=JOB NO.
6GH2 #
6GKK ...XX20 STOZ AWORK1(2)
6GN8 ... MBC 2,SWELL,USER,TEMP
6GQR ... BS 2,SMOP
6GTB ...#
6GX^ ...#
6H2L ...XX14P
6H^W ... JOBLOCK 6,2 [ LOCATE JOBBLOCK
6JFG ... BNG 2 SAGIN [ GO BACK IF NOT FOUND
6JHD ...XFSHNBNOJOB
6J^6 ... LDCT 0 1
6KDQ ... ANDX 0 JMISC(2)
6KYB ... BNZ 0 SAGIN [ GO BACK IF JOB IS BEING SAVED
6LD2 ... FCAJO 3,2,N [ FIND CPAT
6LXL ... LDCH 0 ATYPE(3)
6MC= ... SBN 0 CPAT/64
6MWW ... BNZ 0 UPPLUSONE [ NO CPAT - GO BACK AND LINGER
6NBG ...TESTS LDX 1 FX2 [ BEWARE X1!
6ND4 ...#SKI JWPHASE4
6NFL ...(
6NH8 ... JBS XAUT,1,XAUTO [J IF IN AUTO AB ACT
6NJQ ... JBSS UPPLUSTWO,3,EXBEINGAB [J IF BEINNG AB'ED
6NL# ...XAUT LDX 0 JOBEVENTS(3)
6NMW ... SMO FX1
6NPD ... ANDX 0 XABBITS
6NR2 ... BNZ 0 UPPLUSTWO [J IF AB TYPE B-IN SET
6NSJ ...)
6NW6 ... LDX 0 CONTEXT(3) [ AB JOBS CONTEXT
6P*Q ... ANDN 0 2
6PTB ... BNZ 0 NOUSER [ J IF NO-USER CONTEXT
6Q*2 ... ANDN 0 8
6QSL ... BNZ 0 RMOP [ J IF MOP
6R#= ... JMBAS XSMOP,1,SWELL,SMOP [ J IF WELL MOP AS NO JOBLOCK
6RRW ... BRN STOPIT
6S?G ...NOUSER
6SR6 ... LDX 0 CONTEXT(3)
6T=Q ... ANDN 0 8
6TQB ... BZE 0 SAGIN [ NO-USER BACK USELESS
6W=2 ... JMBAS STOPIT,1,SWELL,SMOP [ J IF WELL MOP
6WPL ... BRN SAGIN
6X9= ...RMOP JBS SAGIN,1,SWELL [ CANT BE USER AND WELL
6XNW ... JBC SAGIN,1,SMOP [ MUST BE MOP
6Y8G ...STOPIT
6YD# ... LDX 1 FX1
6YS3 ... CALL 5 STOPJOB1 [ ACTUALLY STOP THE JOB
6^2T ... BRN UPPLUSONE
6^9N ... LDX 1 FX2 [ BEWARE X1!
6^?M ... JBC SETUS,1,USER
6^CJ ... BS 3,EXUSAB
6^HF ...SETUS
6^MB ... JBC SETAB,1,TEMP
7272 ... BS 3,EXABTEMP
72LL ...SETAB LDCT 0 4
736= ... ORS 0 JOBEVENTS(3) [ AB TYPE BREAKIN
73D2 ... CALL 5 TESTOUT
73PR ...#SKI JWPHASE4
73TN ... BRN UPPLUSTHREE
73^K ...#SKI JWPHASE4<1$1
74C= ... BRN UPPLUSTWO
74SY ...SAGIN LDX 2 FX2
754Q ... JMBAS XSMOP,2,SWELL,SMOP
75#J ... BRN UP
75JB ...XSMOP LDX 3 FX2
75Y5 ...XRND FINDACTF 3,3,CPAT,,UPPLUSONE,FPTR [ LOOK FOR MOP WAITING CPAT
76?S ... LDX 0 ACTNUM(3)
76MH ... TXU 0 AWORK1(2)
773= ... BCS XRND
77GW ... NGN 2 1 [ INDICATE NO JOBLOCK
782G ... BRN TESTS
7M6W #
7MLG # STOPJOB ENTRY FOR MONITORING FILE FULL. JOBNO(2)=JOB NO.
7N66 #
7NKQ XX12P
7P5B LDX 6 JOBNO(2)
7PK2 CALL 5 SFINDCPA
7Q4L ... BRN UP
7QJ= BRN NNN
7R3W XX15P
7RHG LDX 3 2
7S36 FJOCA 2
7SGQ NNN
7T2B #SKI K6PROCONTX>99-99
7TG2 TRACE JOBNO(3),STOPJOBF
7T^L CALL 5 STOPJOB
7WF= ... BRN UP [NOT STOPPABLE
7WYW ... BS 3,BRMONFUL
7XDG ... BRN UP [EXIT BACK TO MONFILE
7YXB #
7^C2 # STOPJOB ENTRY FOR INOPERABLE MOP CONSOLE
7^WL #
82B= XX16P
82TW #SKI K6PROCONTX>99-99
835N ... TRACE 6,STOPJOBI
83*G ... CALL 5 SFINDCPA [SET X3 -> CPA
83K# ... BRN UP
83T6 ... NGN 2 1
844Y ... BRUSEN NOUS16,3 [J IF NO USER
84#Q ... FJOCA 2,3
84JJ ...NOUS16
84SB CALL 5 STOPJOB
85#2 ... BRN UP [NOT STOPPABLE
85RL ... BS 3,BRMOPINOP
86?= ... BRN UPPLUSONE
87Q6 #
889Q # NBREAKIN ENTRY
88PB # SET X6=JOB NO. AND -
8992 # J TO NBREAKIN ENTRY POINT
89NL #
8=8= XX17 LDX 6 ACOMMUNE1(2)
8=MW ... SMO ACOMMUNE3(2)
8?7G BRN 0
8?86 ...[
8?8Q ...[ STOPJOB FOR READ FAILURE
8?9B ...[
8?=2 ...XX18P
8?=L ...#SKI JSKI33<1$1
8??= ... GEOERR 1,NOTYET
8??W ...#SKI JSKI33
8?#G ...(
8?*6 ...#SKI K6PROCONTX>99-99
8?*Q ... TRACE 6,READFLAB
8?BB ... CALL 5 SFINDCPA [X3 -> CPA
8?C2 ... BRN UP [NOT FOUND
8?CL ... CALL 5 STOPJOB1 [STOP THE JOB
8?CR ... BRN RFCALL [MAYBE NOT STOPPABLE
8?CY ... BRN RFCONT [STOPPABLE
8?D5 ...RFCALL
8?D= ... CALL 6 RFCHEK
8?DC ... BRN UPPLUSONE [CANT OVERRIDE
8?DJ ...RFCONT
8?DW ... BS 3,BRREADFAIL
8?FG ... LDX 2 FX2
8?G6 ... SENDPARS 2,3,GMON,JABAND
8?J2 ... BRN UPPLUSTWO [OK
8?J3 ...#
8?J4 ...# ENHANCEMENT (DS8213) TO LET READFAIL BREAK-IN OVERRIDE
8?J5 ...# PREVIOUS MOP TYPE BREAK-IN, IF IT EXISTS
8?J6 ...#
8?J7 ...RFCHEK
8?J8 ... LDX 0 JOBEVENTS(3)
8?J9 ... ANDX 0 PMASK(1)
8?J= ... BNZ 0 RFBSET [J IF BREAK-IN INHIBITED OR
8?J? ... [SET FOR ANYTHING OTHER THAN
8?J# ... [MOP TYPE BREAK-IN
8?J* ... CALL 5 STOPMOP
8?JB ... BRN RFBSET [THIS INSTR NEVER ACTUALLY REACHED
8?JC ... TRACE JOBEVENTS(3),RFOVER
8?JD ...#
8?JF ...# THE FOLLOWING UNSETS THE MOP BREAKIN MARKERS AND IT IS ON THE
8?JG ...# LINES OF THE BROKIN MACRO, BUT OMITS MOPWAIT
8?JH ...#
8?JJ ... LDX 2 ACTRING(3)
8?JK ... SBN 2 ACTRING
8?JL ...PBROKIN1
8?JM ... LDX 2 BPTR(2)
8?JN ... BXE 2 3,PBROKIN4
8?JP ... LDX 0 ATYPE(2)
8?JQ ... BXE 0 PBROKADCB(1),PBROKIN2
8?JR ... BXE 0 PBROKALCB(1),PBROKIN3
8?JS ... BXU 0 PBROKCILCB(1),PBROKIN1
8?JT ... LDX 0 PBROKCIMSK(1)
8?JW ... ANDS 0 CIREADY(2)
8?JX ... BRN PBROKIN4
8?JY ...PBROKIN2
8?J^ ... LDX 0 PBROKADMSK(1)
8?K2 ... ANDS 0 IWAIT(2)
8?K3 ... BRN PBROKIN4
8?K4 ...PBROKIN3
8?K5 ... LDX 0 PBROKALMSK(1)
8?K6 ... ANDS 0 GWAIT(2)
8?K7 ...PBROKIN4
8?K8 ...#
8?K9 ...# IF GMON/JABAND HAS ALREADY BEEN CHAINED TO CPAT BY ABANDON,
8?K= ...# FREE IT
8?K? ...#
8?K# ... HUNT2J 2,GMON,JABAND,3,NFAB
8?K* ... FREECORE 2
8?KB ...NFAB
8?KC ... EXIT 6 1 [CONTINUE WITH READFAIL BREAK-IN,
8?KD ... [OVERRIDING MOP TYPE BREAK-IN
8?KF ...RFBSET
8?KG ... EXIT 6 0
8?KH ...#
8?KW ...)
8?M6 #
8?N7 ...#UNS CRAMP
8?P8 ...(
8?Q9 ...[
8?R= ...[ STOPJOB FOR MOP OFF LIMBO
8?S? ...[
8?T# ...XX21P
8?W* ... CALL 5 SFINDCPA1
8?XB ... BRN UP [NON-EXISTENT
8?YC ... CALL 5 STOPJOB
8?^D ... BRN NOSTOP5 [NOT STOPPABLE
8#2F ... LDN 7 #40
8#3G ... BRN XX5UP
8#4H ...[
8#5J ...)
8#5Q ...XX25P
8#5Y ...#UNS BIWRFL
8#66 ...(
8#6# ...#SKI K6PROCONTX>99-99
8#6G ... TRACE 6,WRITFLAB
8#6N ... CALL 5 SFINDCPA [X3 -> CPA
8#6W ... BRN NFCPA [NOT FOUND
8#74 ... CALL 5 STOPJOB1 [STOP THE JOB
8#7= ... BRN UP [NOT STOPPABLE
8#7D ... BS 3,BRWRITEFAIL
8#7L ... BRN UPPLUSONE [OK
8#7S ...)
8#82 ...#
8#8= ...UPPLUSTHREE
8#8# ... LDN 3 3
8#8B ... BRN UPPLUS
8#8D ...UPPLUSTWO
8#8G ... LDN 3 2
8#8J ... BRN UPPLUS
8#8L ...UPPLUSONE
8#8N ... LDN 3 1
8#8Q ... BRN UPPLUS
8#8S ...UP
8#8W ... LDN 3 0
8#8Y ...UPPLUS
8#9G ... UPPLUS 0(3)
8#9J ...#
8#?H ...# THIS SUBROUTINE SEARCHES THE ACTIVITY CHAIN FOR THE CPA SPECIFIED
8#D# ...# BY THE JOB NUMBER IN X6. EXITS 0 IF NOT FOUND. EXITS 1 IF FOUND
8#K5 ...# NO COORDINATION.
8#PW ...# ON ENTRY: X6 - JOB NUMBER OF ACTIVITY REQUIRED
8#RF ...# X7 - LINK FOR RE-ENTRY IN OTHER MACHINE
8#T4 ...# (FOR SHARED FILESTORE ENHANCEMENT ONLY)
8#WM ...# ON EXIT: X0 - OVERWRITTEN
8*3D ...# X1 = FX1
8*89 ...# X2 - PTR TO JOBQUE BLOCK (IF FOUND)
8**2 ...# X3 - PTR TO CPAT (IF FOUND)
8*FR ...# X4 - OVERWRITTEN
8*LJ ...# X5 - LINK ACCUMULATOR
8*R* ...# X6 - JOB NUMBER (OR ACTIVITY NUMBER IF NO USER ACTIVITY)
8*Y6 ...# X7 - UNCHANGED
8B5= ...SFINDCPA1
8C4G SFINDCPA
8CJ6 JOBLOCK 6,2
8D3Q BPZ 2 OB1
8D6W ...[NOW SEE IF NO USER CASE
8D=2 ... BNZ 6 SERR [J IF JOB NUMBER
8D*6 ... SMO FX2
8DD= ... LDX 6 ACOMMUNE2 [ACTIVITY NUMBER
8DHB ... FINDACTN 3,6,SERR [J IF NO ACTIVITY BLOCK
8DLG ... LDCH 0 ATYPE(3)
8DPL ... SBN 0 CPAT/64
8DXW ... BNZ 0 SERR [J IF NOT CPAT
8F66 ... BRN SFOUND
8F#B ...OB1
8FGL ...[N PARAMETER USED IN CASE BEING SAVED
8GFW FCAJO 3,2,N
8G^G LDCH 4 ATYPE(3)
8HF6 SBN 4 CPAT/64
8HRH ... BNZ 4 SERR [J IF NOT CPAT
8J5Y ...SFOUND
8JDB EXIT 5 1 [FOUND
8JKJ ...SERR
8JQQ ... EXIT 5 0 [NOT FOUND
8JY2 #
8PS= #
8Q?W #
8QRG NFCPA GEOERR 1,CPALOST
8R?6 NFHLS GEOERR 1,HLSQLOST
8RQQ #
8S=B # MEND AREA
8SQ2 #
8W8W #END
^^^^ ...47634206000400000000