{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: RETURN867)}}
====== RETURN867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CHANGEFILE|CHANGEFILE]], [[george:macro:CJOBLOCK|CJOBLOCK]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERR|COMERR]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERRTEST|ERRTEST]], [[george:macro:FPUT|FPUT]], [[george:macro:FREETAB|FREETAB]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT|HUNT]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOCK|LOCK]], [[george:macro:LOGACCESS|LOGACCESS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:PAIR|PAIR]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SETUPTAB|SETUPTAB]], [[george:macro:SSEARCH|SSEARCH]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TABSET|TABSET]], [[george:macro:TABULATE|TABULATE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TOPFCB|TOPFCB]], [[george:macro:TSININC|TSININC]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UP|UP]]
22FL SEG RETURN,1,N.R.BOULT,LIBRARY
22KH ...[
22PD ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22T* ...[
22^= SEGENTRY K1RETURN,QK1RETURN
23DW SEGENTRY K2RETURN,QK2RETURN
23YG SEGENTRY K3RETURN,QK3RETURN
24D6 SEGENTRY K4RETURN,QK4RETURN
24XQ SEGENTRY K5RETURN,QK5RETURN
25CB SEGENTRY K7RETURN,QK7RETURN
25X2 SEGENTRY K8RETURN,QK8RETURN
26BL #
26W= FSHENTRY K9RETURN,,,
27*W FSHENTRY K10RETURN,,QK10RETURN,QK10RETURN
27TG FSHENTRY K11RETURN,QK11RETURN,,QK11RETURN
28*6 #
28SQ NDUMPER 12HDUMPER
29#B NPROCTP 12HGEO3PROCTAPE
29S2 #
2=?L NLANG 4HC1
2=R= SLINK
2?=W PAIR RETURNA,1
2?QG SLINK1
2#=6 PAIR RETURNA,2
2D76 QK1RETURN
2DLQ LDN 7 1 [ENTRY MARKER
2F6B LDN 0 1
2FL2 STO 0 AWORK3(2)
2G5L MHUNT 3,FILE,FABSNB
2GK= LDX 0 ATYPE(3)
2H4W ANDN 0 #200
2HJG BNZ 0 THU2 [BRANCH IF NAMED WORKTAPE
2J46 LDCT 0 #200
2JHQ SMO HDREC(3)
2K3B LDX 1 A1-2(3)
2KH2 ANDX 0 1
2L2L BZE 0 THU1
2LG= ANDN 1 #7777
2L^W BZE 1 THU1
2MFG SETREP NOFILE [ERROR IF +N
2M^6 BRN TT
2NDQ THU2
2NYB LDCT 0 #200
2PD2 SMO HDREC(3)
2PXL STO 0 A1-2(3) [HIGHEST LEVEL
2QC= BRN THU1
2QWW THU
2RBG HUNT 3,FILE,FABSNB
2RW6 THU1
2S*Q LDN 0 1
2STB ORS 0 ATYPE(3) [MAG TAPE
2T*2 LDN 5 0 [FIRST TAPE ROUND
2TSL BRN TOP
2W#= QK2RETURN
2WRW SETNCORE 3,3,FLIB,FTJOB
2X?G MHUNT 2,FILE,FABSNB [COPY USERNAME TO FTJOB
2XR6 LDX 0 A1(2) [FOR USE WHEN UPDATING BUDGETS
2Y=Q SBN 0 4
2YQB BNZ 0 XLFAB
2^=2 ADN 2 A1+1
2^PL XFTJ
329= ADN 3 A1
32NW MOVE 2 3
338G GETACT ACTDOC
33N6 LDX 3 BPTR(2)
347Q LINKSET 3,SLINK(1) [LINK FOR K7RETURN
34MB HUNT 1,FILE,FABSNB [NAME OF DIRECTORY
3572 CHAIN 1,3
35LL HUNT 1,AONBS,GLIST [TSNS TO RETURNED
366= CHAIN 1,3
36KW HUNT 1,FLIB,FTJOB
375G CHAIN 1,3
37K6 LDX 2 3
384Q FPUT
38JB UP
3942 XLFAB
39HL SMO A1(2)
3=3= ADN 2 A1-5
3=GW BRN XFTJ
3?2G QK3RETURN [RETURNA MACRO
3BCW LDN 7 3
3BXG LDX 6 EXEC1(2) [TSN
3CC6 OPENSYS XBRKERR,SERIAL,GENERAL
3CWQ NREC
3DBB STEP
3DW2 BZE 3 POOL
3F*L BXU 6 1(3),NREC
3FT= LDX 0 2(3)
3G#W BZE 0 POOL [BRANCH IF POOL TAPE
3GSG READAGAIN
3H#6 SETNCORE 12,3,FILE,FABSNB
3HRQ HUNT 1,FILE,FRB
3J?B LDN 0 A1+2(1)
3JR2 LDN 1 A1+1(3)
3K=L MOVE 0 3 [USER NAME
3KQ= STOZ A1+4(3) [ZEROISE LOCAL NAME
3L9W LDN 0 A1+4(3)
3LPG LDN 1 A1+5(3)
3M96 MOVE 0 5
3MNQ NGN 0 1
3N8B STO 0 A1+10(3)
3NN2 STO 6 A1+11(3) [TSN
3P7L LDN 0 10
3PM= STO 0 A1(3)
3Q6W LDN 0 #2000 [INDICATE TSN GIVEN
3QLG DSA 0 ATYPE(3)
3R66 MFREE FILE,FRB
3RKQ BACKSPACE
3S5B BRN THU
3SK2 POOL
3T4L CLOSETOP
3Y2B XUP
3YG2 UP
3Y^L QK4RETURN
3^F= LDN 7 4 [ENTRY FROM LIBSEC
3^YW LDN 5 0 [X4 ALREADY SET UP
42DG SETNCORE 3,1,FLIB,FTJOB
42Y6 STEPAGAIN 1
435# ...TAC1 HUNT 1,FLIB,FTJOB
43=G ... LDN 0 2(3)
43CN ... LDN 1 A1(1)
43JW ... MOVE 0 3
43Q4 ...TAC ACROSS RETURNIT,1
43XB QK5RETURN
44C2 LDN 7 5
44WL SETNCORE 18,3,FILE,FABSNB
45B= STEPAGAIN
45TW LDX 6 1(3) [TSN
46*G LDX 5 5(3)
46T6 SLL 5 1 [X5 -VE IF TEMP TAPE
47#Q HUNT 1,FILE,FABSNB
47SB LDN 0 10
48#2 BPZ 5 PN1 [J IF NOT TEMP
48RL ADN 0 6
49?= PN1 STO 0 HDREC(1)
49QW LDN 0 #2001
4==G DSA 0 ATYPE(1)
4=Q6 LDN 0 2(3)
4?9Q LDN 1 A1+1(1)
4?PB MOVE 0 3 [MOVE IN USER NAME
4#92 HUNT 3,FILE,FABSNB
4#NL BPZ 5 PN2 [J IF NOT TEMP TAPE
4*8= HUNT 1,FLIB,FTJOB
4*MW LDN 0 A1(1)
4B7G LDN 1 A1+4(3)
4BM6 MOVE 0 3 [MOVE IN JOB NAME AS LEFT BY UNLOAD
4C6Q LDN 0 1
4CLB STO 0 A1+7(3)
4D62 STO 0 A1+8(3)
4DKL SMO FX1
4F5= LDX 0 NLANG
4FJW STO 0 A1+9(3) [TEMP DIR LANGUAGE
4G4G ADN 3 6
4GJ6 PN2
4H3Q STOZ A1+4(3) [ZEROISE LOCAL NAME
4HHB LDN 0 A1+4(3)
4J32 LDN 1 A1+5(3)
4JGL MOVE 0 5
4K2= NGN 0 1
4KFW STO 0 A1+10(3)
4K^G STO 6 A1+11(3) [STORE TSN
4LF6 BNG 5 PN3
4LYQ LDN 5 12
4MDB ALTLEN 3,5
4MY2 SETNCORE 3,1,FLIB,FTJOB
4NCL PN3
4NX= HUNT 3,FILE,FABSNB
4PBW HUNT 1,FLIB,FTJOB
4PWG LDN 0 A1+1(3)
4QB6 LDN 1 A1(1)
4QTQ MOVE 0 3 [MOVE IN USER NAME FOR
4R*B OPENDIR XBRKERR,GENERAL,ERASING
4RGJ ... HUNT 3,FILE,ENT
4RMQ ... LDX 6 ESER(3)
4RSY ... SSEARCH ,6,1
4S26 ... LDX 5 5(3)
4S7# ... ANDN 5 #7777
4S#L BRN TAC
4SS= TOP
4T?W HUNT 3,FILE,FABSNB
4TRG LDX 0 ATYPE(3) [TEST IF NAMED WORKTAPE
4W?6 ANDN 0 #200
4WQQ BZE 0 TOPA
4X=B LDN 5 1 [TEMP DIR TO BE OPENED
4XQ2 TOPA
4Y9L OPENDIR YBRKIN,GENERAL,QUERY
4YP= TESTREPN OK,TT1
4^8W HUNT 3,FILE,FABSNB
4^NG HUNT 1,FILE,ENT
5286 LDX 0 ATYPE(3)
52MQ ANDN 0 #200
537B BNZ 0 OK1 [DO NOT CHECK IF NAMED WORKTAPE
53M2 LDX 0 ELOC1(1)
546L BZE 0 OK1 [OR IF DIRECTORY ENTRY HAS NO NAME
54L= SMO HDREC(3)
555W LDX 0 A1-6(3)
55KG BZE 0 OK1 [OR IF NO NAME SPECIFIED
5656 SMO HDREC(3) [CHECK IF SPECIFIED GEN NO IS
56JQ LDX 0 A1-2(3) [SAME AS THAT IN DIRECTORY ENTRY
574B BNG 0 TOPA1
57J2 SLL 0 1
583L BNG 0 TOPA1 [J IF REL GEN NO
58H= BZE 0 TOPA1 [OR IF NO GEN NO
592W SRL 0 1
59GG ANDN 0 #7777
5=26 BXU 0 EGEN(1),TOPA2
5=FQ TOPA1 SMO HDREC(3) [CHECK IF SPECIFIED REEL NO IS
5=^B LDX 0 A1-3(3) [SAME AS THAT IN DIRECTORY ENTRY
5?F2 ANDN 0 #777
5?YL BXE 0 EREEL(1),OK1
5#D= TOPA2
5#XW CLOSETOP [CLOSE DIRETORY
5*CG SETREP DISAGREE
5*X6 TT1
5BBQ ERRTEST 3,TERR,DISAGREE,VRYWRONG,NOUSER,WRGEN
5BWB BZE 5 TRYT
5CB2 TESTREPN NAME,TT
5CTL SETREP NOFILE
5D*= TT ERRTEST 3,TERR,NAME,NOFILE
5DSW T2 GEOERR 1,OPENDIR
5F#G TRYT
5FS6 TESTREPN NOFILE,TT
5G?Q HUNT 3,FILE,FABSNB
5GRB LDX 6 ALOGLEN(3) [LENGTHEN FOR TEMP DIR
5H?2 ADN 6 6
5HQL ALTLEN 3,6,FILE,FABSNB
5J== HUNT 3,FILE,FABSNB
5JPW SBX 6 HDREC(3)
5K9G SBN 6 6
5KP6 BZE 6 PA1
5L8Q SMO HDREC(3)
5LNB LDN 0 A1(3)
5M82 LDX 1 0
5MML ADN 1 6
5N7= SMO 6
5NLW MOVE 0 0
5P6G PA1 SMO HDREC(3)
5PL6 LDN 0 A1-6(3)
5Q5Q LDX 1 0
5QKB ADN 1 6
5R52 MOVE 0 6
5RJL CJOBLOCK 2
5S4= LDN 0 JNAME(2) [MOVE IN JOB NAME
5SHW SMO HDREC(3)
5T3G LDN 1 A1-6(3)
5TH6 MOVE 0 3
5W2Q LDN 0 1
5WGB STO 0 3(1)
5X22 STO 0 4(1)
5XFL SMO FX1
5X^= LDX 0 NLANG
5YDW STO 0 5(1)
5YYG LDN 0 6
5^D6 ADS 0 HDREC(3)
5^XQ LDN 5 1 [INDICATE SECOND TIME
62CB BRN TOP [TRY AGAIN
62X2 OK1
63BL LDX 0 7
63W= SBN 0 3
64*W BZE 0 XNOTRAPCH [J IF K3 ENTRY
64TG HUNT 3,FILE,ENT
65*6 LDX 0 EINCLOOK(3)
65SQ BPZ 0 OK3 [J IF TAPE NOT BEING USED AS DUMPTAPE
66#B PDUMP
66S2 CLOSETOP [DIRECTORY
67?L CLOSETOP [SYSTEM.SERIAL
67R= LDX 0 AWORK3(2)
68=W BNZ 0 PDUMP1 [IF NECESSARY
68QG CLOSETOP [CLOSE :SYSTEM.INCINDEX
69=6 PDUMP1
69PQ COMERR HDINUSE
6=9B OK3
6=P2 TOPFCB 3 [FIND USERNAME OF DIRECTORY
6?8L LDX 2 FX1
6?N= LDX 4 FME1(3) [AND CHECK FOR :DUMPER
6#7W LDX 5 FME2(3)
6#MG LDX 6 FME3(3)
6*76 TXU 4 NDUMPER(2)
6*LQ TXU 5 NDUMPER+1(2)
6B6B TXU 6 NDUMPER+2(2)
6BL2 BCS PROCOK [JUMP IF UNEQUAL
6C5L LDX 4 ELOC1(1)
6CK= LDX 5 ELOC2(1)
6D4W LDX 6 ELOC3(1)
6DJG TXU 4 NPROCTP(2) [CHECK LOCAL NAME
6F46 TXU 5 NPROCTP+1(2) [FOR GEO3PROCTAPE
6FHQ TXU 6 NPROCTP+2(2)
6G3B BCS PROCOK [JUMP IF UNEQUAL
6GH2 SMO FX2
6H2L LDX 0 AWORK3
6HG= BZE 0 PROC2 [JUMP IF INCINDEX OPEN
6H^W # OPEN :SYSTEM.INCINDEX
6JFG CLOSETOP
6J^6 CLOSETOP
6KDQ OPENSYS XBRKERR,INCINDEX,READ,QUERY
6KYB TESTREP OK,PROC1
6LD2 TESTREPN CLUDGE,XINCERR
6LXL COMERR ERG3PT
6MC= PROC1
6MWW STOZ AWORK3(2) [SET INCINDEX OPEN MARKER
6NBG OPENSYS XBRKERR,SERIAL,GENERAL
6NW6 LDN 5 0
6P*Q BRN TOPA
6PTB PROC2
6Q*2 HUNT 1,FILE,ENT
6QSL LDX 4 ESER(1) [GET TSN
6R#= TSININC PDUMP,4,2 [AND SEARCH :SYSTEM.INCINDEX
6RRW PROCOK
6S?G SETUPTAB [REMEMBER POSITION IN
6SR6 TABSET [DIRECTORY FOR RETURNIT
6T=Q CHECKTRAPS [ACOMMUNE7 => TRAPS
6TQB LDX 0 ACOMMUNE7(2) [X0 => TRAPS
6W=2 ANDN 0 CERASET [
6WPL BNZ 0 XTRAPSET [J IF ERASE TRAP SET
6X9= CLOSETOP [CLOSE DIRECTORY
6XNW CLOSETOP [AND :SYSTEM SERIAL
6Y8G LDX 0 AWORK3(2)
6YN6 BNZ 0 XNOINC [IF NECESSARY
6^7Q CLOSETOP [CLOSE :SYSTEM.INCINDEX
6^MB XNOINC
7272 COMERR ERNOTRAP [OUTPUT ERROR MESSEGE ETC
72LL XTRAPSET [
736= TABULATE [RESET READ POINTERS FOR DIRECTORY
73KW FREETAB [NO MORE TABS REQUIRED
745G XNOTRAPCH [
74K6 LDX 0 7
754Q SBN 0 1
75JB BNZ 0 NLOG
7642 LOGACCESS 4
76HL NLOG
773= GETACT ACTDOC
77GW LDX 3 BPTR(2)
782G LINKSET 3,SLINK1(1) [LINK FOR K8RETURN
7?CW HUNT 1,FILE,ENT
7?XG CHAIN 1,3
7#C6 STO 7 ACC7(3)
7#WQ LOCK 3
7*BB CHANGEFILE 3,0,1
7*W2 CHANGEFILE 3
7B*L UNLOCK 3
7BT= LDX 2 3
7C#W FPUT
7CSG LDX 0 7
7D#6 SBN 0 1
7DRQ BZE 0 OK4 [J IF COMMAND
7F?B OK5
7NKQ QK10RETURN
7T2B UP
7TG2 OK4
7T^L LDX 0 AWORK3(2)
7WF= BNZ 0 OKEND [IF NECESSARY
7WYW CLOSETOP [CLOSE :SYSTEM.INCINDEX
7XDG OKEND
7XY6 ENDCOM
7YCQ QK8RETURN
7YXB QK7RETURN
7^C2 GEOERR 1,NOTRET
7^WL #
889Q TERR
88PB SBN 7 3
8992 BNZ 7 TERR1
89NL GEOERR 1,RETURNA
8=8= TERR1
8=MW CLOSETOP
8?7G LDX 0 AWORK3(2)
8?M6 BNZ 0 TERR2 [IF NECESSARY
8#6Q CLOSETOP [CLOSE :SYSTEM.INCINDEX
8#LB TERR2
8*62 ENDCOM
8*KL WRONGREP
8B5= GEOERR 1,WRONGREP
8BJW XINCERR
8C4G GEOERR 1,RTNOINC
8CJ6 XBRKERR
8D3Q GEOERR 1,BREAKIN
8DHB YBRKIN
8F32 CLOSETOP
8FGL SBN 7 1
8G2= BNZ 7 X1
8GFW LDX 0 AWORK3(2)
8G^G BNZ 0 XCOMBK
8HF6 CLOSETOP
8HYQ XCOMBK
8JDB COMBRKIN
8JY2 X1
8KCL BRN OK5
8KX= MENDAREA 50,K99RETURN
8LBW #END
^^^^ ...631562550002