{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: SHARE866)}}
====== SHARE866 ======
(George Source)
**Macros used:** [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INFORMX|INFORMX]], [[george:macro:JCAFSDV|JCAFSDV]], [[george:macro:JCMESH|JCMESH]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JNCMESH|JNCMESH]], [[george:macro:JSWOUT|JSWOUT]], [[george:macro:JWTBSW|JWTBSW]], [[george:macro:LADDP|LADDP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PARAMOVE|PARAMOVE]], [[george:macro:PARSORT|PARSORT]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SHAREOFF|SHAREOFF]], [[george:macro:SHAREON|SHAREON]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:TRACE|TRACE]]
22FL ... SEG SHARE,866,S.SEXTON
22^= ... SEGENTRY K1SHARE,QK1
232H ...#UNS ASHARE1
233S ...#SKI
2355 ...(
236D ...SMESS1 +ESHLST1
23?L ...#
23DS ...QK1 LDX 0 SMESS1(1)
23L2 ... STO 0 AWORK1(2)
23R8 ... COMERRX AWORK1(2)
23R9 ...)
23R= ...#UNS ASHARE1
23R? ...(
23R# ...#
23R* ...# DATA AREAS SET UP:
23RB ...# AWORK1 +VE IF SHARE ON
23RC ...# -VE IF SHARE OFF
23RD ...# AWORK2 = D.L. PTR
23RF ...# AWORK3 = APIA PTR
23RG ...# AWORK4 = GEOG UNIT NO
23RH ...#
23RJ ...#
23RK ...PDA +26
23RL ...PSTR 4H00ON
23RM ... 4H00OF
23RN ...#
23RP ...# MESSAGE IDENTIFIERS
23RQ ...#
23RR ...PJENVNT +JENVMUSTNT
23RT ...PJSETP8 +JSETP8 [1ST
23RW ...PJPARMIS +JPARMIS [ERROR-PARAM MISSING
23RX ...PAPFERR +APFERR [FORMAT ERROR
23RY ...PESHNOTDA +ESHNOTDA [ERROR-MUST BE DA DEVICE
23R^ ...PESWOUT +ESWOUT [ERROR-UNIT SWITCHED OUT
23S2 ...PWAITSWIT +EWAITSWIT [ERROR-WAITING TO BE SW OUT
23S3 ...PCAFS +ECAFS [ERROR-CONNECTED TO CAFS
23S4 ...PCMESH +CMESH [UNIT NN IS CME SHARED
23S5 ...PESHONREJ +ESHONREJ [ERROR-CANNOT BE CME SHARED
23S6 ...PDMEDED +CDMEDED [UNIT NN IS DME DEDICATED
23S7 ...PESHOFFREJ +ESHOFFREJ [ERROR-SHARE OFF REJECTED
23S8 ...PTOOMANY +ETOOMANY [ERROR-ONLY 1 PERI DESC ALLOWED
23S9 ...#
23S= ...#
23S? ...# S/R TO OUTPACK UNIT NO PARAM FROM AWORK4
23S# ...# ON EXIT X1=FX1, X2=FX2, X0 CORRUPTED
23S* ...#
23SB ...XOUTOPNO
23SC ... SBX 7 FX1
23SD ... OUTPACK AWORK4(2),1,GEOPER
23SF ... ADX 7 FX1
23SG ... EXIT 7 0
23SH ...#
23SJ ...# S/R TO INFORM MESSAGE IN X6
23SK ...# ON EXIT X1=FX1, X2=FX2, X0 + X5 CORRUPTED
23SL ...#
23SM ...XINFORM
23SN ... SBX 7 FX1
23SP ... LDN 5 1
23SQ ... INFORMX 5,6,1
23SR ... ADX 7 FX1
23SS ... EXIT 7 0
23ST ...#
23SW ...QK1
23SX ... JENVNOT YENV,CME,EXCL
23SY ... SPARAPAS [GET 1ST PARAM
23S^ ... MHUNT 3,CPB,CUNI
23T2 ... LDX 0 ANUM(3)
23T3 ... BNG 0 Y1 [ERROR IF 1ST PARAM MISSING
23T4 ... BZE 0 Y1 [OR NULL
23T5 ... ANDN 0 #7777
23T6 ... SBN 0 2
23T7 ... BNG 0 Y2 [FORMAT ERROR
23T8 ... LDX 0 APARA(3)
23T9 ... SRL 0 12
23T= ... TXU 0 PSTR(1)
23T? ... BCC SHON [^ IF SHARE ON
23T# ... TXU 0 PSTR+1(1)
23T* ... BCS Y2 [^ IF NOT SHARE OFF
23TB ... NGN 0 1
23TC ... BRN SSTO
23TD ...SHON
23TF ... LDN 0 6
23TG ...SSTO
23TH ... STO 0 AWORK1(2)
23TJ ... LDX 0 ANUM(3)
23TK ... ANDN 0 #7777
23TL ... PARAMOVE 0 [THROW AWAY 1ST PARAM
23TM ... PARSORT YBRKN,ALL,INCOUT,GROPE
23TN ... HUNTW 1,CPAR,JSCE [IF NO PARAM BLOCK FINISH AS
23TP ... BNG 1 XENDA [PARSORT WILL HAVE O/P A MESSAGE
23TQ ... LDX 3 JSCEP(1)
23TR ... STO 3 AWORK2(2) [D.L. PTR
23TS ... FREECORE 1
23TT ... HUNTW 1,CPAR,JSCE
23TW ... BPZ 1 Y3 [ERROR IF TOO MANY PARAMS
23TX ... LDX 1 FX1
23TY ... LGEOG 3,4
23T^ ... STO 4 AWORK4(2)
23W2 ... LTYPE 3,4
23W3 ... TXU 4 PDA(1)
23W4 ... BCS YNOTDA [ERROR IF NOT DA DEVICE
23W5 ... LADDP 3,4
23W6 ... STO 4 AWORK3(2) [APIA PTR
23W7 ... JSWOUT AWORK2(2),YSWOUT [ERROR IF SWITCHED OUT
23W8 ... LDX 0 AWORK1(2)
23W9 ... BNG 0 TSHOFF [^ IF SHARE OFF
23W= ...TSHON
23W? ... TRACE AWORK4(2),SHAREON
23W# ... JWTBSW AWORK2(2),YWTBSW [OR IF WAITING TO BE SW OUT
23W* ... JCAFSDV AWORK2(2),YCAFS [OR CONNECTED TO CAFS
23WB ... LDX 3 AWORK3(2)
23WC ... LDX 3 BSUNIT3(3)
23WD ... ANDN 3 #10
23WF ... BNZ 3 YTWIN [GEOERR IF STATUS CHANGE IN PROG
23WG ... JCMESH AWORK2(2),SHONOK
23WH ... SHAREON AWORK2(2),SHONREJ
23WJ ...SHONOK
23WK ... LDX 6 PCMESH(1)
23WL ...XEND
23WM ... CALL 7 XOUTOPNO
23WN ... CALL 7 XINFORM
23WP ...XENDA
23WQ ... ENDCOM
23WR ...#
23WS ...SHONREJ
23WT ... LDX 6 PESHONREJ(1)
23WW ... BRN YCMERA
23WX ...#
23WY ...TSHOFF
23W^ ... TRACE AWORK4(2),SHAREOFF
23X2 ... JNCMESH AWORK2(2),SHOFFOK
23X3 ... SHAREOFF AWORK2(2),SHOFFREJ
23X4 ...SHOFFOK
23X5 ... LDX 6 PDMEDED(1)
23X6 ... BRN XEND
23X7 ...SHOFFREJ
23X8 ... LDX 6 PESHOFFREJ(1)
23X9 ... BRN YCMERA
23X= ...#
23X? ...# ERROR LABELS
23X# ...#
23X* ...YENV
23XB ... LDX 6 PJENVNT(1)
23XC ... BRN YCMERB
23XD ...YCMER
23XF ... COMERRX 6,7
23XG ...Y1
23XH ... LDX 7 PJSETP8(1)
23XJ ... LDX 6 PJPARMIS(1) [1ST PARAM MISSING
23XK ... BRN YCMER
23XL ...Y2
23XM ... LDX 6 PAPFERR(1) [FORMAT ERROR
23XN ... BRN YCMERB
23XP ...Y3 SMO FX1
23XQ ... LDX 6 PTOOMANY
23XR ... BRN YCMERB
23XS ...YBRKN
23XT ... GEOERR 1,BISHARE
23XW ...YNOTDA
23XX ... LDX 6 PESHNOTDA(1) [MUST BE DA DEVICE
23XY ...YCMERA
23X^ ... CALL 7 XOUTOPNO
23Y2 ...YCMERB
23Y3 ... COMERRX 6
23Y4 ...YSWOUT
23Y5 ... LDX 6 PESWOUT(1) [UNIT SW OUT
23Y6 ... BRN YCMERA
23Y7 ...YWTBSW
23Y8 ... LDX 6 PWAITSWIT(1) [UNIT WAITING TO BE SW OUT
23Y9 ... BRN YCMERA
23Y= ...YCAFS
23Y? ... LDX 6 PCAFS(1) [UNIT CONNECTED TO CAFS
23Y# ... BRN YCMERA
23Y* ...YTWIN
23YB ... GEOERR 1,NOTCME
23YC ...)
23YD ...#
23YG ...#END
^^^^ ...676126560004