{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SCHEDMTX867)}}
====== SCHEDMTX867 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BBS|BBS]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BSXD|BSXD]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DOWN|DOWN]], [[george:macro:FDTENT|FDTENT]], [[george:macro:FINDREC|FINDREC]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:LF|LF]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGSTOP|LONGSTOP]], [[george:macro:MBSXD|MBSXD]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OPENINC|OPENINC]], [[george:macro:PAIR|PAIR]], [[george:macro:PRESINC|PRESINC]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REMOVE|REMOVE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:TAPEOPEN|TAPEOPEN]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRACE|TRACE]], [[george:macro:UPDOLC|UPDOLC]], [[george:macro:VFREE|VFREE]], [[george:macro:VFREEW|VFREEW]]
227T ... SEG SCHEDMTX,866,C.R.JOHNSON,SCHEDULER
22*N ...[
22HH ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22PD ...[
22^= SEGENTRY K1SCHEDMTX,X1SCHEDMTX
23DW ...[
23YG ...[
24D6 ...[
29XX ... BITDEFS AWORK2,0,WORK2B0
2=3S ...[
2?5L ...PAIR PAIR DTSTART,1
2JRJ ...[
2K3B ...[ ******************************************************************
2K?8 ...[
2KH2 ...[ THIS SUBROUTINE SETS THE CHAIN ALTERED BIT IN ALL THE
2KQS ...[ FDT ENTRIES.
2L2L [
2LG= SACT LDX 2 BOLC
2MFG LDX 1 A1(2) [COUNT OF FDT ENTRIES
2M^6 BZE 1 SACT2
2N?H ...SET8
2NKY ... BS 2,BIFDTCA [SET 'CHAIN ALTERED' BIT
2NYB ADN 2 FDTLEN [NEXT ENTRY
2PD2 BCT 1 SET8
2PXL SACT2 EXIT 7 0
2PXM ...[
2PXN ...[ ******************************************************************
2PXP ...[
2PXQ ...[ THIS SUBROUTINE LOOKS FOR AN FDT ENTRY.
2PXR ...[
2PXS ...XFDTENT [
2PXT ... FDTENT 3,6,NOENTRY [J IF NO ENTRY
2PXW ... EXIT 7 1 [ENTRY FOUND
2PXX ...NOENTRY [
2PXY ... EXIT 7 0 [ENTRY NOT FOUND
2PX^ ...[
2PY2 ...[ ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
2PY3 ...[
2PY4 ...[ THIS SUBROUTINE CHECKS IF DUMPER REQUIRES ANY TAPES
2PY5 ...[ AND TAKES APPRPRIATE ACTION IF TRUE
2PY6 ...[
2PY7 ...XINCWORD [
2PY8 ... JBS XDUMPST,,BMTSREQ [J IF DUMPER REQUIRES TAPES
2PY9 ... EXIT 7 0 [CONTINUE
2PY= ...XDUMPST [DUMPER REQUIRES TAPES
2PY? ... DOWN DTSUBSA,1 [GO DOWN TO DEAL WITH DUMPERS TAPES
2PY# ... BRN STARTOLCA [RESTART OFFLINE CHAIN SCAN
2PY* ...[
2P^4 ...[ ******************************************************************
2P^R ...[
2Q2G ...[ THIS SUBROUTINE CHECKS THE FDT FOR BIT BIFDTJL - IF IT IS SET A DTA
2Q39 ...[ (DUMP TAPE ACTIVITY) IS CREATED FOR THE APPROPRIATE TSN,THE COR
2Q3Y ...[ FDINCS BLOCK IS CHAINED AFTER IT,THE BIT IS CLEARED AND THE DTA
2Q4M ...[ FPUT'ED ONTO THE ACTIVITY LIST.
2Q5B ...[
2Q65 ...XFDTCHECK
2Q6# ... SBX 6 FX1 [ALLOW FOR COORDINATION
2Q6D ... SMO FX2 [
2Q6J ... STO 6 AWORK1 [SAVE LINK
2Q6N ...XFDTSTART [
2Q6S ... LDX 3 BOLC [POINT TO FDT BLOCK
2Q7H ... LDX 3 A1(3) [X3 => NO. OF ENTRIES IN FDT
2Q8= ... BZE 3 XFDTEND [J IF NO ENTRIES TO SERVICE
2Q8^ ... SLL 3 2 [FOUR WORDS PER ENTRY
2Q9N ... ADX 3 BOLC [X3 => LAST ENTRY IN FDT
2Q=C ... SBN 3 FDTLEN [LAST ENTRY IS DUMMY
2Q?6 ... LDN 2 1 [X2 => COUNT OF FDINCS
2Q?T ...XFDTLOOP [
2Q#8 ... LDX 5 FDSN(3) [X5 => TSN
2Q#J ... JMBS XFDTWRONG,3,BIFDTUW,BIFDTOW [J IF TAPE IS WRONGED IN FDT
2Q*? ... JBS XFDTCD,3,BIFDTCL [J IF TAPE CANTDO LOADED
2QB2 ... JBS XFDTFOUND,3,BIFDTJL [J IF TAPE JUST LOADED
2QBP ... JBC XFDTLOAD,3,BIFDTO [J IF TAPE LOADED
2QCD ... ADN 2 1 [INCREMENT NUMBER OF FDINCS
2QD7 ...XFDTLOAD [
2QDW ... SBN 3 4 [UPDATE MODIFIER
2QFK ... TXL 3 BOLC [END OF FDT?
2QG# ... BCC XFDTLOOP [GO AND LOOK AT NEXT ENTRY
2QH3 ...XFDTEND [
2QHB ... BC BOLC,BIFDTLMEF [CLEAR 'LOOK AT FDT FIRST' BIT
2QHQ ... LDX 2 FX2 [RESET X2
2QH^ ... LDX 6 AWORK1(2) [
2QJ8 ... ADX 6 FX1 [RESET LINK
2QJF ... EXIT 6 0 [FINISHED CHECKING FDT
2QK8 ...XFDTFOUND [A TAPE HAS JUST BEEN LOADED
2QKX ... BC 3,BIFDTJL [CLEAR THE 'JUST LOADED' BIT
2QM* ... SMO FX2 [X2 IS CORRUPT
2QN4 ... STO 5 AWORK2 [AWORK2 => TSN FOR SETUPACT
2QNR ... LDX 3 FX2 [X3 => DTS ACTIVITY
2QPG ...XFDTHUNT [
2QQ9 ... HUNT2 3,FILE,FDINCS [FIND NEXT FDINCS
2QQY ... BCT 2 XFDTHUNT [J IF NOT CORRECT FDINCS YET
2QRM ... LDX 2 FX2 [RESET X2
2QSB ... CHAIN 3,2 [RECHAIN CORRECT FDINCS AFTER DTS
2QTS ... CALL 7 SETUPACT [SET UP DTA FOR TSN IN AWORK2,
2QWH ... [CHAIN FDINCS AND FPUT DTA.
2QXK ... BRN XFDTSTART [GO AND START SCANNING FDT AGAIN
2QYN ...[
2Q^C ...[ TAPE HAS BEEN 'CANTDO LOADED' ... SO SET UP A FCANTDO BLOCK
2R26 ...[
2R2T ...XFDTCD [
2R3J ... LDX 7 2 [SAVE FDINCS COUNT IN X7
2R4? ... JBS XFCANT,BOLC,BIFDTCDPR [J IF FCANTDO PRESENT
2R52 ... SETNCORE 7,1,FILE,FCANTDO [SET UP A FCANTDO BLOCK
2R5P ... BS BOLC,BIFDTCDPR [SET THE 'FCANTDO PRESENT'BIT
2R6D ... LDN 4 1 [SET COUNT OF ENTRIES TO ONE
2R77 ... STO 4 A1(1) [STORE COUNT
2R7W ... BRN XFCANTOK [FCANT NOW READY
2R8K ...XFCANT [INCREASE LENGTH OF FCANTDO
2R8Y ... MHUNTW 1,FILE,FCANTDO [X1 -> FCANTDO
2R9# ... LDX 4 A1(1) [X4 => NO. OF ENTRIES IN FCANTDO
2R=3 ... ADN 4 1 [INCREMENT NO. OF ENTRIES
2R=Q ... STO 4 A1(1) [UPDATE NO. OF ENTRIES
2R?9 ... BXU 4 ALOGLEN(1),XFCANTOK [J IF BIG ENOUGH
2R?N ... ADN 4 8 [INCLUDE A1 IN NEW LENGTH
2R#7 ... ALTLEN 1,4,FILE,FCANTDO [INCREASE LENGTH OF BLOCK
2R#L ... SBN 4 8 [RESET X4
2R*5 ... MHUNTW 1,FILE,FCANTDO [REHUNT FCANTDO
2R*L ...XFCANTOK [FCANT NOW OK
2RC4 ... SMO 4 [X4 CONTAINS NEW NO. OF ENTRIES
2RCR ... STO 5 A1(1) [STORE TSN IN FCANTDO
2RDG ... LDX 2 7 [RESET FDINCS COUNT IN X2
2RF9 ... BRN XFDTCONT [NOW REMOVE REDUNDANT ENTRY
2RFY ...[
2RGM ...[ TAPE HAS BEEN WRONGED (OR CANTDO LOADED) ... SO REMOVE REDUNDANT E
2RHB ...[
2RJ5 ...XFDTWRONG [
2RJS ... JMBAC XFDTLOAD,3,BIFDTJL,BIFDTO [J IF DTA SERVICING TAPT
2RJY ... LF 3,FDTFSNO,1 [X1 => FILESTORE NUMBER
2RK4 ... BZE 1 XFDTCONT [J IF HOST FILESTORE
2RK8 ... ORX 5 GSIGN [SET B0 OF TSN
2RK# ... BRN XFDTCD [INSERT ENTRY IN FCANTDO
2RKH ...XFDTCONT [
2RL= ... LDX 1 FX2 [X1 => DTS ACTIVITY
2RM# ... STO 5 AWORK2(1) [STORE TSN IN AWORK2
2RMT ... BC 1,WORK2B0 [CLEAR B0 OF TSN IF NECESSARY
2RNC ...XFDTFIND [
2RP6 ... HUNT2 1,FILE,FDINCS [FIND NEXT FDINCS
2RPT ... BCT 2 XFDTFIND [J IF NOT CORRECT FDINCS YET
2RQJ ... LDX 2 FX2 [RESET X2
2RR? ... CHAIN 1,2 [RECHAIN CORRECT FDINCS AFTER DTS
2RS2 ... CALL 7 XTAPEM [DECREMENT ADTCOUNT IN ALL
2RSP ... [APPRPRIATE REQUEST BLOCKS
2RTD ... MFREEW FILE,FDINCS [FREE FILE FDINCS BLOCK
2RW7 ... LONGOFF [START SCAN DOWN OFLC AGAIN
2RWW ...[
2RXK ...[ NOW REMOVE RECORD FOR THIS TAPE FROM FDT
2RY# ...[
2R^3 ... LDX 1 BOLC [X1 -> OFLC
2R^Q ... LDX 2 A1(1) [X2 => COUNT OF ENTRIES
2S2F ... SBN 2 1 [X2 => NEW COUNT OF ENTRIES
2S38 ... STO 2 A1(1) [STORE NEW COUNT OF ENTRIES
2S3X ... BZE 2 XFDTEND [J IF THERE WAS ONLY ONE ENTRY
2S4L ... ADN 2 1 [RESET X2
2S5* ... SMO FX2 [X2 CORRUPT
2S64 ... LDX 4 AWORK2 [X4 => TSN
2S6R ...NEXTFDSN [NOW REFIND ENTRY
2S7G ... BXE 4 FDSN(1),REMOVE [J IF ENTRY FOUND
2S89 ... ADN 1 4 [THIS SCAN IS POINTLESS ...
2S8Y ... BCT 2 NEXTFDSN [ ... IT JUST SETS UP ACCUMULATORS AG
2S9M ... GEOERR 1,DTSTSKIP [ENTRY DISSAPPEARED
2S=B ...REMOVE [
2S?5 ... SBN 2 1 [IS ENTRY LAST ONE?
2S?S ... BZE 2 XFDTSTART [J IF YES
2S#H ... LDN 0 FDSN+4(1) [X0 -> NEXT ENTRY
2S*= ... ADN 1 FDSN [X1 -> REDUNDANT ENTRY
2S*^ ... SLL 2 2 [FOUR WORDS PER TSN
2SBN ...XNMOV LDEX 7 2 [MOVE REST OF ENTRIES UP
2SCC ... SMO 7 [ALLOWANCE BEING MADE FOR > 512 WORDS
2SD6 ... MOVE 0 0 [MOVE UP TO 512 WORDS
2SDT ... BNZ 7 RSID [J IF 512 WORDS NOT JUST MOVED
2SFJ ... LDN 7 512 [SET UP X7
2SG? ...RSID SBX 2 7 [ANY MORE WORDS TO MOVE??
2SH2 ... BNG 2 XFDTSTART [IF NOT START ANOTHER
2SHP ... BZE 2 XFDTSTART [SCAN DOWN THE FDT
2SJD ... ADX 0 7 [UPDATE MOVE ADDRESSES
2SK7 ... ADX 1 7 [ DITTO
2SKW ... BRN XNMOV [GO AND MOVE SOME MORE WORDS
2SLK ...[
2T69 ...[
2TKT ...[
3BJL ...[ ******************************************************************
3BKS ...[
3BM2 ...[ THIS SUBROUTINE SETS UP A DUMP TAPE ACTIVITY FOR THE TAPE
3BN8 ...[ WHOSE TSN IS IN AWORK2 OF THE ACTIVITY BLOCK. THE FIRST
3BPB ...[ FDINCS BLOCK FOUND AFTER THE CURRENT ACTIVITY IS THEN
3BQJ ...[ CHAINED AFTER THE DTA AND THE DTA IS THEN FPUT'ED.
3BRQ ...[
3BSY ...SETUPACT
3BW6 ... SBX 7 FX1 [RELATIVIZE LINK ACCUMULATOR
3BXG GETACT ACTDOC,ADUMPT,1 [SET UP DUMP TAPE ACTIVITY
3CC6 ... LDX 5 AWORK2(2) [GET TSN BEFORE CORRUPTING X2
3DW2 LDX 3 BPTR(2) [X2 POINTS TO ITS BASE
3F5S ...[
3F*L [ CHECK LINKSET PARAMETERS
3FKD ...[
3FT= LINKSET 3,PAIR(1) [SET UP LINK
3G#W ... STO 5 ADTSN(3) [MOVE IN TSN
3GSG ... MHUNTW 1,FILE,FDINCS [
3H#6 ... CHAIN 1,3 [CHAIN FDINCS AFTER NEWLY SET UP DTA
3HRQ ... LDX 2 3 [
3K=L FPUT [PUT ACTIVITY ON LIST
3KQ= ADX 7 FX1 [RESETLINK
3L9W ... EXIT 7 0 [
3LPG [
3L^# ...[ ******************************************************************
3M96 [
3MNQ ...[ THIS SUBROUTINE IS DESIGNED TO DO A NON-CORDINATING SEARCH OP THE
3N8B ...[ OLC, UPDATING ALL THE RELEVANT REQUEST BLOCKS. THERE ARE FOUR
3NN2 ...[ ENTRY POINTS CORRESPONDING TO FOUR SEPERATE ACTIONS TO BE TAKEN
3P7L [
3PM= [ 1 XTAPEM/XTAPEP : SEARCH DOWN THE OFF LINE CHAIN
3Q6W [ INCREMENTING/DECREMENTING ADTCOUNT IN
3QLG [ ALL REQUEST BLOCKS WHOSE INC. NO. IS IN
3R66 [ THE RANGE GIVEN BY FILE FDINCS BLOCK
3RKQ [
3S5B ...[ ENTRY : X2 = FX2
3SK2 ...[ FILE FDINCS BLOCK PRESENT
3T4L [
3TJ= [ 2 XCOUNT : SEARCH DOWN OLC UPDATING ADTCOUNT WITH A
3W3W [ VALUE SPECIFIED IN X0, IN ALL REQUEST
3WHG [ BLOCKS WHOSE INC. NO. IS SAME AS IN X4
3WR# ...[ AND WHOSE FILESTORE NUMBER IS IN X6.
3X36 [
3XGQ [ ENTRY : X2 = FX2
3Y2B [ X0 = COUNT OF DTAS AVAILABLE
3YG2 [ X4 = INC. NO.
3YSC ...[ X6 = FILESTORE NUMBER.
3^6S ...[
3^F= [ 3 XSTATE : SEARCH DOWN OLC SETTING APPROPRIATE BIT IN
3^YW [ FDTSTATE WORD IN ALL REQUEST BLOCKS WHOSE
42?? ...[ INC.NO. IS GIVEN IN X4 AND WHOSE FILESTORE
42KN ...[ NUMBER IS IN X6.
42Y6 [
43CQ [ ENTRY : X2 = FX2
43XB [ X0 = STATE WORD
44C2 [ X4 = INC. NO.
44LS ...[ X6 =FILESTORE NUMBER
44WL [
45B= [ EXIT IN ALL THESE CASES ALL THE ACCUMULATORS ARE CORRUPTED
46*G [
46T6 [ NOTE THE LINK ACCUMULATOR IS X7
47#Q UPDOLC
47#X ...[
47*4 ...[ ******************************************************************
47*9 ...[
47*B ...[ THIS SUBROUTINE CHECKS DOWN THE FDT FOR BIT BIFDTO;
47*H ...[ IF IT IS SET THEN CACULATE THE WAITING INTERVAL
47*N ...[ AND STORE IT IN CLONG3,
47*T ...[ OTHERWISE SET CLONG3 ZERO.
47B2 ...[
47B7 ...RVMESSTIME
47B# ... LDX 2 BOLC [X2 => START OF OFLC
47BF ... LDX 3 A1(2) [X3 => NO. OF TAPES IN FDT
47BL ... BZE 3 ZEROIZEA [J IF NO TAPES, NO MESSAGE OUTPUT
47BR ... SLL 3 2 [FOUR WORDS PER ENTRY
47BY ... ADX 3 BOLC [X3 => LAST ENTRY IN FDT
47C5 ... SBN 3 4 [LAST ENTRY IS EMPTY
47C= ...RMREPEAT [
47CC ... JBS XCALTIME,3,BIFDTO [J IF BIFDTO SET
47CJ ... SBN 3 4 [UPDATE MODIFIER
47CP ... TXL 3 BOLC [END OF FDT?
47CW ... BCC RMREPEAT [J IF NOT
47D3 ... BRN ZEROIZEA [NO MESSAGE TO OUTPUT
47D8 ...XCALTIME [CALCULATE WAITING INTERVAL
47D* ... LDX 2 FX2 [RESET X2
47DG ... LDX 4 AWORK4(2) [X4 => REMAINING WAIT INTERVAL
47DM ... BZE 4 SKIPERR [X4 SHOULDNT BE ZERO AT THIS POINT
47DS ... LDN 6 60/FONINTP [60 SECS IS THE RVMESS REVIEW TIME
47D^ ... STO 6 CLONG3(2) [CLONG3 => REVIEW INTERVAL
47F6 ... LDX 6 ASYSTEMMESS [X6 => MESSAGETIME
47F? ... LDN 0 FONINTP [X0 => FONINTP INTERVAL (4 AT PRESENT
47FD ... DVS 5 0 [X6 => WAITING INTERVAL
47FK ... LDX 5 6 [X5 => WAITING INTERVAL
47FQ ... LDN 0 2 [REQUEST OUTPUT EVERY TWO
47FX ... MPY 5 0 [MESSAGETIMES ... AS TAPEOPEN DOES
47G4 ... BNG 4 RESETIME [J IF FIRST TIME THROUGH
47G9 ...XLOWEST [
47GB ... BXL 4 6,TIMELEFT [CHOOSE LOWEST OF TIME LEFT
47GH ... [AND MESSAGETIME
47GN ... STO 6 AWORK4(2) [STORE MESSAGETIME IN AWORK4
47GT ... LDX 4 6 [X4 => MESSAGETIME
47H2 ... BRN TESTREV [J TO TEST REVIEW TIME
47H7 ...TIMELEFT [
47H# ... STO 4 AWORK4(2) [STORE TIME LEFT IN AWORK4
47HF ...TESTREV [
47HL ... LDX 6 CLONG3(2) [X6 => RVMESS REVIEW TIME
47HR ... BXL 4 6,XNOTIME [J IF REVIEW TIME > TIME LEFT
47HY ... SBX 4 6 [REDUCE TIME LEFT BY REVIEW
47J5 ... STO 4 AWORK4(2) [STORE TIME LEFT
47J= ... EXIT 7 0 [EXIT
47JC ...XNOTIME [
47JJ ... STOZ AWORK4(2) [SET 'OUTPUT MESSAGE WHEN
47JP ... STO 4 CLONG3(2) [CLONG3 IS ZERO' MARKER.
47JW ... EXIT 7 0 [EXIT
47K3 ...RESETIME [
47K8 ... LDX 4 6 [X4 -> WAITING INTERVAL
47K* ... BRN XLOWEST [
47KG ...ZEROIZEA [
47KM ... SMO FX2 [X2 IS CORRUPT
47KS ... STOZ AWORK4 [SET 'NO TAPES TO BE LOADED' MARKER
47K^ ... BRN ZEROIZE [
47L6 ...[
47L? ...[ ******************************************************************
47LD ...[
47LK ...[ THIS SUBROUTINE PROCESSES CLONG3 AND TAKES APPROPRIATE ACTION:-
47LQ ...[ IF CLONG3 = 0 OR 1 RVMESS SETS CLONG3 = 0,OUTPUTS THE MESSAGE ,
47LX ...[ IF AWORK4 =-1 OR IS POSITIVE THEN NO MESSAGE WILL BE OUTPUT
47M4 ...[ IF CLONG3 > 1 RVMESS EXITS
47M9 ...[
47MB ...RVMESS
47MH ... LDX 2 FX2 [RESET X2
47MN ... LDX 6 CLONG3(2) [X6 => CLONG3 (TIME INTERVAL)
47MT ... SBN 6 2 [NO MESSAGE THIS TIME IF CLONG3 > 1
47N2 ... BPZ 6 RVMESSEND [J IF NO MESSAGE
47N7 ... LDX 6 AWORK4(2) [X6 => REMAINING WAITING INTERVAL
47N# ... BNZ 6 ZEROIZE [J IF NO MESSAGE TO BE OUTPUT
47NF ... LDX 2 BOLC [X6 => START OF OLC
47NL ... LDX 6 A1(2) [X6 => NO OF TAPES IN FDT
47NR ... BZE 6 ZEROIZE [J IF FDT IS EMPTY
47NY ... SBX 7 FX1 [RELATIVIZE BECAUSE OF COORDINATION
47P5 ... DOWN DTSUBS,11 [GO DOWN TO OUTPUT MESSAGE
47P= ... ADX 7 FX1 [RESET LINK ACCUMULATOR
47PC ... LDN 2 1 [SET THE 'RECALCULATE
47PJ ... SMO FX2 [WAITING INTERVAL' FLAG
47PP ... NGS 2 AWORK4 [LOOKED AT BY RVMESSTIME AND RVMESS
47PW ...ZEROIZE [
47Q3 ... LDX 2 FX2 [X2 WAS CORRUPTED
47Q8 ... STOZ CLONG3(2) [SET CLONG3 ZERO
47Q* ...RVMESSEND [
47QG ... EXIT 7 0 [EXIT
47QM ...[
47QS ...[
47SB X1SCHEDMTX
48#2 [
48F8 ...[ ******************************************************************
48LB ...[
48RL [ IF BIT 0 OF ADUMPST WORD IN DTS BLOCK IS SET THEN DUMPER HAS
49?= [ BEEN INITIATED AND THE DTS WILL SET UP ACDOC/ADUMPTS FOR ALL
49QW [ TAPES GIVEN IN FILE FGET BLOCK
4==G [
4=Q6 [ OTHERWISE DTS WILL SEARCH DOWN OLC FOR REQUEST BLOCK THAT NEEDS
4?9Q [ ATTENTION
4?PB [
4#92 [ A REQUEST BLOCK NEEDS ATTENTION IF :
4#NL [ (1) IT HAS REACHED A TERMINAL STATE
4*8= [ (2) ADTCOUNT=0AND NOT IN A
4*MW [ TERMINAL STATE
4*QF ...[
4*T4 ...[
4*XM ...[
4B2= ...[
4B4T ...[
4B7G [
4BM6 [
4C6Q [
4C8Q ...[ ******************************************************************
4C=Q ...[
4C#Q ... STOZ CLONG3(2) [SET CLONG3 ZERO FIRST TIME AROUND
4CBQ ... STOZ AWORK4(2) [AND AWORK4
4CDQ ... BRN STARTOLCA [J TO SERVICE EVENT(S)
4CGQ ...MESSTIME [
4CJQ ... LONGSET #170,XNOEVENT [CLONG1 => DTS WAITING STYLE
4CLQ ...XNOEVENT [
4CNQ ... CALL 7 RVMESS [RVMESS PROCESSES CLONG3 WHICH IS
4CQQ ... [SET > 1 BY SUBROUTINE RVMESSTMIME
4CSQ ... [ BIFDTO IS FOUND SET FOR AN
4CWQ ... [ OR IF CLONG3 IS ALREADY >
4CYQ ... [ I.E. A MESSAGE IS TO BE OU
4D2Q ... [SET TO 0 BY COORDINATOR WHEN
4D4Q ... [ OR 1 A MESSAGE IS TO BE OUTPUT
4D6Q ... [ IN THIS CASE RVMESS OUTPUT
4D8Q ... [ AND THEN STOZ'S CLONG3
4D=Q ... BRN XLONGSTOP [NO EVENTS TO SERVICE?
4D#Q ...STARTOLCA [CHECK FOR CANTDO LOAD TAPES
4D*6 ... JBC STARTOLC,BOLC,BIFDTLMEF [J IF NO EXTANT LOADED TAPES ETC.
4D*G ... CALL 6 XFDTCHECK [CHECK FDT FOR BIFDTJL - IF SET CREAT
4D*W ... [DTA, CHAIN FDINCS, CLEAR BITS, FPUT
4DSQ ...STARTOLC [RE-COMMENCE SEARCHING DOWN OLC
4DWQ ... LONGSET #170,SETBEFORE [CLONG1 => DTS WAITING STYLE
4DY4 ...SETBEFORE [
4D^B ... STOZ AWORK1(2) [
4F2Q ... CALL 7 RVMESS [OUTPUT MESSAGE IF NECESSARY
4F5= CALL 7 XINCWORD [CHECK IF DUMPER INITIATED
4FJW LDX 3 BOLC [BASE OF OFF-LINE CHAIN
4G4G ...STEPOLC [
4GJ6 ... LDX 3 FPTR(3) [
4H3Q SOLC BXE 3 CXOL,XENDOLC [J IF END OF OLC
4HHB ... JMBS STEPOLC,3,BHAPPY,BINCUNVERR [J IF FREQ ALREADY DEALT W
4J32 ... JBS TERMST,3,BTERMST [J IF IN A TERMINAL STATE
4JGL ... LDX 6 ADTCOUNT(3) [X6 => NUMBER OF SERVICING DTAS
4LYQ BNZ 6 TESTNEG [J IF THERE IS A DTA SERVICING
4M?2 ...TESTNEGP1 [
4MK= ... LDX 4 FDTINCNUM(3) [X4=> INCREMENT NUMBER
4MXG ... LDX 6 FDTFILSTR(3) [X6 => FILESTORE NUMBER
4N9Q ... PRESINC 4,6,7 [ANY FDINCS WITH THIS INCREMENT & FIL
4NJ4 ... BZE 7 XNOINC [J IF NOT
4NL? ... STO 7 ADTCOUNT(3) [STORE FDINCS COUNT
4NNG ... CALL 7 SACT [SET CHAIN ALTERED BITS
4NQP ... BRN STEPOLC [CONTINUE DOWN OFLC
4NSY ...XNOINC [
4NX= ... LONGOFF [OPENINC MIGHT WAIT...SO CLEAR CLONG1
4NYM ... BZE 6 XHOSTFS [J IF ZERO FILESTORE NUMBER
4P24 ... BS BOLC,BIFDTAFS [SET 'ALIEN FILESTORE' BIT
4P3F ... DOWN SCHEDMTA,1 [OPEN ALIENFS.INCINDEX, ETC.
4P4W ... BRN SETUP3 [J TO HUNT FOR FRB
4P6? ... LDX 0 ACOMMUNE1(2) [X0 => STATE OF REQUEST
4P7N ... BRN XSETB [SET STATE IN FREQ BLOCKS
4P95 ...SETUP3 [
4P=G ... MHUNTW 3,FILE,FRB [X3 -> FRB
4P?X ... BRN VERIF1 [
4P*# ...XHOSTFS [
4PBW OPENINC XBR,READ [OPEN S/INCINDEX
4PWG [
4QB6 [ X4 CONTAINS INCREMENT NUMBER
4QTQ [ SEARCH FOR THIS RECORD IN S/INCINDEX
4R*B [
4RR= ... BS BOLC,BIFDTOPEN [SET THE 'INCINDEX OPEN' BIT
4S96 ... FINDREC ,AINCNOR,4,XINCLST [J IF INCREMENT NOT FOUND
4SM2 ... READAGAIN [READ INC RECORD INTO FRB
4T4W ... MHUNTW 3,FILE,FRB [
4TGQ ... JBS VERIF,3,BIAVEST [J IF INCREMENT VERIFIED
4TYL ... BSXD 0,BINCUNVERR [X0 => UNVERIFIED INC MASK
4WBG ... BRN XSETB [SET STATE IN FREQ BLOCKS
4WSB ...TESTNEG [TEST FOR NEGATIVE ADTCOUNT
4X== ... BPZ 6 STEPOLC [J IF OK
4XN6 ... STOZ ADTCOUNT(3) [MUST DEAL WITH THIS FREQ
4Y62 ... BRN TESTNEGP1 [
4YHW ...XINCLST [ INC. HAS BEEN LOST
4Y^Q ... MBSXD 0,BPERLOST,BTERMST [X0 => FILE PERM LOST MASK
4^CL ...XSETB [
4^TG ... CALL 7 XSTATE [UPDATE FREQ BLOCKS
52?B ...XCLOSE [CLOSE INCINDEX IF OPEN
52P= ... JBCC XNOCLOSE,BOLC,BIFDTOPEN [J IF INCINDEX NOT OPEN
537B CLOSETOP [CLOSE S/INCINDEX
53C8 ...[
53M2 [ AFTER CLOSING INCINDEX - NEED TO FREE FRB. THIS EXISTS IN
546L [ ALL CASES EXCEPT WHEN FINDREC FAILS TO LOCATE RECORD
54BD ...[
54G4 ...XNOCLOSE [
54KN ... VFREEW FILE,FRB [FREE INCINDEX RECORD
54P# ... VFREE FILE,FABSNB [PRESENT IN CASE OF ALIEN FILE
54SY ... BC BOLC,BIFDTAFS [CLEAR 'ALIEN FILESTORE' BIT
54YM ... BRN STARTOLCA [START SCAN AGAIN
55?4 ...[
55KG [ NO MORE REQUESTS NEED SERVICING; IF DUMPER NOT INITIATED
55XX ...[ THEN WE CHECK DOWN THE FDT FOR TAPE ENTRIES TO SERVICE,
56=# ...[ USING SUBROUTINE 'XFDTCHECK',AND THEN PUT THE DTS TO SLEEP.
56JQ [
574B XENDOLC
57J2 CALL 7 XINCWORD [CHECK IF DUMPER STARTED
57LK ... CALL 6 XFDTCHECK [CHECK FDT FOR BIFDTJL - IF SET CREAT
57P8 ... [DTA,CHAIN FDINCS,CLEAR BIT,FPUT DTA
57RR ...XLONGSTOP [
57WB ... LDX 2 FX2 [RESET X2
57Y^ ... LDX 7 CLONG3(2) [X7 => WAITING INTERVAL
583J ... BNZ 7 XLSTIME [J IF CLONG3 STILL OK
5867 ... CALL 7 RVMESSTIME [CHECK FDT FOR BIFDTO - IF SET CALCUL
588Q ... [WAITING INTERVAL AND STORE IN CLONG3
58?* ... [OTHERWISE STOZ CLONG3
58?Q ... LDEX 0 CLONG1(2) [TEST FOR MORE EVENTS
58#7 ... BZE 0 XEND [J IF MORE EVENTS
58#J ... JBCC XEND,BOLC,BIFDTCDPR [CLEAR 'FCANTDO PRESENT' BIT
58#^ ... MFREEW FILE,FCANTDO [FREE FCANTDO BLOCK
58*B ...XEND [
58*Y ... LDX 7 CLONG3(2) [X7 => WAITING INTERVAL
58DH ... BNZ 7 XLSTIME [J IF CLONG3 IS NOW OK
58H6 ... LONGSTOP XBR,MESSTIME [LONGSTOP WITHOUT A TIME INTERRUPT
58KP ... BRN STARTOLCA [J WHEN EVENT OCCURS
58N# ...XLSTIME [
58QX ... LONGSTOP XBR,MESSTIME,,,7 [LONGSTOP WITH A TIME INTERRUPT
58TG ... BRN STARTOLCA [J TO MESSTIME ON TIME INTERRUPTS
58Y5 ...[
592W [ INCREMENT DOES NOT NEED TO BE VERIFIED
59=N ...[
59GG VERIF
5=26 ... JMBS XINCLST,3,BIOBS,BINSUITRV [J IF OBSOLETE OR NOT SUITABLE
5=FQ ...VERIF1 [ENTRY FOR ALIEN TAPE
5=^B LDX 7 AMTS(3) [X7 = NO. OF TAPES
5?B4 ... BZE 7 XINCLST [J IF NO TAPES IN INCINDEX RECORD
5?QQ ... LDN 0 INCMAGLEN [X0 => LENGTH OF TAPE ENTRY
5#7D ... MPY 0 7 [X1 => LENGTH OF TAPE ENTRIES
5#J6 ... ADX 3 1 [AMAG-2(3) NOW POINTS TO LAST ENT
5#YS ... STOZ AWORK2(2) [ZEROISE AWORK2 AND AWORK1
5**G ... STOZ AWORK1(2) [
5*Q8 ... STOZ ADUMTST(2) [USED TO SAVE FDT COUNT
5B6W ...NEXTSN [LOOK AT NEXT TAPE
5BHJ ... JBS XNOTEST,BOLC,BIFDTAFS [J IF ALIEN FILESTORE TAPE
5BY= ... MBSXD 5,BMRETURN,BMUSWR,BMOPWR
5C#Y ... ANDX 5 AMAG-1(3) [MAG TAPE STATE
5CPL ... BNZ 5 THIS2 [J IF WRONGED OR RETURNED
5D6# ...XNOTEST [
5DH2 ... LDX 5 AMAG-2(3) [NEXT TSN FROM INCINDEX
5DXN ... BNG 5 THIS2 [J IF NEGATIVE TSN
5F#G [
5FS6 [ TEST IF THE TAPE IS IN FDT BLOCK
5G?Q [
5GRB ... FDTENT 2,5,THIS6 [J TO THIS6 IF TSN IS NOT IN FDT
5H?2 ...THISTSN [
5HQL ... JMBS THIS2,2,BIFDTOW,BIFDTUW [J IF WRONGED IN FDT
5HQX ... JMBAC NODTA,2,BIFDTJL,BIFDTO
5HR8 ... TRACE 5,INCTSNA
5HRF ... LDX 1 FX2
5HRQ ...NXFDINCS
5HS3 ... HUNT2 1,FILE,FDINCS
5HS# ... BXU 5 FDINCTSN(1),NXFDINCS
5HSK ...NINCF
5HSW ... LDX 2 FDINCNO(1)
5HT7 ...NINC
5HTD ... SBN 2 1
5HTP ... BNG 2 NINC1
5HW2 ... SMO 2
5HW? ... BXE 4 FDINCINC(1),NOUT
5HWJ ... SMO 2
5HWT ... BXL 4 FDINCINC(1),NINC
5HX6 ...
5HXC ...NINC1
5HXN ... LDX 0 FDINCNO(1)
5HX^ ... SBX 0 2
5HY= ... SBN 0 1
5HYH ... LDN 5 1
5HYS ... LDX 2 FDINCNO(1)
5H^5 ... SBN 2 1
5H^B ... ADS 5 FDINCNO(1)
5H^M ... BZE 0 NINC3
5H^Y ...NINC2
5J29 ... SMO 2
5J2G ... LDX 5 FDINCINC(1)
5J2R ... ADN 2 1
5J34 ... SMO 2
5J3* ... STO 5 FDINCINC(1)
5J3L ... SBN 2 2
5J3X ... BCT 0 NINC2
5J48 ...NINC3
5J4F ... ADN 2 1
5J4Q ... SMO 2
5J53 ... STO 4 FDINCINC(1)
5J5# ... TRACE 4,INCNOT
5J5K ... LDX 5 FDINCNO(1)
5J5W ... ADN 5 4 [INCREASE FDINCS BY ONE
5J67 ... LDX 4 1 [ TO LEAVE SPARE WORD
5J6D ... ALTLEN 4,5
5J6P ... BRN NOUT2
5J72 ...NODTA
5J7? ... TRACE 5,INCTSNB
5J7J ... LDX 1 FX2
5J7T ...NXTF2
5J86 ... HUNT2 1,ACTDOC,ADUMPT
5J8C ... HUNT2 1,FILE,FDINCS
5J8N ... BXU 5 FDINCTSN(1),NXTF2
5J8^ ... BRN NINCF
5J9= ...NOUT
5J9H ... TRACE 4,INCPRES
5J9S ...NOUT2
5J== ... LDN 0 1 [NOW INCREASE COUNT
5JPW ... SMO FX2 [OF ENTRIES IN FDT
5K9G ... ADS 0 ADUMTST [
5KP6 ...THIS2 [GET ANOTHER TSN FROM INCINDEX
5L8Q ... SBN 3 INCMAGLEN [X3 -> NEXT ENTRY
5LNB ... BCT 7 NEXTSN [J IF ANY TSNS LEFT
5NLW [
5P6G [ ALL TAPES IN INCINDEX HAVE BEEN EXAMINED
5PL6 ...[ ADUMTST(2) = COUNT OF TAPES IN FDT
5QKB [ TSN/STATE OF A SUITABLE UNOPENED TAPE IN AWK2/AWK3
5R52 [
5R#S ...XTSNCLA [
5RQW ... LDX 2 FX2 [
5S8Y ... LDX 0 ADUMTST(2) [X0 => COUNT OF ENTRIES IN FDT
5SM2 ... BZE 0 NONEFDT [J IF NO TAPES IN FDT
5T54 ... CALL 7 XCOUNT [STORE COUNT IN ALL RELEVANT FREQ BLO
5TH6 CALL 7 SACT [SET CHAIN ALTERED BITS IN ALL DTAS
5W2Q BRN XCLOSE [ J TO CLOSE S/INCINDEX
5W=J ...[
5WGB [ A TAPE HAS BEEN FOUND WHICH IS NOT TW OR RETURNED
5X22 [ AND IS NOT IN FDT SO STORE TSN/STATE IN AWK2/AWK3
5X9S ...[
5XFL THIS6
5XRL ... JBC XTSNOK,BOLC,BIFDTCDPR [J IF NO CANTDO LOADED TAPES
5Y5L ... MHUNTW 1,FILE,FCANTDO [FIND THE FCANTDO BLOCK
5Y7S ... LDX 2 A1(1) [X2 => COUNT OF TAPES
5Y8X ... BZE 2 XTSNOK [J IF NO TAPES IN FCANT
5Y=2 ...XTLOOP [
5Y=* ... BC BOLC,BIFDTAW [CLEAR 'ALIEN TAPE WRONGED OR INSECUR
5Y=N ... MHUNTW 1,FILE,FCANTDO [X1 -> FCANTDO...SHORT OF ACCUMULATOR
5Y?5 ... SMO 2 [
5Y?L ... LDXC 1 A1(1) [X1 => TSN IN FCANTDO
5Y#7 ... BCC XHOST [J IF NOT WRONGED ALIEN TAPE
5Y#N ... BS BOLC,BIFDTAW [SET 'ALIEN TAPE WRONGED OR INSECURE'
5Y*9 ...XHOST [
5Y*Q ... BXE 5 1,XTSNCL [J IF TAPE NOT TO BE USED
5YB? ... BCT 2 XTLOOP [LOOK AT NEXT ENTRY
5YBS ...XTSNOK [
5YCF ... LDX 2 FX2 [RESET X2
5^59 ... LDX 1 AMAG-1(3) [X1 => STATE OF TAPE
5^73 ... LDX 0 AWORK2(2)
5^8T ... BZE 0 XTSNOKA [NO TAPE YET SELECTED
5^=M ... BBS 7,1,THIS2 [TO BE TAPEWRONGED
5^#F ...XTSNOKA
5^B? ... STO 5 AWORK2(2) [TSN OF UNOPENED TAPE
5^D6 STO 1 AWORK3(2) [STATE OF THIS TAPE
5^PG ... BRN THIS2 [LOOK AT NEXT TAPE ENTRY
622W ...XTSNCL [THIS TAPE CANTDO LOADED
624D ... JBS THIS2,BOLC,BIFDTAW [J IF WRONGED OR INSECURE ALIEN TAPE
6262 ... SMO FX2 [
6296 ... STO 5 AWORK1 [STORE CANTDO TSN IN AWORK1
62*C ... BRN THIS2 [
62FP ...NONEFDT [
62M8 ... LDX 2 FX2 [RESET X2....BUG 3744
62RF ... LDX 0 AWORK2(2) [X0 => TSN
62XQ ... BNZ 0 TAPEIN [J IF A TAPE FOUND
6343 ... LDX 5 AWORK1(2) [CANTDO LOADED TAPE??
638# ... JBC NOTAPE,BOLC,BIFDTCDPR [J IF NO AVAILABLE TAPE
63#K ... BZE 5 NOTAPE [ DITTO
63DW ... MHUNTW 1,FILE,FCANTDO [REMOVE THIS TSN FROM FCANTDO BLOCK
63FD ... LDX 2 A1(1) [IT MUST BE LOADED OR WRONGED
63G2 ... BZE 2 NOTAPE [J IF NO ENTRIES
63GJ ... SBN 2 1 [REDUCE COUNT
63H6 ... BNZ 2 NOTFREE [J IF MORE THAN ON E ENTRY
63HN ... FREECORE 1 [FREE FCANTDO BLOCK
63JH ... BC BOLC,BIFDTCDPR [CLEAR 'FCANTDO PRESENT' BIT
63KB ... BRN XCLOSE [RESTART SCAN...FIRST CLOSE INCINDEX
63KY ...NOTFREE [
63LG ... ADN 2 1 [RESET X2
63M4 ...XTLOOPY [
63ML ... SMO 2 [
63N8 ... BXU 5 A1(1),XTSNOTF [J IF NOT THIS TAPE
63NQ ... SMO 2 [
63P# ... STOZ A1(1) [SET THIS ENTRY ZERO
63RJ ... BRN XCLOSE [RESTART SCAN...FIRST CLOSE INCINDEX
63S6 ...XTSNOTF [
63SN ... BCT 2 XTLOOPY [LOOK AT NEXT TAPE
63T= ...NOTAPE [NO TAPES AVAILABLE
63W= [
64*W [ THERE ARE NO TAPES ALREADY UP WHICH COULD SERVICE THIS REQUEST
64TG ...[ AND THERE ARE NO TAPES IN INCINDEX WHICH COULD BE USED;
65*6 ...[ THAT IS ALL THE TAPES IN INCINDEX RECORD ARE WRONGED OR RETURNED.
66S2 [ IN THIS CASE ALL REQUESTS FOR FILES ON THIS INCREMENT WILL BE
676C ...[ MARKED AS TEMPORARILY LOST.
67DS ...[
67R9 ... MBSXD 0,BTEMLOST,BTERMST [X0 => TEMPORARILY LOST MASK
685L ... BRN XSETB [UPDATE FREQ BLOCKS
68D3 ...[
68QG [ REQUIRED TO SET UP A DUMP TAPE ACTIVITY FOR TAPE GIVEN IN
69=6 [ AWORK2( STATE IN AWORK3)
69PQ [
6=9B TAPEIN
6=BJ ... JBC TAPEIN1,BOLC,BIFDTAFS [J IF TAPE NOT ALIEN
6=HQ ... DOWN SCHEDMTA,2 [ SET UP A FDINCS BLOCK FOR ALIEN TAP
6=NY ... BRN TAPEIN2 [J IF OK
6=W6 ... LDX 0 ACOMMUNE1(2) [X0 => STATE OF REQUEST
6?3# ... BRN XSETB [SET STATE IN FREQ BLOCKS
6?8G ...TAPEIN1 [
6?*N ... DOWN DTSUBS,8 [ SET UP A FDINCS BLOCK FOR HOST TAPE
6?GW ...TAPEIN2 [
6?N= CALL 7 XTAPEP [ INCREMENT ADTCOUNT IN ALL FREQS
6#7W [ WHOSE INC. NOS LIE WITHIN THE
6#MG [ RANGE OF INCS IN FDINCS
6#NN ... DOWN DTSUBSS,16
6#PW ... [BIFDTO,LENGTHEN FDT BY 4 WORDS,
6#QS ... [ALSO INSERT FILESTORE NUMBER - IN X6
6#RS ... LDX 2 FX2 [RESET X2
6#T= ... LDX 6 CLONG3(2) [X6 => REMAINING MESSAGETIME ..IF AN
6#WN ... BNZ 6 TSNOPEN [J IF MESSAGETIME OK
6#Y6 ... LDX 6 AWORK4(2) [X6 => REMAINING WAITING INTERVAL
6#^J ... BNZ 6 TSNOPEN [J IF MESSAGETIME DEALT WITH OR IS ST
6*32 ... LDN 6 1 [SET THE 'RECALCULATE WAITING INTERVA
6*4D ... NGS 6 AWORK4(2) [MARKER .... LOOKED AT BY RVMESSTIME
6*5W ...TSNOPEN [NOW ASK FOR TAPE USING TAPEOPEN (INF
6*7# ... LDX 6 AWORK2(2) [X6 = TSN
6*7M ... CALL 7 XFDTENT [X3 -> FDT ENTRY
6*82 ... CALL 7 SKIPERR [ENTRY DISSAPPEARED
6*8* ... JBC XHOSTOPEN,BOLC,BIFDTAFS [J IF HOST TAPE
6*8N ... DOWN SCHEDMTA,3 [GO DOWN TO OPEN TAPE
6*93 ... BRN TOTESTRY [J IF TAPEOPEN OK
6*9B ... BRN TOTESTRY1 [J IF ALIEN TAPE INSECURE (REPLY OPWR
6*9P ...XHOSTOPEN [
6*=8 ... JBS TONULL,3,BIFDTNW [J IF NO WPR REQUIRED
6*?L ... TAPEOPEN XBR,6,WRITE,DUMPER,INFORM,NOTOL,REPLY
6**4 ... BRN TOTESTRY [
6*BG ...TONULL [
6*CY ... TAPEOPEN XBR,6,,DUMPER,INFORM,NOTOL,REPLY
6*FB ...TOTESTRY [NOW TEST REPLYS
6*GS ... MFREEW CPAR,GPERCON [DON'T NEED THIS BLOCK
6*HH ...TOTESTRY1 [
6*J= ... CALL 7 XFDTENT [REFIND FDT ENTRY
6*KN ... CALL 7 SKIPERR [ENTRY DISSAPPEARED...HELP
6*QF ... TESTREP2 INFORM,XINFORM,OK,TRELEASE,NOTOWN,TRELEASE,QUERY,TRELEASE
6*SB ... TESTREP2 HDDRDIS,TRELEASE,OPWRONG,XOPWRONG,USWRONG,XUSWRONG
6*W# ... BRN XINFORM [NOT INTERESTED IN ANY OTHER REPLYS
6*XQ ...TRELEASE [
6*^8 ... BC 3,BIFDTO [CLEAR 'TO BE OPENED' BIT
6B2L ... BS 3,BIFDTJL [SET 'JUST LOADED' BIT
6B3* ... BS BOLC,BIFDTLMEF [SET 'LOOK AT FDT FIRST' BIT
6B44 ... BRN XINFORM [
6B95 ...XOPWRONG [OPERATOR WRONGED
6BB6 ... BS 3,BIFDTOW [SET THE OPERATOR WRONGED BIT IN FDT
6BCJ ... BRN XINFORM [
6BF2 ...XUSWRONG [USER WRONGED
6BGD ... BS 3,BIFDTUW [SET USER WRONGED BIT IN FDT
6BHW ...XINFORM [TAPEOPEN (INFORM) OK
6BL2 BRN XCLOSE [CLOSE INCINDEX BEFORE
6C5L [STARTING FRESH LOOP
6CK= ...SKIPERR [
6D4W GEOERR 1,SHMTSKIP [GENERAL CODING ERRORS
6DJG [
8=8= ...[
8=MW ...TERMST [
8?7G ... DOWN DTSUBSS,15
8?M6 ... BRN STARTOLC
9F== [
9FPW XBR GEOERR 1,SYSBRKIN [BREAK IN ON SYSTEM ISSUED OPEN
9G9G MENDAREA 100,K99SCHEDMTX
9GP6 #END
9H8Q
^^^^ ...03423471000100000000