{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SCEDIT84)}}
====== SCEDIT84 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ASCEDIT|ASCEDIT]], [[george:macro:CATMASK|CATMASK]], [[george:macro:CLOSE|CLOSE]], [[george:macro:CLOSEABANDON|CLOSEABANDON]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERRX|COMERRX]], [[george:macro:CREATEB|CREATEB]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FNORM|FNORM]], [[george:macro:HUNTW|HUNTW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:ON|ON]], [[george:macro:OPEN|OPEN]], [[george:macro:PHOTO|PHOTO]], [[george:macro:REPERR|REPERR]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VFREE|VFREE]], [[george:macro:WIND|WIND]]
22FL #SEG SCEDIT [LEN WAGSTAFF
22^= #OPT K0SCEDIT=0
23DW #LIS K0SCEDIT>K0ALLGEO
23YG 8HSCEDIT
24D6 #
24XQ #
25CB SEGENTRY K1SCEDIT,X1SCEDIT
25X2 # ENTRY POINT TO IMPLEMENT 'SCREENEDIT' COMMAND
26BL #
26W= ...NOCOMBIT #77776777
27*W #
27B9 ...ZCOMDEV +JCOMDEV [MAY NOT BE ISSUED FR THIS DEVICE
27BJ ...ZPARMIS +JPARMIS [PARAMETER MISSING
27BX ...ZEDSHRIEK +EDSHRIEK [NULL 2NDPARA NOT ALLOWED WITH !
27C= ...ZNOEDIT +JNOEDIT [NOT SUITABLE FOR EDITING
27CK ...ZPERITYPE +ERPERITYPE [WRONG TYPE OF FILE
27CY ...#
27D? ...ZER2 LDN 6 ZCOMDEV
27DL ... BRN XER3
27D^ ...ZER3 LDN 6 ZPARMIS
27F# ... BRN XER3
27FM ...ZER4 LDN 6 ZEDSHRIEK
27G2 ... BRN XER2
27G* ...ZER5 LDN 6 ZNOEDIT
27GN ... BRN XER1
27H3 ...ZER6 LDN 6 ZPERITYPE
27HB ... BRN XER2
27HP ...#
27J4 ...XER1 CLOSEABANDON
27JC ...XER2 CLOSE
27JQ ...XER3 LDX 1 FX1
27K5 ... ADX 1 6
27KD ... LDX 6 0(1)
27KR ... COMERRX 6
27L6 ...#
27LF ...PARA SBX 7 FX1
27LS ... SPARAPAS
27M7 ... MHUNT 3,CPB,CUNI
27MG ... ADX 7 FX1
27MT ... EXIT 7 0
27N8 ...#
27NH ...CREA SBX 7 FX1
27NW ... CREATEB 3 [CREATE FILE/CREATE
27P9 ... LDCT 0 #400
27PJ ... STO 0 CEINF1(3) [SERIAL FILE
27Q= ... LDX 0 AWORK2(2)
27QK ... STO 0 CETM(3) [TYPE/MODE WORD
27QY ... ADX 7 FX1
27R? ... EXIT 7 0
27RL ...#
27R^ ...# USE OF AWORK WORDS:
27S# ...# AWORK1: ZERO=> OLDFILE IS WORKFILE
27SM ...# AWORK2: TYPE/MODE WORD FOR OLDFILE - USED BY S/R
27T2 ...# 'CREA' TO ASK FOR NEWFILE OF SAME TYPE
27TG #
27Y5 ...XISBITNG #00010000 [FLAG FOR NON GRAPHIC FILES
282N ...SCOMMENT
287W ... CATMASK COMMENT
28*6 X1SCEDIT
28SQ ... HUNTW 3,AMXOR,ADCB [MAKE SURE ITS VDU
29#B ... BNG 3 ZER2
2=?L LDX 3 A1+FPTR(3)
2=R= LDX 0 FOURTHWD(3)
2?=W ANDN 0 #77
2?QG SBN 0 10
2#=6 BNZ 0 ZER2 [J IF NOT VDU
2#PQ #
2*9B ... CALL 7 PARA [GET "OLDFILE" PARAMETER
2B8L LDX 0 ANUM(3)
2BN= BNG 0 ZER3 [PARA MISSING
2C7W BZE 0 ZER3
2CMG LDCH 0 APARA(3) [FLAG IN AWORK1..
2D76 SBN 0 #21 [..ZERO=>WORKFILE
2DLQ STO 0 AWORK1(2) [..NON-ZERO ELSE
2F6B #
2FL2 PHOTO 7
2G5L NAMETOP 3,FILE,FNAME
2GK= ... FNORM 3 [NORMALISE FILENAME
2H4W TESTMOVE 7,NOHNT
2HJG MHUNT 3,FILE,FNAME
2J46 NOHNT NAMETOP 3,CPB,CUNI [IN CASE NEEDED FOR ERRORS
2JHQ TESTREP NAMEFORM,ZZZ [J IF 1ST PARA RUBBISH
2K3B #
2L^W USEROPEN XBRK,READ,LEAVE
2MFG REPERR REPOK [J IF OPENED OK
2M^6 ... BRN ZZZ [ELSE ERROR MESSAGE ALREADY GIVEN
2NDQ #
2NNJ ...REPOK MHUNTW 3,FILE,ENT
2NYB ... LDX 0 ETM(3)
2P88 ... BPZ 0 ZER6 [J IF FILE IS AMORPHOUS
2PD2 ... STO 0 AWORK2(2)
2PMS ... CALL 7 PARA [GET "NEWFILE" PARAMETER
2PXL LDX 0 ANUM(3)
2QC= BNG 0 NULL [J IF NULL
2QWW BZE 0 NULL
2RBG BRN NTNUL
2RW6 #
2S*Q NULL LDX 0 AWORK1(2) [IF 1ST PARA=!,NULL..
2STB BZE 0 ZER4 [..2ND PARA NOT ALLOWED
2T*2 ... CALL 7 CREA [SET UP FILE CREATE
2YQB MHUNT 3,FILE,FABSNB [LEFT BY USEROPEN
2^5H ... LDX 2 HDREC(3)
2^DN ... ADX 2 3
2^RT ... LDX 0 A1-2(2)
3272 ... ADN 0 1
32G7 ...NT4K STO 0 A1-2(2)
32T# ... LDN 4 A1-6(2)
338F ... LDX 2 FX2
33HL ... MHUNT 3,CPB,CUNI
33WR ... LDN 0 12
349Y ... STO 0 ANUM(3)
34K5 ... LDX 5 3
34Y= ... ADN 5 APARA
35?C ... MOVE 4 3
35LL BRN OPEN
366=
36KW #
375G NTNUL VFREE FILE,FABSNB [2ND PARA NOT NULL
37*# ... VFREE FILE,ADJUNCTS
37K6 PHOTO 7
384Q NAMETOP 3,FILE,FNAME
38JB FNORM 3 [NORMALISE IT
3942 TESTMOVE 7,NOHT2
39HL MHUNT 3,FILE,FNAME
3=3= NOHT2 NAMETOP 3,CPB,CUNI
3=GW TESTREP NAMEFORM,ZZ1 [J IF 2ND PARA RUBBISH
3?2G #
3?G6 ... TESTREPN ADJUNCTS,OPEN1 [J IF NO ADJUNCTS
3?^Q MHUNTW 3,FILE,ADJUNCTS
3#FB LDCT 1 #400 [LOOK AT APPEND BITS
3#^2 ORS 3 1
3*DL LDCH 5 A1+1(3)
3*Y= ANDN 5 #30
3BCW ... ERN 5 #30
3BXG ... BNZ 5 OPEN1 [J IF APPEND NOT GIVEN
3CC6 #
3CG= ... USEROPEN XBRK2,APPEND,CREATE,LEAVE
3CKB ... REPERR RPOK3 [J IF OPENED OK
3CNG ... BRN ZZ1
3CRL ...#
3CWQ ...RPOK3 WIND
3C^W ... BRN RPOK2
3D52 ...#
3D86 ...OPEN1 CALL 7 CREA [SET UP FILE'CREATE
3D?= ...OPEN USEROPEN XBRK2,GENERAL,EMPTY,CREATE,LEAVE
3DBB REPERR RPOK2 [J IF OPENED OK
3DW2 BRN ZZ1
3DYN ...#
3F3B ...RPOK2 MHUNTW 3,FILE,ENT
3F64 ... LDX 0 ETM(3)
3F8Q ... TXU 0 AWORK2(2)
3F?D ... BCS ZER5 [J IF O/F NOT SAME TYPE AS N/F
3F#5 ... SLL 0 1
3F#Q ... SBN 0 #24 [LOOK AT INPUT FILE TYPE
3F*C ... STO 0 7 [SAVE IT
3FB6 ... ASCEDIT ON [SET SCREEN EDITING MODE FLAG
3FDS ... SETNCORE ASCREENLEN,3,AMXOR,ASCREEN
3FHG ... LDN 4 A1(3) [ZEROISE ASCREEN BLOCK
3FL8 ... LDN 5 A1+1(3)
3FNW ... STOZ A1(3)
3FRJ ... MOVE 4 ASCREENLEN-1
3FW= ... LDX 0 AMXMSK(2) [PRESERVE MULTIPLEXOR MASK
3FYY ... STO 0 ISMXMS(3)
3G3L ... ANDX 0 NOCOMBIT(1) [UNSET COMMANDS BIT
3G4^ ... ORX 0 SCOMMENT(1) [ENSURE ERROR MESSAGES NOT LOST
3G6# ... STO 0 AMXMSK(2)
3G92 ... LDCT 0 #002 [SO SCEDITOR KNOWS TO CLEAR
3G?N ... ORS 0 ISMFORM(3) [SCREEN ON 1ST PTR READY
3G#9 ... BZE 7 XACR [LOOK IF FILES ARE GRAPHIC
3G#Q ... LDX 0 XISBITNG(1)
3G*? ... ORS 0 ISBITS(3) [SET NON GRAPHIC FLAG
3G*S ...XACR
3GBB ... ACROSS SCEDITOR,5
3GF4 ...#
3GHQ ...#
3GLD ...XBRK2 CLOSE [BRK-IN; 1 FILE TO CLOSE
3GP6 ...#
3GRS ...XBRK VFREE FILE,CREATE [BRK-IN; NO FILES TO CLOSE
3GWG ... COMBRKIN
3G^8 ...#
3H3W ...ZZ1 CLOSE
3H6J ...#
3H9= ...ZZZ ENDCOM
3H#6 #
3H*C ...#
3HBN ...#
3HC^ ...#
3HF= ...#
3HGH ...#
3HHS ...#
3HK5 ... SEGENTRY K50SCEDIT
3HLB ...ZDUM1 0
3HMM ... SEGENTRY K51SCEDIT
3HNY ...ZDUM2 0
3HQ9 ...#
3HRQ #END
^^^^ ...224716450011