{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SCHEDULE867)}}
====== SCHEDULE867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLENGD|ALTLENGD]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CHNUMCO1|CHNUMCO1]], [[george:macro:CHNUMCOD|CHNUMCOD]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:ICT|ICT]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:MBS|MBS]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:PARAFREE|PARAFREE]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:PARANUMB|PARANUMB]], [[george:macro:PARAPASS|PARAPASS]], [[george:macro:POP|POP]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SHLSQ|SHLSQ]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:SPARANOX|SPARANOX]], [[george:macro:SPRIVJUMP|SPRIVJUMP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:TRACE|TRACE]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VOP|VOP]], [[george:macro:WRONG|WRONG]]
22FL ...#LIS K0SCHEDULE>K0HLS>K0COMMAND>K0GREATGEO>K0ALLGEO
22^= ...#SEG SCHEDULE60 [RICHARD GRIMWADE
23DW ... 8HSCHEDULE
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23SK ...[
23YG #
24D6 ...# THIS COMMAND INFORMS THE HLS SUBJECT PROGRAM
24XQ ...# OF THE OPERATOR JOB SCHEDULING REQUIREMENTS
25CB # TO DO THIS IT PUTS AN ENTRY FOR THE JOB ON THE TEMP HLSQ
25X2 #
26BL ... SEGENTRY K1SCHEDULE,XK1
26P2 ... SEGENTRY K2SCHEDULE,XK2
26SG ... SEGENTRY K3SCHEDULE,XK3
26W= #
26X3 ... BITDEFS AWORK3,6,SCOM
26X8 ...#UNS ICT
26X9 ... BITDEFS AWORK3,12,XAP
26XH ... BITDEFS AWORK3,14,XCP,XMP
26XS ... BITDEFS AWORK3,16,XCC,XST,XEP
26Y# ... BITDEFS AWORK3,20,XGP,XGB,XGR,XGQ
26YK ... BITDEFS AWORK4,0,NUM,OPENJL,USER,XME,NULL,WELL,OPENUSER
26YT ... BITDEFS AWORK4,7,XBACK,POPPED
26^B ...[
2727 ...[
272Y ...#DEF TABSIZE=7
2735 ...TABLE +7,8HGRBREAK ,+2,2HGB,#4,#5540
2736 ... +7,8HGRRERUN ,+2,2HGN,#2,#5540
2737 ... +7,8HGRQUERY ,+2,2HGQ,#1,#5540
2738 ... +8,8HGRRUNDUM,+2,2HGP,#10,#5540
2739 ... +7,8HEXPRESS ,+2,2HEP,#40,#17
273= ... +5,8HSTART ,+2,2HST,#100,#217
273? ...XCPR +7,8HCOREPRI ,+2,2HCP,#1000,#17
273# ...XMPR +7,8HMILLPRI ,+2,2HMP,#400,#17
275? ... +6,8HCANCEL ,+2,2HCC,#200,#100
2764 ...XMES +7,8HMESSAGE ,+2,2HME,#20,+0
276# ...#UNS ICT
276J ...XAPR +6,8HACTPRI ,2,2HAP,#4000,#17
276T ...#DEF TABENTS=0?-TABLE/TABSIZE
277L ...[
278C ...#DEF SIZELIST=10
2798 ...XJOBLIST +SIZELIST
279^ ... 12H
27=Q ... 12HJOBLIST
27## ... +1
27*5 ... +1
27*F ... 4H****
27*W STRING +1
27TG 4H:
28*6 TWO +2
28FJ ...[
28G2 ...SPARA SBX 7 FX1
28GD ... SPARANOX 4
28GW ... ADX 7 FX1
28H# ... EXIT 7 0
28K4 ...[
28L2 ...[ START OF MAIN CODE
28N9 ...[
28QD ...[
28SQ XK1
294J ... STOZ AWORK1(2)
29#B ... STOZ AWORK3(2) [ HLSYONQ WORD
29S2 ... STOZ AWORK4(2) [ VARIOUS MARKERS
2=3S ... BS 2,SCOM
2=?L ... LDN 3 STRING(1)
2=R= ... CALL 7 SPARABEG
2?=W ... BRN XJONO
2?QG ... CHEKLFN2 XJONOF,NLFN [J TO XJONO IF NO USERNAME
2#=6 [AND TO NLFN IF NOT L.F.N.FORMAT
2#PQ LDX 4 JPARNUM(3) [GET PARAM NO.
2*9B LDN 5 3
2*P2 TXL 4 5
2B8L BCC NUNA [J IF NOT 1ST OR 2ND PARAM
2BN= LDN 5 1
2C7W TXU 4 TWO(1)
2CMG BCC X1 [J IF USERNAME IS 2ND PARAM
2D76 LDN 5 2
2DLQ X1 SPARANOX 5 [GET JOBNAME PARAMETER
2F6B CHEKLFN2 NJBNA,NLFN [J TO NJBNA IF NO JOBNAME AND
2FL2 [ TO NLFN IF FORMAT ERROR
2G5L ... CALL 7 SNAMES
2GK= ... CALL 6 SRNAM
2H4W ... STO 4 AWORK1(2)
2HJG ... BS 2,USER
2STB #
2T*2 # RETURNS WITH JOBNUMBER IN X4
2TSL #
2TT7 ...OTHERS
2TTN ... LDN 5 TABENTS [ NO OF ENTRIES
2TW9 ... LDN 6 TABLE [ TABLE START
2TWQ ...NEXT LDN 4 2 [ TWO IDENTS PER ENTRY
2TX5 ... SMO 6
2TXD ... LDN 3 0(1) [ CURRENT ENTRY
2TXS ...XL CALL 7 SPARABEG [ LOOK FOR IDENT
2TY* ... BRN NOT [ J IF NOT FOUND
2TYW ... SMO 6 [ CHECK FOR ME PARAM
2T^C ... LDX 7 5(1) [ AS HANDLED DIFFERENTLY
2T^Y ... TXU 7 XMES+5(1)
2W2F ... BCC XPLUS
2W2J ... BXE 7 XCPR+5(1),PRIORITY
2W2K ... BXE 7 XMPR+5(1),PRIORITY
2W2L ...#UNS ICT
2W2M ...(
2W2P ... BXE 7 XAPR+5(1),XACTPRI
2W2Q ...)
2W35 ... FREECORE 3
2W36 ...XM ORX 7 AWORK3(2)
2W44 ... STO 7 AWORK3(2)
2W4K ... SMO 6 [ CHECK FOR VALIF COMBINATION
2W56 ... ANDX 7 6(1)
2W5M ... BNZ 7 WRONG [ J IF NOT ALLOWED
2W68 ... BRN MORE [ OK SO LOOK FOR NEXT PARAM
2W6H ...NOT SMO 6 [ TRY SHORT FORM
2W6W ... LDN 3 3(1)
2W7= ... BCT 4 XL [ IF NOT TESTED FOR ALREADY
2W7R ...MORE ADN 6 TABSIZE [ NEXT ENTRY IN TABLE
2W8# ... BCT 5 NEXT [ J IF NOT END OF TABLE
2W8T ... BRN SDUN [ FINISHED
2W8Y ...[ STORE MP/CP IN ADATA/CSTORE
2W8^ ...PRIORITY
2W92 ... LDN 4 1 [COUNT OF CP/MP PARAMETERS
2W93 ... LDX 0 ANUM(3)
2W94 ... BZE 0 NOT3 [J IF NULL PRIORITY
2W95 ... LDCH 0 APARA(3)
2W96 ... SBN 0 #30
2W97 ... BNZ 0 PR52 [J IF NOT OF FORM X(Y)
2W98 ... BXE 7 XCPR+5(1),NOT3 [ERROR IF CORE PRIORITY
2W99 ... LDX 4 JPARNUM(3)
2W9= ... PARALYSE ,,4
2W9? ... TESTREP2 UNPAIR,UNPAIR
2W9# ... PARANUMB 4
2W9* ... SBN 4 2
2W9B ... BNZ 4 NOT3 [ERROR IF NOT 2 PARAMETERS
2W9C ... LDN 4 2
2W9D ... PARALYSE #34,,4 [REMOVE BRACKETS FROM (Y)
2W9F ... PARANUMB 4
2W9G ... SBN 4 5
2W9H ... BPZ 4 NOT3 [ERROR IF> 4MILL PRIORITIES
2W9J ... ADN 4 5
2W9K ... MFREE CPB,CUNI
2W9L ...PR5 PARAPASS
2W9M ...PR52 MHUNT 2,CPB,CUNI
2W9N ... NGX 0 ANUM(2)
2W9P ... BPZ 0 NULLPRI [J IF NULL PRIORITY
2W9Q ... CHNUMCO1 1
2W9R ... TESTREP2 CHNUMERR,VNUMERR [ERROR IF PRIORITY NOT NUMERIC
2W9S ... LDX 0 ACOMMUNE1(2)
2W9T ... SBN 0 1
2W9W ... BNG 0 XERANGE [ERROR IF PRIORITY OUT OF RANGE
2W9X ... SBN 0 63
2W9Y ... BPZ 0 XERANGE [ERROR IF PRIORITY OUT OF RANGE
2W9^ ...PR7 HUNT 2,ADATA,ASUP
2W=2 ... BPZ 2 PR8 [J IF NOT FIRST CP/MP
2W=3 ...#UNS ICT
2W=4 ...#SKIP
2W=5 ...(
2W=6 ... MHUNT 3,CPB,CUNI
2W=7 ... NAME 3,ADATA,ASUP [SET UP BLOCK TO HOLD....
2W=8 ... ALTLENGD 3,2 [...CP AND MP
2W=9 ... LDX 2 3
2W== ... STOZ A1(2) [INITIALISE MP
2W=? ... STOZ A1+1(2) [INITIALISE CP
2W=# ...)
2W=* ...#UNS ICT
2W=B ... CALL 6 SRASUP [SET UP & INITIALISE ASUP BLOCK
2W=C ...[ TO HOLD CP$MP$AP
2W=D ... BRN PR83
2W=F ...PR8 LDX 6 2
2W=G ... MFREE CPB,CUNI
2W=H ... LDX 2 6
2W=J ...PR83 SMO FX2
2W=K ... LDX 0 ACOMMUNE1
2W=L ... BXE 7 XCPR+5(1),PR87 [J IF CP
2W=M ... SRL 3 22 [SET X3=0 IF 1ST MP......
2W=N ... SRC 3 2 [...OTHERWISE LEAVE CHAR. MOD
2W=P ... ADX 3 2
2W=Q ... DCH 0 A1(3) [SAVE MP IN ADATA/CSTORE
2W=R ... BCHX 3 £
2W=S ... SBX 3 2 [X3 IS PTR TO MP IN ADATA/CSTORE
2W=T ... LDN 6 XMPR
2W=W ... BRN PR9
2W=X ...PR87 STO 0 A1+1(2) [SAVE CP IN ADATA/CSTORE
2W=Y ... LDN 6 XCPR
2W=^ ...PR9 BCT 4 PR5
2W?2 ... LDX 2 FX2
2W?3 ... BRN XM
2W?4 ...NULLPRI
2W?5 ... SMO FX2
2W?6 ... STOZ ACOMMUNE1
2W?7 ... BRN PR7
2W?9 ...#UNS ICT
2W?= ...(
2W?? ...# VALIDATE ACTPRI PARAMETER
2W?# ...#
2W?* ...XACTPRI
2W?B ... JBS XAP0,,ICTSW [DO NOT PROCESS ANY ACTPRI UNLESS
2W?C ... FREECORE 3 [ICTSW IS SET
2W?D ... BRN MORE
2W?F ...XAP0
2W?G ... LDX 0 ANUM(3)
2W?H ... BZE 0 VNUMERR [ 'NOT NUMERIC' ERROR
2W?J ... CHNUMCO1 1
2W?K ... TESTREP2 CHNUMERR,VNUMERR [ 'NOT NUMERIC' ERROR
2W?L ... LDX 0 ACOMMUNE1(2) [ PICK UP VALUE OF PARAM
2W?M ... SBN 0 1 [ - MUST BE BETWENN 1 AND 3
2W?N ... BNG 0 XERANGE [ 'OUT OF RANGE' ERROR
2W?P ... SBN 0 3
2W?Q ... BPZ 0 XERANGE [ 'OUT OF RANGE' ERROR
2W?R ... HUNT 2,ADATA,ASUP
2W?S ... BPZ 2 XAP1 [ J IF NOT 1ST CP/MP/AP
2W?T ... CALL 6 SRASUP [SET UP AND INITIALISE ASUP BLOCK
2W?W ...#
2W?X ... [TO HOLD CP/MP/AP
2W?Y ...[
2W?^ ... BRN XAP2
2W#2 ...XAP1 LDX 6 2
2W#3 ... MFREE CPB,CUNI
2W#4 ... LDX 2 6
2W#5 ...XAP2 SMO FX2
2W#6 ... LDX 0 ACOMMUNE1
2W#7 ... SRC 0 8
2W#8 ... STO 0 A1+2(2) [SAVE AP IN ADATA/ASUP
2W#9 ... LDX 2 FX2
2W#= ... LDN 6 XAPR
2W#? ... BRN XM [RETURN TO PARAMETER VALIDATION LO
2W## ...)
2W#* ...[
2W#B ...[ VALIDATE MESSAGE PARAM
2W#C ...[
2W#D ...XPLUS MHUNT 3,CPB,CUNI
2W#F ... LDX 0 ANUM(3)
2W#G ... SRL 0 12 [ CHECK IF TYPE 2
2W#J ... SBN 0 2 [ CHECK FOR TYPE 2
2W*L ... LDX 4 JPARNUM(3) [ SPLIT OUT MESSAGE
2W*W ... BNZ 0 NOT2
2WB7 ... FREECORE 3
2WBG ... LDN 3 2
2WBT ...PLYSE PARALYSE ,,4
2WC9 ... LDN 4 2
2WCC ... BCT 3 PLYSE
2WCK ... LDN 4 1
2WCR ... CALL 7 SPARA
2WC^ ... PARAFREE
2WD? ... BS 2,XME
2WDD ... MHUNT 3,CPB,CUNI
2WDK ... NAME 3,ADATA,CSTORE
2WDS ... BRN NEXT
38BL ...#
38G7 ...SDUN
38KN ...#
38P9 ...# THE REST OF THE SCHEDULE COMMAND IS DEALT WITH IN AN OVERFLOW
38SQ ...# SEGMENT.
38Y? ...#
393S ... ACROSS JWELLONE,4 [GO TO DEAL WITH REST OF COMMAND
397* ...#
39=W ...XK2 [RE-ENTRY POINT FROM 'JWELLONE'
39BC ...#
39HL THEND
39MH ... LDX 2 FX2
39RD ... JBS SNUL,2,NULL
39X* ...TENDCOM
3=3= ENDCOM
3=3G ...[
3=3Q ...SNUL MONOUT ASCMESS
3=42 ... BRN TENDCOM
3=43 ...#UNS ICT
3=44 ...(
3=45 ...# SR TO SET UP ADATA/ASUP BLOCK
3=46 ...#
3=47 ...SRASUP
3=48 ... SBX 6 FX1
3=49 ... MHUNT 3,CPB,CUNI
3=4= ... NAME 3,ADATA,ASUP
3=4? ... ALTLENGD 3,3
3=4# ... LDX 2 3
3=4* ... STOZ A1(2)
3=4B ... STOZ A1+1(2)
3=4C ... STOZ A1+2(2)
3=4D ... ADX 6 FX1
3=4F ... EXIT 6 0
3=4G ...)
3=4H ...[
3=4J ...[
3=4Q ...SPARABEG [ OBTAIN SPECIFIED PARAM
3=52 ... SBX 7 FX1 [ LINK
3=5= ... SPARABEG 1,0(3),,,0 [ GET PARAM IF EXISTS
3=5G ... ADX 7 FX1 [ RESTORE LINK
3=5Q ... MHUNT 3,CPB,CUNI
3=62 ... LDX 0 ANUM(3) [ SEE IF EXISTS
3=6= ... BNG 0 SPOUT [ J IF NOT
3=6G ... EXIT 7 1
3=6Q ...[
3=72 ...SPOUT FREECORE 3 [ FREE CPB/CUNI
3=7= ... EXIT 7 0
3=7G ...[
3=7Q ...[
3=82 ...[
3=8= ...POP SBX 5 FX1
3=8C ...
3=8J ...POPC POP POPC,,JWACCESS
3=8K ...POPX
3=8L ... BS 2,POPPED
3=8M ... ADX 5 FX1
3=92 ... EXIT 5 0
3=9= ...[
3=9G ...VOPCLOS
3=9Q ... SBX 5 FX1
3=9W ... LDX 2 FX2 [X2 SOMETIMES CORRUPT ON ENTRY!!
3==2 ... JMBAC PEX,2,OPENJL,OPENUSER
3=== ... CLOSETOP
3==G ...PEX ADX 5 FX1
3==M ...VOP JBCC (5),2,POPPED
3==S ... VOP ,JWACCESS
3=?2 ... EXIT 5 0
3=?= ...[
3=?G ...[
3=?Q ...[
3=#2 ...SNAMES
3=#= ... HUNT 3,CPB,CUNI
3=#G ... LDX 4 ACES [LOAD SPACES
3=#Q ... STO 4 ACOMMUNE1(2)
3=*2 ... LDN 4 ACOMMUNE1(2)
3=*= ... LDN 5 ACOMMUNE2(2) [ SPACEFILL ACOMMUNE
3=*G ... MOVE 4 5 [ AREA
3=*Q ... LDEX 0 ANUM(3) [NO. CHARS IN JOBNAME
3=B2 ... LDN 4 APARA(3) [PTR TO JOBNAME
3=B= ... LDN 5 ACOMMUNE1(2)
3=BG ... SMO 0
3=BQ ... MVCH 4 0 [MOVE IN JOBNAME
3=C2 ... STO 0 AWORK1(2) [SAVE COUNT OF JOBNAME CHARS
3=C= ... HUNT2 3,CPB,CUNI [FIND /CUNI CONTAINING USERNAME
3=CG ... LDEX 0 ANUM(3)
3=CQ ... LDN 4 APARA(3)
3=D2 ... LDN 5 ACOMMUNE4(2)
3=D= ... SMO 0
3=DG ... MVCH 4 0 [MOVE USERNAME INTO ACOM. AREA
3=DQ ... STO 0 AWORK2(2)
3=F2 ... EXIT 7 0
3=GW #
3?2G # THIS PATH IS ENTERED WHEN THERE IS NO USERNAME PARAM. , AND THEREFORE
3?G6 # A JOBNUMBER PARAMETER IS ASSUMED
3?^Q #
3#9J ...XJONOF
3#FB ... FREECORE 3
3#P8 ...XJONO
3#^2 PARAPASS [GET JOBNO. PARAM
3*DL MHUNT 3,CPB,CUNI
3*Y= NGX 4 ANUM(3)
3BCW BPZ 4 NJBNO [JOBNO. PARAM MISSING
3BXG CHNUMCOD 1,3 [CONVERT NO. TO BINARY
3CC6 TESTREP CHNUMERR,NUMERR [TO REPORT NUMBER ERROR
3CLY ... BS 2,NUM
3CWQ LDX 4 ACOMMUNE1(2)
3DBB #SKI K6ALLGEO>99-99
3DW2 TRACE 4,*JOBNO**
3F*L BZE 4 NOTVAL [ JOBNUMBER MUST BE NON-ZERO
3FT= BNG 4 NOTVAL [ AND +VE.
3G54 ... CALL 5 POP
3G#W CALL 6 SRNUM [ S/R TO CHECK IF JOB EXISTS
3GSG ... STO 4 AWORK1(2)
3H#6 ... BRN OTHERS
3J?B #
3JR2 # THE FOLLOWING S/R CHECKS FOR THE EXISTENCE OF JOB , GIVEN
3K=L # THE JOBNUMBER
3KQ= #
3L4M ...SRNUM SBX 6 FX1
3LC4 ... JOBLOCK 4,3
3LPG BNG 3 SRNUM1 [J IF NO JOBBLOCK
3M96 SPRIVJUMP JSISSUE,3,SYS [J IF SYSTEM ISSUED
3MNQ SRNUM2
3MYJ ... ADX 6 FX1
3N8B EXIT 6 0
3NN2 SRNUM1
3NRF ... SHLSQ 4,3,NONEX [SEARCH HLSQ FOR JOB ENTRY
3NT8 ... BRN SRNUM2
3NWY ...[
3P2C ...[
3P2W ...[ USE SUPPLEMENTARY MODE 'QUERY' TO PREVENT
3P3* ...[ GEOERR IF FILE ALREADY OPEN TO JOB - B1511
3P3S ...[ 04.03.82
3P4? ...NONEX OPENSYS (GEOERR),JOBLIST,GENERAL,QUERY
3P4Q ...[ TEST REPLY
3P59 ... TESTREP OK,OPENOK
3P5N ... TESTREP CLUDGE,XNOJL
3P67 ...[ THE FOLLOWING 'TESTREP' CAN BE REMOVED WHEN
3P6L ...[ 'OPENSYS' IS CORRECTED TO REPLY WITH 'CLUDGE'
3P75 ...[ INSTEAD OF 'NAME' WHEN DIRECTORY IS OPEN TO JOB
3P7J ... TESTREP NAME,XNOJL
3P83 ... GEOERR 1,SCNOJL [ UNEXPECTED REPLY
3P8G ...OPENOK
3P9* ... BS 2,OPENJL
3P#S ... GETJOB 4,SYSTEM
3PD? ... TESTRPN2 OK,NONX
3PHQ ... MBS 2,OPENJL,WELL
3PM= BRN SRNUM2 [J IF FOUND
3Q6W #
3QLG # THE FOLLOWING S/R CHECKS FOR THE EXISTENCE OF JOB, GIVEN
3R66 # THE JOBNAME AND USERNAME
3RKQ #
3S5B SRNAM LDN 3 BJOBQ
3S9? ... SBX 6 FX1
3S*8 ... CALL 5 POP
3SF5 ... ADX 6 FX1
3SK2 SRNAM2
3T4L LDX 3 FPTR(3)
3TJ= TXU 3 CXJO
3W3W BCC SRNAM1 [J IF END OF Q FOUND
3WHG LDN 0 3
3X36 SRNAM3
3XGQ SMO 0
3Y2B LDX 4 JNAME-1(3)
3YG2 SMO 0
3Y^L TXU 4 ACOMMUNE1-1(2)
3^F= BCS SRNAM2 [J IF NO MATCH
3^YW BCT 0 SRNAM3
42DG LDN 0 3
42Y6 SRNAM4
43CQ SMO 0
43XB LDX 4 JUSER-1(3)
44C2 SMO 0
44WL TXU 4 ACOMMUNE4-1(2)
45B= BCS SRNAM2 [J IF NO MATCH
45TW BCT 0 SRNAM4
46*G SPRIVJUMP JSISSUE,3,SYS [J IF SYSTEM ISSUED
46T6 LDX 4 JOBNUM(3) [BLOCK FOUND - LOAD JOBNUMBER
47#Q EXIT 6 0
47SB #
48#2 # THE FOLLOWING IS THE SEARCH DOWN THE HLSQ
48RL #
49?= SRNAM1
49QW LDN 3 BHLSQ
4==G SRNAM5
4=Q6 LDX 3 FPTR(3)
4?9Q TXU 3 CXHL
4?PB ... BCC NOJOB [J IF JOB NON EXISTENT
4#92 LDN 0 3
4#NL SRNAM6
4*8= SMO 0
4*MW LDX 4 HLSJNAM-1(3)
4B7G SMO 0
4BM6 TXU 4 ACOMMUNE1-1(2)
4C6Q BCS SRNAM5 [J IF NO MATCH
4CLB BCT 0 SRNAM6
4D62 LDN 0 3
4DKL SRNAM7
4F5= SMO 0
4FJW LDX 4 HLSUNAM-1(3)
4G4G SMO 0
4GJ6 TXU 4 ACOMMUNE4-1(2)
4H3Q BCS SRNAM5 [J IF NO MATCH
4HHB BCT 0 SRNAM7
4J32 LDX 4 HLSJONO(3) [GET JOBNUMBER
4JGL EXIT 6 0
4KH8 ...[
4KHT ...NOJOB
4KJG ... SBX 6 FX1
4KK7 ... SETNCORE SIZELIST,3,FILE,FABSNB
4KKS ... LDN 5 A1(3)
4KLF ... LDN 4 XJOBLIST(1)
4KM6 ... MOVE 4 SIZELIST
4KM# ... JBC NOJOB1,2,OPENJL
4KMB ... STEPAGAIN
4KMD ... LDN 4 JLUSER(3)
4KMG ... BRN NOJOB2
4KMJ ...NOJOB1
4KMR ... CALL 7 SNAMES
4KN2 ... LDN 4 ACOMMUNE4(2)
4KN9 ...NOJOB2
4KND ... HUNT 3,FILE,FABSNB
4KP5 ... LDN 5 A1+1(3)
4KQC ... MOVE 4 3
4KQH ... USEROPEN XBRK,GENERAL,UNTRAP,FROZEN
4KRF ...[ TEST FOR CLUDGE - B2032
4KRJ ... TESTREP OK,OPENUSEROK
4KRM ... TESTREP CLUDGE,XNOJL [ FILE ALREADY OPEN TO JOB
4KRQ ... BRN NONX
4KRT ...OPENUSEROK
4KS3 ... MBS 2,WELL,OPENUSER
4KS6 ... JBC NOJOB3,2,OPENJL
4KS7 ... STEPAGAIN 1
4KS8 ... LDN 4 JLJOBNAME(3)
4KS9 ... BRN NOJOB4
4KS= ...NOJOB3
4KSB ... CALL 7 SNAMES
4KT3 ... LDN 4 ACOMMUNE1(2)
4KT* ...NOJOB4
4KTN ... GETJOB 4,USER
4KW* ... TESTRPN2 OK,NONX
4KWJ ... STEPAGAIN
4KWR ... LDX 4 JLJOBNO(3)
4KX2 ... ADX 6 FX1
4KY# ... EXIT 6 0
4KYF ...[
4KYL ...[
4KYR ...SYS CALL 5 VOPCLOS
4KYY ... MONOUT EXSYS
4K^5 ... BRN THEND
4K^= ...[
4K^G #
4LF6 # THE FOLLOWING IS THE ERROR REPORTING ROUTINE
4LYQ #
4M#F ...NONX
4MN8 ... LDX 6 Y1(1) [JOB NON EXISTENT
4N3X ... BRN RCLOS
4NCL NLFN LDX 6 Y2(1) [NOT LFN FORMAT
4NX= BRN RERR
4PBW NUNA LDX 7 Y3(1) [USERNAME PARAM MISSING
4PWG BRN RER1
4QB6 NJBNA
4QTQ LDX 7 Y4(1) [JOBNAME PARAM MISSING
4R*B RER1 LDX 6 Y5(1)
4RT2 BRN RER2
4S#L NJBNO FREECORE 3 [FREE /CUNI
4SS= BNZ 4 X3
4T?W ... BS 2,NULL
4TRG ... BRN OTHERS
4^8W X3
4^NG LDX 6 Y5(1)
5286 BRN RERR
52MQ NUMERR
537B LDX 6 Y6(1) [NO. FORMAT ERROR
53M2 BRN RERR
546L NOTVAL
54L= LDX 6 Y7(1)
555W RERR NGN 7 1
55KG RER2
5656 COMERRX 6,7 [REPORT ERROR
565M ...[
5668 ...[
566P ...[
5674 ...NOT2 CALL 7 SPARA
5676 ...#UNS ECS
5678 ...NOT3 LDX 6 Y9(1)
567R ... BRN RCLOS
568# ...[
56*C ...VNUMERR
56*D ... LDX 6 Y6(1)
56*F ... BRN RCLOS
56*G ...UNPAIR
56*H ... LDX 6 Y14(1)
56*J ... BRN RCLOS
56*K ...XERANGE
56*L ... LDX 6 Y15(1)
56*M ... BRN RCLOS
56*T ...XNOJL LDX 6 Y21(1)
56*W ... BRN RCLOS
56*X ...[
56*Y ...[
56*^ ...XK3
56B4 ...[
56B7 ...XBRK CALL 5 VOPCLOS
56BH ...#
56BK ...XBRKIN
56BN ... COMBRKIN
56C9 ...[
56CQ ...[
56D? ...WRONG
56DS ... LDX 6 Y10(1)
56F* ...RCLOS
56FW ... CALL 5 VOPCLOS
56GC ... BRN RERR
56GY ...[
56HF ...[
56JQ Y1 +JXEXIST
574B Y2 +JNLFNF
57J2 Y3 +JUSNA
583L Y4 +JJOBNA
58H= Y5 +JPARMIS
592W Y6 +CHNUMERR
59GG Y7 +FWHSTAT
5=63 ...Y9 +APFERR
5=9Y ...Y10 +ASCOMBER
5=FB ...Y14 +ERUNPAIR
5=FF ...Y15 +ERANGE
5=FN ...Y21 +JSYSFILE
5=FQ #
5=^B # THE FOLLOWING ARE MESSAGE IDENTIFIERS
5?F2 #
5#XW ...Z3 +ASCMESS
5*CG #
5B#B ...#
5BBQ #END
^^^^ ...33556317000100000000