{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: RITEFAIL864)}}
====== RITEFAIL864 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BS|BS]], [[george:macro:COOR2|COOR2]], [[george:macro:DATUMBLK|DATUMBLK]], [[george:macro:DELBLKS|DELBLKS]], [[george:macro:DOWN|DOWN]], [[george:macro:FAILURE|FAILURE]], [[george:macro:FINDFAIL|FINDFAIL]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GFCBC|GFCBC]], [[george:macro:HUNT2|HUNT2]], [[george:macro:JMBC|JMBC]], [[george:macro:MAPBCH|MAPBCH]], [[george:macro:OFFQUE|OFFQUE]], [[george:macro:OPTRAN|OPTRAN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TRACE|TRACE]], [[george:macro:TRANSBEG|TRANSBEG]], [[george:macro:TRANSFIN|TRANSFIN]], [[george:macro:TRANSRET|TRANSRET]], [[george:macro:UNSETFB|UNSETFB]], [[george:macro:UP|UP]]
22FL ... SEG RITEFAIL,863,FRANK BLUNDELL,BSTS
22^= ...#
23DW ... SEGENTRY K1RITEFAIL,QK1RI
23YG ... SEGENTRY K2RITEFAIL,QK2RI
24D6 ... SEGENTRY K3RITEFAIL,QK3RI
24XQ ... SEGENTRY K4RITEFAIL,QK4RI
25CB ... FSHENTRY K5RITEFAIL,QK5RI,,QK5RI
25X2 ... FSHENTRY K7RITEFAIL,QK7RI,QK7RI,QK7RI
26BL ... FSHENTRY K8RITEFAIL,QK8RI,QK8RI,QK8RI
26W= ... FSHENTRY K9RITEFAIL,QK9RI,,QK9RI
27*W ...#
27TG ...STYPE
28*6 ...#HAL +BSTB+BQBLK,0
28SQ ...#
29#B ...TERR1 GEOERR 0,WRNGBLK
29S2 ...# ***************************************
2=?L ...#
2=R= ...# ENTRY FOR LISTFAIL MACRO
2?=W ...#
2?QG ...QK1RI [*****
2#=6 ... CALL 0 XBSA [CONVERT LFN TO BSA ADDRESS
2#PQ ... CALL 0 XLIST [CHANGE ENTRY FROM ONE BLOCK TO NEXT
2*9B ... UP
2*P2 ...# *****************************************
2B8L ...#
2BN= ...# ENTRY FOR TIDYFAIL MACRO
2C7W ...# CHANGES BLOCK NUMBERS,REQUEUES APPROPRIAT Q BLOCKS, REMOVES ENTRY IN
2CMG ...# CURRENT FAIL LIST AND UNSETS FAIL BITS IF NECESSARY
2D76 ...#
2DLQ ...# ACOMMUNE1 CONTAINS LFN
2F6B ...# ACOMMUNE2 CONTAINS BLOCK NUMBER OF FAILED BLOCK (TO BE REPLACED)
2FL2 ...# ACOMMUNE3 CONTAINS BLOCK NUMBER OF NEW BLOCK
2G5L ...#
2GK= ...#
2H4W ...QK2RI [*****
2HJG ...#SKI K6RITEFAIL>99-99
2J46 ...(
2JHQ ... TRACE ACOMMUNE1(2),TIDYFAIL
2K3B ...#SKI K6RITEFAIL>199-199
2KH2 ...(
2L2L ... TRACE ACOMMUNE2(2)
2LG= ... TRACE ACOMMUNE3(2)
2L^W ...)
2MFG ...)
2M^6 ... LDX 5 ACOMMUNE1(2)
2NDQ ... LDX 6 ACOMMUNE2(2)
2NYB ... LDX 7 ACOMMUNE3(2)
2PD2 ... LDX 1 ACOMMUNE1(2)
2PMS ... STO 1 ACOMMUNE6(2)
2PXL ... SLL 1 1
2QC= ... ADX 1 ALFTP
2QWW ... LDX 4 A1(1)
2RBG ... BNG 4 XNFILE [JUMP IF THIS L.F DOES NOT EXIST
2RW6 ... ANDN 4 #7777
2S*Q ... ADX 4 AFDTP [POINTER TO FILE DESCRIPTION
2STB ... DATUMBLK ACOMMUNE3(2),4
2T*2 ... BZE 1 XNFILE [JUMP IF BLOCK NUMBEROUT OF RANGE
2TSL ... CALL 0 XFAIL
2T^S ... LDX 0 ACOMMUNE6(2)
2W72 ... STO 0 ACOMMUNE1(2) [LFN
2W#= ... CALL 0 XBSA [CONVERT LFN TO ADDRESS BSA
2WRW ... LDX 4 ACOMMUNE3(2)
2X?G ... STO 4 ACOMMUNE2(2)
2XR6 ... CALL 0 XWAIT [REQUEUE APPROPRIATE Q BLOCKS
2Y=Q ... LDX 0 ACOMMUNE4(2)
2YQB ... BNZ 0 RNJ1 [J IF BLANKET
2^=2 ... CALL 0 XLIST
2^PL ...RNJ2 LDX 1 AWORK1(2)
329= ... CALL 7 UNSTFB [ CLEAR OUT FAIL BIT
32NW ... UP
338G ...RNJ1 LDN 0 RNJ2
33N6 ... STO 0 AWORK4(2) [LINK
347Q ... BRN YLIST [REDUCE COUNT OF CURRENT FAILS
34MB ...#
3572 ...XNFILE
35LL ... GEOERR 0,WRNGLFN
366= ...# ***************************************:
36KW ...#
375G ...# ENTRY FOR BADBLOCK MACRO
37K6 ...# UNSETS FAIL BITS AND REQUEUES ALL ONLINE Q BLOCKS FOR A GIVEN BSUN
384Q ...#
38JB ...# ACOMMUNE1 CONTAINS BSUN
3942 ...#
39HL ...#
3=3= ...#
3=GW ...#
3?2G ...QK3RI [*****
3?G6 ...#SKI K6RITEFAIL>99-99
3?^Q ... TRACE ACOMMUNE1(2),BADBLOCK
3#FB ... LDX 1 ACOMMUNE1(2)
3#^2 ... CALL 0 XBSB [CONVERT BSUN TO ADDRESS OF BSA
3*DL ... STOZ ACOMMUNE2(2)
3*Y= ... CALL 0 XWAIT [REQUE ONLINE Q BLOCKS
3BCW ... SMO AWORK1(2)
3BXG ... LDX 0 BSFAIL
3CC6 ... ANDN 0 BOFB [IF ONLINE FAIL BIT NOT SET
3CWQ ... BZE 0 TUP [THEN DONT UNSET IT!
3DBB ... UNSETFB 2,ACOMMUNE1(2)
3DW2 ...TUP UP
3F*L ...# ********************************************
3FT= ...#
3G#W ...# SR TO REQUE BLOCKS FROM BSWQ TO BSA Q.
3GSG ...# AWORK1 CONTAINS ADDRESS OF BSA
3H#6 ...# ACOMMUNE1 CONTAINS LFN OR BSUN
3HRQ ...# ACOMMUNE2 CONTAINS ZERO IF BSUN IN 1 OR BLOCK NUMBER
3J?B ...# LINK X0 STORED IN ACOMMUNE6
3JR2 ...#
3K=L ...#
3KQ= ...XWAIT
3L9W ... STO 0 ACOMMUNE6(2)
3LPG ... LDX 1 AWORK1(2)
3M96 ... LDN 7 0
3MNQ ... LDX 0 ACOMMUNE2(2)
3N8B ... BNZ 0 SCA [JUMP IF OFFLINE
3NN2 ... LDN 7 2
3P7L ...SCA LDN 6 BSQWCHAN(1) [BASE OF WAIT Q
3PM= ... LDX 3 6
3Q6W ...SH LDX 3 FPTR(3) [ADDRESS OF Q BLOCK
3QLG ...SHA LDX 2 FX2
3R66 ... TXU 3 6
3RKQ ... BCC SD [JUMP IF END OF Q
3S5B ... SBN 3 CHAINADD
3SK2 ... LDN 4 BA1(3) [RESCUE PARAMETERS BA AREA IF ACTIVIT
3T4L ... LDX 1 EXEC3(3) [DATUMISED BLOCK NUMBER
3TJ= ... LDX 0 ATYPE(3)
3W3W ... SMO FX1
3WHG ... TXU 0 STYPE
3X36 ... BCS SR1
3XGQ ... LDX 1 ADBLKNO(3)
3Y2B ... LDN 4 ATRAN(3)
3YG2 ...SR1 LDN 5 AWORK2(2)
3Y^L ... MOVE 4 3
3^F= ... LDX 0 AWORK2(2)
3^YW ... ANDN 0 2
42DG ... ERX 0 7
42Y6 ... BNZ 0 SG [JUMP IF WRONG TYPE OF TRANSFER
43CQ ... BNZ 7 SY [JUMP IF ONLINE
43XB ... LDX 0 AWORK3(2)
44C2 ... ANDN 0 #377
44WL ... TXU 0 ACOMMUNE1(2)
45B= ... BCS SG [JUMP IF WRONG LFN
45TW ... LDX 0 AWORK4(2)
46*G ... ANDX 0 BSTSMASK
46T6 ... TXU 0 ACOMMUNE2(2)
47#Q ... BCS SG
47SB ...SY LDX 4 CHAINADD(3)
48#2 ...#SKI K6RITEFAIL>199-199
48RL ...(
49?= ... TRACE 3,REQUE
49QW ... TRACE 6,
4==G ...)
4=Q6 ... ADN 3 CHAINADD
4?9Q ... OFFQUE 3
4?PB ... SBN 3 CHAINADD
4#92 ... OPTRAN 3,1,AWORK1(2)
4#NL ... LDX 3 4
4*8= ... BRN SHA
4*MW ...SG ADN 3 CHAINADD [ADJUST POINTER
4B7G ... BRN SH
4BM6 ...SD LDX 1 FX1
4C6Q ... LDX 2 FX2
4CLB ... LDX 0 ACOMMUNE6(2)
4D62 ... EXIT 0 0
4DKL ...# **********************************************************
4F5= ...#
4FJW ...# SR TO CONVERT LFN IN ACOMMUNE1 TO ADDRESS OF APPROPRIATE BSA
4G4G ...# ADDRESS OF BSA LEFT IN AWORK1 X1,X2 RESET TO FX1,FX2
4GJ6 ...# LINK X0
4H3Q ...#
4HHB ...#
4J32 ...XBSA
4JGL ... LDX 1 ACOMMUNE1(2)
4K2= ... SLL 1 1
4KFW ... ADX 1 ALFTP
4K^G ... LDX 1 A1(1)
4LF6 ... SRL 1 12
4LYQ ...XBSB MPY 1 ASBSAB
4MDB ... NGX 2 2
4MY2 ... ADX 2 BBAC
4NCL ... ADX 2 ASBSAB
4NX= ... SMO FX2
4PBW ... STO 2 AWORK1
4PWG ... LDX 2 FX2
4QB6 ... LDX 1 FX1
4QTQ ... EXIT 0 0
4R*B ...# *******************************************
4RT2 ...#
4S#L ...# SR TO REMOVE ANENTRY FROM THE CFL AND PLACE IT IN THE FFL
4SS= ...# X0 LINK STORED IN AWORK4
4T?W ...# LFN IN ACOMMUNE1,BLOCK NUMBER IN ACOMMUNE2
4TRG ...# USES ALL ACCS X1=FX1 X2=FX2
4W?6 ...#
4WQQ ...XLIST
4X=B ... SBX 0 FX1
4XQ2 ... STO 0 AWORK4(2)
4Y9L ... LDX 6 ACOMMUNE1(2)
4YP= ... LDX 7 ACOMMUNE2(2)
4^8W ...XDA HUNT2 2,BSTB,BFRAIL,ATFAPTR
4^NG ... LDX 0 A1(2) [CHECK IF LIST BEING ALTERED
5286 ... BPZ 0 XDB [JUMP IF OK
52MQ ... COOR2
537B ... BRN XDA
53M2 ...XDB LDN 1 A1-1(2)
546L ... NGN 0 1
54L= ...XD ADN 1 2 [CHECK IF ROOM IN LIST FOR NEW ENTRY
555W ... TXU 0 0(1)
55KG ... BCS XD
5656 ... SBN 1 A1-3(2)
56JQ ... TXL 1 ALOGLEN(2)
574B ... BCS XE
57J2 ... LDX 4 ALOGLEN(2)
583L ... ADN 4 AFRAILEX
58H= ... LDCT 0 #400 [LOCKOUT MARKER
592W ... ORS 0 A1(2)
59GG ... LDX 3 2
5=26 ... ALTLEN 3,4
5=FQ ... HUNT2 3,BSTB,BFRAIL,ATFAPTR
5=^B ... LDCT 0 #400
5?F2 ... ERS 0 A1(3)
5?YL ... LDX 4 3
5#D= ...XEA FINDFAIL 3,7,6,CFL,XERR,AWORK1(2)
5#XW ... LDX 2 4
5*CG ... NGN 0 1
5*X6 ...XF ADN 2 2
5BBQ ... TXU 0 A1-1(2) [SEARCH FOR END OF F.F LIST
5BWB ... BCS XF
5CB2 ... LDX 0 0(3) [SET UP RECORD
5CTL ... STO 0 A1-1(2) [BLOCK NUMBER
5D*= ... LDX 0 6
5DSW ... SRC 0 6 [
5F#G ... STO 0 A1(2) [ L.F.N IN B0-B23
5FS6 ... NGN 0 1
5G?Q ... STO 0 A1+1(2) [END OF BLOCK MARKER
5GRB ... SBN 3 1
5H?2 ...PA ADN 3 1 [REMOVE RECORD FROM CFL BY MOVING
5HQL ... LDX 4 2(3) [REMAINDER UP
5J== ... STO 4 0(3)
5JPW ... TXU 4 0 [TEST FOR END OF LIST
5K9G ... BCS PA
5KP6 ... FSHCODE B,XIAMA
5L8Q ...(
5LNB ... LDN 4 3 [LENGTH
5M82 ... SETUPCORE 4,3,FSH,FSHBDEL [USED BY DELBLKS MACRO
5MML ... STO 4 A1(3) [RECORD HEADER
5N7= ... STO 6 A1+1(3) [RESIDENCE NO
5NLW ... STO 7 A1+2(3) [BLOCK NO
5P6G ... TRANSBEG FSHTFID,RITEFAIL,5,FSH,FSHBDEL,ACOMMUNE1,YLIST,AUT,SUP
5PL6 ...XIAMA
5Q5Q ...)
5QKB ... LDX 2 FX2
5R52 ...YLIST HUNT2 3,BSTB,BFAIL,AWORK1(2)
5RJL ... LDN 0 1
5S4= ... SBS 0 A1(3) [SUBTRACT ONE FROM CFL COUNT
5SHW ... LDX 1 FX1
5T3G ... LDX 2 FX2
5TH6 ... LDX 0 AWORK4(2)
5W2Q ... ADX 0 FX1
5WGB ... EXIT 0 0
5X22 ...XE LDX 4 2
5XFL ... LDX 2 FX2
5X^= ... BRN XEA
5YDW ...XERR GEOERR 0,CFRECLST
5YYG ...XFAIL LDX 2 FX2
5^D6 ... SBX 0 FX1
5^XQ ... STO 0 AWORK4(2)
62CB ... STO 1 ACOMMUNE1(2) [PRESERVE X1
62X2 ... DOWN RITEFAIL,4
63BL ... LDX 0 AWORK4(2)
63W= ... ADX 0 FX1
64*W ... EXIT 0 0
64TG ...
65*6 ...# ***********************************************
65SQ ...#
66#B ...# SUBROUTINE TO UNSET OFFLINE FAIL BIT
66S2 ...#
67?L ...UNSTFB
67R= ... UNSETFB 1,1
68=W ... EXIT 7 0
68QG ...#
69=6 ...# ********************************************
69PQ ...#
6=9B ...# ENTRY POINT FOR FAILURE MACRO
6=P2 ...# X5 = RESIDENCE NO
6?8L ...# X6 = BLOCK NO TO BE REPLACED
6?N= ...# X7 = BLOCK NO TO BE INSERTED
6#7W ...# X1 = DATUMISED B.S. ADDRESS OF NEW BLOCK
6#MG ...#
6*76 ...QK4RI
6*LQ ... LDX 1 ACOMMUNE1(2)
6B6B ... FAILURE
6BL2 ... UP
6C5L ...#
6CK= ... FSHCODE A,USLSS
6D4W ...(
6DJG ...# ****************************************************
6F46 ...#
6FHQ ...# ENTRY POINT IN M/C A TO UPDATE FSH/FHSBDEL BLOCK
6G3B ...#
6GH2 ...QK5RI
6H2L ... DELBLKS ALLOWFAIL
6HG= ... TRANSRET
6H^W ...#
6JFG ...USLSS
6J^6 ...)
6KDQ ... FSHCODE AORB
6KYB ...(
6LD2 ...#
6LXL ...# ***********************************************
6MC= ...#
6MWW ...# ENTRY POINT TO EITHER UPDATE PFL ENTRY OR DELETE
6NBG ...# PFL ENTRY CORRESPONDING TO THAT IN OTHER M/C.
6NW6 ...#
6P*Q ...XCERR GEOERR 0,NOPFL
6PTB ...QK7RI
6Q*2 ... CALL 0 XBSA [GET ADDRESS OF BSA IN THIS M/C
6QSL ... LDX 7 ACOMMUNE2(2) [BLOCK NO
6R#= ... ANDX 7 BSTSMASK [ROUNDED DOWN
6RRW ... FINDFAIL 3,7,ACOMMUNE1(2),PFL,XCERR,AWORK1(2) [
6S?G ... [GET POINTER TO PFL ENTRY
6SR6 ... LDX 0 ACOMMUNE3(2) [NEW ENTRY WITH UPDATED BLOCKLET
6T=Q ... BZE 0 REMVL [J IF ENTRY TO BE REMOVED
6TQB ... STO 0 1(3) [BITS TO PFL ENTRY
6W=2 ...RETN
6WPL ... TRANSFIN ,AUT [BACK TO HOME
6X9= ... TRANSRET [LETS GET THIS SUPERVISORY GOING
6XNW ...REMVL
6Y8G ... NGN 1 1 [BLOCK TERMINATOR
6YN6 ...RUP
6^7Q ... LDX 0 2(3) [SHIFT LOWER ENTRIES UP 2
6^MB ... STO 0 0(3)
7272 ... TXU 0 1
72LL ... BCC RETN [J IF SHIFT UP COMPLETE
736= ... ADN 3 1
73KW ... BRN RUP
745G ...#
74K6 ...# ************************************************
754Q ...# ENTRY POINT TO CREATE NEW PFL ENTRY IN BFAIL BLOCK
75JB ...#
7642 ...# X5 = RESIDENCE NO
76HL ...# X6,X7 = PFL ENTRY TO BE INSERTED
773= ...#
77GW ...QK8RI
782G ... STO 5 ACOMMUNE1(2) [RESIDENCE NO
78G6 ... CALL 0 XBSA [GET ADDRESS OF THIS M/CS BSA
78^Q ...SHFS5
79FB ... HUNT2 3,BSTB,BFAIL,AWORK1(2) [AND ASSOCIATED BFAIL BLOCK
79^2 ... LDX 0 A1(3)
7=DL ... BPZ 0 SHFS6 [J IF BLOCK NOT BEING TAMPERED WITH
7=Y= ... COOR2 [ELSE WAIT
7?CW ... BRN SHFS5
7?XG ...SHFS6
7#C6 ... LDN 2 A1-1(3)
7#WQ ... NGN 0 1
7*BB ...SHFS7
7*W2 ... ADN 2 2
7B*L ... TXU 0 0(2)
7BT= ... BCS SHFS7 [J IF TERMINATOR NOT FOUND YET
7C#W ... SBN 2 A1-3(3)
7CSG ... TXL 2 ALOGLEN(3) [HAS BLOCK GOT TO BE LENGTHENED?
7D#6 ... BCS SHFS8 [J IF NOT
7DRQ ... LDX 4 ALOGLEN(3)
7F?B ... ADN 4 AFAILEX [NEW LENGTH
7FR2 ... LDX 5 GSIGN
7G=L ... ORS 5 A1(3)
7GQ= ... ALTLEN 3,4
7H9W ... HUNT2 3,BSTB,BFAIL,AWORK1(2) [
7HPG ... ERS 5 A1(3) [CLEAR 'BEING TAMPERED WITH' BIT
7J96 ... NGN 0 1
7JNQ ...SHFS8
7K8B ... ADN 3 2
7KN2 ... TXU 0 A1-1(3) [END OF BLOCK YET?
7L7L ... BCS SHFS8 [J IF NOT
7LM= ... STO 0 A1+1(3) [TERMINATOR FOUND - SO STORE AGAIN
7M6W ... STO 6 A1-1(3) [NEW ENTRY INSERTED HERE
7MLG ... STO 7 A1(3)
7N66 ... BRN RETN
7NKQ ...)
7P5B ...# ******************************************
7PK2 ...#
7Q4L ...# ENTRY FROM READFAIL SEGMENT (OVERFLOW)
7QJ= ...# FINDS FCB IN MACHINE A WITH FCB NUMBER SPECIFIED BY X6
7R3W ...# SETS CLOSE ABANDON MARKER AND MARKS FOR FILE TO BE THROWN
7RHG ...# OFFLINE IF OPENED CAREFULLY
7S36 ...#
7SGQ ...QK9RI
7T2B ... FSHCODE A,XFSHAFCB
7TG2 ...(
7T^L ... GFCBC 6,2,XFCBERR [FIND PTR TO FCB REQD
7WF= ... BS 2,BFCLOSEAB [SET CLOSE ABANDON MARKER
7WYW ... LDX 3 2 [ -> FCB
7XDG ... JMBC NOTCAREF,2,BFCARE [ J-NOT CAREFULLY OPEN FILE
7XY6 ... MAPBCH 4,3 [ CHECKS BIT IN FMAPP BLK
7YCQ ... BNZ 0 NOTOFFLINE [ J IF SWAPPED BLOCK
7YXB ...[
7^C2 ...[ IF THE FILE IS OPEN CAREFULLY AND THE CORRUPT OR FAILING
7^WL ...[ BLOCK IN THE FILE IS A SWAPPED BLOCK THEN WE ONLY
82B= ...[ CLOSEABANDON THE FILE AND DO NOT THROW IT OFFLINE.
82TW ...[
83*G ...NOTCAREF
83T6 ... BS 3,BFCLOSEABOF [ THROW FILE OFFLINE
84#Q ...NOTOFFLINE
84SB ... TRANSRET [RETURN SUPERVISORY ACTIVITY
85#2 ...XFCBERR
85RL ... GEOERR 1,FCB NOTA [FILE NOT OPEN ON MACHINE A
86?= ...XFSHAFCB
86QW ...)
87=G ...#END
^^^^ ...330406100002