{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: RESET83)}}
====== RESET83 ======
(George Source)

**Macros used:** [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:CHNUMCOD|CHNUMCOD]], [[george:macro:COMERR|COMERR]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:PARABEG|PARABEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTREP|TESTREP]]

<code - RESET83.txt>22FL ...#SEG  RESET8                       [R.WEYAND
22^=    #OPT  K0RESET=0 
23DW    #LIS  K0RESET>K0ALLGEO  
23YG                   8HRESET8 
24D6    # ENTRY POINTS  
24XQ          SEGENTRY K1RESET,Z1RESET  
25CB          MENDAREA 10,K100RESET 
25X2    #     THIS SEGMENT TAKES THE SPECIFIED WIDTH PARAMETER AND STORES   
26BL    #     IT IN THE AMXOR/ADCB FOR 7900 AND THE AMXOR/ALCB FOR 7007/7920
26GH ...#     BUT IF THE CODE PARAMETER IS GIVEN AND WAS ISSUED FROM A VDU VIA  
26LD ...#     A 7900,THE SEGMENT WILL RECORD THE REQUIRED CODE CONVERSION,CODE 1
26Q* ...#     OR CODE 2,IN THE AMXOR/ADCB   
26W=    XCHAR +5
27*W    XWID  8HWIDTH   
27TG    XMIN  +40   
28*6    XMAX  +511  
28G# ...#   
28MG ...XCODE +4,4HCODE 
28SQ    Z1RESET 
29#B          PARABEG  1,XCHAR(1)   
29S2          MHUNT    3,CPB,CUNI   
2=?L          LDX   4  ANUM(3)  
2=R= ...      BZE   4  XERR 
2?=W ...      BNG   4  XCOD 
2?QG          CHNUMCOD ,3   
2#=6          TESTREP  CHNUMERR,XEND
2#PQ          LDX   5  ACOMMUNE1(2) 
2*9B          BXGE  5  XMIN(1),XCHC        [MIN ALLOWED IS 40   
2*P2          LDX   5  XMIN(1)  
2B8L          BRN      XCHCA
2BN=    XCHC  BXL   5  XMAX(1),XCHCA       [MAX ALLOWED IS 511  
2C7W          LDX   5  XMAX(1)  
2CMG    XCHCA   
2D76          LDCH  4  JSOURCE1(2)  
2DLQ          SBN   4  10   
2F6B          BZE   4  XCHMX
2FL2          SBN   4  1
2G5L          BZE   4  XCHMX
2GK=          SBN   4  13   
2H4W          BNZ   4  XEND 
2HJG          MHUNTW   3,AMXOR,ADCB 
2HPN ...      LDX   0  ICURSOR(3)       [IGNORE IF VDU, B1198   
2HWW ...      BNG   0  XEND 
2J46          DEX   5  ICHARS(3)
2JHQ    XEND  ENDCOM
2K3B    XCHMX MHUNTW   3,AMXOR,ALCB 
2K6G ...      SMO      A1+FPTR(3)        [IGNORE IF VDU, B1198  
2K9L ...      LDEX  0  FOURTHWD 
2K#Q ...      SBN   0  10   
2KCW ...      BZE   0  XEND 
2KH2          DEX   5  CHARS(3) 
2L2L          BRN      XEND 
2L37 ...#   
2L3N ...XCOD  FREECORE 3
2L49 ...      PARABEG  1,XCODE(1)   
2L4Q ...      MHUNT    3,CPB,CUNI   
2L5? ...      LDX   4  ANUM(3)  
2L5S ...      BNG   4  XERR                [FIRST PARAMETER NOT "CODE"  
2L64 ...      BZE   4  XERR                [FIRST PARAMETER NOT "CODE"N""   
2L6* ...      CHNUMCOD ,3                  [CONVERT "CODE NUMBER"   
2L6W ...      TESTREP  CHNUMERR,XEND       [ERROR IF CONVERSION NOT SUCCESSFUL  
2L7C ...      LDCH  0  JSOURCE1(2)  
2L7Y ...      SBN   0  #30  
2L8F ...      BNZ   0  XEND                [NOT MOP ON 7900 
2L92 ...      MHUNTW   3,AMXOR,ADCB 
2L9H ...      SMO      A1+FPTR(3)   
2L=4 ...      LDEX  0  FOURTHWD 
2L=K ...      SBN   0  10   
2L?6 ...      BNZ   0  XEND                [NOT A 7181/1 VDU
2L?M ...      LDCT  0  #400 
2L#8 ...      LDX   5  ACOMMUNE1(2)        ["CODE NUMBER"   
2L#P ...      SBN   5  1
2L*= ...      BNZ   5  XCOD2               [NOT "CODE1" 
2L*R ...      ORS   0  ICONTU(3)           [CODE 1 : UNSET CODE 2 FLAG IF SET   
2LB# ...      ERS   0  ICONTU(3)
2LBT ...      BRN      XEND 
2LCB ...XCOD2 SBN   5  1
2LCX ...      BNZ   5  XERR1               [NOT "CODE2" : ERROR 
2LDD ...      ORS   0  ICONTU(3)           [CODE 2 : SET CODE 2 FLAG
2LD^ ...      BRN      XEND 
2LFG ...#   
2LG=    XERR  COMERR   JPARMIS  
2LQ4 ...XERR1 COMERR   ERMCH               ['N' NOT RECOGNISED  
2L^W    #END
^^^^ ...35574353000300000000
</code>