{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SETPG867)}}
====== SETPG867 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:CHNUMCOD|CHNUMCOD]], [[george:macro:DOFINDGV|DOFINDGV]], [[george:macro:DOFINDJV|DOFINDJV]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:PARANEXT|PARANEXT]], [[george:macro:PARAPASS|PARAPASS]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SPARANXT|SPARANXT]], [[george:macro:TESTHKL|TESTHKL]], [[george:macro:TESTHOOK|TESTHOOK]], [[george:macro:TESTREP|TESTREP]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREE|VFREE]]
22FL ... SEG SETPG,,CENT(INSTALLATION HOOKS),,G400
22^= [
23DW [ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23YG [
24D6 #
24XQ # THIS CHAPTER IS FOR G3PLUS-IH MK2
25CB #
25X2 # OVERFLOW FROM SETPC
26BL #
26W= SEGENTRY K1SETPG,XCMS [SP COMMAND SOURCE
27*W SEGENTRY K2SETPG,XGCO [SP GEORGE CORE
27TG SEGENTRY K3SETPG,XGLV [SP GLOBAL VARIABLE
28*6 SEGENTRY K4SETPG,XJBV [SP JOB VARIABLE
28SQ #
29#B # SP - COMMAND SOURCE
29S2 #
2=?L XOPSM 12H*OPERATORS
2=HD ...XBACK 8H*BACK
2=R= TEN4 +10000
2?=W XMOP 4H*MOP
2?QG XCI 4H*CI
2#=6 XCR 4H*CR
2#PQ XTR 4H*TR
2*9B X13 #13
2*P2 X30 #30
2B8L XO74 #74
2BN= XO77 #77
2C7W #
2CMG #
2D76 # ##################################################################
2DLQ #
2F6B # K K 1
2FL2 # K K 11
2G5L # K K 1
2GK= # K K 1
2H4W # KKK 1
2HJG # K K 1
2J46 # K K 1
2JHQ # K K 1
2K3B # K K 1
2KH2 #
2L2L # ##################################################################
2LG= #
2L^W XCMS
2MFG #
2M^6 # THIS ROUTINE SETS THE PARAMETER TO THE SOURCE FROM WHICH COMMANDS
2NDQ # ARE ISSUED. IF THE COMAND IS IN A HOOK THE PARAMETER IS SET TO
2NYB # THE SOURCE FROM WHICH THE HOOK WAS ISSUED
2PD2 #
2PXL [COMDAT TO HOLD 'NEW' PARAM
2QC= SETNCORE APARA-A1+10,3,COMDAT,CSETP
2QWW STO 3 AWORK1(2) [SAVE PTR TO COMDAT
2Q^F ... LDX 5 EXT+10(2)
2R44 ... ANDN 5 #7777 [X5 - TOP BREAK-IN LEVEL
2R5* ... STOZ 6
2R6M ... SEGENTRY K80SETPG
2R9= ... TESTHOOK XCMS0 [JUMP IF IN A HOOK
2R?T ... SEGENTRY K81SETPG
2RBG LDX 0 CPLEV(2)
2RD4 ... BZE 0 XCMS1
2RFL ... TXU 5 0
2RH8 ... BCC XCMS1
2RJQ ... SBN 0 1
2RR2 ... BZE 0 XCMS1 [BR IF LEVEL ABOVE CURRENT
2R^= ... TXU 5 0 [LEVEL IS CP LEVEL 0 OR
2S7G ... BCC XCMS1 [TOP BREAK-IN LEVEL
2S*Q LDX 3 FX2
2SG8 ... HUNT2J 3,CPB,CALAS,,XCMSERR [CALAS FOR SP COMMAND
2SLL ... HUNT2J 3,CPB,CALAS,,XCMSERR [CALAS FOR LEVEL ABOVE SP
2SR4 ... BRN XCMS01
2SXG ...XCMS0
2T3Y ... HUNT2 3,CPB,CALAS
2T8B ... LDX 7 CPBCPLEV(3)
2T#S ... SLL 7 2
2TF= ... SRL 7 2
2TKN ... BZE 7 XCMS1
2TQ6 ... TXU 7 5 [BR IF NOW AT CP LEVEL 0
2TWJ ... BCC XCMS1 [OR TOP BREAKIN LEVEL
2TYR ... BNZ 6 XCMS01
2W32 ... TESTHKL XCMS0,3
2W7D ...XCMS01
2W#= LDX 7 CPBFSD(3)
2WRW BPZ 7 XCMS2A [J IF SOURCE ANOTHER MACRO
2W^P ... LDX 7 CPBCPLEV(3)
2X7J ... BPZ 7 XCMSERR [SOURCE NOT COMMAND OR PROG
2XM8 ... LDN 6 1
2Y6S ... BRN XCMS0
2^PL XCMS2A
329= LDX 7 CPBFSD(3)
32NW ANDN 7 #77 [ISOLATE FILE HEIGHT
338G SMO FX2
33N6 LDN 3 FILERING [FPTR FOR FILERING
347Q XCMS2
34MB LDX 3 1(3) [GET NEXT ELEMENT (BACKWARD)
3572 BCT 7 XCMS2 [GET ELEMENT FOR FILE HEIGHT 1
35LL XCMS3
366= LDX 2 AWORK1(2) [LOOK AT CSETP BLOCK
36KW ADX 3 2(3)
375G LDX 3 BPTR(3) [X3 POINTS TO FCB
37K6 LDX 1 3 [X1 HOLDS COPY OF X3
384Q LDN 6 #12 [:
38JB DCH 6 APARA(2)
3942 BCHX 2 £
39HL LDN 6 FUSER1
3=3= CALL 0 XCMV [MOVE USER TO COMDAT BUT NOT END SPAC
3=GW LDN 6 #36 [.
3?2G DCH 6 APARA(2)
3?G6 BCHX 2 £
3?^Q LDN 6 FLOC1
3#FB CALL 0 XCMV [MOVE LOC. NAME TO COMDAT BUT NOT END
3#^2 XCMS7
3*DL LDN 6 #30 [(
3*Y= DCH 6 APARA(2)
3BCW BCHX 2 £
3BXG LDX 5 FGEN(3) [FGN
3CC6 LDN 6 0
3CWQ SMO FX1
3DBB DVR 5 TEN4
3DW2 LDCT 7 #200 [ROUND UP
3F*L MODE 1
3FT= LDN 4 4
3G#W XCMS8
3GSG CBD 6 APARA(2) [STORE FGN(DECIMAL) IN APARA
3H#6 BCHX 2 £
3HRQ BCT 4 XCMS8
3J?B LDN 4 4
3JR2 LDN 6 #37 [/
3K=L DCH 6 APARA(2)
3KQ= BCHX 2 £
3L9W XCMS11
3LPG LDCH 6 FLAN(3)
3M96 DCH 6 APARA(2)
3MNQ BCHX 3 £
3N8B BCHX 2 £
3NN2 BCT 4 XCMS11
3P7L XCMS12
3PM= LDN 6 #31 [)
3Q6W DCH 6 APARA(2)
3QLG LDN 1 37 [SET ANUM TO NO OF CHARS IN PARAM
3R66 SMO FX2
3RKQ LDX 2 AWORK1
3S5B STO 1 ANUM(2) [STORE CHAR. COUNT
3SK2 BRN XITA
3T4L XCMS1
3TJ= LDX 1 FX1
3W3W LDX 2 FX2
3WHG LDX 3 AWORK1(2) [X3 POINTS TO COMDAT
3X36 LDX 7 JSOURCE1(2)
3XGQ SRL 7 18 [JOBSOURCE=OPS?
3Y2B BNZ 7 XCMS1A
3Y3M ... LDX 7 CONTEXT(2)
3Y4Y ... ANDN 7 4
3Y69 ... BZE 7 XCMS1AA
3Y7G ... LDN 6 XBACK(1)
3Y8R ... LDN 7 APARA
3Y=4 ... ADX 7 3
3Y?* ... MOVE 6 2
3Y#L ... LDN 7 5
3Y*X ... STO 7 ANUM(3)
3YC8 ... BRN XITA
3YDF ...XCMS1AA
3YG2 LDX 7 XTR(1) [SOURCE = *TR
3Y^L BRN XCMS1X
3^F= XCMS1A
3^YW TXU 7 JTHREE
42DG BCS XCMS1B
42Y6 LDX 7 XCR(1) [*CR
43CQ BRN XCMS1X
43XB XCMS1B
44C2 TXU 7 X13(1) [MOP ON CBS
44WL BCC XCMS1C
45B= TXU 7 X30(1) [OR MBS
45TW BCS XCMS1D
46*G XCMS1C
46T6 LDX 7 XMOP(1)
47#Q BRN XCMS1X
47SB XCMS1D
48#2 TXU 7 XO74(1)
48RL BCS XCMS1E
49?= LDX 7 XCI(1) [*CI
49QW BRN XCMS1X
4==G XCMS1E
4=Q6 TXU 7 XO77(1) [J IF YES
4?9Q BCC XCOPS
4?PB LDX 7 JSOURCE1(2) [ERROR SHOULD NOT GET HERE
4#92 XCMS1X
4#NL STO 7 APARA(3)
4*8= LDN 7 4
4*MW STO 7 ANUM(3) [SET PARAM COUNT TO 4
4B7G BRN XITA [RETURN TO SETPARAM
4BM6 XCOPS
4C6Q LDN 6 XOPSM(1)
4CLB LDN 7 APARA
4D62 ADX 7 3
4DKL MOVE 6 3 [MOVE *OPERATORS TO COMDAT
4F5= LDN 7 10
4FJW STO 7 ANUM(3) [SET PARAM COUNT TO 1O
4G4G BRN XITA [RETURN TO SETPARAM
4GJ6 #
4H3Q # THIS ROUTINE MOVES NAMES TO COMDAT
4HHB #
4J32 XCMV
4JGL LDN 4 12
4K2= ADX 3 6 [X3 NOW POINTS TO NAME SOURCE
4KFW XCMV1
4K^G LDCH 6 0(3)
4LF6 DCH 6 APARA(2)
4LYQ BCHX 2 £
4MDB BCHX 3 £
4MY2 BCT 4 XCMV1
4NCL LDX 3 1 [RESTORE X3
4NX= EXIT 0 0
4PBW XCMSERR
4PWG GEOERR 1,CMSERROR
4QB6 #
4QTQ #
4R*B #
4RT2 #
4S#L #PAGE
4SS= # SP - GEORGE CORE
4T?W #
4TRG MAGIC +7036875
4W?6 MINUS #35
4WQQ SPEC 8H-8388608
4X=B #
4XQ2 #
4Y9L XDEC
4YP= SBX 5 FX1
4^8W STO 5 GEN0
4^NG SMO FX2
5286 LDN 2 AWORK1 [RESULT ADDRESS
52MQ STOZ 0(2)
537B STOZ 1(2)
53M2 LDN 7 1 [INITIALISE COUNT
546L BPZ 4 POZ [J IF RESULT NON-NEG
54L= ADN 7 1 [ELSE UP CT FOR MINUS
555W NGX 4 4
55KG BNG 4 SPECIAL [TREAT #40000000#
5656 LDX 6 MINUS(1)
56JQ DCH 6 0(2) [INSERT MINUS
574B BCHX 2 £ [STEP PTR
57J2 POZ
583L MPY 4 MAGIC(1) [CONV TO DL FRACTION
58H= LDN 0 7
592W MODE 0
59GG XCDR
5=26 CBD 4 0(2)
5=FQ LDCH 6 0(2)
5=^B BNZ 6 YOKO
5?F2 BCT 0 XCDR [DO NEXT
5?YL BRN WEND
5#D= ONO BCHX 2 £
5#XW CBD 4 0(2)
5*CG ADN 7 1 [UPDATE CHAR CT
5*X6 YOKO
5BBQ BCT 0 ONO
5BWB WEND
5CB2 LDX 4 7
5CTL ADN 4 3
5D*= SRL 4 2
5DSW BRN XITDC
5F#G SPECIAL
5FS6 LDN 1 SPEC(1) [-8388608
5G?Q MOVE 1 2
5GRB LDN 7 8
5H?2 LDN 4 2
5HQL XITDC
5J== LDX 5 GEN0
5JPW ADX 5 FX1
5K9G EXIT 5 0
5KP6 XCONV
5L8Q SBX 5 FX1
5LNB CHNUMCOD 1,3
5M82 TESTREP CHNUMERR,XCONV1
5MML ADX 5 FX1
5N7= EXIT 5 1 [NORMAL EXIT
5NLW XCONV1
5P6G ADX 5 FX1
5PL6 EXIT 5 0
5Q5Q #
5QKB # #############################################################
5R52 #
5RJL # K K 222
5S4= # K K 2 2
5SHW # K K 2
5T3G # K K 2
5TH6 # KKK 2
5W2Q # K K 2
5WGB # K K 2
5X22 # K K 2
5XFL # K K 2222222
5X^= #
5YDW # #############################################################
5YYG #
5^D6 XGCO
5^XQ SETNCORE 64,3,COMDAT,CSETP
62CB STOZ ANUM(3)
62X2 LDN 7 2
63BL PARALYSE #34,,7 [SPLIT PARAM FOLLOWING GCO
63W= XGCO1
64*W PARANEXT [GET NEXT LOCATION
64TG MHUNT 3,CPB,CUNI
65*6 LDX 7 ANUM(3)
65SQ BNG 7 XITA
66#B BZE 7 XERR [ERROR IF NULL
66S2 CALL 5 XCONV [CONV START TO BIN.
67?L BRN XERR1 [ERROR RETURN
67R= LDX 7 ACOMMUNE1(2)
68=W STO 7 AWORK3(2)
68QG PARAPASS
69=6 MHUNT 3,CPB,CUNI
69PQ LDX 7 ANUM(3)
6=9B BNG 7 XONLY
6=P2 BZE 7 XERR [ERROR IF NULL
6?8L CALL 5 XCONV [NO. OF LOCS. TO BIN
6?N= BRN XERR1 [ERROR RETURN
6#7W LDX 7 ACOMMUNE1(2)
6#MG #
6*76 # X7 HOLDS NO. OF LOCS.
6*LQ #
6B6B BNG 7 XERR
6BL2 BRN XRANGE
6C5L XONLY
6CK= LDN 7 1
6D4W STO 7 ACOMMUNE1(2)
6DJG XRANGE
6F46 ADX 7 AWORK3(2) [ADD IN START LOC.
6FHQ SBN 7 2
6G3B SBX 7 CORES
6GH2 BPZ 7 XERR [ERROR IF OUT OF RANGE
6H2L LDX 7 AWORK3(2)
6HG= BNG 7 XERR [ERROR IF START LOC, -VE
6H^W HUNT 3,COMDAT,CSETP
6JFG NGN 6 1
6J^6 STO 6 AWORK4(2) [INITIALISE SUPP. MOD
6KDQ XGCO2
6KYB LDX 2 FX2
6LD2 LDX 6 ACOMMUNE1(2) [NO. OF LOCS.
6LXL SBN 6 1
6MC= BNG 6 XGCO5 [NO MORE
6MWW STO 6 ACOMMUNE1(2)
6NBG LDX 6 AWORK4(2)
6NW6 ADN 6 1
6P*Q STO 6 AWORK4(2)
6PTB ADX 6 AWORK3(2) [NOW X6 IS ADDR REQUIRED
6Q*2 SMO 6
6QSL LDX 4 0
6R#= CALL 5 XDEC [GEORGE CORE LOC. IN DEC.
6RRW LDX 2 FX2
6S?G LDX 0 7
6SR6 ADX 0 ANUM(3)
6T=Q ADN 0 3
6TQB SRL 0 2 [ROUND TO WDS
6W=2 TXL 0 ALOGLEN(3) [ANY ROOM?
6WPL BCS XGCO3 [Y
6X9= ADN 0 32
6XNW ALTLEN 3,0,COMDAT,CSETP
6Y8G XGCO3
6YN6 LDX 5 ANUM(3)
6^7Q BZE 5 XGCO4 [J IF 1ST TIME
6^MB LDN 6 1
7272 ADS 6 ANUM(3)
72LL LDN 6 #34
736= SRC 5 2
73KW ADX 3 5 [BUILD CHAR MOD
745G DCH 6 APARA(3) [SEPERATING COMMA
74K6 BCHX 3 £
754Q XGCO4
75JB ADN 2 AWORK1
7642 ADN 3 APARA
76HL SMO 7
773= MVCH 2 0
77GW MHUNT 3,COMDAT,CSETP
782G ADS 7 ANUM(3)
78G6 BRN XGCO2
78^Q XGCO5
79FB MFREE CPB,CMULTI
79^2 MFREE CPB,CUNI
7=DL VFREE CPB,CUNI
7=Y= BRN XGCO1
7?CW #
7?XG #
7#C6 #PAGE
7#WQ #
7*BB # SP --- GLOBAL & JOB VARIABLES
7*W2 #
7B*L #DEF VLOCK=A1+1 [LOCKOUT WORD
7BT= #DEF VDATALEN=A1+2 [POINTER TO END OF USED SPACE,RELATIV
7C#W # ENTRY FORMAT
7CSG #DEF VHEADER=0 [ENTRY HEADER
7D#6 #DEF REDTAPE2=1 [2ND WORD OF RED TAPE
7DRQ #DEF VNAME=2 [3 WORD VARIABLE NAME
7F?B #DEF VDATA=5 [VALUE DATA
7FR2 #
7G=L #
7GQ= # #############################################################
7H9W #
7HPG # K K 3333
7J96 # K K 3 3
7JNQ # K K 3
7K8B # K K 3
7KN2 # KKK 33
7L7L # K K 3
7LM= # K K 3
7M6W # K K 3 3
7MLG # K K 3333
7N66 #
7NKQ # #############################################################
7P5B #
7PK2 XGLV
7Q4L LDN 4 2
7QJ= CALL 7 XHNT1 [DECODE NAME
7R3W CHECKLFN2 XERR,XERR,3 [CHECK FORMAT
7RHG MHUNT 3,CPB,CUNI
7S36 LDX 0 ACES [SPACE-FILL AWORK AREA
7SGQ STO 0 AWORK1(2)
7T2B STO 0 AWORK2(2)
7TG2 STO 0 AWORK3(2)
7T^L LDN 5 APARA(3) [FROM ADDRESS
7WF= LDN 6 AWORK1(2) [TO ADDRESS
7WYW SMO ANUM(3)
7XDG MVCH 5 0 [MOVE IN NAME
7XY6 XGLV3
7YCQ CALL 7 SLOCGV [LOCATE ENTRY
7YXB BNG 3 XITN [NULL RESULT
7^C2 LDX 5 VHEADER(3) [HEADER
7^WL SBN 5 VDATA-VHEADER [-RED TAPE+NAME AREA
82B= BZE 5 XITN [NO DATA-NULL RESULT
82TW ADN 5 APARA-A1
83*G SETUPCORE 5,1,COMDAT,CSETP
83T6 SBN 5 APARA-A1
84#Q CALL 7 SLOCGV [RELOCATE ENTRY
84SB BPZ 2 XGLV1 [J IF NOT NULL
85#2 STOZ ANUM(1) [SET O/P NULL
85RL BRN XITA [AND EXIT
86?= XGLV1
86QW LDX 4 VHEADER(3)
87=G SBN 4 VDATA-VHEADER [LENGTH OF DATA
87Q6 TXL 5 4
889Q BCC XGLV2 [J IF BLOCK BIG ENOUGH
88PB FREECORE 1 [ELSE FREE IT
8992 BRN XGLV3 [AND TRY AGAIN
89NL XGLV2
8=8= SLL 4 2 [LENGTH IN WORDS
8=MW LDCH 0 REDTAPE2(3) [SPARE CHARS
8?7G SBX 4 0
8?M6 STO 4 ANUM(1) [STORE COUNT
8#6Q LDN 2 VDATA(3) [START OF DATA
8#LB LDN 3 APARA(1) [O/P BLOCK ADDRESS
8*62 SMO 4
8*KL MVCH 2 0 [MOVE IN DATA
8B5= BZE 0 XGLV4 [J IF NO SPARE
8BJW LDN 2 ACES
8C4G SMO 0
8CJ6 MVCH 2 0 [FILL WITH SPACES
8D3Q XGLV4
8DHB BRN XITA [AND EXIT
8F32 SLOCGV
8FGL DOFINDGV AWORK1(2),3 [LOCATE ENTRY
8G2= EXIT 7 0
8GFW #PAGE
8G^G #
8HF6 # #############################################################
8HYQ #
8JDB # K K 4
8JY2 # K K 44
8KCL # K K 4 4
8KX= # K K 4 4
8LBW # KKK 4 4
8LWG # K K 4444444
8MB6 # K K 4
8MTQ # K K 4
8N*B # K K 4
8NT2 #
8P#L # #############################################################
8PS= #
8Q?W XJBV
8QRG LDN 4 2
8R?6 CALL 7 XHNT1 [DECODE NAME
8RQQ CHECKLFN2 XERR,XERR,3 [CHECK FORMAT
8S=B MHUNT 3,CPB,CUNI
8SQ2 LDX 0 ACES [SPACE-FILL AWORK AREA
8T9L STO 0 AWORK1(2)
8TP= STO 0 AWORK2(2)
8W8W STO 0 AWORK3(2)
8WNG LDN 5 APARA(3) [FROM ADDRESS
8X86 LDN 6 AWORK1(2) [TO ADDRESS
8XMQ SMO ANUM(3)
8Y7B MVCH 5 0 [MOVE IN NAME
8YM2 XJBV3
8^6L CALL 7 SLOCJV [LOCATE ENTRY
8^L= BNG 3 XITN [NULL RESULT
925W LDX 5 VHEADER(3) [HEADER
92KG SBN 5 VDATA-VHEADER [-RED TAPE+NAME AREA
9356 BZE 5 XITN [NO DATA-NULL RESULT
93JQ ADN 5 APARA-A1
944B SETUPCORE 5,1,COMDAT,CSETP
94J2 SBN 5 APARA-A1
953L CALL 7 SLOCJV [RELOCATE ENTRY
95H= BPZ 2 XJBV1 [J IF NOT NULL
962W STOZ ANUM(1) [SET O/P NULL
96GG BRN XITA [AND EXIT
9726 XJBV1
97FQ LDX 4 VHEADER(3)
97^B SBN 4 VDATA-VHEADER [LENGTH OF DATA
98F2 TXL 5 4
98YL BCC XJBV2 [J IF BLOCK BIG ENOUGH
99D= FREECORE 1 [ELSE FREE IT
99XW BRN XJBV3 [AND TRY AGAIN
9=CG XJBV2
9=X6 SLL 4 2 [LENGTH IN WORDS
9?BQ LDCH 0 REDTAPE2(3) [SPARE CHARS
9?WB SBX 4 0
9#B2 STO 4 ANUM(1) [STORE COUNT
9#TL LDN 2 VDATA(3) [START OF DATA
9**= LDN 3 APARA(1) [O/P BLOCK ADDRESS
9*SW SMO 4
9B#G MVCH 2 0 [MOVE IN DATA
9BS6 BZE 0 XJBV4 [J IF NO SPARE
9C?Q LDN 2 ACES
9CRB SMO 0
9D?2 MVCH 2 0 [FILL WITH SPACES
9DQL XJBV4
9F== BRN XITA [AND EXIT
9FPW SLOCJV
9G9G DOFINDJV AWORK1(2),3 [LOCATE ENTRY
9GP6 EXIT 7 0
9H8Q #
9HNB XHNT1
9J82 SBX 7 FX1
9JML SPARANXT ,,4
9K7= BRN XHNT2
9KLW XHNT
9L6G SBX 7 FX1
9LL6 PARANEXT ,,4
9M5Q XHNT2
9MKB TESTREP UNPAIR,XERR
9N52 ADX 7 FX1
9NJL HUNT 3,CPB,CUNI
9P4= EXIT 7 0
9PHW XITN
9Q3G LDN 4 0
9QH6 LDN 7 0
9R2Q LDN 5 AWORK1
9RGB XITC
9S22 ADN 4 2
9SFL SETUPCORE 4,3,COMDAT,CSETP [PARAM BLK
9S^= STO 7 ANUM(3)
9TDW BZE 7 XITA
9TYG SMO 5
9WD6 LDN 1 0(2)
9WXQ LDN 2 APARA(3)
9XCB SMO 7
9XX2 MVCH 1 0 [PARAM TO BE INSERTED
9YBL SBN 4 2
9YW= SLL 4 2
9^*W SBX 4 7
9^TG BZE 4 XITA
=2*6 LDN 1 ACES
=2SQ SMO 4
=3#B MVCH 1 0
=3S2 XITA
=4?L UP [OK
=4R= #
=5=W XERR
=5QG UPPLUS 1 [ PARAMETER FORMAT ERROR
=6=6 #
=6PQ XERR1
=79B UPPLUS 2 [NUMBER FORMAT ERROR
=7P2 #
=88L #
=8N= #END
^^^^ ...070260020008