{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: REQESLIP861)}}
====== REQESLIP861 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:CAPCA|CAPCA]], [[george:macro:CHECKB|CHECKB]], [[george:macro:EVENTFIN|EVENTFIN]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FINDPUC|FINDPUC]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:FREEPTAB|FREEPTAB]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:JBC|JBC]], [[george:macro:MELRERING|MELRERING]], [[george:macro:MELUNRING|MELUNRING]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MURDER|MURDER]], [[george:macro:NAME|NAME]], [[george:macro:PCATEST|PCATEST]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTRCTP|TESTRCTP]], [[george:macro:TESTRT|TESTRT]], [[george:macro:TRACE|TRACE]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:UNPLUGRT|UNPLUGRT]], [[george:macro:UNSETRCTP|UNSETRCTP]]
22FL #LIS K0REQESLIP>K0OPCA>K0OBJPROG>K0ALLGEO>K0GREATGEO
22^= #SEG REQESLIP4 [RUTH PORTER.
23DW 8HREQESLIP
23YG SEGENTRY K1REQESLIP,XENT1
24D6 # THIS SEGMENT DEALS WITH THE EXTRACODE WHICH ALTERS A REQUEST
24XQ # SLIP
25CB XRESVIOL
25X2 UNPLUG
26BL ILLEGAL RESVIOL
26W= XILLINS
27*W UNPLUG
27TG ILLEGAL ILLINS [ILLEGAL INSTRUCTION
282N ...#UNS IMR
287W ...#SKI
28*6 SIXTY +60
28SQ Q77770077 #77770077 [MASK FOR WORD 0 OF REQ SLIP
29#B Q73160001 #73160001 [WORD 0 OF 14 WORD BLOCK
29S2 Q73200001 #73200001 [WORD 0 OF 16 WORD BLOCK
2=?L Q12 #12
2=R= Q41 #41
2?=W Q73 #73
2?*F ...#UNS IMR
2?D4 ...(
2?GM ...REMILL #74727170
2?K= ... +0
2?MT ...)
2?QG #DEF VREQSLIP=A1 [START OF REQ SLIP IN AOBRES BLOCK
2#=6 # ENTRY FOR CHANGING REQ SLIP (X=1)
2#PQ XENT1
2*9B #SKIP K6REQESLIP>199-199
2*P2 TRACE 1,REQSLIP1
2B8L CALL 7 XSTART
2BN= LDX 3 ANM(2) [MEMBER NUMBER
2C7W ANDN 3 3
2CMG BNZ 3 XILLINS [ERROR IF NOT EMBER 0
2D76 LDN 0 3
2DLQ LDCT 5 #200 [MASK FOR MEMBER SUSPENSION
2F6B Z4
2FL2 ADN 3 K61
2G5L SMO FX2
2GK= ANDX 5 ASU1(3)
2H4W BZE 5 XILLINS
2HJG BCT 0 Z4
2J46 LDX 5 EVENT2(2)
2JHQ CALL 7 XADDR [FIRST WORD OF NEW REQ SLIP
2K3B ANDX 0 Q77770077(1)
2KH2 #SKIP K6REQESLIP>199-199
2L2L TRACE 0,REQWORD0
2LG= TXU 0 Q73160001(1)
2L^W BCC Z1 [JUMP IF 14 WORD BLOCK
2MFG TXU 0 Q73200001(1)
2M^6 BCS XILLINS [ERROR IF NOT 16 WORD BLOCK
2NDQ Z1 ADN 5 1
2NYB CALL 7 XNAME
2PD2 ADN 5 1
2PXL CALL 7 XADDR [WORD 2 OF REQ SLIP
2QC= #SKIP K6REQESLIP>199-199
2QWW TRACE 0,REQWORD2
2RBG BNG 0 XILLINS [ERROR IF BIT 0 IS SET
2RW6 LDCH 7 0(3)
2S*Q ANDN 7 #17 [TRUSTED STATUS OF NEW REQ SLIP
2STB MHUNTW 1,AOBRES [OLD REQ. SLIP
2T*2 LDCH 0 VREQSLIP+2(1)
2TSL ANDN 0 #17 [OLD TRUSTED STATUS
2W#= #SKIP K6REQESLIP>199-199
2WRW TRACE 0,REQOLDST
2X?G STO 7 4
2XR6 ORX 7 0
2Y=Q ERX 7 0
2YQB BNZ 7 XILLINS [ERROR IF STATUS INCREASED
2^=2 SMO FX2
2^PL LDX 7 ATRUST
329= BZE 7 NOTRUST [J IF NO STATUS
32NW LDX 7 4
338G SRC 7 6
33N6 SMO FX2
347Q STO 7 ATRUST [STORE NEW STATUS IN PCA
34MB NOTRUST
3572 FJOPCA 3,FX2
35LL TESTRCTP 3,RCTP
366= BRN XMCH
36KW RCTP
375G ANDN 4 4
37K6 BNZ 4 XMCH
384Q TESTRT XTPRT,3,PCA
38JB ... BRN XNRT
3942 XTPRT UNPLUGRT PUC [UNPLUG PUC IF RT.
395Y ... BRN XRNM
397W ...#
399S ...# TO CORRECT B4991 - REMOVE NON-RREALTIME PUC FROM PROGRAM RING
39?Q ...#
39*N ...XNRT FINDPUC ,3
39CL ... MELUNRING 3
39FJ ...#
39HL XRNM NAME FX2,APET [RENAME TP/PCA APET
3=3= #SKIP G4
3=GW (
3?2G FINDPUC ,1 [FREE THE PUCS SEG TABLE
3?G6 LDX 4 ASEGTAB(1)
3?^Q LDX 1 ADATUM(1) [PTR TO DATUM
3#FB SRC 1 11
3#^2 LDN 0 8
3*DL BNG 1 NSHIFT [J IF ODD PAGE
3*Y= SLL 0 12
3BCW NSHIFT
3BXG SMO BGLOT
3CC6 SBS 0 0(1) [UNLOCK PAGE
3CWQ FREEPTAB 4
3DBB )
3DW2 FINDPUC ,4
3F*L MURDER 4 [MURDER PUC/PCA AND
3FT= UNSETRCTP FX2 [RESET JOB AS NON RCTP TYPE.
3G#W MHUNTW 1,AOBRES
3GSG XMCH
3H#6 ADN 5 3
3HRQ ADN 1 VREQSLIP+5 [INIT MEMBER PTRS.
3J?B NGN 4 1 [& MEMBER NO
3JR2 LDN 6 0 [& NEW MEMBER INDICATOR
3K=L CALL 7 XMEMBER
3KQ= CALL 7 XMEMBER
3L9W CALL 7 XMEMBER [CHECK FOR NEW MEMBERS
3LPG SBN 5 5
3M96 SBN 1 5 [RESET MEMBER PTRS
3MNQ CALL 7 XMEMBER
3MSM ...#UNS IMR
3MYJ ...#SKI
3N4F ...(
3N8B LDX 0 AWORK1(2)
3NN2 STO 0 APR1(2)
3NXS ...)
3P7L SBN 1 8
3PM= SBN 5 8 [RESET PTRS TO START OF REQ SLIP
3Q6W #SKIP K6REQESLIP>199-199
3QLG TRACE 6,REQNWMEM
3R66 BZE 6 Z3 [J IF ONLY ONE MEMBER
3RKQ LDX 3 FX2 [SUSPENSION WDS FOR NEW MEMBERS
3S5B SBN 3 K61
3SK2 LDN 0 0 [SUSPENSION FOR MEMBER 0
3T4L BRN Z2B
3TJ= Z2
3W3W LDCT 0 #200 [SUSPENSION FOR MEMBER 1-3
3WHG Z2B
3X36 ADN 3 K61 [NEXT ASU WORD
3XGQ ANDN 6 #17 [NEW MEMBER INDICATOR
3Y2B BZE 6 Z1B [J.IF NO MORE NEW MEMBERS
3YG2 SRC 6 1
3Y^L BPZ 6 Z2 [J.IF RELEVANT BIT UNSET
3^F= STO 0 ASU1(3) [SUSPENSION WORD FOR NEW MEMBER
3^YW BRN Z2
42DG Z1B [FIND NONSUSPENDED MEMBERS
42Y6 LDX 3 FX2
43CQ NGN 0 1
43XB LDN 6 4
44C2 Q1
44WL LDX 7 ASU1(3)
45B= BNG 7 Q2 [JUMP IF SUSPENDED
45TW ADN 0 1
46*G Q2
46T6 ADN 3 K61
47#Q BCT 6 Q1
47SB BZE 0 Z3
48#2 LDN 0 64
48RL SMO FX2
49?= SBX 0 ALIMIT
49QW BPZ 0 XILLINS
4==G Z3 LDN 4 16
4=Q6 LDX 6 1
4?9Q LDX 7 6
4?PB FOUTMOVE 2,5,6,4,HLOCK1 [MOVE 16 WORDS INTO AOBRES BLOCK
4#92 STOZ 13(1) [CLEAR CHECK SUM
4#NL BCHX 1 £
4*8= LDCH 3 0(1) [LENGTH OF REQ SLIP
4*MW SUM 6 0(3)
4B7G NGS 6 13(1) [FILL IN CHECKSUM
4BM6 TESTRT RTPR,,PCA
4C6Q BRN NRTP
4C=M ...#UNS IMR
4CBJ ...#SKI
4CGF ...(
4CLB RTPR LDN 6 4 [IF PROGRAM IS REALTIME,
4D62 NPR LDCH 0 APR1(2) [ PRIORITY:=MIN(PRIORITY+16,59) FOR
4DKL SBN 0 44 [ ALL MEMBERS
4F5= BNG 0 PROK
4FJW NGN 0 1
4G4G PROK ADN 0 60
4GJ6 DCH 0 APR1(2)
4H3Q BCHX 2 £
4HHB BCT 6 NPR
4HHJ ...)
4HHQ ...#UNS IMR
4HHY ...(
4HJ6 ...RTPR
4HJ# ...[ CALCULATE MEMBER PRIORITIES
4HJG ...[
4HJN ... MHUNTW 1,AOBRES
4HJW ... LDX 0 A1+7(1)
4HK4 ... STO 0 ACOMMUNE1(2)
4HK= ... LDX 0 A1+9(1)
4HKD ... STO 0 ACOMMUNE2(2)
4HKL ... LDX 0 A1+11(1)
4HKS ... STO 0 ACOMMUNE3(2)
4HL2 ... LDX 0 A1+8(1)
4HL8 ... STO 0 ACOMMUNE4(2)
4HLB ... LDN 5 4
4HLJ ...XCALC1
4HLQ ... SMO 5
4HLY ... LDX 0 ACOMMUNE1-1(2)
4HM6 ... LDN 1 4
4HM# ... BZE 0 XCALC3
4HMG ... LDN 1 0
4HMN ... LDN 4 4
4HMW ...XCALC2
4HN4 ... SMO 4
4HN= ... TXL 0 ACOMMUNE1-1(2)
4HND ... ADN 1 0
4HNL ... BCT 4 XCALC2
4HNS ...XCALC3
4HP2 ... SMO 5
4HP8 ... STO 1 ACOMMUNE5-1(2)
4HPB ... BCT 5 XCALC1
4HPJ ... LDN 4 4
4HPQ ...XCALC4
4HPY ... SMO 4
4HQ6 ... LDX 1 ACOMMUNE5-1(2)
4HQ# ... SRC 1 2
4HQG ... SMO FX1
4HQN ... LDCH 0 REMILL(1)
4HQW ... DCH 0 7
4HR4 ... SRC 7 6
4HR= ... BCT 4 XCALC4
4HRD ...[
4HRL ... LDX 1 2
4HRS ... ADN 1 AMR1 [START OF MILL PRI'S IN APET
4HS2 ... ORX 1 GSIGN [CHARACTER 2 IS MILL PRI. IN AMR'S
4HS8 ... FJOPCA 3,2
4HSB ... LDX 5 AMILLP(3) [REMEMBER CURRENT PRI'S
4HSJ ... LDN 6 4
4HSQ ...XAMR
4HSY ... SLC 7 6
4HT6 ... DCH 7 0(1) [STORE MILL PRI.IN APET
4HT# ... DCH 7 AMILLP(3) [ & IN JOB BLOCK
4HTG ...XAMR1
4HTN ... BCHX 3 £
4HTW ... ADN 1 1
4HW4 ... BCT 6 XAMR [J IF STILL MORE MEMBERS
4HW= ... SBN 3 1 [RESET JOB BLOCK PTR.
4HWD ... SBN 1 AMR1+4 [RESET PCA PTR
4HWL ... PCATEST 1,NORM [J IF NOT TP
4HWS ... FINDPUC 1,1 [AS TP,FIND PUC & STORE MILL PRI.
4HX2 ... ORX 1 GSIGN [ IN PUC'S APET
4HX8 ... SLC 7 6
4HXB ... DCH 7 AMR1(1)
4HXJ ...NORM
4HXQ ... BXE 5 AMILLP(3),NRTP [J IF PRI'S UNCHANGED
4HXY ... JBC NRTP,,EVBREALTIME [J IF REALTIME EVENT OFF
4HY6 ... UNPLUG
4HY# ... CAPCA
4HYG ... LDN 6 1
4HYN ... HLSINFORM XBRK,REALTIME,JOBNO(2),6
4HYW ...XBRK
4H^4 ... RUNPROG
4H^= ...)
4J32 NRTP MELRERING FX2
4JGL EVENTFIN
4K2= # UNPLUGS PROGRAM,CHECKS THAT PROG AREA IS IN RESERVATIONS AND LOCATES
4KFW # PROGRAMS DATUM
4K^G XSTART
4LF6 SBX 7 FX1
4LYQ LDN 6 16
4MDB CHECKB EVENT2(2),6,XRESVIOL
4MY2 ADX 7 FX1
4NCL EXIT 7 0
4NX= XADDR
4PBW LDX 3 5
4PWG FADDRESS 2,3,HLOCK1 [CONVERT TO GEORGE ADDRESS
4QB6 LDX 0 0(3)
4QTQ EXIT 7 0
4R*B # CHECKS PROGRAM NAME
4RT2 XNAME
4S#L LDX 3 5
4SS= FADDRESS 2,3,HLOCK1
4T?W LDN 0 4
4TRG LDCH 6 0(3)
4W?6 BRN ZN2 [FIRST CHAR MUST BE A LETTER
4WQQ ZN1 LDCH 6 0(3) [LOAD CHAR OF NAME
4X=B TXL 6 Q12(1)
4XQ2 BCS ZN3 [JUMP IF NUMERIC
4Y9L ZN2 TXL 6 Q41(1)
4YP= BCS XILLINS [ERROR IF NON ALPHANUMERIC
4^8W TXL 6 Q73(1)
4^NG BCC XILLINS [ERROR-NON ALPHANUMERIC
5286 ZN3 BCHX 3 £
52MQ SBN 0 1
537B BNZ 0 ZN1 [NEXT CHAR
53M2 EXIT 7 0
546L # CHECKS FOR NEW MEMBERS.REPORTS AN ERROR IF ANY OLD MEMBER HAS BEEN
54L= # DELETED
555W XMEMBER
55KG ADN 5 2
5656 ADN 1 2
56JQ LDX 3 5
574B ADN 4 1 [STEP MEMBER NO
57J2 FADDRESS 2,3,HLOCK1 [CONVERT TO GEORGE ADDRESS
583L LDX 0 0(3) [NEXT MEMBER WORD
58H= BZE 0 ZMEM1 [JUMP IF MEMBER NOT THERE
592W ANDN 0 #7777 [CHECK BOTTOM 12 BITS OF ENTRY
59GG SMO 4
5=26 SBN 0 #7700
5=FQ BNZ 0 XILLINS [ERROR IF WRONG FORMAT
5=KM ...#UNS IMR
5=PJ ...#SKI
5=TF ...(
5=^B LDCH 0 0(3) [MOST SIGNIFICANT PRIORITY CHAR
5?F2 SMO FX1
5?YL TXL 0 SIXTY
5#D= BCS ZMEM3 [JUMP IF LESS THAN SIXTY
5#XW LDN 0 59
5*CG ZMEM3 LDX 2 4
5*X6 SRC 2 2 [SET UP CHARACTER PTR
5BBQ SMO FX2
5BWB DCH 0 AWORK1(2) [PRIORITY TO APPROPRIATE CHAR
5C68 ...)
5CB2 LDX 2 FX2 [RESET X2
5CTL LDX 0 0(1) [OLD ENTRY
5D*= BZE 0 ZMEM2 [JUMP IF NO OLD ENTRY
5DSW EXIT 7 0
5F#G ZMEM2 LDN 0 1
5FS6 SMO 4
5G?Q SLC 0 0
5GRB ORX 6 0 [SET BIT TO INTRODUCE NEW MEMBER
5H?2 EXIT 7 0
5HQL ZMEM1 LDX 0 0(1)
5J== BNZ 0 XILLINS [ERROR IF AN OLD MEMBER DELETED
5JPW EXIT 7 0
5K9G #
5KP6 #REP 20
5L8Q +0
5LNB #
5M82 #END
^^^^ ...03752072000400000000