{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: RIGHT867)}}
====== RIGHT867 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:CCOUT|CCOUT]], [[george:macro:CLWTBWR|CLWTBWR]], [[george:macro:COOR3|COOR3]], [[george:macro:DFJUMPS|DFJUMPS]], [[george:macro:DFLOAD|DFLOAD]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ENRING|ENRING]], [[george:macro:ERRORX|ERRORX]], [[george:macro:FMOPG|FMOPG]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOPACK|GEOPACK]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2B|HUNT2B]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INFORMX|INFORMX]], [[george:macro:IPBANON|IPBANON]], [[george:macro:IRIGHT|IRIGHT]], [[george:macro:IWRONG|IWRONG]], [[george:macro:JALLOC|JALLOC]], [[george:macro:JDISENG|JDISENG]], [[george:macro:JEXOTIC|JEXOTIC]], [[george:macro:JFREE|JFREE]], [[george:macro:JMNBWR|JMNBWR]], [[george:macro:JMT|JMT]], [[george:macro:JNRGROP|JNRGROP]], [[george:macro:JONL|JONL]], [[george:macro:JRIGHT|JRIGHT]], [[george:macro:JV7900|JV7900]], [[george:macro:JWRONG|JWRONG]], [[george:macro:JWTBSW|JWTBSW]], [[george:macro:LAMOP|LAMOP]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGON|LONGON]], [[george:macro:LPROP|LPROP]], [[george:macro:LPUNSET|LPUNSET]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOPSTATE|MOPSTATE]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OVER|OVER]], [[george:macro:PAIR|PAIR]], [[george:macro:PARSORT|PARSORT]], [[george:macro:PCT7020|PCT7020]], [[george:macro:RIGHT|RIGHT]], [[george:macro:SAWCEJX|SAWCEJX]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETMODEQ|SETMODEQ]], [[george:macro:SETWTBWR|SETWTBWR]], [[george:macro:SPARANOX|SPARANOX]], [[george:macro:TERROR|TERROR]], [[george:macro:UNIFREE|UNIFREE]], [[george:macro:UNLOAD|UNLOAD]], [[george:macro:WRONG|WRONG]], [[george:macro:XRIGHT|XRIGHT]], [[george:macro:XWRONG|XWRONG]], [[george:macro:YRIGHT|YRIGHT]], [[george:macro:YWRONG|YWRONG]]
22FL ...#SEG RIGHT [BOB WEYAND
22PD ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD. 1982
22^= #OPT K0RIGHT=0
23DW #LIS K0RIGHT>K0PERI>K0COMMAND>K0ALLGEO
23YG 8HRIGHT
24D6 ...# THIS SEGMENT SERVICES THE RIGHT AND WRONG COMMANDS
28SQ #
29#B #
29S2 # ENTRY POINTS
2=?L #
2=R= SEGENTRY K2RIGHT,X2RIGHT
2?=W SEGENTRY K3RIGHT,X3RIGHT
2?BR ... SEGENTRY K4RIGHT,X4RIGHT
2?GN ...# K4 ACROSS FROM SWITCH IN WITH CPAR/JSCES & AWORK2 SET UP
2?LK ...#
2?QG #
2#=6 XJRIGHT +JRIGHT
2#PQ XJWRONG +JWRONG
2*9B XJWATWR +JWATWR
2*P2 XJCANWR +JCANTWR
2*YS ...XJMNRI +JMNRI
2B8L XJRES +JRES
2BN= XNOPER +JNOPER
2C7W XPFERR +APFERR
2C=F ...XJWTSW +JWTBSW
2C*4 ...XJMPON +JMOPPEDON
2CCN ...XERAT +JERAT
2CD^ ...XERTGEO +JERTGEO
2CG? ...#UNS ISUMBI
2CJW ...XJIDEBUSY +JIDEBUSY1
2CMG RMPX +11
2D76 RUPX +10
2DLQ RFD +13
2F6B RIPB +24
2FL2 RPRPMSK #37777
2G5L RUMSK #777000
2GK= PROPMASK #37700
2H4W RMTYP +5
2HJG XTP +1
2J46 XLP +2
2JHQ XCP +4
2K3B RMAXTP +6
2KH2 PLINK
2L2L PAIR LISTINIT,5
2LG= PLINKTC [TP OR CP
2L^W PAIR LISTINTC,5
2MFG RLINK
2M^6 PAIR PCTSTART,1
2N6# ...PLINKGR
2N?G ... PAIR ENGAGE,11
2NDQ TERROR [USED FOR COMMAND ERRORS
2NYB SBX 7 FX1
2PD2 MHUNTW 2,CPAR,JSCE [LOCATE CPAR/JSCE BLOCK
2PXL LDX 5 JSCEQ(2)
2QC= FREECORE 2 [FREE IT
2QWW SRL 5 12 [PARAMETER NUMBER
2RBG LDN 4 0 [PARAMETER ANALYSIS LEVEL
2RW6 SPARANOX 5,4 [REACCESS PARAMETER
2S*Q ERRORX 6
2STB UNIFREE [FREE CPB,CUNI BLOCK
2T*2 ADX 7 FX1
2TSL EXIT 7 0
2TW3 ...TERROR1
2TXD ... SBX 7 FX1
2TYT ... MHUNTW 2,CPAR,JSCE
2W2= ... LDX 5 JSCEQ(2)
2W3M ... ANDN 5 #7777
2W54 ... OUTPARAM 5,JSCER,CPAR,JSCE
2W6F ... ERRORX 6
2W7W ... MFREEW CPAR,JSCE
2W9? ... ADX 7 FX1
2W=N ... EXIT 7 0
2W#= RHUNT [HUNTS FOR PARAMETER BLOCK
2WRW HUNTW 2,CPAR,JSCE [FIND CPAR/JSCE BLOCK
2X?G EXIT 6 0
2XR6 ROUTSS [OUTPUTS SS SEGMENT,CODE IN X0
2Y=Q SBX 7 FX1
2YQB LDX 1 FX2
2^=2 STO 0 ACOMMUNE1(1)
2^PL LDX 2 JSCEA(2) [IDENTIFIER NO
329= ANDN 2 #7777
32NW CCOUT 2,AWORK1(1)
338G ADX 7 FX1
33N6 EXIT 7 0
347Q #
34MB RCH1 #770000
3572 RPCT [SETS WAITING TO BE WRONGED BIIT
35LL LDX 4 APCTDEV(3) [... IN INTERFACE BLOCK
366= SMO FX1
36KW ANDX 4 RCH1
375G SMO FX2
37K6 LDX 0 AWORK3 [REL POINTER TO A PCT RECORD WHITHIN
384Q ADX 4 0 [THE A7020/INFORM BLOCK
38JB SBX 1 0
3942 PCT7020 1,4
39HL LDCT 0 #4
3=3= ORS 0 EWAIT(1)
3=GW EXIT 6 0
3=HJ ...#UNS AV7900S
3=J= ...(
3=JY ...#
3=KL ...# SUBROUTINE TO TEST IF AN IPB IS A VIRTUAL 7900 AND IF TRUE TO
3=L# ...# RIGHT OR WRONG IT IN THE DEVICE LIST
3=M2 ...# ON ENTRY X3 -> AN IPB (7900) DEVICE LIST
3=MN ...# IF THE V7900 IS RIGHTED/WRONGED IN DL, IT WILL BE WRONGED/RIGHTED
3=NB ...# RESPECTIVELY
3=P4 ...# EXITS+1 IF THE 7900 IS NOT A VIRTUAL 7900, ELSE EXITS+0
3=PQ ...# LINK IN X7
3=QD ...RIORWRV7900
3=R6 ... JV7900 3,RIORWR
3=RS ... EXIT 7 1 [7900 IS NOT A VIRTUAL 7900 : EXIT +1
3=SG ...RIORWR
3=T8 ... LDCT 0 #400 [REVERVSE 'DEVICE WRONGED' BIT IN DL
3=TW ... ERS 0 JK52B(3)
3=WJ ... CLWTBWR 3 [CLEAR WAITING TO BE WRONGED' BIT
3=X= ... [IN DL AS IT IS NOT DONE AT LABEL XL
3=XY ... EXIT 7 0 [V7900 WRONGED/RIGHTED : EXIT +0
3=YL ...#
3=^# ...)
3=^H ...
3=^Q ...ZMOP
3=^^ ... MOPSTATE 3,7,AMOP,2
3?28 ... EXIT 6 0
3?2G X2RIGHT [ENTRY POINT FOR RIGHT COMMAND
3?G6 NGN 6 1 [SET X6 -VE
3?^Q BRN RSTT
3#FB X3RIGHT [ENTRY POINT FOR WRONG COMMAND
3#^2 LDN 6 6
3*DL RSTT
3*Y= STO 6 AWORK2(2) [STORE RI/WR MARKER
3BCW PARSORT YUK,ALL [ANALYSE PARAMETERS
3BMN ...X4RIGHT
3BXG RRSTT
3CC6 CALL 6 RHUNT [HUNT CPAR/JSCE BLOCK ON X2
3CWQ BNG 2 OVER [PACK UP IF NONE LEFT
3DBB LDX 3 JSCEP(2) [LOAD DEVICE LIST POINTER
3DW2 SAWCEJX JSCEB(2),T1,RMRIGHT,RMRIGHT
3F*L # BR TO RMRIGHT IF DEVICE REMOTE
3FT= T1
3G#W LDX 5 JSCEA(2) [LOAD JSOURCE1
3GSG LDX 2 FX2
3H#6 LTYPE 3,4 [PERIPHERAL TYPE TO X4
3HRQ LDX 0 AWORK2(2)
3J?B BPZ 0 RWRONG [BR IF ENTERED FOR WRONG
3JR2 # CODING FOR LOCAL RIGHT COMMAND
3K2S ... JWTBSW 3,XWTBSW
3K=L CLWTBWR 3 [CLEAR 'WAITING TO BE WRONGED' BIT
3KQ= JRIGHT 3,RALRI [BR IF ALREADY RIGHT
3L9W JEXOTIC 3,XNFW
3LPG TXU 4 RIPB(1)
3M96 BCC RXIPB [BR IF IPB
3MNQ CHECKFLA 3,XNFW [BR IF DEVICE NOT FLAGWAVER
3MYJ ...#SKI IDFMARK8<1$1
3N8B XRIGHT 3 [RIGHT THE MPX OR UPX IN THE IDF
3N*J ...#SKI IDFMARK8
3NGQ ... XRIGHT YUK,3 [RIGHT MX OR UX IN IDF
3NN2 BRN XNFW
3P7L RXIPB
3P9J ... CALL 6 ZMOP
3P?G ...YRIDF
3P*D ... IPBANON RWAIT
3PCD ...#SKI IDFMARK8<1$1
3PM= YRIGHT 3 [RIGHT THE IPB IN THE IDF
3PSD ...#SKI IDFMARK8
3P^L ... YRIGHT YUK,3 [RIGHT IPB IN IDF
3Q2B ...#UNS AV7900S
3Q36 ...(
3Q3W ... CALL 7 RIORWRV7900 [IF A V7900, RIGHT IT IN DEVICE LIST
3Q4L ... BRN RIGHTEDINDL [V7900 RIGHTED : SKIP RIGHT MACRO AS
3Q5B ... [IT IS NOT VALID FOR V7900'S
3Q66 ...)
3Q6W XNFW
3QLG RIGHT 3 [RIGHT THE DEVICE
3QW# ...RIGHTEDINDL
3R66 JMT 3,XMT [BR IF MAGNETIC TAPE
3RKQ TXU 4 XLP(1)
3S5B BCS XNOTLP [BR IF NOT LINEPRINTER
3SK2 LPUNSET 3 [UNSET 'PAPER ALIGNED' MARKER
3SNF ... JNRGROP 3,XSLOPP
3SRY ... JDISENG 3,XSLOPP
3SXC ... GETACT ACTCDT
3T2W ... LDX 2 BPTR(2)
3T6* ... STO 3 CPPTR(2)
3T9S ... LDN 1 PLINKGR(1)
3T*? ... LINKSET 2,0(1)
3TDQ ... BRN NOTLP
3TJ= XNOTLP
3W3W TXU 4 XTP(1)
3WHG BCC XSLOPP [BR IF TAPE PUNCH
3X36 TXU 4 XCP(1)
3XGQ BCS XNSLOPP [BR IF NOT CARD PUNCH
3Y2B XSLOPP
3YG2 # NOW TO SET UP AN ACTIVITY FOR THE SLOW OUTPUT DEVICE
3Y^L SETALLOC 3 [MARK DEVICE ALLOCATED
3^F= GETACT ACTLF,CENTRAL [SET A CENTRAL ACTLF
3^YW LDX 2 BPTR(2) [X2 POINTS TO NEW ACTLF
42DG STO 3 CPPTR(2) [GIVE DEVICE TO ACTLF
42Y6 STO 5 JSOURCE1(2) [STORE GEOG NO IN JSOURCE1
43CQ TXU 4 XLP(1)
43XB BCC TOLP [J IF LP
44C2 LINKSET 2,PLINKTC(1)
44WL BRN NOTLP
45B= TOLP
45TW LINKSET 2,PLINK(1)
46*G NOTLP
46T6 FPUT
47#Q BRN RALRI
47C* ...RWAIT
47FY ... LDX 7 2
47JH ... COOR3 #62
47M6 ... LDX 2 7
47PP ... BRN YRIDF
47SB XNSLOPP
48#2 BZE 4 RIN [BR IF TAPE READER
48RL SBN 4 3
49?= BNZ 4 RALRI [BR IF NOT CARD READER
49QW RIN
4==G LONGON #60 [WAKE UP ACTIVITIES WAITING FOR DOC
4=Q6 RALRI
4?9Q LDX 7 XJRIGHT(1)
4?PB BRN RLOCRT [BR TO OUTPUT MESSAGE
4#92 # INSERT MT CODING HERE
4#NL XMT
4*8= LPROP 3,7
4*MW SRL 7 7
4B7G ANDN 7 1
4BM6 BNZ 7 RALRI [BRANCH IF NINE TRACK
4C6Q DFLOAD 3,SMODE,7 [LOAD STANDARD MODE INTO X7
4CLB SETMODEQ 3,7 [AND STORE IN DEVICE LIST
4D62 BRN RALRI [BR TO OUTPUT MESSAGE
4DKL RWRONG [ENTERED FOR WRONG
4F5= # [X3 = DEVICE LIST POINTER
4FJW # [X4 = TYPE
4FQ4 ... TXU 4 RIPB(1)
4FX= ... BCC ZIPB [BR IF IPB
4G4G JMNBWR 3,RCNWRL [BR IF DEVICE CANNOT BE WRONGED
4GJ6 JALLOC 3,RALLOC [BR IF DEVICE ALLOCATED
4H3Q JWRONG 3,XDWUA [BR IF ALREADY WRONGED
4HHB JEXOTIC 3,XNOTFW [BR IF EXOTIC
4K2= CHECKFLA 3,XNOTFW [BR IF NOT FLAGWAVER
4K=4 ...#SKI IDFMARK8<1$1
4KFW XWRONG RCNWRL,3 [WRONG THE MPX OR UPX IN THE IDF
4KM4 ...#SKI IDFMARK8
4KS= ... XWRONG YUK,RCNWRL,3 [WRONG THE MPX OR UPX IN THE IDF
4K^G BRN XNOTFW
4LF6 ZIPB
4LFK ... CALL 6 ZMOP
4LG4 ... LDX 5 2
4LGH ... LDX 2 FX2
4LH4 ... BZE 7 XMPON [J IF MOPPED ON
4LHM ... BNG 7 XMPON
4LJ= ... LDX 6 7
4LJF ... SBN 6 5
4LJN ... BZE 6 ZIPBWR
4LK2 ... ANDN 7 1
4LK^ ... BNZ 7 XMPON [ J IF BEING MOPPED ON
4LLY ... BRN RALLOC [J IF BEING MOPPED OFF OR ONLINE
4LMX ...ZIPBWR
4LN= ... LDX 2 5
4LNK ... IPBANON ZWAIT
4LNY ...#SKI IDFMARK8<1$1
4LYQ YWRONG RCNWRL,3 [WRONG THE IPB IN THE IDF
4M5Y ...#SKI IDFMARK8
4M?6 ... YWRONG YUK,RCNWRL,3 [WRONG THE IPB IN THE IDF
4M?R ...#UNS AV7900S
4M#D ...(
4M*5 ... CALL 7 RIORWRV7900 [IF A V7900, WRONG IT IN DEVICE LIST
4M*Q ... BRN XDWUA [V7900 WRONGED : SKIP DISENGPER AND
4MBC ... [WRONG MACROS AS THEY ARE NOT VALID
4MC4 ... [FOR V7900'S
4MCP ...)
4MDB XNOTFW
4MY2 JMT 3,XWRMT [BR IF MAG TAPE
4NCL DISENGPE 3 [DISENGAGE THE DEVICE
4NX= XL
4PBW CLWTBWR 3 [CLEAR 'WAITING TO BE WRONGED' BIT
4PWG WRONG 3 [WRONG THE DEVICE
4QB6 XDWUA
4QTQ LDX 7 XJWRONG(1)
4R*B BRN RLOCRT [BR TO OUTPUT MESSAGE
4RF? ...ZWAIT
4RK8 ... COOR3 #62
4RP5 ... BRN ZIPBWR
4RT2 RALLOC [DEVICE ALLOCATED (WR)
4S#L SETWTBWR 3 [SET 'WAITING TO BE WRONGED' BIT
4SS= RWTWMESS
4T?W LDX 7 XJWATWR(1) [MESSAGE IDENTIFIER
4TRG BRN RLOCRT
4W?6 XWRMT
4WQQ # WR MT CODING
4X=B DFJUMPS 3,LOAD,TL [BR IF TAPE LOADED
4XQ2 BRN XL [NO 3APE UP - AS NORMAL
4Y9L TL
4YP= SETALLOC 3 [MARK ALLOCATED FOR UNLOAD
4YT7 ... SETWTBWR 3 [SET 'WAITINGTOBEWRONGED' &
4Y^4 ...# [..FREEPER(ISSUED BY UNLOAD MACRO..
4^4^ ...# [..WILL WR IT & GIVE MESSAGE
4^8W UNLOAD 3,,,UNL [UNLOAD DECK
4^H? ... MFREEW CPAR,JSCE
4^TN ... BRN RRSTT
5286 RLOCRT
52MQ CALL 6 RHUNT
537B GEOPACK 4,JSCEA(2)
53M2 FREECORE 2
546L OUTPACK 4,1,GEOPER
54L= LDN 5 0 [CLUSTER CONSOLE ROUTING PARAMETER
555W INFORMX 5,7,1 [SEND MESSAGE
55KG BRN RRSTT
5656 OVER
56JQ ENDCOM
574B YUK
57J2 GEOERR 1,BREAKIN [BREAKIN LABEL FROM PARSORT
583L #
58H= RMRIGHT [WR&RI REMOTE DEVICES
58ND ... LDEX 0 JSCEB(2) [J. IF CI
58TL ... BZE 0 RMRCI
58WB ...#UNS ISUMBI
58X6 ...(
58XW ... SAWCEJX JSCEB(2),USTATE,UWRONG [IF ON 7900,SKIP UNIT MOPPED OFF
58YL ... [/ONLINED CHECK
58^B ...USTATE
5926 ...)
592W JFREE 3,NOTMOPPEDON
59GG JONL 3,NOTMOPPEDON
59K5 ...#UNS ISUMBI
59MN ...(
59Q? ...UWRONG
59SW ... JWRONG 3,NOTMOPPEDON
59XF ...)
5=26 LAMOP 3,3 [LOAD ADDRESS OF THE AMOP
5=44 ... BRN RSKIPCI [MISS CI CODE
5=62 ...RMRCI ANDX 3 BITS22LS [PROG. PROP. NO.
5=7Y ... ORX 3 GSIGN [PLUS BIT 0
5=9W ... FMOPG 1,3,IPB [FIND RELEVANT AMOP
5=?S ... BNG 1 NOTMOPPEDON
5=*Q ... LDX 3 1 [CONTINUE DOWN COMMONPATH
5=CN ...RSKIPCI
5=FQ SMO FX2
5=^B STO 3 AWORK1
5?F2 LDCH 0 JSCEA(2)
5?YL SBN 0 #77
5#D= BNZ 0 NOTCONSOLE [BR IF DEVICE NOT OP'S CONSOLE
5#XW SMO FX2
5*CG LDXC 0 AWORK2
5*X6 BCS RALRI [BR IF RIGHT
5BBQ BRN RCNWRL [... AND ERROR IF WRONG
5BWB NOTCONSOLE
5CB2 SAWCEJX JSCEB(2),T1,R7900 [BR TO R7900 IF 7900 DEVICE
5CFX ... LDX 0 JSCEA(2)
5CKS ... BNZ 0 NOTMP [J IF NOT MOP LINE
5CPP ... SMO FX2
5CTL ... LDX 0 AWORK2 [RI OR WR?
5C^H ... BPZ 0 RCNWR7 [CANNOT BE WRONGED
5D5D ... BRN NORI [MAY NOT BE RTED
5D9* ...NOTMP HUNT2 3,AMXOR,ALINES [X3 TO HOLD ADDS ALINES
5D*= LDX 0 JSCEB(2)
5DSW SRL 0 7 [LINE NUMBER TIMES 4
5F#G ... ANDN 0 #174
5FS6 SMO 0
5G5W ... LDX 1 A1+BPTR(3) [POINT TO LCB
5GCL ... BZE 1 NOPER [BR IF NOT THERE
5GJG ... SMO 0
5GPB ... LDX 0 A1+FOURTHWD(3)
5H36 ... SLL 0 1
5H#W ... BNG 0 RATS
5HLL ... SBN 1 A1+FPTR
5HYB ... HUNT2B 3,A7020,INFORM,1
5J== STOZ 7
5JPW LDX 0 JSCEA(2) [PCT TERMINAL IDENTIFIER
5K9G SRL 0 6
5KP6 ANDN 0 #7777
5L86 XFR2 SMO 7 [FIND,USING THE PCT TERMINAL
5LNB LDX 5 IDUNIQUE(3)
5M82 SRL 5 12 [IDENTIFIER AN APPROPRIATE ENTRY
5MML TXU 0 5 [IN A7020 INFORM BLOCK
5N7= BCC XFR1
5NLW ADN 7 APCTRLEN
5P6G BRN XFR2
5PL6 XFR1 SMO FX2
5Q5Q STO 7 AWORK3 [STORE REL.POINTER TO A PCT RECORD
5QKB ADX 3 7
5R52 LDX 1 3 [STORE ABS.POINTER TO A PCT RECORD
5RJL LDX 5 JSCEA(2)
5S4= ANDN 5 #77 [INTERFACE NO
5SHW BZE 5 PFERR [ERROR IF NO INTERFACE NUMBER
5T3G LDN 6 6
5TH6 RLOOP
5W2Q LDX 7 APCTDEV(3)
5WGB LDCT 2 #200 [PT TO CHAR1
5X22 SMO 3
5XFL LDCH 0 APCTDEV+1(2)
5X^= BXE 0 5,RFND72
5YDW ADN 3 2
5YYG BCT 6 RLOOP
5^D6 BRN RCNWRR
5^XQ RFND72
62CB SMO 3
62X2 LDCH 7 APCTDEV(2) [LOADS INT BIT POSN
63BL SMO FX2
63W= LDX 6 AWORK2
64*W BPZ 6 RMWRG [BRANCH FOR WRONG
64TG LDCH 0 APCTD(1) [LOAD CH SHOWING WHICH INTS RIGHTED
65*6 ANDX 0 7
65SQ BNZ 0 RMALRT [BR IF ALREADY RIGHTED
66#B LDX 0 APCTDEV+1(3) [LOOK AT DEVICE TYPE
66S2 ANDN 0 #77
67?L SBN 0 3
67R= BZE 0 RMALR [NO FURTHER ACTION FOR 7023
68=W ADN 0 3
68QG ANDN 0 1
69=6 BZE 0 RMRIN [BR IF INPUT DEVICE
69PQ LDX 0 APCTD(1)
6=9B SRL 0 6 [CH WITH ACT MASK TO RT HAND END
6=P2 ANDX 0 7
6?8L BZE 0 RMALR [NO FURTHER ACTION IF ACTIVITY
6?N= # [ALREADY SET UP ON LP OR TP
6#7W LDX 6 APCTSTAT(1)
6#MG BNG 6 RMALR [NO FURTHER ACTION IF TERMINAL INOP
6*76 LDX 6 APCTD(1)
6*LQ SRL 6 12
6B6B ANDX 6 7
6BL2 BZE 6 RMALR [.. OR IF INTERFACE INOP
6C5L BRN RMALRA
6CK= RMRIN
6D4W NGN 0 1
6DJG BRN RMALRA
6F46 RMALRT
6FHQ LDX 0 APCTD(1)
6G3B SRL 0 6
6GH2 ANDX 0 7
6H2L BNZ 0 RMALR [BR IF NO ACT FOR INTERFACE
6HG= CALL 6 RHUNT
6H^W SMO FX2
6JFG STO 1 ACOMMUNE1 [PRESERVE X1
6J^6 CALL 6 RPCT
6KDQ ERS 0 EWAIT(1) [UNSET WAITING TO BE WRONGED BIT
6KYB SMO FX2
6LD2 LDX 1 ACOMMUNE1 [RESTORE X1
6LXL RMALR
6MC= LDN 0 0
6MWW RMALRA
6NBG SRC 7 6
6NW6 ORS 7 APCTD(1) [MARK INTERFACE RIGHTED
6P*Q BZE 0 RMEND [BR IF ACTLF NOT REQUD
6PTB #
6Q*2 BNG 0 RMRINA
6QSL # ACTLF SET UP BELOW
6R#= SRL 7 12
6RRW ERS 7 APCTD(1) [INDICATE ACT SET UP FOR INTERFACE
6S?G LDX 5 IDUNIQUE(1)
6SR6 LDX 7 APCTDEV(3)
6T=Q LDX 6 APCTDEV+1(3)
6TQB GETACT ACTLF,GREMOTE [SET MP A REMOTE ACTLF
6W=2 CALL 6 RHUNT
6WPL SMO FX2
6X9= LDX 0 AWORK3
6XNW DSA 0 7 [X7 HAS FORM OF REQD APCTID WORD
6Y8G SMO FX2
6YN6 LDX 6 ACC6 [RESTORE X6 TO PRE-GETACT
6^7Q SMO FX2
6^MB LDX 3 BPTR [POINT TO ACTLF
7272 STO 5 JSOURCE1(3) [JSOURCE1 FOR JOHN WRATTEN
72LL SMO FX2
736= LDX 3 AWORK1 [AMOP ADDRESS
73KW HUNT2 3,AMXOR,ALINES
745G LDX 0 JSCEB(2) [LINE NO
74K6 SRL 0 9
754Q ANDN 0 #77
75JB SLL 0 2
7642 SMO 0
76HL LDX 3 A1+BPTR(3)
773= SBN 3 A1+FPTR [X3 POINTS TO LCB
77GW HUNT2B 3,A7020,INFORM [BACK TO INFORM BLOCK
782G RHNTF
78G6 LDX 3 BPTR(3) [HUNT BACK FOR ACT
78^Q LDX 0 ATYPE(3)
79FB BXL 0 CACT,RHNTF
79^2 # ACT FOUND.
7=DL LDX 2 FX2
7=Y= LDX 1 BPTR(2) [POINT TO NEW ACT
7?CW ENRING JOBRING(1),JOBRING(3) [RING INTO TEMP RING
7?XG LDX 2 BPTR(2)
7#C6 STO 6 ACC4(2)
7#WQ STO 7 ACC5(2)
7*BB LINKSET 2,RLINK(1) [SET LINK TO PCTSTART
7*W2 FPUT [PUT NEW ACT ON LIST
7B*L BRN RMEND
7BT= RMRINA
7C#W LONGON #60
7CSG RMEND
7D#6 LDX 1 FX1
7DRQ BRN RALRI
7F?B #
7FR2 RMWRG [WRONGS 7020 DEVICE
7G=L LDX 0 APCTDEV+1(3)
7GQ= ANDN 0 #77
7H9W SBN 0 3
7HPG BZE 0 RCNWRR [CAN'T WRONG A 7023
7J96 LDX 0 APCTD(1)
7JNQ SRL 0 6 [CH WITH ACT MASK TO RH END
7K8B ANDX 0 7
7KN2 BZE 0 RWTBR [BR IF THERE IS AN ACT FOR DEVICE
7L7L SRC 7 6
7LM= ORS 7 APCTD(1)
7M6W ERS 7 APCTD(1) [MARK INTERFACE WRONGED
7MLG LDX 1 FX1
7N66 BRN XDWUA
7NKQ #
7P5B RWTBR
7PK2 CALL 6 RHUNT
7Q4L CALL 6 RPCT [IF ALLOCATED MARK WAITING TO BE WRD
7QJ= LDX 1 FX1
7R3W BRN RWTWMESS
7RHG #
7S36 R7900 [RI & WR 7900 DEVICES
7SGQ RHNTA
7T2B LDX 3 FPTR(3) [HUNT FOR ADEVS BLOCK
7TG2 LDX 0 ATYPE(3)
7THP ...#UNS ISUMBI
7TKD ...(
7TM7 ... SMO FX2
7TNW ... LDX 6 AWORK2
7TQK ... BXGE 0 CACT,R79MPDOFF [NO ADEVS : NOT MOPPED ON
7TS# ...)
7TW3 ...#UNS ISUMBI
7TXQ ...#SKI
7T^L BXGE 0 CACT,NOTMOPPEDON [BR IF IPB MOPPED OFF OR INOP
7WF= SRL 0 12
7WYW SBN 0 AMXOR+ADEVS
7XDG BNZ 0 RHNTA
7XY6 # X3 POINTS TO ADEVS
7YCQ LDX 0 JSCEA(2) [IPB IDENTIFIER
7YXB ANDN 0 #7777
7^C2 SBX 0 A1+FOURTHWD(3)
7^WL SLL 0 2
82B= ADX 3 0 [X3 POINTS TO ADEVS ENTRY FOR IDE
82C? ... LDN 0 #41
82D# ... SLL 0 7
82F* ... ANDX 0 A1+FOURTHWD(3) [MASK ON TEST BIT
82GB ... BNZ 0 RTEST [J IF ON TEST
82HC ... LDN 0 #2100 [MASK ATTACHED BITS
82JG ... SLL 0 12
82ML ... ANDX 0 A1+FOURTHWD(3)
82QQ ... BNZ 0 RATS [J IF ATTACHED
82R2 ...#UNS ISUMBI
82R= ...(
82RG ... LDX 0 A1+FOURTHWD(3)
82RQ ... ANDN 0 #17
82S2 ... BZE 0 R79MOP [MOP CONSOLE
82S= ... SBN 0 10
82SG ... BZE 0 R79MOP [MOP DISPLAY
82SQ ...)
82T2 ...#UNS ISUMBI
82T= ...#SKI
82TG ...(
82TW SMO FX2
83*G LDX 6 AWORK2
83K# ...)
83T6 BPZ 6 R79WR [BR IF ENTRY FOR WRONG
84#Q LDX 1 A1+BPTR(3)
84SB BZE 1 R79FR [BR IF NOT ALLOCATED
85#2 SBN 1 A1+FPTR
85RL NGN 0 #1001 [LOADS #77776777
86?= ANDS 0 IWAIT(1) [UNSET WAITING TO BE WRONGED
86QW R79FR
87=G LDCT 0 #2 [BIT 7
87Q6 ANDX 0 A1+FOURTHWD(3)
889Q BZE 0 R7ALR [BR IF ALREADY RIGHTED
88PB ERS 0 A1+FOURTHWD(3) [UNSET WRONGED BIT
8992 LDX 0 A1+FOURTHWD(3)
89G5 ... ANDN 0 #17
89R9 ...#UNS ISUMBI
89TS ...#SKI
89YD ... BZE 0 NORI [MOP-MAY NOT BE RTED
8=8= SBN 0 3
8=MW BZE 0 R79OT [BR IF LP
8?7G SBN 0 1
8?M6 BZE 0 R79IN [ CR
8#6Q SBN 0 1
8#LB ... BZE 0 R79TW
8*62 SBN 0 1
8*KL BZE 0 R79IN [ TR
8B5= SBN 0 1
8BJW BNZ 0 R7ALR [ IGNOR IF NOT TP
8C4G R79OT [OUTPUT DEVICES
8CJ6 LDX 0 A1+BPTR(3)
8D3Q BNZ 0 R79ALR [BR IF RINGED
8DHB # [OTHERWISE SET UP ACTLF
8F32 DOWN IPBINB,4
8FGL BRN R79ALR
8FLH ...R79TW
8FQD ... DOWN IPBINB,20
8FW* ... BRN R79ALR
8G2= R79IN
8G67 ... LDX 0 A1+FOURTHWD(3) [DONT SEND 1-SHOT..
8G=4 ... SLL 0 4 [..INPUT IF ACTIVITY..
8G*^ ... BNG 0 NOCCO [..ALREADY BEING SET UP
8GFW LDN 0 #122
8G^G CALL 7 ROUTSS
8HF6 ...NOCCO LONGON #60
8HYQ R7ALR
8JDB R79ALR
8JY2 LDX 1 FX1
8KCL BRN RALRI
8KCY ...#UNS ISUMBI
8KD= ...(
8KDJ ...R79MOP
8KDW ... LDCT 0 #121
8KF8 ... ANDX 0 A1+FOURTHWD(3)
8KFG ... ORX 0 A1+BPTR(3)
8KFS ... BNZ 0 R79MOPBUSY [ATTACHING,INITIALISING,MOPPINGOFF OR
8KG6 ... [RINGED : REPORT IDENTIFIER BUSY
8KGD ... LDCT 5 2
8KGQ ... ORN 5 #40 [WRONGED BITS(7&18)
8KH4 ... BPZ 6 R79WRMOP [WRONG COMMAND
8KHB ...R79RIMOP
8KHN ... LDX 0 A1+FOURTHWD(3)
8KJ2 ... SRC 0 6
8KJ# ... BPZ 0 R79ALR [ALREADY RIGHTED(B18)
8KJL ... SRC 0 9
8KJY ... BPZ 0 R79MOPBUSY [NOT YET CLOSED(B9) : REPORT BUSY
8KK= ... ORS 5 A1+FOURTHWD(3)
8KKJ ... ERS 5 A1+FOURTHWD(3) [MARK RIGHTED IN CORE
8KKW ... LDX 7 JSCEA(2) [ID NO
8KL8 ... LDN 3 7 [PTR TO ID NO
8KLG ... LDX 1 JSCEP(2) [DEV LIST PTR
8KLS ... LAMOP 1,4 [AMOP ADDR INTO X4
8KM6 ... DOWN IPBINB,20 [TO INITIALISE
8KMD ...R79MPDOFF
8KMQ ... BPZ 6 R79WIDF [WRONG COMMAND
8KN4 ...R79RIDF
8KNB ... CALL 6 RHUNT [RE-FIND JSCE BLOCK
8KNN ... IRIGHT YUK,NOTMOPPEDON,JSCEP(2),JSCEA(2)[MARK RIGHTED IN IDF,
8KP2 ... [IF MOP IDENTIFIER
8KP# ... BRN RALRI
8KPL ...R79WRMOP
8KPY ... LDX 0 A1+FOURTHWD(3)
8KQ= ... SRC 0 6
8KQJ ... BNG 0 RNTR [ALREADY WRONGED(B18)
8KQL ...#UNS ATELE
8KQN ...#SKI
8KQQ ...(
8KQW ... SLC 0 1
8KR8 ... BNG 0 RCNWR7 [PSEUDO VDU
8KR* ...)
8KRG ... ORS 5 A1+FOURTHWD(3) [MARK WRONGED IN CORE
8KRJ ...#UNS ATELE
8KRL ... SLC 0 15
8KRN ...#UNS ATELE
8KRQ ...#SKI
8KRS ... SLC 0 14
8KS6 ... BNG 0 R79WIDF [ALREADY CLOSED(B9)
8KSD ... LDN 0 #227
8KSQ ... CALL 7 ROUTSS [SEND CRASH CLOSE
8KT4 ...R79WIDF
8KTB ... CALL 6 RHUNT [RE-FIND JSCE BLOCK
8KTN ... IWRONG YUK,NOTMOPPEDON,JSCEP(2),JSCEA(2)[MARK WRONGED IN IDF,
8KW2 ... [IF MOP IDENTIFIER
8KW# ... BRN XDWUA
8KWL ...)
8KX= R79WR [WRONGS 7900 IDENTIFIER
8LBW LDX 0 A1+FOURTHWD(3)
8LWG ANDN 0 #77 [DEVICE TYPE
8MB6 SBN 0 3
8MTQ ... BNG 0 RCNWR7 [CANT WRONG IF NOT LP,CR,TR OR TP
8N*B SBN 0 2 [ TYPES 3,4,6,7
8NT2 BZE 0 RCNWR7
8P#L SBN 0 3
8PS= BPZ 0 RCNWR7
8Q?W LDX 1 A1+BPTR(3)
8QRG BZE 1 R7NR [BR IF NOT ALLOCATED
8R?6 LDN 0 #1000
8RQQ ORS 0 IWAIT-A1-FPTR(1) [MARK WAITING TO BE WRONGED
8S=B LDX 1 FX1
8SQ2 BRN RWTWMESS
8T9L #
8TP= R7NR [IDE NOT ALLOCATED
8W8W LDCT 0 #2
8WNG ORS 0 A1+FOURTHWD(3) [MARK WRONGED
8X86 LDX 0 A1+FOURTHWD(3)
8XMQ ANDN 0 #77
8Y7B SBN 0 4
8YM2 BZE 0 RCR [BR IF CR
8^6L SBN 0 2
8^L= BNZ 0 RNTR [BR IF NOT TR
925W RCR
92KG LDN 0 #124 [STOP INPUT & CLEAR SS CODE
9356 CALL 7 ROUTSS
93JQ RNTR
944B LDX 1 FX1
94J2 BRN XDWUA
953L RCNWRL
95H= RCNWRR
962W RCNWR7
96GG LDX 1 FX1
9726 LDX 6 XJCANWR(1)
97FQ XERRORMESS
97^B CALL 7 TERROR
98F2 BRN RRSTT
98JX ...XERRORMESS1
98NS ... CALL 7 TERROR1
98SP ... BRN RRSTT
98YL NOTMOPPEDON
99D= LDX 1 FX1
99XW LDX 6 XJRES(1)
9=32 ... BRN XERRORMESS
9=66 ...XWTBSW
9=9= ... LDX 1 FX1
9=#B ... LDX 6 XJWTSW(1)
9=CG ... BRN XERRORMESS
9=GL ...XMPON
9=KQ ... LDX 1 FX1
9=NW ... LDX 6 XJMPON(1)
9=S2 ... BRN XERRORMESS
9=X6 #
9?BQ NOPER [NOT ON INSTALLATION
9?WB LDX 1 FX1
9#B2 LDX 6 XNOPER(1)
9#TL BRN XERRORMESS
9**= #
9*SW PFERR [INTERFACE NUMBER MISSING
9B#G LDX 1 FX1
9BS6 LDX 6 XPFERR(1)
9C?Q BRN XERRORMESS
9CRB #
9CWT ...NORI LDX 1 FX1
9D2# ... LDX 6 XJMNRI(1)
9D5R ... BRN XERRORMESS
9D9= ...#
9D#P ...RATS LDX 1 FX1
9DD8 ... LDX 6 XERAT(1)
9DHM ... BRN XERRORMESS
9DJ* ...#
9DK3 ...RTEST LDX 1 FX1
9DKP ... LDX 6 XERTGEO(1)
9DLC ... BRN XERRORMESS1
9DM6 ...#
9DMG ...#UNS ISUMBI
9DMW ...(
9DN= ...R79MOPBUSY
9DNL ... LDX 1 FX1
9DP2 ... LDX 6 XJIDEBUSY(1)
9DPB ... BRN XERRORMESS
9DPQ ...#
9DQ6 ...)
9DQL MENDAREA 55,K100RIGHT
9F== #END
^^^^ ...25330101000400000000