{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SCAN865)}}
====== SCAN865 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEND|ALTLEND]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR1Y|COOR1Y]], [[george:macro:DCA|DCA]], [[george:macro:DLCA|DLCA]], [[george:macro:FINDLCA|FINDLCA]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHACTPR|FSHACTPR]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHKILL|FSHKILL]], [[george:macro:FWAIT|FWAIT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:GLPERI|GLPERI]], [[george:macro:HUNT2|HUNT2]], [[george:macro:IDFSCAN|IDFSCAN]], [[george:macro:JLBUSY|JLBUSY]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LNLI|LNLI]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAMEX|NAMEX]], [[george:macro:PAIR|PAIR]], [[george:macro:PHOTO|PHOTO]], [[george:macro:RINGTWO|RINGTWO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETALLOC|SETALLOC]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:TESTMOVE|TESTMOVE]]
22FL ...#SEG SCAN8 [PHILIP TURNER
22^= #LIS K0SCAN>K0MULTIPLX>K0ALLGEO>K0GREATGEO
23DW 8HSCAN8
23YG # ENTRY POINTS
24D6 SEGENTRY K1SCAN,Z1SCAN
24XQ SEGENTRY K2SCAN,Z2SCAN
25CB SEGENTRY K3SCAN,Z3SCAN
25X2 SEGENTRY K4SCAN,Z4SCAN
26BL MENDAREA 25,K100SCAN
26W= [
27*W [THIS SEGMENT GETS INFORMATION ABOUT THE DEVICE FROM THE IDF, AND OUT-
27TG [PUTS A N/L SEQUENCE TO EACH LINE WITH A MOP TERMINAL OF TYPE KNOWN
28*6 [TO GEORGE.
28SQ [
29#B [
29S2 [
2=?L #DEF SWITCHBOARD=1
2=R= [
2?=W [
2?GN ... SEGENTRY K25SCAN [USED BY PRESETRP MACRO
2?QG XAMXMSKPR +AMXMSKPR
2#=6 XCONTEXT #20412
2#PQ MXORALINES
2*9B #HAL AMXOR+ALINES,0
2*P2 PCTYPE
2B8L #HAL AMOP+APCT,0
2BN= SENTYPE
2C7W #HAL AMOP+ASENT,0
2CMG [
2D76 PAIR1 PAIR SCAN,4
2DLQ PAIR2 PAIR PCTBEGIN,1
2F6B PAIR3 PAIR SENTINEL,1
2FL2 [
2G5L #DEF ZALEN=BUFFER-A1 [LINE CONTROL BLOCK LENGTH
2GK= [
2H4W [THE DATA BELOW IS PUT INTO THE LINE CONTROL BLOCK FOR ALL 7071 TELETYPE
2HJG [TERMINALS. IT IS DEVICE DEPENDENT, AND MAY CHANGE FOR OTHER CONSOLES.
2J46 [
2JHQ ... SEGENTRY K50SCAN [USED BY AUTMOP MACRO
2K3B TNOCHS +11 [NORMAL TERMINATOR CHARACTER NO. +1
2KH2 ...TNLBUFF #76357632 [NEWLINE AND FES CHARACTERS
2L2L #76207603 [NULL AND DC3 CHARACTERS
2LG= TEOM #76130000 [END OF MESSAGE CH.
2LQ4 ... SEGENTRY K31SCAN
2L^W TCHARS +72 [CARRIAGE WIDTH OF 7071 CONS. (CHARS)
2MFG #FID 0 5 6 [COUNT OF CHARS. IN NEW LINE MESSAGE.
2M^6 TREADY +8 [NUMBER OF CHARACTERS FOR 'READY'
2NDQ #76672076 [BACKWARDS POINTING ARROW AND SPACE
2NYB #27760177 [BELL AND DC1 AND NULL
2PD2 +0 [HWGROT
2PXL XDELE +0 [RESET TO 8 BY AUTOMOP
2QC= #76737673
2QWW #76737673
2RBG #DEF TERMLEN=0?-TNOCHS [TERMINAL RECORD LENGTH.
2RW6 [
2S*Q [
2STB TABLE BRN U4C [7071 CONSOLE.
2T*2 BRN U4P [7020 PCT.
2TSL BRN U4S [SENTINEL.
2W#= [
2WRW [
2X?G Z1SCAN
2XB5 ... FSHCODE B,SNOPRA1
2XDN ...(
2XH? ... FSHACTPR
2XKW ...SNOPRA1
2XNF ...)
2XR6 LDX 3 AMOPADDR(2)
2XW= ...#UNS IDFMARK8
2X^B ... IDFSCAN (GEOERR),U4OFF,CPPTR(3)
2Y4G ...#UNS IDFMARK8
2Y7L ...#SKI
2Y=Q IDFSCAN U4OFF,CPPTR(3)
2YQB SETALLOC CPPTR(3) [SET AMOP WAITING
2^=2 LDX 2 3
2^PL FWAIT #54 [FOR THE END OF E.M.S.
329= FON #102,1 [WAKE UP NEXT AMSCAN, OR EMS ACTIVITY
32NW COOR1Y [WAIT FOR AMOP TO DO MODE #4000 PERI.
32RF ... FSHCODE B,SNOTA1
32W4 ...(
32YM ... BRN PRDONE
333= ...SNOTA1
335T ...)
338G Z2SCAN [ENTRY FROM MOP-ON COMMAND
33?5 ... FSHCODE B,PRDONE
33*N ...(
33D? ... FSHACTPR
33GW ...PRDONE
33KF ...)
33N6 SETNCORE ZALEN,3,AMXOR,ALCB,1,1,2 [GET LINE CONTROL BLOCK.
347Q NGS 3 GTIM(3)
34MB LDN 7 TNOCHS(1) [INSERT N/L SEQUENCE IN SCAN LCB
3572 LDN 0 GNOCHS(3)
35LL MOVE 7 4
366= LDX 3 AMOPADDR(2) [FIND THE ALINES BLOCK, IF ANY
36KW U00 LDX 3 FPTR(3)
375G LDX 0 ATYPE(3)
37K6 BXGE 0 CACT,U4FIN [SUICIDE IF NO ALINES.
384Q BXU 0 MXORALINES(1),U00
38JB MHUNTW 1,IDF,B7071 [FIND THE UNIT DESCRIPTION BLOCK.
3942 STO 3 AWORK2(2) [SAVE POINTERS.
39HL LDX 3 AMOPADDR(2)
3=3= LNLI CPPTR(3),7
3=GW STO 1 AWORK1(2)
3?2G U0 LDX 3 7 [SET MODIFIER FOR NEXT ALINES ENTRY.
3?G6 LDCT 0 #40
3?^Q SLL 3 2
3#FB SMO 7 [GET IDF DESCRIPTION FOR THIS LINE.
3#^2 LDX 4 A1(1)
3*DL ADX 3 AWORK2(2) [POINTER TO CURRENT ALINES ENTRY.
3*Y= LDCT 6 #200
3BCW ANDX 0 A1+FOURTHWD(3)
3BXG ANDX 6 4 [NON-ZERO IF ATTACHED LINE.
3CC6 BZE 0 U1B [J. IF "TO BE SCANNED" BIT NOT SET,
3CWQ ORX 0 6 [OTHERWISE CLEAR IT, AND SET
3DBB ERS 0 A1+FOURTHWD(3) ["ATTACHED" BIT IF NEEDED.
3DW2 BNG 4 U3 [J. IF TERMINAL DEVICE TYPE UNKNOWN.
3F*L LDCT 5 #420 [OTHERWISE MARK "SETTING UP"
3FT= ANDN 4 #77 [AND INSERT THE TYPE.
3G#W STO 6 AWORK3(2) [SET NON-ZERO IF LINE IS ATTACHED.
3GSG ORS 5 A1+FOURTHWD(3)
3H#6 DEX 4 A1+FOURTHWD(3)
3HRQ LDN 0 HIGHTYPE [J. IF INTERNAL TYPE #
3J?B BZE 4 U4B [GIVEN BY IDF IS TOO LOW.
3JR2 BXL 0 4,U4B [OR TOO HIGH.
3K=L SMO 4 [J. ON TERMINAL TYPE.
3KQ= BRN TABLE-1
3L9W U1B BZE 6 U1C [J. IF NOT ATTACHED.
3LPG U1BA MFREEW IDF,CONNAME
3M96 LDX 1 AWORK1(2)
3MNQ BRN U3
3N8B U1C SBN 4 2 [J. IF NOT PCT TYPE.
3NN2 BNZ 4 U3
3P7L U1D MFREEW IDF,B7020
3PM= LDX 1 AWORK1(2)
3Q6W BRN U3
3QLG U2A BZE 7 U4FIN [J. IF FINISHED ALL LINES.
3R66 HUNT2 3,AMXOR,ALINES,AMOPADDR(2)
3RKQ U2B MHUNTW 1,IDF,B7071 [AND RESET THE POINTERS.
3S5B STO 3 AWORK2(2)
3SK2 STO 1 AWORK1(2)
3T4L U3 BZE 7 U4FIN
3TJ= BCT 7 U0
3TN7 ...U4FIN
3TS4 ... FSHCODE B,NOKILLA
3TX^ ...(
3W3W ... FSHKILL
3W7R ...NOKILLA
3W?N ...)
3WCK ... SUICIDE [END IF NO MORE LINES.
3WHG U4OFF FON #102,1 [WAKE UP NEXT AMSCAN, OR EMS ACTIVITY
3X36 U4NXT LDX 3 FPTR(3) [FREE ANY ALINES BLOCK FOR THIS AMOP.
3XGQ LDX 0 ATYPE(3)
3Y2B BXGE 0 CACT,U4FIN
3YG2 BXU 0 MXORALINES(1),U4NXT
3Y^L FREECORE 3
3^F= BRN U4FIN
3^YW U4A GEOERR 1,IDFERROR
42DG U4B GEOERR 1,TERMTYPE
42Y6 [
43CQ U4S GETACT BMOP,ASENT
43XB LDX 3 AMOPADDR(2)
44C2 LDX 2 BPTR(2)
44WL STO 7 ACC7(2) [PRESERVE LINE NO.
45B= STO 3 AWORK4(2) [PRESERVE AMOP ADDRESS
45TW LINKSET 2,PAIR3(1) [LINK TO K1SENTINEL
46*G FPUT [PUT CPA ON LIST.
46T6 BRN U2A [J. FOR NEXT LINE.
47#Q [
47SB U4P LDCT 0 #200 [J. IF LINE IS ATTACHED.
48#2 ANDX 0 A1+FOURTHWD(3)
48RL BNZ 0 U4PAT
49?= GETACT BMOP,APCT [OTHERWISE SET UP AN AMOP/APCT ACTY.
49QW LDX 3 AMOPADDR(2)
4==G LDX 0 CPPTR(3)
4=Q6 LDX 6 3
4?9Q LDX 3 BPTR(2)
4?PB STO 0 CPPTR(3)
4#92 STO 6 ACC6(3) [AMOP ADDRESS
4#NL STO 7 ACC7(3) [PRESERVE LINE #
4*8= LINKSET 3,PAIR2(1) [LINK TO K1PCTBEGIN
4*MW MHUNTW 2,IDF,B7020 [FIND SUPPLEMENTARY LINE DESCRIPTION
4B7G CHAIN 2,3 [BLOCK AND CHAIN AFTER NEW ACTIVITY.
4BM6 LDX 2 3 [PUT ACTIVITY ON LIST.
4C6Q FPUT
4CLB BRN U2A [J. FOR NEXT LINE.
4D62 U4PAT LDCT 5 #420 [UNSET 'SETING UP' MARKERS
4DKL ERS 5 A1+FOURTHWD(3)
4F5= BRN U1BA
4FJW [
4G4G U4C LDX 1 3 [ADDRESS OF ALINES ENTRY.
4GJ6 MHUNTW 3,AMXOR,ALCB [FIND THE LINE CONTROL BLOCK.
4H3Q STO 7 GUNITNO(3) [PRESERVE LINE NO.
4HHB SLL 7 2
4J32 U5 STO 1 AWORK4(2) [SAVE ADDRESS OF LINE ENTRY.
4JGL LDCT 0 #402 [UNSET B0 & INDICATE PERI FROM AMSCAN
4K2= ERS 0 A1+FOURTHWD(1)
4KFW RINGTWO A1(1),A1(3) [ENRING LCB WITH ALINES ENTRY.
4K^G LOCKC 3,REFIND [LOCK THE LCB
4LF6 CALL 1 REFIND
4LYQ LDX 3 2
4MDB LDX 1 FX1
4MY2 LDX 2 FX2
4NCL LDX 2 AMOPADDR(2)
4NX= LDX 6 GUNITNO(3)
4PBW FINDLCA ,6
4PWG JLBUSY 1,REJ
4QB6 LDN 5 GREP1(3)
4QTQ DLCA 1,STO,5,CREP
4R*B SLL 6 15
4RT2 DCA ,STO,6,MODE
4S#L LDN 5 #11
4SS= DLCA 1,DLA,5,MODE
4T?W STO 5 GLASTM(3)
4TRG LDX 5 GNOCHS(3)
4W?6 DLCA 1,DLA,5,COUNT
4WQQ LDN 5 GNLBUFF(3)
4X=B PHOTO 4
4XQ2 DLCA 1,STO,5,CTSA
4Y9L LDX 0 JTIME
4YP= STO 0 GTIM(3)
4^8W GLPERI
4^NG COOR1 [WAIT FOR TRANSFER TO FINISH
5286 TESTMOVE 4,U5A [J. IF NO CORE MOVEMENT.
52MQ MHUNTW 3,AMXOR,ALCB [OTHERWISE RELOCATE THE LCB.
537B U5A LDCH 0 GREP1(3)
53M2 SRC 0 1
546L BPZ 0 S1 [J. IF THE LINE IS INOPERABLE.
54L= SRC 0 1
555W BNG 0 S1 [J IF NOT IMPLEMENTED
55KG ANDN 0 #1
5656 BNZ 0 S0 [BRANCH IF ERROR IN TRANSMISSION
56JQ #SKI SWITCHBOARD
574B (
57J2 [!!!!!!!!!!!!!!!!! FRIG FOR CARLTON DRIVE SWITCHBOARD !!!!!!!!!!!!!!!!!!
583L LDX 0 GREP1(3) [LINE INOPERABLE IF IT REPLIES
58H= ANDN 0 #77 ["BREAK IN" TO NULL TRANSFER.
592W BCT 0 S1
59GG [!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
5=26 )
5=FQ STOZ GFAIL(3)
5=^B LDX 5 GUNITNO(3)
5?F2 GETACT CPAT
5?YL LDX 3 AMOPADDR(2)
5#D= LDX 6 AWORK3(2)
5#XW LDX 2 BPTR(2)
5*CG STO 3 AWORK4(2) [PRESERVE AMOP ADDRESS
5*X6 STO 5 ACC7(2) [LINE NO.
5BBQ LINKSET 2,PAIR1(1) [LINK TO K4SCAN
5BWB FPUT [PUT THE CPA ON THE LIST.
5CB2 BZE 6 U5B [J. IF LINE NOT ATTACHED.
5CTL MHUNTW 1,IDF,CONNAME [CHAIN IN DATA BLOCK HOLDING
5D*= CHAIN 1,BPTR(2) [CONCEPTUAL NAME.
5DSW U5B LDCT 6 #730 [MASK FOR INTERLOCK BITS.
5F#G BRN S2
5FS6 REFIND [LOCKC
5G?Q MHUNTW 2,AMXOR,ALCB
5GRB EXIT 1 0
5H?2 [
5HQL XBI GEOERR 1,NOBISCAN [ERROR IF BROKEN IN ON HERE
5J== REJ GEOERR 1,REJECT [ERROR IF OUTPUT NULL REJECTED
5JPW [
5K9G S0 LDX 0 GFAIL(3) [J. IF NULL ENDED IN ERROR 2ND. TIME.
5KP6 BNZ 0 S1
5L8Q LDN 0 1 [MARK 1ST. ERROR.
5LNB STO 0 GFAIL(3)
5M82 LDX 1 AWORK4(2) [RELOCATE ALINES ENTRY.
5MML TESTMOVE 4,U5
5N7= HUNT2 1,AMXOR,ALINES,AMOPADDR(2)
5NLW ADX 1 7
5P6G BRN U5 [J. TO REPEAT THE OUTPUT.
5PL6 [
5Q5Q S1 STOZ GFAIL(3) [CLEAR FAILURE COUNT
5QKB LDCT 6 #310 [MASK FOR INTERLOCK BITS.
5R52 S2 LDX 3 AWORK4(2) [RELOCATE ALINES ENTRY.
5RJL TESTMOVE 4,S3
5S4= HUNT2 3,AMXOR,ALINES,AMOPADDR(2)
5SHW ADX 3 7
5T3G S3 ADN 6 1 [MASK OUT EXTRANEOUS INTERLOCK BITS.
5TH6 ANDS 6 A1+FOURTHWD(3)
5W2Q BNG 6 S4 [J. IF LINE WAS OPERABLE
5WGB LDX 0 A1+FOURTHWD(3) [OTHERWISE, WAS IT ATTACHED?
5X22 ADXC 0 0
5XFL BCC S4
5X^= MFREEW IDF,CONNAME [IF SO FREE THE CONCEPTUAL NAME BLOCK
5YDW S4 SBX 3 7
5YYG SRL 7 2
5^D6 BRN U2B [J. FOR NEXT LINE.
5^XQ [
62CB [THIS ENTRY POINT IS FOR THE CPA TO FIND THE IDF ENTRY FOR THIS LINE.
62X2 [IF AN ENTRY IS FOUND FOR A 7071 CONSOLE AN LCB IS CREATED AND IT
63BL [OUTPUTS "GOOD MORNING".
63W= [IF AN ENTRY IS FOUND FOR A SENTINEL IT GOES TO DEAL WITH THE TRANSFER.
64*W [IF NO RELEVANT ENTRY IS FOUND THE CPA COMMITS SUICIDE.
64TG [
65*6 XPCT LDX 6 AWORK4(2) [AMOP ADDRESS
65SQ ADXC 5 5 [J IF LINE IS ATTACHED
66#B BCS X0
66S2 LDX 0 PCTYPE(1) [.IF WE'RE ALREADY A PCT ACTIVITY
67?L BXE 0 ATYPE(2),YPCT
67R= NAMEX 2 [OTHERWISE RESET OUR TYPE AND LENGTH
68=W ALTLEND 2,BMOPLEN+APCTLEN
68QG YPCT SMO AWORK4(2)
69=6 LDX 0 CPPTR
69PQ STO 0 CPPTR(2)
6=9B ACROSS PCTBEGIN,1
6=P2 X1A LDX 0 SENTYPE(1)
6?8L BXE 0 ATYPE(2),X1
6?N= NAMEX 2 [RENAME IT
6#7W ALTLEND 2,BMOPLEN+ASENTLEN
6#MG BRN X1
6*76 [
6*LQ X0 LDCT 6 #420 [LEAVE LINE LOOKING "IDLE".
6B6B ERS 6 A1+FOURTHWD(3)
6BL2 BRN U4FIN
6C5L [
6C9H ...X1
6C*D ... FSHCODE B,NOKILLA2
6CF* ...(
6CK= ... FSHKILL
6CP7 ...NOKILLA2
6CT4 ...)
6CY^ ... ACROSS SENTINEL,1
6D4W [
6DJG [
6F46 Z3SCAN
6F6P ... FSHCODE B,NOPRA3
6F9# ...(
6F?X ... FSHACTPR
6FBG ...NOPRA3
6FF5 ...)
6FHQ LDX 3 AWORK4(2)
6G3B LDN 6 1
6G6G ...#UNS IDFMARK8
6G9L ... IDFSCAN (GEOERR),SYSOF,CPPTR(3),7
6G#Q ...#UNS IDFMARK8
6GCW ...#SKI
6GH2 IDFSCAN SYSOF,CPPTR(3),7 [LOOK FOR THIS LINE IN IDF
6H2L LDN 6 0 [SET MARK TO SHOW MOPPED ON.
6HG= SYSOF HUNT2 3,AMXOR,ALINES,AWORK4(2) [RELOCATE ALINES ENTRY
6H^W LDX 5 7
6JFG SLL 5 2
6J^6 ADX 3 5
6KDQ BNZ 6 X0 [J. IF MOPPED OFF ALREADY.
6KYB DLA 6 A1+FOURTHWD(3) [CLEAR THE OLD DEVICE TYPE.
6LD2 LDXC 5 ACOMMUNE2(2) [J. IF TERMINAL DEVICE TYPE UNKNOWN
6LXL BCS X0
6MC= LDCH 6 5 [GET INTERNAL TYPE #
6MWW #SKI K6MULTIPLX>99-99
6NBG (
6NW6 BZE 6 U4A [SHOULD NEVER BE ZERO,
6P*Q LDN 0 HIGHTYPE [OR > HIGHEST INTERNAL TERMINAL TYPE.
6PTB BXL 0 6,U4B
6Q*2 )
6QSL ERN 6 ASENTMACH [J. IF NOT SENTINEL.
6R#= BNZ 6 X2
6RRW ORN 5 #4000 [PUT IN "ALREADY INTERRUPTED" BIT
6S?G X2 ORS 5 A1+FOURTHWD(3) [SET NEW DEVICE TYPE
6SR6 BZE 6 X1A [J IF SENTINEL
6T=Q ERN 6 ASENTMACH$APCTMACH [J. IF REMOTE BATCH TERMINAL.
6TQB BZE 6 XPCT
6TS^ ... FSHCODE B,NOPRPR
6TXJ ...(
6W27 ... BRN NOPRA4 [ OMIT THE FSHACTPR - ALREADY DONE
6W4Q ...NOPRPR
6W7* ...)
6W=2 [
6WPL [THIS SECTION SETS UP THE LINE CONTROL BLOCK
6X9= [ON ENTRY X7=LINE NO.
6XNW [
6Y8G Z4SCAN
6Y?5 ... FSHCODE B,NOPRA4
6Y*N ...(
6YD? ... FSHACTPR
6YGW ...NOPRA4
6YKF ...)
6YN6 SMO AWORK4(2)
6^7Q LDX 4 AWORK1 [OBTAIN MAX. CHAR. TRANSFER COUNT.
6^MB ADN 4 ZALEN*4+3
7272 SRL 4 2 [FORM LENGTH OF LINE CONTROL BLOCK
72LL SETUPCORE 4,3,AMXOR,ALCB,1,1,2 [GET LINE CONTROL BLOCK.
736= STOZ A1+BPTR(3) [ZEROISE THE BLOCK.
73KW LDN 0 A1+BPTR(3)
745G LDN 1 A1+BPTR+1(3)
74K6 MOVE 0 BUFFER-A1-BPTR-1
754Q NGS 3 GTIM(3)
75JB LDX 0 7
7642 STO 0 JSOURCE2(2)
76HL LDX 1 AWORK4(2)
773= LGEOG CPPTR(1),0
77GW STO 0 JSOURCE1(2)
782G STO 1 IDENTM(3)
78G6 STO 7 GUNITNO(3)
78^Q LTYPE CPPTR(1),0
79FB DCH 0 JSOURCE1(2)
79^2 LDX 1 FX1
7=DL LDX 0 XAMXMSKPR(1)
7=Y= STO 0 AMXMSK(2) [SET MPX MASK WORD
7?CW LDX 0 XCONTEXT(1)
7?XG STO 0 CONTEXT(2) [SET CONTEXT BITS
7#C6 LDN 0 TNOCHS(1)
7#WQ LDN 1 GNOCHS(3)
7*BB MOVE 0 TERMLEN [INSERT INFORMATION IN LCB
7*W2 HUNT2 2,AMXOR,ALINES,AWORK4(2)
7B*L LDX 5 7
7BT= SLL 5 2
7C#W ADX 2 5
7CSG RINGTWO A1(2),A1(3) [ENRING LCB WITH ALINES ENTRY.
7D#6 LDX 0 GSIGN [MARK 'CPA SET UP'.
7DRQ ERS 0 A1+FOURTHWD(2)
7F?B ACROSS MORNING,1 [OUTPUT THE 'GOOD MORNING' MESSAGE
7FR2 [
7G=L #
7GQ= #
7H9W #END
^^^^ ...66745237000200000000