{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SCHDJOBA867)}}
====== SCHDJOBA867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:APJOBSET|APJOBSET]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:CAPCA|CAPCA]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DOWN|DOWN]], [[george:macro:EVENTFIN|EVENTFIN]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FINMOVE|FINMOVE]], [[george:macro:FON|FON]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETJOB|GETJOB]], [[george:macro:GETWORD|GETWORD]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:ICT|ICT]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JLADJUST|JLADJUST]], [[george:macro:JWELLADD|JWELLADD]], [[george:macro:JWELLSUB|JWELLSUB]], [[george:macro:LONGWAIT|LONGWAIT]], [[george:macro:MBC|MBC]], [[george:macro:MELADJUST|MELADJUST]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OLPFIN1|OLPFIN1]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:PAIR|PAIR]], [[george:macro:POP|POP]], [[george:macro:PROGBRKIN|PROGBRKIN]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:RUNJSA|RUNJSA]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:TOPCA|TOPCA]], [[george:macro:TOPCA1|TOPCA1]], [[george:macro:TRACE|TRACE]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:VFREEW|VFREEW]], [[george:macro:VOP|VOP]], [[george:macro:WAITVOP|WAITVOP]], [[george:macro:WORDFIN|WORDFIN]]
22FL #SEG SCHDJOBA860 [R.D.P.CLIFTON
22^= #OPT K0SCHDJOBA=0
23DW #LIS K0SCHDJOBA>K0WORK>K0ALLGEO>K0FILESTORE
23YG #OPT K6SCHDJOBA=K6WORK>K6ALLGEO>K6FILESTORE
24D6 8HSCHDJOBA
24J3 ...[
24MY ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
24RT ...[
24XQ SEGENTRY K1SCHDJOBA,ZK1
252W SEGENTRY K2SCHDJOBA,ZK2
2562 FSHENTRY K3SCHDJOBA,,ZK3,ZK3
2596 FSHENTRY K4SCHDJOBA,ZK4,ZK4,ZK4
25#= FSHENTRY K5SCHDJOBA,ZK5,,ZK5
25*? FSHENTRY K7SCHDJOBA,ZK7,,ZK7
25B# FSHENTRY K8SCHDJOBA,ZK8,,ZK8
25CB RLINK1
25X2 PAIR HLSREAD,3 [LINK TO SCHED.PERI XCODE
26BL TIMEFACTOR +1000/K9
26W= X24HRS +1000/K9*24*60*60
27*W XFONINTP +FONINTP
27TG [
28*6 [ THESE ROUTINES ARE USED BY THE WAIT,DEWELL,AND WRITE SWITCH
28SQ [ EXTRACODES.
29#B UNPLUGCAPCA
29S2 SBX 7 FX1
2=?L UNPLUG
2=R= CAPCA
2?=W X7XIT ADX 7 FX1
2?QG EXIT 7 0
2#=6 [
2#PQ XGETWORD
2*9B SBX 7 FX1
2*P2 GETWORD 5,3,WRITE
2B8L TESTREP2 OK,X7XIT
2BN= GEOERR 1,**HELP**
2C7W ZK1
2CMG LDX 0 HLSCONREC(2)
2D76 SBN 0 2
2DLQ BZE 0 SWIT2 [WAIT EXTRACODE
2F6B SBN 0 4
2FL2 BZE 0 SWIT6 [
2G5L SBN 0 1
2GK= BZE 0 SWIT7
2H4W BRN (GEOERR)
2HJG # THE ROUTINE BELOW DEALS WITH THE WAIT EXTRACODE OF THE JOBSTARTER
2J46 # IT HAS THE FOLLOWING CONTROL AREA
2JHQ # WORD0 51/1 OR 52/#113
2K3B # WORD1 0-THE REPLY WORD
2KH2 # WORD2 1-THE NO OF WORDS IN THE CONTROL RECORD
2L2L # WORD3 ADDRESS IN THE PROGRAM OF THE CONTROL RECORD
2LG= # THE SINGLE WORD OF THE CONTROL RECORD IS SET TO 2
2L^W SWIT2
2MFG LDN 6 0
2M^6 TOPCA
2NDQ LDX 5 EVENT2(2) [ADDRESS OF CONTROL AREA
2NYB ADN 5 1 [THE REPLY WORD
2PD2 LDX 7 ACTNUM(2)
2PXL TOPCA1 RLINK1(1) [ENABLES USER TO CHANGE FROM AN OLPA
2QC= BNG 6 XSWITCPA [J IF SWITCH XCODE
2QWW BNZ 6 XDWELLCPA [J IF DEWELL XCODE
2RBG LDX 6 HLSREVIEW [LOAD WAIT TIME I.P.
2RW6 BZE 6 NOWT [J IF NO WAITING
2S*Q CALL 7 UNPLUGCAPCA
2STB STO 5 AWORK1(2)
2T*2 WTCHCK
2TSL LDX 0 HLSLASTWAKE
2W#= BNG 0 PERIODIC [J IF 1ST HLSWAIT SINCE EMS
2WRW LDX 5 CLEANCT
2X?G SBX 5 0
2XR6 BPZ 5 NMIDN [J IF NOT GONE OVER 12PM
2Y=Q ADX 5 X24HRS(1)
2YQB NMIDN DVS 4 TIMEFACTOR(1) [CONVERT TO SECS
2^=2 LDN 6 60
2^PL MPY 6 HLSREVIEW
329= BZE 6 NOF1 [J IF HLSREVIEW NOT HUGE
32NW LDX 7 BITS22LS
338G NOF1 SBX 7 5 [SECS LEFT TO WAIT
33N6 BZE 7 PERIODIC
347Q BPZ 7 NOPERIODIC
34MB PERIODIC
3572 LDX 0 BIT9
35LL ORS 0 HLSWAIT
366= LDX 0 CLEANCT
36KW STO 0 HLSLASTWAKE
375G LDN 6 60
37K6 MPY 6 HLSREVIEW
384Q BZE 6 NOF2
38JB LDX 7 BITS22LS
3942 NOF2
39HL NOPERIODIC
3=3= DVS 6 XFONINTP(1) [CONVERT TO FONINTP INTERVAL COUNT
3=GW LDCT 0 #040
3?2G ANDX 0 HLSWAIT
3?G6 BZE 0 NNKICK [J IF NOKICK BIT CLEAR
3?^Q LDCT 4 #700
3#FB ORN 4 #10
3#^2 ORX 4 BIT9
3*DL ANDX 4 HLSWAIT
3*Y= BZE 4 WTLONG [J IF IN NOKICK SITUATION
3BCW ERS 0 HLSWAIT [CLEAR NO KICK BIT
3BXG NNKICK
3CC6 LDX 4 HLSWAIT
3CWQ STOZ HLSWAIT
3DBB BNZ 4 REACT
3DW2 WTLONG
3F*L LONGWAIT XBRK,#33,,,6
3FT= BRN WTCHCK
3G#W REACT
3GSG LDX 5 AWORK1(2) [PROG ADDRESS OF REPLY WORD
3H#6 CALL 7 XGETWORD
3HRQ LDX 0 FINISH
3J?B BZE 0 NOFIN
3JR2 ORX 4 GSIGN [KEEP FINISH BIT SET
3K=L NOFIN
3KQ= REPRUN
3L9W STO 4 0(3) [TRANSFER CONTENTS OF HLSWAIT
3LPG WORDFIN
3M96 RUNPROG [RETURN TO SUBJECT PROGRAM
3MNQ NOWT EVENTFIN [CONTINUE PROGRAM
3N8B #
3NN2 # SI JOBS MAY BE BROKEN IN ON AT FINISH TIME
3P7L XBRK PROGBRKIN
3PM= SWIT6
3Q6W SCHEDDEWELL
3QLG LDX 3 HLSCONREC+8(2)
3R66 LDX 4 HLSCONREC+1(2)
3RKQ LDN 6 1 [MARKS DEWELL CASE
3S5B BRN TOPCA
3SK2 XDWELLCPA [NOW WE'RE IN THE PCA
3T4L STO 5 AWORK1(2) [REPLY WORD ADDRESS
3TJ= STO 7 AWORK2(2) [ACTNUM OF OLPA
3W3W CALL 7 UNPLUGCAPCA
3WB? XOPEN OPENSYS ,JOBLIST,GENERAL,QUERY
3WNN TESTRPN2 OK,SWITBAD2
3X36 POP NOSEM,,JWACCESS,,,,NOWAIT
3X=Y BNG 3 NOSUMCHECK
3XGQ HUNTMISB 2,JWELL
3Y2B LDEX 0 JOBENTS+JOBCTS(2)
3YG2 LDEX 5 JOBENTS+JWENTRY+JOBCTS(2)
3Y^L ADX 0 5 [TOTAL JOBS RUNNING
3^F= BXGE 0 3,SWITBAD3
3^YW NOSUMCHECK
43CQ BZE 4 XDEWELLBAD
43XB GETJOB 4,SYSTEM
44C2 TESTRPN2 OK,XDEWELLBAD [J IF NO SUCH JOB
44WL STEPAGAIN
45B= ADX 3 JOBDATASIZE
45TW LDN 4 1
46*G JBS XDEWELLBDX,3,JLBRUNNING
46T6 LDN 4 2
47#Q JBS XDEWELLBDX,3,JLBNOTCAND
47SB JBS XDWMOP,3,JLBMOP
48#2 JBC XDEWELLBAD,,HLSBS
48RL BRN XDWOK
49?= XDWMOP
49QW JBC XDEWELLBAD,,HLSMS
4==G XDWOK
4=Q6 READAGAIN
4?9Q MHUNTW 3,FILE,FRB
4?PB NAME 3,FILE,FWB
4#92 JLADJUST 3
4#NL BS 3,JLBRUNNING
4*8= REWRITE
4*MW MHUNTW 3,FILE,FWB
4B2? LDX 4 ALOGLEN(3)
4B#N SETUPCOR 4,2,JWELL,COPYSYS
4BM6 MHUNTW 3,FILE,FWB
4C6Q LDN 4 A1(3)
4CLB LDN 5 A1(2)
4D62 SMO ALOGLEN(3)
4DKL MOVE 4 0 [MAKE COPY OF JWELL/COPYSYS...
4F5= NAME 3,JWELL,COPYSYS [FOR JWELLADD/SUB.
4FJW DOWN SETJOBQ,3
4G4G JWELLADD LIVE
4GJ6 JWELLSUB WELL
4H3Q MFREEW JWELL,COPYSYS
4HHB XOKCPA
4J32 LDN 4 0
4JGL BRN XCPAEND [SET REPLY AND RUN PROG
4K2= XDEWELLBAD
4KFW LDN 4 0
4K^G XDEWELLBDX
4LF6 CLOSETOP
4LYQ BRN SWITBADX
4MDB SWIT7
4MY2 SCHEDSWIT
4NCL LDX 0 HLSCONREC+1(2)
4NX= BNG 0 SWITRESET [J IF RESETTING SWITCHES
4PBW ANDN 0 1
4PWG LDX 6 HLSFACE
4QB6 LDN 7 0
4QTQ BNZ 0 SWITSTO [J IF INTERFACE SWITCHES WANTED
4R*B LDX 6 HLSFACE+1
4RT2 LDX 7 HLSFACE+2
4S#L SWITSTO
4SS= STO 6 HLSCONREC+2(2)
4T?W STO 7 HLSCONREC+3(2)
4TRG LDX 5 AWORK3(2)
4W?6 LDX 3 APETADDR(2)
4WQQ LDN 4 HLSCONREC(2)
4X=B LDN 6 4
4XQ2 FINMOVE 3,5,4,6,HLOCK2 [MOVE CONTROL RECORD BACK TO PROGRAM
4Y9L BRN SETOKREP
4YP= SWITRESET
4^8W ANDN 0 1
4^NG BNZ 0 SWITFACE [J IF RESETTING INTERFACE BITS
5286 LDX 0 HLSCONREC+2(2)
52MQ STO 0 HLSFACE+1
537B LDX 0 HLSCONREC+3(2)
53M2 STO 0 HLSFACE+2
546L BRN SETOKREP
54L= SWITFACE
555W LDX 4 HLSCONREC+2(2)
55KG NGN 6 1 [MARKS SWITCH CASE
5656 BRN TOPCA
56JQ XSWITCPA
574B STO 5 AWORK1(2)
57J2 CALL 7 UNPLUGCAPCA
583L POPX POP POPX,,JWACCESS
58H= LDCT 6 #600
592W ANDX 6 4
59GG OPENSYS ,JOBLIST,GENERAL,QUERY
5=26 TESTRPN2 OK,SWITBAD [J IF CLUDGE FOR EXAMPLE
5=FQ LDCT 0 #140
5=^B ANDX 0 HLSFACE
5?F2 ORX 6 0 [PRESERVE SETTING OF FS BITS
5?YL STO 6 HLSFACE
5#D= RUNJSA HOSTOPEN
5#XW CLOSETOP
5*CG LDN 4 0
5*X6 BRN VOP
5BBQ SWITBAD3
5BWB LDN 4 3
5C68 CLOSETOP
5CB2 SWITBADX
5CTL ORX 4 GSIGN
5D*= BRN VOP
5DSW SWITBAD2
5F#G LDX 4 GSIGN
5FBD BRN XCPAEND
5FDB NOSEM
5FG# CLOSETOP
5FJ= WAITVOP ,,JWACCESS
5FL8 BRN XOPEN
5FN6 SWITBAD
5FQ4 LDX 4 GSIGN
5FS6 VOP
5G?Q VOP ,JWACCESS
5GRB XCPAEND
5H?2 LDX 2 FX2
5HQL LDX 5 AWORK1(2)
5J== CALL 7 XGETWORD
5JPW BRN REPRUN
5K9G SETOKREP
5KP6 LDN 5 0 [SET TO ZERO FOR REPLY WORD
5L8Q S5 LDX 2 FX2
5LNB LDX 3 EVENT2(2) [ADDR. OF C.AREA
5M82 ADN 3 1 [ADDR OF REPLY WORD
5MML LDX 1 APETADDR(2)
5N7= FADDRESS 1,3,HLOCK1 [GEORGE ADDR OF REPLY WORD TO X3
5NLW STO 5 0(3) [SET THE REPLY WORD
5P6G #SKIP K6SCHEDJOB>199-199
5PL6 TRACE 0(3),REPLY
5Q5Q VFREEW ADATA,CSTORE
5QKB LDX 1 FX1
5R52 SFIN9 OLPFIN1 RLINK1(1) [RESTARTS SUBJ-PROG WITHOUT
5RJL [LENGTHY STARTING ROUTINES
5RJM #
5RJN #
5RJP ZK2 [ENTRY FOR UPDATE OF JOB BLOCK FROM SCHEDULE
5RJQ #
5RJR # THE CODE BELOW UPDATES THE JOBBLOCK......
5RJS # FOR SCHEDULE
5RJT #
5RJW BITDEFS AWORK3,14,XCP,XMP,XCC,XST,XEP
5RK7 #UNS ICT
5RKD (
5RKP BITDEFS AWORK3,12,XAP
5RL2 JBC TJB0,2,XEP [J IF NO EXPRESS PARAM
5RL? LDN 4 0
5RLJ TJB0 JBC TJB1,2,XAP [J IF NO ACTPRI PARAM
5RLT MHUNTW 3,ADATA,ASUP
5RM6 LDX 4 A1+2(3)
5RMC SLC 4 8 [SHIFT ACT PRIORITY TO B22,23
5RMN TJB1 APJOBSET 6,4 [UPDATE JOB BLOCK
5RM^ [ FOR EXPRESS AND ACT PRI PARAMS
5RN= )
5RNH FINDJOBQ 1,6,NINT
5RNS LDX 4 1 [SAVE PTR TO JOBBLOCK
5RP5 LDX 6 AMILLP(1)
5RPB TJB2 JBC TJB5,2,XEP [J IF NOT EP/CCEP
5RPM JBC TJB3,2,XCC [J IF NOT CCEP
5RPY BC 1,JBEXPREQ
5RQ9 CALL 0 TDEFCOR1 [SET X0=DEFAULT CP
5RQG DEX 0 ACOREP(1) [PUT DEFAULT CP INTO JOBBLOCK
5RQR LDN 6 0
5RR4 BRN TJB5
5RR* TJB3 BS 1,JBEXPREQ [MARK AS EXPRESSED
5RRL LDN 0 60
5RRX DEX 0 ACOREP(1) [SET CP IN JOBBLOCK
5RS8 SMO FX1
5RSF LDX 6 XMILLPEXP
5RSQ LDX 0 JMISC(1)
5RT3 BNG 0 TJB4 [J IF BACKGROUND JOB
5RT# FON #31
5RTK BRN TJB45
5RTW TJB4 FON #32
5RW7 TJB45 LDX 1 4 [PTR TO JOBBLOCK
5RWD TJB5 JBC PMILL,2,XCP [J IF NO CP GIVEN
5RWP MHUNTW 3,ADATA,ASUP
5RX2 LDX 0 A1+1(3) [GET CP
5RX? TJB65 DEX 0 ACOREP(1)
5RXJ PMILL JBC XMELA,2,XMP [J IF NO MP GIVEN
5RXT MHUNTW 3,ADATA,ASUP
5RY6 LDX 6 A1(3)
5RYC XMELA LDX 5 JOBNUM(1)
5RYN BXE 6 AMILLP(1),NINT
5RY^ STO 6 AMILLP(1)
5R^= CALL 4 XMEL
5R^H NINT
5R^S LDX 6 5
6=D6 #UNS ICT
6=K# #SKI
6=QJ MBC 2,XEP,XCC,XCP,XMP
6=XQ #UNS ICT
6?4Y MBC 2,XEP,XCC,XCP,XMP,XAP
6?=8 ACROSS JWELLONE,5
6?PS #
6#9D #
6#P4 #
6*8N XMILLPEXP #73737373
6*N# #
6B7Y #
6BMJ # MOVE MILL PRIORITIES TO PCA
6C78 # AND RE-ORDER PROGRAM RING IF NECESSARY
6CLS #
6D6D XMEL
6DL4 LDEX 0 JMISC(1)
6F5N BZE 0 (4) [EXIT IF NO CORE IMAGE
6FK# MELADJUST 1
6G4Y EXIT 4 0
6GJJ [ GET DEFAULT CORE PRIORITY FOR JOB
6H48 [ ON ENTRY, X1->JOBBLOCK; ON EXIT,X3->JOB'S CPAT
6HHS TDEFCOR1
6J3D STO 0 GEN0 [LINK ADDRESS
6JH4 FCAJO 3,1
6K2N BRN TDEFCP
6KG# [ GET DEFAULT CORE PRIORITY FOR JOB
6K^Y [ X3->JOB'S CPAT
6LFJ TDEFCOR
6L^8 STO 0 GEN0
6MDS TDEFCP
6MYD LDN 5 0
6ND4 LDX 0 CONTEXT(3)
6NXN SLL 0 20
6PC# BPZ 0 XNOTMOP [J IF BACKGROUND JOB
6PWY LDN 5 1
6QBJ XNOTMOP
6QW8 LDX 0 JSOURCE3(3)
6R*S SLL 0 2
6RTD BNZ 0 XCLUSTER [J IF CLUSTER JOB
6S*4 ORN 5 2
6SSN XCLUSTER
6T## SMO 5
6TRY LDX 0 CLUSBACKCP
6W?J BRN (GEN0)
6WR8 #
6X=S #
6XQD #
6Y=4 #
#W88 #END
^^^^ ...300017770001