{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: RESTERR864)}}
====== RESTERR864 ======
(George Source)
**Macros used:** [[george:macro:BLOCK|BLOCK]], [[george:macro:BWNZ|BWNZ]], [[george:macro:CATMASK|CATMASK]], [[george:macro:CLOSEFRBS|CLOSEFRBS]], [[george:macro:COOR3|COOR3]], [[george:macro:ERROR|ERROR]], [[george:macro:FAILURE|FAILURE]], [[george:macro:FILECOUNT|FILECOUNT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:MARK|MARK]], [[george:macro:MASK|MASK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:ON|ON]], [[george:macro:OR|OR]], [[george:macro:OUTMON|OUTMON]], [[george:macro:READ|READ]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:UPDATE|UPDATE]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREE|VFREE]], [[george:macro:VFREEW|VFREEW]]
22FL ... SEG RESTERR,864,BRIAN MATTHEWS,RESTORE
22^=
23DW SEGENTRY K1RESTERR,X1RESTERR
23YG SEGENTRY K2RESTERR,X2RESTERR
24D6 SEGENTRY K3RESTERR,X3RESTERR
24XQ SEGENTRY K4RESTERR,X4RESTERR
25CB SEGENTRY K5RESTERR,X5RESTERR
25X2 SEGENTRY K7RESTERR,X7RESTERR
26BL SEGENTRY K8RESTERR,X8RESTERR
26W= SEGENTRY K9RESTERR,X9RESTERR
27*W SEGENTRY K10RESTERR,X10RESTERR
27TG SEGENTRY K13RESTERR,X13RESTERR
28*6 SEGENTRY K14RESTERR,X14RESTERR
28SQ SEGENTRY K15RESTERR,X15RESTERR
29#B SEGENTRY K17RESTERR,X17RESTERR
29S2 SEGENTRY K18RESTERR,X18RESTERR
2=?L SEGENTRY K19RESTERR,X19RESTERR
2=R= SEGENTRY K20RESTERR,X20RESTERR
2?=W SEGENTRY K21RESTERR,X21RESTERR
2?QG SEGENTRY K30RESTERR,X30RESTERR
2#=6
2#PQ # THE PURPOSE OF THIS SEGMENT IS TO PRODUCE BETTER DIAGNOSTIC
2*9B # INFORMATION ON TAPE FORMAT ERRORS AND TAPE FAILURES DURING
2*P2 # GENERAL RESTORE. VARIOUS INFORMATION CAN BE DEDUCED ABOUT THE
2B8L # CAUSE OF THE FAILURE FROM THE POSITION IN THE GENERAL RESTORE
2BN= # SEGMENTS WHERE THE FAILURE HAS OCCURRED.
2C7W # THE USER AND/OR LOCAL NAME OF THE LAST START-OF-SUBFILE SENTINEL
2CMG # READ IS PRINTED OUT IN APPROPRIATE CASES, IN ORDER TO PROVIDE
2D76 # SOME INDICATION OF THE POSITION, ON THE INCREMENT DUMP TAPE,
2DLQ # WHERE THE FAILURE HAS OCCURRED
2F6B # ENTRY
2FL2 # THIS SEGMENT CAN BE ENTERED FROM ANY OF THE FOLLOWING RESTORE
2G5L # SEGMENTS- RESTEND, RESTOREG, RESTMERG, OR RESTLIMB. EACH OF
2GK= # THE ENTRY POINTS IN THE SEGMENT CORRESPOND TO A PARTICULAR
2H4W # TYPE OF TAPE FORMAT ERROR.
2HJG # EXIT
2J46 # ACROSS TO SEGMENT RESTFAIL WHICH IS DESIGNED TO TIDY UP THE
2JHQ # FILECHAIN BEFORE REQUESTING ANOTHER INCREMENT DUMP TAPE.
2K3B
2KH2
2L2L MESS1 +14
2LG= 52H LAST SSF SENTINEL READ : .
2L^W MESS2 +11
2MFG 40H LAST SSF SENTINEL READ :
2M^6 MESS3 +13
2NDQ ... 48H FORMAT ERROR IN INC. NO. ? ON MT ?
2NYB MESS4 +13
2PD2 ... 48H TAPE FAILURE IN INC. NO. ? ON MT ?
2PXL MESS5 +10
2QC= 36H ESF OR SSF SENTINEL WAS EXPECTED
2QWW MESS6 +10
2RBG 36H MASTER'S SSF SENTINEL WAS EXPECTED
2RW6 MESS7 +13
2S*Q 48H BLKS READ FROM MT NOT SAME AS IN SSF SENTINEL
2STB MESS8 +8
2T*2 28H ESF SENTINEL WAS EXPECTED
2TSL MESS9 +8
2W#= 28H SSF SENTINEL WAS EXPECTED
2WRW MESS10 +12
2X?G 44H NAME IN SSF SENTINEL NOT NAME IN TOP FCB
2XR6 MESS11 +13
2Y=Q 48H NAME RECORD IN A DIRECTORY IS INCORRECT LENGTH
2YQB MESS12 +8
2^=2 28H A NAME RECORD WAS EXPECTED
2^PL MESS13 +9
329= 32H A TRAPS RECORD WAS EXPECTED
32NW MESS14 +12
338G 44H AN INCOMPLETE DIRECTORY ENTRY ENCOUNTERED
33N6 MESS17 +14
347Q 52H MT KNOWN TO S/SERIAL BUT NOT TO S/INCINDEX
34MB MESS18 +13
3572 48H NO RECORD IN S/INCINDEX OF INCREMENT
35LL MESS19 +12
366= 44H NO RECORD IN S/SERIAL OF COPY TAPE
36KW MESS21 +12
375G 44H NO RECORD IN S/DUMPER OF COPY TAPE
37K6 MESS22 +11
384Q 40H NO RECORD IN S/INCINDEX OF MT
38JB MESS23 +11
3942 40H A SUPERFLUOUS TAPE MARK ENCOUNTERED
39HL MESS24 +5
3=3= 16HLONG BLOCK READ
3=GW XTHOU 1000000
3?2G
3?G6 X1RESTERR [ESF OR SSF EXPECTED
3?^Q LDN 3 MESS3
3#FB CALL 6 XFORPT [OUTPUTS HEADER MESSAGE
3#^2 LDN 3 MESS5
3*DL CALL 7 XERRPT [OUTPUTS ERROR MESSAGE
3*Y= CALL 7 SENPT [OUTPUTS LAST SSF READ
3BCW BRN XCLEANUP
3BXG
3CC6 X2RESTERR [SSF FOR MASTER EXPECTED
3CWQ LDN 3 MESS3
3DBB CALL 6 XFORPT
3DW2 LDN 3 MESS6
3F*L CALL 7 XERRPT
3FT= BRN XCLEANUP
3G#W
3GSG X3RESTERR [BLOCKS ON MT NOT SAME AS IN SSF SENT
3H#6 LDN 3 MESS3
3HRQ CALL 6 XFORPT
3J?B LDN 3 MESS7
3JR2 CALL 7 XERRPT
3K=L CALL 7 SENPT
3KQ= BRN XCLEANUP
3L9W
3LPG X4RESTERR [ESF SENT. WAS EXPECTED
3M96 LDN 3 MESS3
3MNQ CALL 6 XFORPT
3N8B LDN 3 MESS8
3NN2 CALL 7 XERRPT
3P7L CALL 7 SENPT
3PM= BRN XCLEANUP
3Q6W
3QLG X5RESTERR [SSF SENT. WAS EXPECTED
3R66 LDN 3 MESS3
3RKQ CALL 6 XFORPT
3S5B LDN 3 MESS9
3SK2 CALL 7 XERRPT
3T4L CALL 7 SENPT
3TJ= BRN XCLEANUP
3W3W
3WHG X7RESTERR [NAME RECORD INCORRECT LENGTH
3X36 LDN 3 MESS3
3XGQ CALL 6 XFORPT
3Y2B LDN 3 MESS11
3YG2 CALL 7 XERRPT
3Y^L CALL 7 SENPT
3^F= BRN XCLEANUP
3^YW
42DG X8RESTERR [NAME RECORD WAS EXPECTED
42Y6 LDN 3 MESS3
43CQ CALL 6 XFORPT
43XB LDN 3 MESS12
44C2 CALL 7 XERRPT
44WL CALL 7 SENPT
45B= BRN XCLEANUP
45TW
46*G X9RESTERR [TRAPS RECORD WAS EXPECTED
46T6 LDN 3 MESS3
47#Q CALL 6 XFORPT
47SB LDN 3 MESS13
48#2 CALL 7 XERRPT
48RL CALL 7 SENPT
49?= BRN XCLEANUP
49QW
4==G X10RESTERR [INCOMPLETE DIR. ENTRY
4=Q6 LDN 3 MESS3
4?9Q CALL 6 XFORPT
4?PB LDN 3 MESS14
4#92 CALL 7 XERRPT
4#NL CALL 7 SENPT
4*8= BRN XCLEANUP
4*MW
4B7G X13RESTERR [MT KNOWN TO S/SERIAL BUT NOT TO S/IN
4BM6 HUNT 1,FILE,FINTER7
4C6Q LDX 5 CURRTSN(1) [X5= TSN OF CURRENT TAPE
4CLB LDN 3 MESS17 [X3=REL POS. OF MESS.
4D62 LDN 4 2 [REL. POS. IN MESSAGE FOR TSN
4DKL CALL 7 STOTSN [OUTPUTS MESSAGE
4F5= BRN XGEOERR
4FJW
4G4G X14RESTERR [NO RECORD IN INCINDEX FOR INC. NO. N
4GJ6 LDN 3 MESS18+11
4H3Q LDX 0 JINCLAST [X0= INCR. REQUIRED
4HHB CALL 6 XBINDEC [CONVERTS BINARY TO DECIMAL
4J32 LDN 3 MESS18 [START ADDRESS OF MESSAGE
4JGL CALL 7 XERRPT
4K2= BRN XGEOERR
4KFW
4K^G X15RESTERR [NO RECORD IN S/SERIAL OF COPY TAPE
4LF6 LDX 5 6 [X6=TSN OF COPY TAPE
4LYQ LDN 3 MESS19
4MDB LDN 4 10
4MY2 CALL 7 STOTSN
4NCL BRN XGEOERR
4NX=
4PBW X17RESTERR [NO RECORD IN :DUMPER OF COPY TAPE
4PWG LDX 5 6 [X6= TSN OF COPY TAPE
4QB6 LDN 3 MESS21 [START ADDRESS OF MESSAGE
4QTQ LDN 4 10
4R*B CALL 7 STOTSN
4RT2 BRN XGEOERR
4S#L
4SS= X18RESTERR [NO RECORD IN INCINDEX OF MT M
4T?W HUNT 1,FILE,FINTER7
4TRG LDX 5 CURRTSN(1) [X5=CURRENT TSN
4W?6 LDN 3 MESS22
4WQQ LDN 4 9
4X=B CALL 7 STOTSN
4XQ2 BRN XGEOERR
4Y9L
4YP= X19RESTERR [B0,B1 OR B3 SET IN REPLY WORD FOR RE
4^8W LDX 0 CPRW1(2)
4^NG BNG 0 XMTPERI [GEOERR IF B0 SET
5286 SLL 0 1
52MQ BNG 0 XLONGBL [J IF LONG BLOCK
537B LDN 3 MESS4
53M2 CALL 6 XFORPT
546L CALL 7 SENPT [SSF SENTINEL PRINT OUT
54L= BRN XCLEANUP
555W
55KG XLONGBL
5656 LDN 3 MESS3
56JQ CALL 6 XFORPT [FORMAT ERROR MESSAGE
574B LDN 3 MESS24
57J2 CALL 7 XERRPT [LONG BLOCK READ MESSAGE
583L CALL 7 SENPT [LAST START SENTINEL
58H= BRN XCLEANUP
592W
59GG X20RESTERR [NOT THE NAME IN TOP FCB
5=26 LDN 3 MESS3
5=FQ CALL 6 XFORPT
5=^B LDN 3 MESS10
5?F2 CALL 7 XERRPT
5?YL CALL 7 SENPT
5#D= BRN XCLEANUP
5#XW X21RESTERR
5*CG LDN 3 MESS4 [ A SUPERFLUOUS TAPE MARK ENCOUNTERED
5*X6 CALL 6 XFORPT
5BBQ LDN 3 MESS23
5BWB CALL 7 XERRPT
5CB2 BRN XCLEANUP
5CBC ...# ******************************************************************
5CBS ...#
5CC9 ...# THIS SUBROUTINE SINULATES A INFOMEX 3
5CCL ...# IT IS A TEMPORARY MEASURE UNTIL THE SEGMENT CAN BE TIDIED UP
5CD3 ...MASK CATMASK CL [ CENTRAL CATEGORY MASK
5CDD ...ZINFOMEX [ CALLED ON X4
5CDT ... SBX 4 FX1 [ RELATIVISE AND SORE LINK
5CF= ... SMO FX2
5CFM ... STO 4 AWORK4
5CG4 ... LDX 1 FX1
5CGF ... ADX 1 3 [ POSITION OF COUNT IN CHAPTER
5CGW ... LDX 4 0(1) [ NO OF WORDS
5CH? ...# THERE SHOULD BE A FINTER5 SET UP
5CHN ...# BUT IF THERE ISNT SET UP ONE
5CJ5 ... HUNTW 2,FILE,FINTER5
5CJG ... BPZ 2 ZFINT5
5CJX ... SETNCORE 14,2,FILE,FINTER5
5CK# ...ZFINT5
5CKP ... ADN 2 A1
5CL6 ... LDX 1 FX1
5CLH ... ADX 1 3
5CLY ... SMO 4
5CM* ... MOVE 1 0 [ MOVE MESSAGE
5CMQ ... LDX 2 4
5CN7 ... SBN 2 1
5CNJ ... SLL 2 2 [ CONVERT TO CHAR COUNT
5CN^ ... SMO FX1
5CPB ... LDX 4 MASK
5CPR ... OUTMON 2,A1+1,4,FILE,FINTER5
5CQ8 ...#
5CQK ... MFREE FILE,FINTER5 [ FINISHED WITH BLOCK
5CR2 ... LDX 4 AWORK4(2) [ RESTORE LINK
5CRC ... ADX 4 FX1
5CRS ... EXIT 4 0
5CS9 ...#
5CSL ...# ******************************************************************
5CTL # THIS SUBROUTINE OUTPUTS MESSAGE TO OPERATORS CONSOLE
5D*= # ENTRY X3= POS. OF MESSAGE REL. TO START OF CHAPTER
5DSW # X7= LINK ADDRESS
5F#G
5FS6 XERRPT
5G?Q SBX 7 FX1
5GRB ... CALL 4 ZINFOMEX [ OUTPUT MESS
5H?2 ADX 7 FX1
5HQL EXIT 7 0
5J==
5JPW
5K9G # THIS SUBROUTINE WILL PRINT OUT THE LAST SSF SENTINEL READ
5KP6 # ENTRY FILE/FINTER6 BLOCK SET UP CONTAINING SSF SENTINEL ;'ALSO
5L8Q # ASSUMES THAT CONBUFF/COUT HAS BEEN SET UP IN PREVIOUS
5LNB # SUBROUTINE
5M82
5MML SENPT
5N7= SBX 7 FX1
5NLW SMO FX2
5P6G STO 7 AWORK3
5PL6 HUNT 1,FILE,FINTER6
5Q5Q LDX 7 ESENTYP(1)
5QKB BZE 7 XEXIT [ J IF F/F6 IS EMPTY
5R52 LDX 7 ESENB(1)
5RJL BPZ 7 XERR2 [J IF NOT A DIRECTORY
5S4= LDN 3 MESS2
5SHW BRN XERR1
5T3G XERR2
5TH6 LDN 3 MESS1
5W2Q XERR1
5WGB
5X22 MHUNTW 1,FILE,FINTER6
5XFL LDX 2 3 [ X2 -> APPROP. MESSAGE
5X^= LDCT 0 #200
5YDW ADS 0 2
5YYG LDN 0 12
5^D6 XAB LDCH 5 ESENUSE1(1)
5^XQ SMO FX1
62CB DCH 5 7(2)
62X2 BCHX 1 £
63BL BCHX 2 £
63W= BCT 0 XAB
64*W BNG 7 XERR4 [J IF A DIRECTORY
64TG BCHX 2 £
65*6 LDN 0 12
65SQ XAC
66#B LDCH 5 ESENLOC1-3(1)
66S2 SMO FX1
67?L DCH 5 7(2)
67R= BCHX 1 £
68=W BCHX 2 £
68QG BCT 0 XAC
69=6 XERR4
69PQ ... CALL 4 ZINFOMEX [ OUTPUT MESS
6=9B XEXIT
6=P2 SMO FX2
6?8L LDX 7 AWORK3
6?N= ADX 7 FX1
6#7W EXIT 7 0
6#MG
6*76
6*LQ # THIS SUBROUTINE CONVERTS THE INCREMENT NO. FROM BINARY
6B6B # TO DECIMAL AND INSERTS IT INTO APP. PLACE IN THE
6BL2 # OUTPUT MESSAGE
6C5L # ON ENTRY, X3=POSITION(RELATIVE TO START OF CHAPTER) OF INC. NO.
6CK= # IN THE OUTPUT MESSAGE
6D4W # X0=INC. NO.
6DJG # X6= LINK ADDRESS
6F46
6FHQ XBINDEC
6G3B SBX 6 FX1
6GH2 LDN 1 0
6H2L SMO FX1
6HG= DVR 0 XTHOU [SET UP PARAMETERS FOR
6H^W LDCT 2 #200
6JFG LDN 4 6
6J^6 MODE 1
6KDQ STOINC
6KYB SMO FX1
6LD2 CBD 1 0(3)
6LXL BCHX 3 £
6MC= BCT 4 STOINC
6MWW ADX 6 FX1
6NBG EXIT 6 0
6NW6
6P*Q
6PTB # THE FIRST ERROR MESSAGE PRINTED OUT IN THE OPERATOR'S CONSOLE
6Q*2 # WILL SPECIFY THE CAUSE OF FAILURE - EITHER TAPE FORMAT ERROR
6QSL # OR TAPE FAILURE. SINCE ONE OF THESE MESSAGES IS ALWAYS PRINTED
6R#= # OUT IT WAS DEEMED TO BE ECONOMICAL TO WRITE THE SETTING UP
6RRW # PROCEDURE AS A SUBROUTINE
6S?G # ENTRY: X3= ADD. OF MESSAGE REL. TO START OF CHAPTER
6SR6 # : F/FINTER7 BLOCK SET UP
6T=Q # : SUBROUTINE "STOTSN" WILL BE CALLED IN
6TQB
6W=2 XFORPT
6WPL SBX 6 FX1
6X9= STO 6 7 [STORE LINK ADDRESS
6XF4 ... SETNCORE 14,1,FILE,FINTER5
6XNW SMO FX2
6Y8G STO 3 AWORK3 [AWORK3=START ADDRESS OF MESSAGE
6YN6 LDCT 3 #400
6^7Q SMO FX2
6^MB ADX 3 AWORK3
7272 ADN 3 7
72BS ... JBC XNOINC,,BGENRES
72LL HUNTW 1,FILE,FINTER7
736= LDN 5 0
73KW BNG 1 XNOBIN [J IF NO FINTER7 BLOCK
745G LDX 5 CURRTSN(1) [X5= CURRENT TAPE
74K6 MHUNTW 1,FILE,FINTER
754Q LDX 0 ALOGLEN(1)
75JB BZE 0 XNOBIN [J IF NO INC: NO. IN FINTER
7642 SMO ALOGLEN(1)
76HL LDX 0 A1-1(1) [X0= INC. CURRENTLY READING
773= CALL 6 XBINDEC [CONVERTS BINARY NO. INTO DECIMAL
77GW XNOBIN
77JD ...# TAPE FAIL FOR PARTIAL RESTORE
77JQ ...#UNS AMTGR
77K4 ... JBS XNOBIN2,,BGENRES
77KB ...#UNS AMTGR
77KN ...#SKIP
77L2 ... BWNZ JINCLAST,XNOBIN2
77LR ...XNOINC
77MJ ... HUNTMISB 1,FI,FRESTUSER
77P6 ... LDN 0 0
77QN ... BNG 1 XNOBIN2
77S= ... LDX 5 FRTSN(1)
77TS ... LDX 0 FRLST(1)
77XB ... CALL 6 XBINDEC
77YY ...XNOBIN2
782G SMO FX2
78G6 LDX 3 AWORK3
78^Q LDX 6 7
79FB LDN 4 11
79^2 CALL 7 STOTSN [OUTPUTS MESS. WITH TSN INSERTED
7=DL ADX 6 FX1 [REPLACE LINK ADDRESS
7=Y= EXIT 6 0
7?CW
7?XG
7#C6 # THIS SUBROUTINE OUTPUTS THE APPROPRIATE MESSAGE WITH THE TSN
7#WQ # INSERTED IN A SPECIFIED POSITION. THE TSN. IS HELD
7*BB # IN CHARACTER FORM
7*W2 # ENTRY: X5 = CURRENT TSN
7B*L # X3 = POSITION OF MESS. RELATIVE TO START OF CHAPTER
7BT= # X4 = REL. POSITION IN MESS. FOR TSN
7C#W # X7= LINK ADDRESS
7CSG
7D#6 STOTSN
7DRQ SBX 7 FX1
7F?B BZE 5 OUTPT [BRANCH IF TSN=0
7FR2 LDX 1 4
7G=L ADX 1 3 [ X0 = COUNT OF 8 X2 =0
7GQ= LDN 2 0
7H9W LDN 0 8
7HPG
7J96 STOMESS
7JNQ STOZ 4
7K8B SLL 45 3 [ CONVERTING
7KN2 BNZ 2 STORE [ TSN
7L7L BZE 4 UPDATE [ INTO
7LM= LDN 2 1 [ CHARACTERS
7M6W STORE
7MLG SMO FX1 [ DEPOSITING THE CHARACTER
7N66 DCH 4 0(1)
7NKQ BCHX 1 £
7P5B UPDATE
7PK2 BCT 0 STOMESS
7Q4L OUTPT [OUTPUTS MESS. TO OPERATORS CONSOLE
7QJ= ... CALL 4 ZINFOMEX [ OUTPUT MESS
7R3W ADX 7 FX1
7RHG EXIT 7 0
7S36 #
7SGQ #
7T2B XGEOERR
7TG2 # BECAUSE OF THE DIFFICULTIES INVOLVED NO ATTEMPT IS MADE TO
7T^L # CLEAN UP THE BACKING STORE WHENEVER AN ERROR IN RESTEND SEGMENT
7WF= # OCCURES. INSTEAD AN APPROPRIATE MESSAGE IS OUTPUT FOLLOWED
7WYW # BY A GEOERR.
7XDG #
7XY6 [
7YCQ COOR3 #53 [WAIT UNTIL MESSAGE OUTPUT
7YXB GEOERR BRIEFPM,IDFORMAT
7^C2 #
7^WL XMTPERI
82B= GEOERR BRIEFPM,MTPERI [B0 OF REPLY WORD SET WHEN WOKEN UP
82TW #
83*G # AFTER THE APPROPRIAT MESSAGE HAS BEEN OUTPUT TO THE OPERATOR'S
83T6 # CONSOLE, A CLEAN UP OF THE FILE CHAIN, AND ACTIVITY CHAIN IS
84#Q # PERFORMED. ONLY MASTER'S FCB IS LEFT IN CORE AND THIS IS MARKED
84SB # AS EMPTY.
85#2 # UPPLUS 1 EVENTUALLY RETURNS TO RESTOREA WHERE A CLEAN UP OF
85RL # THE BACKING STORE IS ACHIEVED BY BACKMAP
86?= #
86QW X30RESTERR
87=G XCLEANUP
87#D ...#UNS APTFREST [ TESTING FRIG
87BB ...(
87D# ... MHUNT 1,FILE,FRESTOR [ HUNT FILE/FRESTOR BLOCK
87G= ... BNG 1 XNOPRINT [ IF PRESENT PRINT BLOCK
87J8 ... BLOCKTRA 1,FRESTOR,128
87L6 ...XNOPRINT
87N4 ...)
87Q6 FILECOUNT 3 [X3=NO.FILES OPEN TO ACTIVITY
87RM ...#UNS AMTGR
87T8 ... JBS XCLOSE,,BGENRES
87WP ...#UNS AMTGR
87Y= ...#SKI
87^X ... BWNZ JINCLAST,XCLOSE [ JUMP UNLESS PARTIAL RESTORE
884G ... SBX 3 AWORK2(2) [ SUBTRACT COUNT OF FILES TO BE LEFT O
889Q XCLOSE
88PB BZE 3 XNOFILES [ NO FILES OPEN
8992 CLOSEFRBS [ CLOSE THE FILE
89NL SBN 3 1
8=8= BRN XCLOSE
8=MW # SINCE THIS SEGMENT CAN BE ENTERED FROM VARIOUS POINTS IN THE
8?7G # RESTORE SEGMENTS IT IS NECESSARY TO DO VFREES FOR THE VARIOUS CORE
8?M6 # BLOCKS
8#6Q XNOFILES
8#8^ ...#UNS AMTGR
8#?8 ...(
8#*C ... JBC XLEAVBLK,,BGENRES
8#CL ... VFREEW FILE,FINTER
8#FT ... VFREEW FILE,FINTER7
8#J4 ...XLEAVBLK
8#L? ...)
8#NG ...#UNS AMTGR
8#QP ...#SKI
8#SY ...(
8#X7 ... VFREEW FILE,FINTER7 [ VARIOUS BLOCKS IN THE
8#^B ... VFREEW FILE,FINTER
8*3K ...)
8*62 VFREE CONBUFF,EMSIN
8*KL VFREEW FILE,FINTER5
8B5= VFREEW FILE,FWB
8BJW VFREEW FILE,FINTER6
8C4G VFREEW FILE,FAPB
8CJ6 VFREEW FILE,FRESTOR
8D3Q VFREEW FILE,FLOCNB
8F32 UPPLUS 1
8FGL #
8G2= MENDAREA 30,K99RESTERR
8GFW #
8G^G #END
^^^^ ...71653530000100000000