{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: REDONMT867)}}
====== REDONMT867 ======
(George Source)
**Macros used:** [[george:macro:APPEND|APPEND]], [[george:macro:CLALLOC|CLALLOC]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMERR|COMERR]], [[george:macro:COOR1|COOR1]], [[george:macro:DCA|DCA]], [[george:macro:DFCLEAR|DFCLEAR]], [[george:macro:DFSET|DFSET]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FNORM|FNORM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FREEMT|FREEMT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GPERI|GPERI]], [[george:macro:LFAILS|LFAILS]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LOCK|LOCK]], [[george:macro:LONGON|LONGON]], [[george:macro:LREPEATS|LREPEATS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PARANOT|PARANOT]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP|PUTREP]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SKIP|SKIP]], [[george:macro:SWITRACE|SWITRACE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:UNLOCK|UNLOCK]]
22FL #LIS K0REDONMT>K0LIBRARY>K0ALLGEO
22^= #SEG REDONMT65 [N.R.BOULT
23DW 8HREDNMT65
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23SK ...[
23YG SEGENTRY K1REDONMT,QK1REDONMT
24D6 #
24XQ #
25CB # THIS SEGMENT IS FOR REDON COMMANDS ON
25X2 # MAGNETIC TAPE DECKS
26BL #
26W= # S/R TO REWIND & DISCONNECT TAPE
27*W #
27TG RFREE
28*6 SBX 3 FX1
28SQ LDX 2 FX2
29#B LDN 0 9 [SET UP REWIND & DISCONNECT MODE
29S2 DCA ,DLA,0,MODE
2=?L LOCK 2 [FOR PERI
2=R= GPERI ,2
2?=W COOR1
2?QG UNLOCK 2
2#=6 FREEMT
2#PQ ADX 3 FX1
2*9B EXIT 3 0
2*P2 QK1REDONMT
2B8L STO 3 CPPTR(2)
2BN= #
2C7W PARANOT 2 [GET SECOND PARAMETER
2CMG MHUNT 3,CPB,CUNI
2D76 LDX 0 ANUM(3)
2DLQ BPZ 0 P1
2F6B CALL 3 RFREE [FREE DECK
2FL2 COMERR JPARMIS,JFENTRANT
2G5L P1 NAMETOP 3,FILE,FNAME
2GK= FNORM 1 [DECODE ENTRANT DESCRIPTION
2H4W TESTREPN NAMEFORM,P2
2HJG CALL 3 RFREE [FREE DECK
2J46 ENDCOM
2JHQ P2 MHUNT 3,FILE,FNAME
2K3B NAMETOP 3,CPB,CUNI [FOR ERRORS
2KH2 MHUNT 3,FILE,FABSNB
2L2L LDX 0 ATYPE(3)
2LG= ANDN 0 #2000 [SERIAL NR BIT
2L^W BNZ 0 PXP [ONLY XENOTAPE POSSIBLE
2MFG TESTREP OK,P3 [NO ADJUNCTS
2M^6 MHUNT 2,FILE,ADJUNCTS
2NDQ LDX 0 TNS(2)
2NYB ANDX 0 TNSM(1)
2PD2 BNZ 0 PNS [NON-STANDARD
2PXL P3
2QC= CALL 3 RFREE [FREE DECK
2QWW P4 COMERR HNOTX [DOES NOT SPECIFY 'X' OR 'NONS'
2RBG PXP TESTREP OK,PXR [NO ADJUNCTS
2RW6 MHUNT 2,FILE,ADJUNCTS
2S*Q LDX 0 TNS(2)
2STB ANDX 0 TNSM(1)
2T*2 BZE 0 PXR [TRY XENO
2TSL CALL 3 RFREE [FREE DECK
2W#= COMERR HTSN
2WRW PXR SMO HDREC(3)
2X?G LDX 6 A1+1(3) [TSN
2XR6 BPZ 6 P3 [NOTXENOTAPE
2Y=Q LDX 2 FX2
2YQB LDX 0 TAFB(1) [POSITION AFTER 1ST BLOCK
2^=2 STO 0 AWORK2(2)
2^PL #SKI K6REDONMT>99-99
329= SWITRACE 0,ROXENO
32NW BRN PWT [TO WAIT FOR TAPE
338G PNS LDX 0 ALOGLEN(3) [LENGTH
33N6 SBN 0 10
347Q BPZ 0 P8 [POSSIBLY LOCAL NAME
34MB P9 CALL 3 RFREE [FREE DECK
3572 COMERR HLOCNAM
35LL P8 SMO HDREC(3)
366= LDX 0 A1-6(3)
36KW BZE 0 P9 [NO LOCAL NAME
375G LDX 0 TFAIL(1)
37K6 LDX 2 FX2
384Q STO 0 AWORK2(2) [ALLOW NON-MAJOR FAILS
38JB #SKI K6REDONMT>99-99
3942 SWITRACE 0,RONONS
39HL PWT
3=3= MFREE CPB,CUNI
3=GW DOWN TAPEWAIT,1 [WAIT FOR TAPE
3?2G #SKI K6REDONMT>199-199
3?G6 SWITRACE EXEC3(2),ROREPLY
3?^Q PICKREP 7
3#FB PARANOT 1
3#^2 PUTREP 7
3*DL TESTREPN UNLOADED,P5
3*Y= COMERR HRCAN [TERMINATED
3BCW P5 TESTREPN FAILED,P6
3BXG OUTNULL
3CC6 COMERR HFAIL [FAILED
3CWQ P6 TESTREPN SECURE,P10
3DBB OUTNULL
3DW2 COMERR HSEC [SECURE TAPE
3F*L P10 BZE 6 PNSE [NONSTANDARD
3FT= TESTREPN NONS,P11
3G54 DFCLEAR ,LOAD
3G#W CALL 3 RFREE [FREE DECK
3H#6 COMERR HXENSTAN
3HRQ P11
3J?B MHUNT 3,FLIB,FMAGH [HEADER BLOCK
3JR2 MHUNT 2,FILE,FABSNB
3K=L LDXC 0 6 [TSN
3KQ= BRN £
3L9W TXU 0 A1+2(3) [CORRECT ?
3LPG BCC P7 [OK
3M96 P12
3MNQ UNLOAD ,,,UNL,AUT,NSD
3N8B COMERR HXENOID [XENOTAPE NOT CORRECTLY IDENTIFIED
3NN2 P7 SMO HDREC(2) [CHECK NAME
3P7L LDX 7 A1-6(2)
3PM= BZE 7 P13
3Q6W SMO HDREC(2)
3QLG LDX 0 A1-5(2)
3R66 SMO HDREC(2)
3RKQ LDX 1 A1-4(2)
3S5B TXU 7 A1+3(3)
3SK2 TXU 0 A1+4(3)
3T4L TXU 1 A1+5(3)
3TJ= BCS P12
3W3W SMO HDREC(2)
3WHG LDX 0 A1-3(2)
3X36 BZE 0 P14 [REEL NOT SPECIFIED
3XGQ ANDN 0 #7777 [TRUNCATE
3Y2B TXU 0 A1+6(3)
3YG2 BCS P12 [REEL INCORRECT
3Y^L P14 SMO HDREC(2)
3^F= LDX 0 A1-2(2)
3^YW BZE 0 P13
42DG ANDN 0 #7777 [TRUNCATE
42Y6 TXU 0 A1+7(3)
43CQ BCS P12 [GEN NOT CORRECT
43XB P13
44C2 LDN 0 27
44WL STO 0 A1(3) [RECORD HEADER
45B= LDN 0 3
45TW SRC 0 2
46*G STO 0 A1+21(3) [INSECURE + XENOTAPE
46T6 LDX 0 GSIGN
47#Q ORS 0 A1+2(3) [B0 IN TSN
47SB #SKI K6REDONMT>199-199
48#2 SWITRACE A1+2(3),ROTSNX
48RL PR
49?= LDX 2 FX2
49QW LFAILS ,0 [CNT OF FAILS
4==G STO 0 A1+25(3)
4=Q6 LREPEATS ,0 [CNT OF REPEATS
4?9Q STO 0 A1+24(3)
4?PB LGEOG ,0 [GEOGRAPHIC NO
4#92 STO 0 A1+23(3)
4#NL LDX 2 CPPTR(2)
4*8= STO 2 A1+22(3) [DEVICE LIST POINTER
4*MW STOZ A1+26(3)
4B7G NAME 3,FILE,FAPB
4BM6 # INSERT RECORD IN :SYSTEM.DOCUMENT
4C6Q OPENSYS XBRKIN,DOCUMENT,GENERAL
4CLB APPEND
4D62 DFSET ,TSN,6 [STORE TSN
4DKL BNG 6 PR1
4F5= DFSET ,NONS [NONSTANDARD
4FJW PR1
4FKM ... CLOSETOP [:SYSTEM DOCUMENT
4FLD ... LGEOG ,5 [X5 => UNIT NUMBER
4FM9 ...SJ1 OUTPACK 5,1,GEOPER,SJ1 [OUTPUT UNIT NUMBER
4FN2 ... BNG 6 SJ2 [J IF XENOTAPE
4FNR ... OUTNULL [TSN NOT APPLICABLE FOR NONSTANDARD T
4FPJ ... BRN SJ3 [
4FQ* ...SJ2 OUTPACK 6,1,TSN,SJ2 [TSN FOR XENOTAPE
4FR6 ...SJ3 MHUNT 3,FILE,FAPB [X3 -> DOCUMENT RECORD
4FRX ... OUTPACK A1+3(3),3,LOCNAME,SJ3
4FSN ...SJ4 MHUNT 3,FILE,FAPB [X3 -> DOCUMENT RECORD
4FTF ... OUTPACK A1+6(3),1,REELNUM,SJ4
4FW= ...SJ5 MHUNT 3,FILE,FAPB [AND AGAIN
4FX3 ... OUTPACK A1+7(3),1,GENNUM,SJ5
4FXS ... FREECORE 3 [FREE APPEND BLOCK
4FYK ... BZE 6 SJ6 [J IF NONSTANDARD
4F^B ... OUTPAR SKIP [SKIP 'NONSTANDARD' STRING
4G27 ... BRN SJ7 [
4G2Y ...SJ6 OUTPAR NULL [INCLUDE 'NONSTANDARD' STRING
4G3P ...SJ7 MONOUT HLOADED [OUTPUT LOADED MESSAGE
4G4G CLALLOC [DE-ALLOCATE DECK
4GJ6 STOZ CPPTR(2)
4H3Q STOZ CPRW1(2)
4HHB STOZ CPRW2(2)
4J32 STOZ CPRSW(2)
4K2= LONGON #61,6 [WAKE UP ACTIVITIES
4KFW ENDCOM
4K^G # NON-STANDARD ONLY SECTION
4LF6 PNSE TESTREP OK,Q1
4LYQ SETNCORE 27,3,FLIB,FMAGH
4MDB BRN Q2
4MY2 Q1 MHUNT 3,FLIB,FMAGH
4NCL Q2
4NX= LDN 0 27
4PBW STO 0 A1(3) [RECORD HEADER
4PWG STOZ A1+1(3) [ZEROISE BLOCK
4QB6 LDN 0 A1+1(3)
4QTQ LDN 1 A1+2(3)
4R*B MOVE 0 25
4RT2 MHUNT 2,FILE,FABSNB [NOW INSERT "NAME"
4S#L SMO HDREC(2)
4SS= LDN 0 A1-6(2)
4T?W LDN 1 A1+3(3)
4TRG MOVE 0 5 [NAME + DETAILS
4W?6 LDN 0 #777
4WQQ ANDS 0 A1+6(3) [TRUNCATE REEL
4X=B LDN 0 #7777
4XQ2 ANDS 0 A1+7(3) [TRUNCATE GENERATION
4Y9L SMO FX1
4YP= LDX 0 TNSS [MARKER WORD
4^8W #SKI K6REDONMT>199-199
4^NG SWITRACE 0,ROTNSS
5286 STO 0 A1+21(3)
52MQ BRN PR [FINISH RECORD
537B #
53M2 # CONSTANTS
546L #
54L= TAFB +4
555W SEGENTRY APRR71
55KG TFAIL +2
5656 TNSS #20000400
56JQ TNSM +1
574B #
57J2 # LOCALS
583L #
58H= #DEF TNS=A1+2
592W #
59GG # GEOERRS
5=26 #
5=FQ XBRKIN GEOERR 1,XBRKIN
5=^B MENDAREA 50,K99REDONMT
5?F2 #END
^^^^ ...47520024000100000000