{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: REQCART866)}}
====== REQCART866 ======
(George Source)
**Macros used:** [[george:macro:AUTWIN|AUTWIN]], [[george:macro:DEMAND|DEMAND]], [[george:macro:FINDSU|FINDSU]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JDED|JDED]], [[george:macro:JSHARED|JSHARED]], [[george:macro:LADDP|LADDP]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGSTOP|LONGSTOP]], [[george:macro:LONGSTOX|LONGSTOX]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFINDSU|MFINDSU]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PAIR|PAIR]], [[george:macro:PLOCKSU|PLOCKSU]], [[george:macro:RELST|RELST]], [[george:macro:RINGACT|RINGACT]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TRACE|TRACE]], [[george:macro:UNLOCKSU|UNLOCKSU]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREE|VFREE]]
22FL #SEG REQCART65 [BOB NICHOLSON
22^= #LIS K0REQCART
23DW 8HREQCART
23YG #
24D6 # IMPLEMENTS USEST,MUSEST,USESTX,SUSEST,SMUSEST AND RELST MACROS
24XQ # IF UNIT IS NOT ONLINE USEST,SUSEST GO UP MUSEST,SMUSEST OUTPUT
25CB # MESSAGES AND WAIT FOR THE UNIT TO COME ONLINE (OR BREAKIN OR
25X2 # CANTDO)
26BL #
26W= #
27*W # THE MACROS USEST,USESTX,MUSEST WILL NOT ACCEPT A UNIT WHICH
27TG # IS IN USE BY S-TRUSTED. MUSEST WAITS FOR THE UNIT TO BE RELEASED
28*6 # THE OTHERS GO UP.
28SQ #
29#B # IF THE UNIT IS OK 1 IS ADDED TO THE COUNT OF USERS IN THE
29S2 # PERIPHERAL LIST.
2=?L #
2=R= # RELST SUBTRACTS ONE FROM COUNT OF USERS AND SETS UP AN ACTDOC
2?=W # WITH A LINK TO K1GRUESOME IF B18 OF WORD 0 OF THE PERIPHERAL
2?QG # RECORD IS SET
2#=6 #
2#PQ SEGENTRY K1REQCART,QK1REQ
2*9B SEGENTRY K2REQCART,QK2REQ
2*P2 SEGENTRY K3REQCART,QK3REQ
2B8L SEGENTRY K4REQCART,QK4REQ
2BN= SEGENTRY K5REQCART,QK5REQ
2C7W SEGENTRY K7REQCART,QK7REQ
2C97 ...#UNS IPBD
2C=D ...(
2C?P ... SEGENTRY K8REQCART,XER1 [NO LONGER USED
2C*2 ... SEGENTRY K9REQCART,XER1 [DITTO
2CB? ... SEGENTRY K10REQCART,QK10REQ [LOCKM MACRO
2CCJ ... SEGENTRY K11REQCART,QK11REQ [UNLOCKSU
2CDT ... SEGENTRY K12REQCART,QK12REQ [TWAIT
2CG6 ...)
2CHC ...#UNS IPBD
2CJN ...#SKI
2CK^ ...(
2CMG SEGENTRY K8REQCART,QK8REQ
2D76 SEGENTRY K9REQCART,QK9REQ
2DBY ...)
2DLQ #
2F6B #SKI CARTON
2FL2 ZLINK PAIR CARTCONT,1
2G5L #SKI CARTON<1$1
2GK= ZLINK PAIR GRUESOME,1
2H4W #
2HJG # GEOERRS
2J46 #
2JHQ XER1 GEOERR 1,NOPEREC [PERIPHERAL RECORD MISSING
2K3B XER2 GEOERR 1,USEBITS [IF CLONG1,CLONG2 HAVE BITS SET
2KH2 #
2L2L #
2L*3 ...#UNS IPBD
2LMD ...#SKI
2L^W (
2MFG QK9REQ [TSMUSEST
2M^6 LDCT 7 #400
2NDQ ORN 7 2
2NYB BRN XJ
2PD2 )
2PXL #
2QC= QK7REQ [USESTX
2QWW LDN 7 0 [ORDINARY MACRO
2RBG LDX 6 ACOMMUNE9(2)
2RW6 #SKI K6REQCART>199-199
2S*Q (
2STB TRACE ACOMMUNE8(2),USESTX
2T*2 TRACE ACOMMUNE9(2)
2TSL )
2T^S ... LDX 0 ACOMMUNE8(2)
2W72 ... STO 0 AWORK1(2) [SAVE EXOF NO
2W#= NGN 0 1
2WRW STO 0 AWORK2(2)
2X?G BRN XC
2XR6 #
2Y=Q QK5REQ [SMUSEST
2YQB LDCT 7 #400 [S-VERSION
2^=2 ORN 7 1 [M-VERSION
2^PL XJ LDN 5 0
329= #SKI K6REQCART>199-199
32NW TRACE ACOMMUNE9(2),SMUSEST
338G BRN XB
33N6 #
347Q QK4REQ [S-VERSION
34MB LDCT 7 #400 [S-VERSION
3572 #SKI K6REQCART>199-199
35LL TRACE ACOMMUNE9(2),SUSEST
366= BRN XB
36KW #
375G QK2REQ [M-VERSION
37K6 LDN 7 1 [M-VERSION
384Q LDN 5 0
38JB #SKI K6REQCART>199-199
3942 (
39HL TRACE ACOMMUNE8(2),MUSEST
3=3= TRACE ACOMMUNE9(2)
3=GW )
3?2G BRN XA
3?G6 #
3?^Q QK1REQ [USEST
3#FB LDN 7 0 [ORDINARY VERSION
3#^2 #SKI K6REQCART>199-199
3*DL (
3*Y= TRACE ACOMMUNE8(2),USEST
3BCW TRACE ACOMMUNE9(2)
3BXG )
3CC6 XA LDX 0 ACOMMUNE8(2)
3CWQ STO 0 AWORK1(2) [SAVE EXOF NUMBER
3DBB XB LDX 6 ACOMMUNE9(2)
3DW2 STOZ AWORK2(2)
3F*L XSTART
3FT= FINDSU 3,6,NOSTUC [FIND ASTUC,IF ANY,FOR THIS UNIT
3G#W LDCT 0 #200
3GSG ANDX 0 ASMARK(3)
3H#6 BNZ 0 NOSTUC [JUMP IF DISENGAGED
3HRQ LADDP HUNIT(3),2 [PTR TO APIA
3HXM ... LDCT 0 #200
3J3J ... ANDX 0 BSUNIT(2)
3J7F ... BNZ 0 NOSTUC
3J?B LDN 0 1
3JR2 ADS 0 BSUNIT2(2) [UPDATE COUNT FO USERS
3K5C ...#UNS IPBD
3KCS ...#SKI
3KQ= (
3L9W LDXC 0 7
3LPG BCS £ [FORGET STRUSTED BIT
3M96 SBN 0 2
3MNQ BZE 0 XD [J IF TSMUSEST
3N8B LDN 0 1
3NN2 ADS 0 BSUNIT4(2) [ELSE UPDATE COUNT
3P7L )
3PM= BNG 7 XD [JUMP IF S-VERSIONS
3RKQ XC PLOCKSU 6,XM,XN [GET THE LOCK-OUT
3S5B MFINDSU 3,6
3SK2 LDCT 4 #140 [JUMP IF REDONED AND/OR S TRUSTED
3T4L ANDX 4 ASMARK(3)
3TJ= BNZ 4 XEA
3W3W LDN 1 BCCB [CHECK IF UNIT IN USE BY S-TRUSTED
3WHG XG LDX 1 BPTR(1)
3X36 TXU 1 CXCC
3XGQ BCC XD [JUMP IF END OF CHAIN
3Y2B LDX 0 BACK2(1)
3YG2 BZE 0 XD [JUMP IF NO MORE EXOFS
3Y^L SMO FX2
3^F= TXU 0 AWORK1
3^YW BCC XG [JUMP IF OUR EXOF
42DG LDCT 0 4
42Y6 ANDX 0 EXMARK(1)
43CQ BZE 0 XG [JUMP IF NOT S-TRUSTED
43XB TXU 6 ASUSN(1)
44C2 BCC XE [JUMP IF IN USE
44WL LDN 4 0
45B= LDEX 0 FIP+5(1) [NUMBER OF AREAS
45TW XH BZE 0 XG
46*G SMO 4
46T6 TXU 6 FDCELLS(1)
47#Q BCC XE [JUMP IF IN USE
47SB ADN 4 6
48#2 SBN 0 1
48RL BRN XH [BACK FOR NEXT AREA
49?= XD LDXC 6 7 [UNIT IS OK
49QW BNZ 6 XF [J IF M-VERSION
4==G #SKI ENTWINE
4=Q6 (
4?9Q LDXC 6 7
4?PB BCS XR [J IF ORDINARY S-VERSION
4#92 UPPLUS 3
4#NL )
4*8= XR UPPLUS 1
4*MW XF BZE 5 XK
4B7G BNG 5 XL [JUMP IF NO DEMAND
4BM6 VFREE ADATA,ADEMAND [FREE ANY BLOCKS LEFT BY DEMAND
4C6Q VFREE GMON,AOUT
4CLB XL LDN 4 6
4D62 LDX 2 FX2
4DKL OUTPARAM 4,AWORK3
4F5= MONOUT EWAV [OUTPUT 'NOW AVAILABLE'
4FJW #SKI ENTWINE<1$1
4G4G XK UPPLUS 2
4GJ6 #SKI ENTWINE
4H3Q (
4HHB XK LDXC 7 7
4J32 BCS XQ [J IF S-M VERSION
4JGL UPPLUS 3
4K2= XQ UPPLUS 2
4KFW )
4K^G NOSTUC [UNIT NOT ONLINE
4LF6 LDXC 0 7
4LYQ BNZ 0 YA [JUMP IF M-VERSIONS
4MDB UP
4MY2 YA LONGSET #67,XER2 [SET WAITING STYLE
4NCL LDXC 0 5
4NX= BNZ 0 REENT [JUMP IF NOT 1ST TIME
4PBW LDX 2 FX2
4PWG LDN 1 AWORK3(2)
4QB6 LDX 4 6
4QTQ LDN 0 6
4R*B SLL 4 3
4RT2 YC SLC 4 6
4S#L DCH 4 0(1)
4SS= BCHX 1 £
4T?W SRL 4 3
4TRG BCT 0 YC
4W?6 LDN 4 6
4WQQ OUTPARAM 4,AWORK3
4X=B MONOUT EWPUT [WAITING ...
4XQ2 LDN 5 1
4Y9L OUTPARAM 4,AWORK3
4Y?J ...#UNS IPBD
4Y*G ...(
4YCD ... OUTPACK JOBNO(2),1,VARDEC
4YFB ... DEMAND 1,EWSULOAD,XCANT,XBREAK,REENT,2
4YH# ...)
4YK= ...#UNS IPBD
4YM8 ...#SKI
4YP= DEMAND 1,EWLOAD,XCANT,XBREAK,REENT,2
4^8W BRN XSTART
4^NG #
5286 #SKI ENTWINE
52MQ (
537B XN LDX 0 AWORK2(2)
53M2 BNG 0 XT [J IF USESTX
546L NGNC 4 1
54L= XM LDN 4 0 [BREAKIN
54NT ...#UNS IPBD
54RD ... RELST 6 [REDUCE COUNT OF USERS
54W3 ...#UNS IPBD
54YL ...#SKI
5539 ...(
555W MFINDSU 3,6
55KG LADDP HUNIT(3),2
5656 LDN 0 1
56JQ SBS 0 BSUNIT2(2)
56M* ...)
56PY ...#UNS IPBD
56X6 ...#SKI
574B SBS 0 BSUNIT4(2)
57J2 BZE 4 XBREAK
583L XT UPPLUS 2
58H= )
592W XBREAK [BREAKIN
59GG UPPLUS 1
5=26 #
5=FQ XCANT [CANTDO
5=^B LDN 4 6
5?F2 OUTPARAM 4,AWORK3
5?YL MONOUT EWNOTAV [NOT AVAILABLE
5#D= UP
5#XW #
5*CG # IN USE BY S-TRUSTED
5*X6 XEA SLL 4 3 [MOVE REDONED BIT TO BIT 0
5BBQ LDXC 4 4
5BWB XE LDN 4 0 [X4=1 IF REDONED
5CB2 LONGSET #71,XER2 [SET WAITING STYLE
5CTL UNLOCKSU 6
5D*= LADDP HUNIT(1),3 [PTR TO AIPA
5DSW LDX 0 AWORK2(2)
5F#G BNG 0 YH
5FS6 LDN 0 1
5G?Q SBS 0 BSUNIT2(3) [SUBTRACT 1 FROM COUNT OF USERS
5GDY ...#UNS IPBD
5GL6 ...#SKI
5GRB SBS 0 BSUNIT4(3)
5H?2 BNZ 7 YD [JUMP IF M-VERSIONS
5HQL YH LONGOFF
5J== UP
5JPW YD BNG 5 YF [JUMP IF NOT FIRST TIME
5K9G LDXC 0 5
5KP6 BZE 0 YE [JUMP IF NO PREVIOUS DEMAND
5L8Q VFREE ADATA,ADEMAND [FREE DEMAND BLOCKS
5LNB VFREE GMON,AOUT
5M82 YE SMO FX2 [OUTPUT SERIAL NUMBER
5MML LDN 1 AWORK3
5N7= LDX 3 6
5NLW LDN 0 6
5P6G SLL 3 3
5PL6 YG SLC 3 6
5Q5Q DCH 3 0(1)
5QKB BCHX 1 £
5R52 SRL 3 3
5RJL BCT 0 YG
5S4= LDN 3 6
5SHW BZE 4 YEA [JUMP IF HASN'T BEEN REDONED
5T3G OUTPARAM 3,AWORK3 [SUSN TO MESSAGE
5TH6 MONOUT EWREDS [MAY ONLY BE ACCESSED BY TRUSTED...
5W2Q YEA OUTPARAM 3,AWORK3 [...PROGS-SUSN TO MESSAGE
5WGB #SKI ALWMK7<1$1
5X22 MONOUT EWREL [WAITING FOR S-TRUSTED
5XFL LDCT 5 #400
5X^= #SKI ALWMK7<1$1
5YDW YF LONGSTOP XBREAK
5YYG #SKI ALWMK7
5^D6 LONGSTOP XBREAK,,EWREL,YF [WAITING FOR S-TRUSTED
5^XQ BRN XSTART
62CB #
62X2 #
63BL # ENTRY POINT FOR RELST
63W= #
64*W #
64TG QK3REQ
657X ...#UNS IPBD
65G# ...#SKI
65SQ (
66#B NGNC 7 1
66S2 QK8REQ [TRELSTX
67?L LDN 7 0
67R= )
68=W LDX 6 ACOMMUNE9(2)
68QG #SKI K6REQCART>99-99
69=6 TRACE 6,RELST
69PQ MFINDSU 3,6 [FIND ASTUC
6=9B LADDP HUNIT(3),2 [PTR TO AIPA
6=HR ...#UNS IPBD
6=W8 ...#SKI
6?8L (
6?N= BZE 7 ZE [J IF T-VERSION
6#7W #SKI K6REQCART>99-99
6#MG (
6*76 SMO BSUNIT4(2)
6*LQ LDN 0 0
6B6B BNZ 0 ZC
6BL2 GEOERR 1,TRELSTX
6C5L ZC
6CK= )
6D4W SBS 7 BSUNIT4(2) [UPDATE COUNT OF USERS
6DJG SMO BSUNIT4(2)
6F46 LDN 0 0
6FHQ BNZ 0 ZE [J IF SOME USERS
6G3B LDCT 0 2
6GH2 ANDX 0 BSUNIT(2)
6H2L BZE 0 ZE [J IF OTHER SIDE DOES NOT WANT LOCK
6HG= AUTWIN GLKT,6 [GIVE IT THE LOCK-OUT
6H^W ZE
6JFG MFINDSU 3,6
6J^6 LADDP HUNIT(3),2
6KDQ )
6KYB #SKI K6REQCART>99-99
6LD2 (
6LXL SMO BSUNIT2(2) [CHECK CUNT FO USERS OON-ZERO
6MC= LDN 0 0 [
6MWW BNZ 0 ZA
6NBG GEOERR 1,RELST
6NW6 ZA
6P*Q )
6PTB LDN 0 1
6Q*2 SBS 0 BSUNIT2(2) [SUBTRACT 1 FROM COUNT FO USERS
6QSL SMO BSUNIT2(2)
6R#= LDN 0 0
6RRW BNZ 0 ZB [JUMP IF STILL IN USE
6S?G LDCT 0 #200
6SR6 ANDX 0 BSUNIT(2)
6T=Q BZE 0 ZB [JUMP IF NOT TO WAKE UP GRUESOME
6TQB LDX 6 HUNIT(3)
6W=2 GETACT ACTDOC
6WPL LDX 2 BPTR(2)
6X9= LINKSET 2,ZLINK(1) [SET LINK TO K1CARTCONT
6XNW STO 6 CPPTR(2) [STORE DEVICE LIST PTR FOR GRUSARSE
6Y8G LDX 6 2 [SAVE POINTER
6YN6 LDN 2 BACT [ADDRESS OF BLANKET
6^7Q RINGACT 6,2 [PUT ACTIVITY AT END OF CHAIN/RING
6^MB LDX 2 6
7272 FPUT
72LL ZB UP
736= #
736# ...#UNS IPBD
736B ...(
736D ...[
736G ...[ LOCKM MACRO
736J ...[
736L ...[ ON ENTRY ACOMMUNE8 CONTAINS HOME UNIT SUSN
736N ...[ ACOMMUNE9 CONTAINS AREA UNIT SUSN
736Q ...[
736S ...[ PLOCKSU IS OBEYED FOR THE LOWEST GEOGRAPHICAL NO. FIRST
736W ...[
736Y ...[ ON EXIT FOR ERRORS ANY LOCKED UNIT IS UNLOCKED AND THE SUSN
7372 ...[ OF THE UNIT IS STORED IN ACOMMUNE9
7374 ...[
7376 ...QK10REQ
7378 ... LDX 6 ACOMMUNE8(2) [X6=HOME UNIT
737= ... LDX 5 6 [=X5 HOME UNIT
737# ... LDX 7 ACOMMUNE9(2) [X7=AREA UNIT
737B ... MFINDSU 1,6 [X1 PTS TO ASTUC OF HOME UNIT
737D ... LDX 4 GEOGU(1) [X4=GEOGRAPHICAL NO OF HOME UNIT
737G ... TXU 6 7
737J ... BCC XLB [J IF HOME=AREA UNIT
737L ... MFINDSU 1,7 [X1 PTS TO ASTUC OF AREA UNIT
737N ... SBX 4 GEOGU(1)
737Q ... BNG 4 XLB [J IF HOME UNIT LOWER THAN AREA UNIT
737S ... LDX 5 7 [ELSE LOAD AREA UNIT
737W ...XLB STO 5 AWORK1(2) [REMEMBER IN CASE OF FAILURE
737Y ... PLOCKSU 5,XBRK1,XIPB [GET LOCK OUT OF LOWEST UNIT
7382 ... TXU 6 7
7384 ... BCC UP2 [J IF HOME=AREA UNIT
7386 ... LDX 5 6 [RELOAD X5 TO HOME UNIT
7388 ... BPZ 4 XLC [J IF HOME UNIT HIGHER THAN AREA UNIT
738= ... LDX 5 7 [LOAD AREA UNIT
738# ...XLC PLOCKSU 5,XBRK2,XPB2 [GET LOCK-OUT FOR OTHER UNIT
738B ...UP2 UPPLUS 2 [EXIT OK
738D ...[
738G ...[ BREAKIN ON FIRST PLOCKSU
738J ...[
738L ...XBRK1 NGNC 3 1
738N ...[
738Q ...[ IPB FAIL ON FIRST PLOCKSU
738S ...[
738W ...XIPB LDN 3 0 [X3=0 IF IPB; X3=1 IF BREAKIN
738Y ... BRN XEND
7392 ...[
7394 ...[ BREAKIN ON SECOND PLOCKSU
7396 ...[
7398 ...XBRK2 NGNC 3 1
739= ...[
739# ...[ IPB FAIL ON SECOND PLOCKSU
739B ...[
739D ...XPB2 LDN 3 0 [X3=0 FOR IPB;X3=1 FOR BREAKIN
739G ... UNLOCKSU AWORK1(2) [UNLOCK PREVIOUSLY LOCKED UNIT
739J ...XEND STO 5 ACOMMUNE9(2) [STO UNLOCKABLE FOR HIGHER ROUTINE
739L ... BNZ 3 UP [J IF BREAKIN
739N ... UPPLUS 1
739Q ...UP UP
739S ...[
739W ...[ UNLOCKSU MACRO
739Y ...[
73=2 ...[ ACOMMUNE9=STORAGE UNIT SERIAL NUMBER
73=4 ...[
73=6 ...[ IT WAKES UP ANYONE WAITING FOR LOCK OUT IN THIS PROCESSOR
73=8 ...[ AND THE OTHER IF SO INDICATED. THE COUNT OF USERS IN BSUNIT4 IS
73== ...[ REDUCED AND ANY EWDAS/ITCH BLOCKS ARE FREED
73=# ...[
73=B ...QK11REQ
73=D ... LDX 0 ACOMMUNE9(2)
73=G ... STO 0 AWORK1(2) [SAVE SUSN
73=J ... FON #72 [WAKE UP ACTIVITIES IN THIS MACHINE..
73=L ... [..WAITING FOR LOCK OUT
73=N ... MFINDSU 1,AWORK1(2) [GET PTR TO ASTUC
73=Q ... LDCT 0 #400
73=S ...#SKI K6EXOFILE>199-199
73=W ...(
73=Y ... ANDX 0 ASMARK(1)
73?2 ... BNZ 0 ND1
73?4 ... GEOERR 1,UNLOCKSU [TRYING TO UNLOCK WHEN ALREADY UNLOCK
73?6 ...ND1
73?8 ...)
73?= ... ERS 0 ASMARK(1) [REVERSE LOCK-OUT BIT
73?# ... LADDP HUNIT(1),1 [X1 PTR TO APIA
73?B ... LDX 0 BSUNIT4(1)
73?D ... SBN 0 1 [TAKE ONE FROM COUNT OF USERS
73?G ... BPZ 0 ND2
73?J ... GEOERR 1,USER CT [COUNT OF USERS WOULD BE -VE
73?L ...ND2 STO 0 BSUNIT4(1) [PUT BACK REDUCED COUNT
73?N ... BNZ 0 ND3 [J IF STILL SOME USERS..
73?Q ... LDCT 0 2 [..ELSE CHECK IF OTHER MACHINE..
73?S ... ANDX 0 BSUNIT(1) [..WANTS LOCK OUT
73?W ... BZE 0 ND3 [J IF IT DOES NOT
73?Y ... AUTWIN GLKT [ELSE GIVE LOCK OUT AWAY
73#2 ...ND3 HUNTW 1,EWDAS,ITCH
73#4 ... BNG 1 ND4 [J IF NOT THERE
73#6 ... LDX 0 ENSUSN(1)
73#8 ... SMO FX2
73#= ... TXU 0 AWORK1
73## ... BCS ND4 [OR FOR A DIFFERENT SUSN
73#B ... FREECORE 1 [OTHERWISE FREE IT
73#D ...ND4 UP [..AND FINISH
73#G ...[
73#J ...[ TWAIT MACRO ACOMMUNE9=SUSN
73#L ...[
73#N ...QK12REQ
73#Q ...#UNS ERATR
73#S ... LDN 6 0
73#W ... LDN 5 0 [MKR FIRST TIME ROUND
73#Y ... LDX 0 ACOMMUNE9(2)
73*2 ... STO 0 AWORK1(2)
73*4 ...RQ4 LONGSET IPBDE,XER2 [WE ARE TO WAIT PERHAPS
73*6 ... FINDSU 1,AWORK1(2),RQ3 [FIND ASTUC
73*8 ... LADDP HUNIT(1),3 [APIA
73*= ... JSHARED 3,RQ3 [J IF SHARED
73*# ... JDED 3,RQ1 [J IF DEDICATED TO END
73*B ...#UNS ERATR
73*D ...(
73*G ...RQ3 LDXC 0 ETWINMK
73*J ... BCS NOTIN [J IF TWINNING NOT INITIALISED
73*L ... LDXC 5 5
73*N ... BCS £ [CLEAR B0
73*Q ... LDN 6 0
73*S ... LDX 0 ETWINMK
73*W ...)
73*Y ...#UNS ERATR
73B2 ...#SKI
73B4 ...RQ3 LDX 0 ETWINMK
73B6 ... ANDN 0 IPBDOWN+GEODOWN
73B8 ... BZE 0 RQ1 [J IF IPB OK
73B= ... ANDN 0 GEODOWN
73B# ... BNZ 0 RQ1 [OR IF OTHER PROCESSOR DOWN
73BB ... BNZ 5 RQ5 [J IF WE'VE BEEN THIS WAY BEFORE
73BD ... LDN 5 1 [MESS ALREADY OUTPUT MKR
73BG ... OUTPACK AWORK1(2),1,CSN [
73BJ ... MONOUT IPBSTB [OUTPUT WAITING FOR IPB OR SUSN
73BL ... OUTPACK JOBNO(2),1,VARDEC
73BN ... OUTPACK AWORK1(2),1,CSN
73BQ ...#UNS ERATR
73BS ...(
73BW ... LDX 7 XMESS1(1) [JOB N NEEDS
73BY ...XLON LONGSTOX RQ8,RQ7,7,RQ5
73C2 ...)
73C4 ...#UNS ERATR
73C6 ...#SKI
73C8 ... LONGSTOP RQ8,RQ7,IPBSTA,RQ5 [WAIT AND OUTPUT JOB N NEEDS SU
73C= ... BRN RQ4 [SEE IF EVENT OCCURRED
73C# ...#UNS ERATR
73CB ...(
73CD ...[ TWINNING NOT INITIALISED
73CF ...NOTIN
73CG ... NGN 0 2 [X0=#77777776
73CH ... ANDX 5 0 [CLEAR B1 OF X5
73CJ ... LDX 1 FX1
73CL ... LDX 0 ETWINMK
73CN ... ANDN 0 INITCOM+INITRQ
73CQ ... BZE 0 NOWT [J IF NO INIT REQUESTED OR RUNNING
73CS ... ANDN 0 INITCOM
73CW ... BNZ 0 RQ5 [J IF INITIALISE IN PROGRESS
73CY ... BNZ 6 XRENT [REENTER DEMAND IF WE DEMANDED
73D2 ... BNG 5 RQ5 [J IF ALREADY OUTPUT TO MON FILE
73D4 ... LDX 7 XMESS2(1) [WAITING FOR TN IN
73D6 ... LDCT 0 #400
73D8 ... ORS 0 5
73D= ... BRN XLON [ENTER LONGSTOP
73D# ...NOWT LDN 6 1
73DB ... LDN 0 INITRQ
73DD ... ORS 0 ETWINMK [SET INITIALISE IN REQESTED BIT
73DG ... MONOUTX XMESS2(1) [WAITING FOR TN IN
73DJ ... DEMAND 1,ENTIN25,RQ7,RQ8,XRENT,2
73DL ... BRN RQ4
73DN ...[
73DQ ...[
73DS ...XMESS1 +IPBSTA [JOB N NEEDS
73DW ...XMESS2 +EINWT [WAITING FOR TN INITIALISE
73DY ...)
73F2 ...RQ7 LONGOFF
73F4 ... BRN RQ4
73F6 ...RQ1 LONGOFF
73F8 ... UPPLUS 1
73F= ...RQ8 UP [BREAKIN
73F# ...)
73KW MENDAREA 20,K99REQCART
745G #
74K6 #END
^^^^ ...06424615000100000000